:: Integral of Continuous Three Variable Functions
:: by Noboru Endou and Yasunari Shidama
::
:: Received June 18, 2024
:: Copyright (c) 2024-2026 Association of Mizar Users
:: (Stowarzyszenie Uzytkownikow Mizara, Bialystok, Poland).
:: This code can be distributed under the GNU General Public Licence
:: version 3.0 or later, or the Creative Commons Attribution-ShareAlike
:: License version 3.0 or later, subject to the binding interpretation
:: detailed in file COPYING.interpretation.
:: See COPYING.GPL and COPYING.CC-BY-SA for the full text of these
:: licenses, or see http://www.gnu.org/licenses/gpl.html and
:: http://creativecommons.org/licenses/by-sa/3.0/.
environ
vocabularies MEASUR12, NUMBERS, XXREAL_0, SUBSET_1, CARD_1, ARYTM_3, ARYTM_1,
RELAT_1, REAL_1, FUNCT_1, XBOOLE_0, TARSKI, ZFMISC_1, PROB_1, SUPINF_2,
PARTFUN1, MESFUNC5, MESFUNC1, MEASUR10, MEASUR11, COMPLEX1, MESFUN12,
ORDINAL2, INTEGRA1, INTEGRA5, MEASURE6, NAT_1, CARD_3, ORDINAL1,
MEASURE5, XXREAL_1, XREAL_0, XXREAL_2, FCONT_1, MEMBERED, REALSET1,
SEQ_4, PRE_TOPC, NORMSP_1, NFCONT_2, SQUARE_1, DUALSP02, RCOMP_1,
CFCONT_1, RAT_1, METRIC_1, FCONT_2;
notations TARSKI, XBOOLE_0, ZFMISC_1, SUBSET_1, FUNCT_1, ORDINAL1, RELSET_1,
XTUPLE_0, PARTFUN1, MCART_1, FUNCT_2, BINOP_1, DOMAIN_1, CARD_3, NUMBERS,
MEMBERED, XXREAL_3, XCMPLX_0, XXREAL_0, SQUARE_1, XREAL_0, RAT_1, NAT_1,
VALUED_1, COMSEQ_2, XXREAL_2, EXTREAL1, COMPLEX1, MESFUNC1, FCONT_1,
FCONT_2, SUPINF_1, SUPINF_2, PROB_1, RCOMP_1, MEASURE5, MEASUR12,
MESFUNC5, MESFUNC6, INTEGRA1, INTEGRA5, MEASUR10, MEASUR11, MESFUN12,
SEQ_4, STRUCT_0, ALGSTR_0, PRE_TOPC, NORMSP_0, NORMSP_1, NFCONT_1,
LOPBAN_5, PRVECT_3, PRVECT_4, NFCONT_2, DUALSP02;
constructors EXTREAL1, SUPINF_1, MESFUNC2, MEASUR11, MESFUN12, MESFUNC6,
DOMAIN_1, FCONT_1, FCONT_2, MEASUR12, INTEGRA1, COMSEQ_2, NEWTON,
INTEGRA5, SEQ_4, BINOP_2, SQUARE_1, NFCONT_1, PRVECT_4, NFCONT_2,
DUALSP02, LOPBAN_5, NDIFF_8, LPSPACE1, MESFUN16;
registrations ORDINAL1, XBOOLE_0, RELAT_1, SUBSET_1, XREAL_0, NAT_1, NUMBERS,
VALUED_0, RELSET_1, MEASURE1, XXREAL_3, MEMBERED, XXREAL_2, SQUARE_1,
FCONT_1, TOPGEN_4, STRUCT_0, NORMSP_0, NORMSP_1, PRVECT_3, PRVECT_4,
RAT_1, FUNCT_2, COMPLEX1, MEASURE5, FOMODEL0;
requirements BOOLE, SUBSET, NUMERALS, REAL, ARITHM;
equalities RCOMP_1, MEASUR10, BINOP_1, MESFUNC6, INTEGRA5, ALGSTR_0, NORMSP_0,
PRVECT_3, PRVECT_4, XTUPLE_0, SQUARE_1, ZFMISC_1, DUALSP02, LOPBAN_5;
expansions TARSKI, XBOOLE_0, MESFUNC1, MEASURE1, FCONT_1, MESFUNC6, INTEGRA5,
NFCONT_1, NFCONT_2;
theorems XBOOLE_0, FUNCT_1, XXREAL_0, XBOOLE_1, XXREAL_3, FUNCT_2, RELAT_1,
MESFUNC5, EXTREAL1, PARTFUN1, MESFUNC1, SUPINF_2, MEASUR10, SUBSET_1,
MEASUR11, MESFUN12, RELSET_1, MESFUNC6, TARSKI, ZFMISC_1, XREAL_1,
PROB_1, ORDINAL1, XTUPLE_0, CARD_3, PRVECT_3, XREAL_0, MESFUN13,
MESFUN14, FINSUB_1, MEASUR12, EUCLID, COMPLEX1, FCONT_1, VALUED_1,
INTEGRA5, RCOMP_1, RFUNCT_1, INTEGRA6, XCMPLX_1, MEASURE5, NDIFF_8,
SEQ_4, RLVECT_1, XXREAL_2, CARD_4, NORMSP_0, NORMSP_1, NFCONT_1,
NFCONT_2, DUALSP03, MEMBERED, RAT_1, PRVECT_4, SQUARE_1, XXREAL_1,
FCONT_2, MESFUN16;
schemes FUNCT_2;
begin :: Preliminaries
Lm1:
for x,a be Real ex r be Real st 0 < r & x in ]. a-r,a+r .[
proof
let x,a be Real;
consider r be Real such that
A1: |.x-a.| < r by XREAL_1:1;
take r;
thus 0 < r by A1;
thus x in ]. a-r,a+r .[ by A1,RCOMP_1:1;
end;
Lm2:
for x,a,b be Real st a <= b holds ]. x-a,x+a .[ c= ]. x-b,x+b .[
proof
let x,a,b be Real;
assume
A1: a <= b;
now let r be Real;
assume r in ]. x-a,x+a .[; then
A2: x-a < r & r < x+a by XXREAL_1:4;
x-b <= x-a by A1,XREAL_1:13; then
A3: x-b < r by A2,XXREAL_0:2;
x+a <= x+b by A1,XREAL_1:7; then
r < x+b by A2,XXREAL_0:2;
hence r in ].x-b,x+b.[ by A3;
end;
hence thesis;
end;
theorem Th1:
for X,Y,Z be RealNormSpace, u be Point of [:X,Y,Z:], x be Point of X,
y be Point of Y, z be Point of Z st u = [x,y,z] holds
||.u.|| <= ||.x.|| + ||.y.||+ ||.z.||
& ||.x.|| <= ||.u.|| & ||.y.|| <= ||.u.|| & ||.z.|| <= ||.u.||
proof
let X,Y,Z be RealNormSpace, u be Point of [:X,Y,Z:], x be Point of X,
y be Point of Y, z be Point of Z;
assume u = [x,y,z]; then
A1: ||.u.|| = sqrt(||.x.||^2 + ||.y.||^2+ ||.z.||^2) by PRVECT_4:9;
||.x.||^2 + ||.y.||^2 + ||.z.||^2 + 0
<= ( ||.x.||^2 + ||.y.||^2 + ||.z.||^2 ) + ( 2*||.x.||) * ||.y.||
by XREAL_1:7; then
||.x.||^2 + ||.y.||^2 + ||.z.||^2 + 0
<= ( ||.x.||^2 + ||.y.||^2 + ||.z.||^2) + ( 2 * ||.x.||) * ||.y.||
+ ( 2 * ||.y.||) * ||.z.|| by XREAL_1:7; then
||.x.||^2 + ||.y.||^2 + ||.z.||^2 + 0
<= ( ||.x.||^2 + ||.y.||^2 + ||.z.||^2) + ( 2 * ||.x.||) * ||.y.||
+ ( 2 * ||.y.||) * ||.z.||+ ( 2 * ||.x.||) * ||.z.||
by XREAL_1:7; then
sqrt(||.x.||^2 + ||.y.||^2 + ||.z.||^2)
<= sqrt(( ||.x.|| + ||.y.|| + ||.z.|| ) ^2 ) by SQUARE_1:26;
hence ||.u.|| <= ||.x.|| + ||.y.||+ ||.z.|| by A1,SQUARE_1:22;
||.x.||^2 <= ||.x.||^2 + ||.y.||^2
& ||.x.||^2 + ||.y.||^2 <= ||.x.||^2 + ||.y.||^2 + ||.z.||^2
by XREAL_1:31; then
||.x.||^2 <= ||.x.||^2 + ||.y.||^2 + ||.z.||^2 by XXREAL_0:2; then
sqrt(||.x.||^2) <= sqrt(||.x.||^2 + ||.y.||^2 + ||.z.||^2) by SQUARE_1:26;
hence ||.x.|| <= ||.u.|| by A1,SQUARE_1:22;
||.y.||^2 <= ||.x.||^2 + ||.y.||^2
& ||.x.||^2 + ||.y.||^2 <= ||.x.||^2 + ||.y.||^2 + ||.z.||^2
by XREAL_1:31; then
||.y.||^2 <= ||.x.||^2 + ||.y.||^2 + ||.z.||^2 by XXREAL_0:2; then
sqrt(||.y.||^2) <= sqrt(||.x.||^2 + ||.y.||^2 + ||.z.||^2) by SQUARE_1:26;
hence ||.y.|| <= ||.u.|| by A1,SQUARE_1:22;
sqrt(||.z.||^2) <= sqrt(||.x.||^2 + ||.y.||^2 + ||.z.||^2)
by SQUARE_1:26,XREAL_1:31;
hence ||.z.|| <= ||.u.|| by A1,SQUARE_1:22;
end;
theorem Th2:
for I,J,K be closed_interval Subset of REAL,
E be Subset of [:[:RNS_Real,RNS_Real:],RNS_Real:] st E = [:[:I,J:],K:]
holds E is compact
proof
let I,J,K be closed_interval Subset of REAL,
E be Subset of [:[:RNS_Real,RNS_Real:],RNS_Real:];
assume
A1: E = [:[:I,J:],K:];
set S = [:[:RNS_Real,RNS_Real:],RNS_Real:];
reconsider AB = [:I,J:] as Subset of [:RNS_Real,RNS_Real:];
reconsider C = K as Subset of RNS_Real;
AB is compact & C is compact by MESFUN16:7,9;
hence E is compact by A1,MESFUN16:8;
end;
theorem Th3:
for f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL, E be set st
f = g & E c= dom f holds
f is_uniformly_continuous_on E iff
for e be Real st 0 < e ex r be Real st 0 < r
& for x1,x2,y1,y2,z1,z2 be Real st [x1,y1,z1] in E & [x2,y2,z2] in E
& |.x2-x1.| < r & |.y2-y1.| < r & |.z2-z1.| < r holds
|. g.([x2,y2,z2])-g.([x1,y1,z1]) .| < e
proof
let f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL, E be set;
assume that
A1: f = g and
A2: E c= dom f;
hereby assume
A3: f is_uniformly_continuous_on E;
thus for e be Real st 0 < e ex r be Real st 0 < r
& for x1,x2,y1,y2,z1,z2 be Real st [x1,y1,z1] in E & [x2,y2,z2] in E
& |.x2-x1.| < r & |.y2-y1.| < r & |.z2-z1.| < r holds
|. g.([x2,y2,z2])-g.([x1,y1,z1]) .| < e
proof
let e be Real;
assume 0 < e; then
consider r be Real such that
A4: 0 < r
& for p1,p2 be Point of [:[:RNS_Real,RNS_Real:],RNS_Real:] st
p1 in E & p2 in E & ||. p1-p2 .|| < r holds ||. f/.p1-f/.p2 .|| < e
by A3;
set r1 = r/3;
take r1;
thus 0 < r1 by A4,XREAL_1:222;
let x1,x2,y1,y2,z1,z2 be Real;
assume
A5: [x1,y1,z1] in E & [x2,y2,z2] in E
& |.x2-x1.| < r1 & |.y2-y1.| < r1 & |.z2-z1.| < r1;
reconsider xx1=x1,yy1=y1,zz1=z1,xx2=x2,yy2=y2,zz2=z2
as Point of RNS_Real by XREAL_0:def 1;
reconsider p1 = [xx1,yy1,zz1], p2 = [xx2,yy2,zz2]
as Point of [:[:RNS_Real,RNS_Real:],RNS_Real:];
-p2 = [-xx2,-yy2,-zz2] by PRVECT_4:9; then
A6: p1-p2 = [xx1-xx2,yy1-yy2,zz1-zz2] by PRVECT_4:9;
A7: xx1-xx2 = x1-x2 & yy1-yy2 = y1-y2 & zz1-zz2 = z1-z2 by DUALSP03:4; then
||.xx1-xx2.|| = |.x1-x2.| by EUCLID:def 2; then
A8: ||.xx1-xx2.|| = |.x2-x1.| by COMPLEX1:60;
||.yy1-yy2.|| = |.y1-y2.| by A7,EUCLID:def 2; then
A9: ||.yy1-yy2.|| = |.y2-y1.| by COMPLEX1:60;
||.zz1-zz2.|| = |.z1-z2.| by A7,EUCLID:def 2; then
||.zz1-zz2.|| = |.z2-z1.| by COMPLEX1:60; then
A10: ||.p1-p2.|| <= |.x2-x1.| + |.y2-y1.| + |.z2-z1.| by A6,A8,A9,Th1;
|.x2-x1.| + |.y2-y1.| < r1 + r1 by A5,XREAL_1:8; then
|.x2-x1.| + |.y2-y1.| + |.z2-z1.| < r1 + r1 + r1 by A5,XREAL_1:8; then
||.p1-p2.|| < r1 + r1 + r1 by A10,XXREAL_0:2; then
A11: ||. f/.p1-f/.p2 .|| < e by A4,A5;
A12: f/.p1 = g.([x1,y1,z1]) by A1,A2,A5,PARTFUN1:def 6;
f/.p2 = f.p2 by A2,A5,PARTFUN1:def 6; then
f/.p1 - f/.p2 = g.([x1,y1,z1]) - g.([x2,y2,z2])
by A1,A12,DUALSP03:4; then
||. f/.p1-f/.p2 .|| = |. g.([x1,y1,z1])-g.([x2,y2,z2]) .|
by EUCLID:def 2;
hence thesis by A11,COMPLEX1:60;
end;
end;
assume
A13:for e be Real st 0 < e ex r be Real st 0 < r
& for x1,x2,y1,y2,z1,z2 be Real st [x1,y1,z1] in E & [x2,y2,z2] in E
& |.x2-x1.| < r & |.y2-y1.| < r & |.z2-z1.| < r holds
|. g.([x2,y2,z2])-g.([x1,y1,z1]) .| < e;
for e be Real st 0 < e holds
ex r be Real st 0 < r &
for p1,p2 be Point of [:[:RNS_Real,RNS_Real:],RNS_Real:] st
p1 in E & p2 in E & ||. p1-p2 .|| < r holds ||. f/.p1-f/.p2 .|| < e
proof
let e be Real;
assume 0 < e; then
consider r be Real such that
A14: 0 < r
& for x1,x2,y1,y2,z1,z2 be Real st [x1,y1,z1] in E & [x2,y2,z2] in E
& |.x2-x1.| < r & |.y2-y1.| < r & |.z2-z1.| < r holds
|. g.([x2,y2,z2])-g.([x1,y1,z1]) .| < e by A13;
take r;
thus 0 < r by A14;
thus for p1,p2 be Point of [:[:RNS_Real,RNS_Real:],RNS_Real:] st
p1 in E & p2 in E & ||. p1-p2 .|| < r holds ||. f/.p1-f/.p2 .|| < e
proof
let p1,p2 be Point of [:[:RNS_Real,RNS_Real:],RNS_Real:];
assume that
A15: p1 in E & p2 in E and
A16: ||. p1-p2 .|| < r;
A17: p1 is Point of [:RNS_Real,RNS_Real,RNS_Real:] &
p2 is Point of [:RNS_Real,RNS_Real,RNS_Real:]; then
consider xx1 be Point of RNS_Real, yy1 be Point of RNS_Real,
zz1 be Point of RNS_Real such that
A18: p1 = [xx1,yy1,zz1] by PRVECT_4:9;
consider xx2 be Point of RNS_Real, yy2 be Point of RNS_Real,
zz2 be Point of RNS_Real such that
A19: p2 = [xx2,yy2,zz2] by A17,PRVECT_4:9;
reconsider x1=xx1, y1=yy1, z1=zz1, x2=xx2, y2=yy2, z2=zz2 as Real;
-p2 = [-xx2,-yy2,-zz2] by A19,PRVECT_4:9; then
A20: p1-p2 = [xx1-xx2,yy1-yy2,zz1-zz2] by A18,PRVECT_4:9;
A21: xx1-xx2 = x1-x2 & yy1-yy2 = y1-y2 & zz1-zz2 = z1-z2 by DUALSP03:4; then
||.xx1-xx2.|| = |.x1-x2.| by EUCLID:def 2; then
A22: ||.xx1-xx2.|| = |.x2-x1.| by COMPLEX1:60;
||.yy1-yy2.|| = |.y1-y2.| by A21,EUCLID:def 2; then
A23: ||.yy1-yy2.|| = |.y2-y1.| by COMPLEX1:60;
||.zz1-zz2.|| = |.z1-z2.| by A21,EUCLID:def 2; then
||.zz1-zz2.|| = |.z2-z1.| by COMPLEX1:60; then
|.x2-x1.| <= ||. p1-p2 .|| & |.y2-y1.| <= ||. p1-p2 .||
& |.z2-z1.| <= ||. p1-p2 .|| by A20,A22,A23,Th1; then
|.x2-x1.| < r & |.y2-y1.| < r & |.z2-z1.| < r by A16,XXREAL_0:2; then
A24: |. g.([x2,y2,z2])-g.([x1,y1,z1]) .| < e by A14,A15,A18,A19;
A25: f/.p1 = g.([x1,y1,z1]) by A1,A2,A15,A18,PARTFUN1:def 6;
f/.p2 = f.p2 by A2,A15,PARTFUN1:def 6; then
f/.p1 - f/.p2 = g.([x1,y1,z1]) - g.([x2,y2,z2])
by A1,A19,A25,DUALSP03:4; then
||. f/.p1-f/.p2 .|| = |. g.([x1,y1,z1])-g.([x2,y2,z2]) .|
by EUCLID:def 2;
hence thesis by A24,COMPLEX1:60;
end;
end;
hence f is_uniformly_continuous_on E by A2;
end;
theorem Th4:
for I,J,K be Interval holds
[:[:I,J:],K:] is Subset of [:[:RNS_Real,RNS_Real:],RNS_Real:]
& [:[:I,J:],K:] in sigma measurable_rectangles(
sigma measurable_rectangles(L-Field,L-Field),L-Field)
proof
let I,J,K be Interval;
set S = sigma measurable_rectangles(L-Field,L-Field);
A1: [:I,J:] in S by MESFUN16:11;
K in L-Field by MEASUR10:5,MEASUR12:75; then
A2: [:[:I,J:],K:] in measurable_rectangles(S,L-Field) by A1;
measurable_rectangles(S,L-Field) c= sigma measurable_rectangles(S,L-Field)
by PROB_1:def 9;
hence thesis by A2;
end;
theorem Th5:
for u being Point of [:RNS_Real,RNS_Real,RNS_Real:], r be Real st 0 < r holds
ex s,x,y,z be Real st 0 < s & s < r & u = [x,y,z]
& [: ].x-s,x+s.[, ].y-s,y+s.[, ].z-s,z+s.[ :] c= Ball(u,r)
proof
let u be Point of [:RNS_Real,RNS_Real,RNS_Real:], r be Real;
assume
A1: 0 < r;
consider xx,yy,zz be Point of RNS_Real such that
A2: u = [xx,yy,zz] by PRVECT_4:9;
reconsider u1 = [xx,yy] as Point of [:RNS_Real,RNS_Real:];
consider s being Real such that
A3: 0 < s & s < r & [:Ball(u1,s), Ball(zz,s):] c= Ball(u,r)
by NDIFF_8:22,A1,A2;
consider s1 be Real, x,y be Real such that
A4: 0 < s1 & s1 < s & u1=[x,y]
& [: ].x-s1,x+s1.[, ].y-s1,y+s1.[ :] c= Ball(u1,s) by A3,MESFUN16:13;
A5: Ball(zz,s1) c= Ball(zz,s) by A4,NDIFF_8:15;
reconsider z=zz as Real;
take s1,x,y,z;
thus 0 < s1 by A4;
thus s1 < r by A3,A4,XXREAL_0:2;
thus u = [x,y,z] by A2,A4;
Ball(zz,s1) = ].z-s1,z+s1.[ by MESFUN16:12; then
[:[: ].x-s1,x+s1.[, ].y-s1,y+s1.[ :], ].z-s1,z+s1.[ :]
c= [:Ball(u1,s),Ball(zz,s):] by A4,A5,ZFMISC_1:96;
hence thesis by A3;
end;
theorem Th6:
for A be Subset of [:RNS_Real,RNS_Real,RNS_Real:] st
(for a,b,c be Real st [a,b,c] in A holds
ex Rx be real-membered set st Rx is non empty bounded_above &
Rx = {r where r is Real : 0 < r &
[: ].a-r,a+r.[, ].b-r,b+r.[, ].c-r,c+r.[ :] c= A})
holds
ex F be Function of A,REAL st
for a,b,c be Real st [a,b,c] in A holds
ex Rx be real-membered set st Rx is non empty bounded_above
& Rx = {r where r is Real :0 < r
& [: ].a-r,a+r.[, ].b-r,b+r.[, ].c-r,c+r.[ :] c= A}
& F.([a,b,c]) = (upper_bound Rx) / 2
proof
let A be Subset of [:RNS_Real,RNS_Real,RNS_Real:];
assume
A1: for a,b,c be Real st [a,b,c] in A holds
ex Rx be real-membered set st Rx is non empty bounded_above
& Rx = {r where r is Real : 0 < r
& [: ].a-r,a+r.[, ].b-r,b+r.[, ].c-r,c+r.[ :] c= A};
defpred P[object,object] means
ex a,b,c be Real, Rx be real-membered set st $1 = [a,b,c]
& Rx is non empty bounded_above
& Rx = {r where r is Real :0 < r
& [: ].a-r,a+r.[, ].b-r,b+r.[, ].c-r,c+r.[ :] c= A}
& $2= (upper_bound Rx) / 2;
A2: for x being object st x in A ex y being object st y in REAL & P[x,y]
proof
let x be object;
assume A3: x in A; then
consider a1 be Point of RNS_Real, b1 be Point of RNS_Real,
c1 be Point of RNS_Real such that
A4: x = [a1,b1,c1] by PRVECT_4:9;
reconsider a = a1, b = b1, c = c1 as Real;
consider Rx be real-membered set such that
A5: Rx is non empty bounded_above
& Rx = {r where r is Real :0< r &
[: ].a-r,a+r.[, ].b-r,b+r.[, ].c-r,c+r.[ :] c= A} by A1,A3,A4;
take y = (upper_bound Rx)/2;
thus y in REAL by XREAL_0:def 1;
thus thesis by A4,A5;
end;
consider F being Function of A,REAL such that
A6: for x being object st x in A holds P[x,F.x] from FUNCT_2:sch 1(A2);
take F;
thus for a,b,c be Real st [a,b,c] in A holds
ex Rx be real-membered set st Rx is non empty bounded_above
& Rx = {r where r is Real :0 < r
& [: ].a-r,a+r.[, ].b-r,b+r.[, ].c-r,c+r.[ :] c= A}
& F.([a,b,c]) =(upper_bound Rx)/2
proof
let a1,b1,c1 be Real;
assume [a1,b1,c1] in A; then
consider a,b,c be Real, Rx be real-membered set such that
A7: [a1,b1,c1] = [a,b,c]
& Rx is non empty bounded_above
& Rx = {r where r is Real : 0 < r
& [: ].a-r,a+r.[, ].b-r,b+r.[, ].c-r,c+r.[ :] c= A}
& F.([a1,b1,c1]) = (upper_bound Rx)/2 by A6;
a1=a & b1=b & c1=c by XTUPLE_0:3,A7;
hence thesis by A7;
end;
end;
Lm3:
for A be set st A c= [:REAL,REAL,REAL:] & A /\ [:RAT,RAT,RAT:] <> {}
holds
ex p be sequence of [:REAL,REAL,REAL:] st rng p = A /\ [:RAT,RAT,RAT:]
proof
let A be set;
assume that
A1: A c= [:REAL,REAL,REAL:] and
A2: A /\ [:RAT,RAT,RAT:] <> {};
[:RAT,RAT:] is countable by CARD_4:7; then
[:RAT,RAT,RAT:] is countable by CARD_4:7; then
A /\ [:RAT,RAT,RAT:] is countable by CARD_3:94; then
consider f being Function of omega, A /\ [:RAT,RAT,RAT:] such that
A3: rng f = A /\ [:RAT,RAT,RAT:] by CARD_3:96,A2;
A /\ [:RAT,RAT,RAT:] c= A by XBOOLE_1:17; then
rng f c= [:REAL,REAL,REAL:] by A1; then
reconsider f as sequence of [:REAL,REAL,REAL:] by A2,FUNCT_2:6;
take f;
thus thesis by A3;
end;
theorem Th7:
for A be Subset of [:RNS_Real,RNS_Real,RNS_Real:] st A is open holds
A in sigma measurable_rectangles(
sigma measurable_rectangles(L-Field,L-Field),L-Field)
proof
let A be Subset of [:RNS_Real,RNS_Real,RNS_Real:];
assume
A1: A is open;
set LF2 = sigma measurable_rectangles(L-Field,L-Field);
set LF3 = sigma measurable_rectangles(LF2,L-Field);
per cases;
suppose A ={};
hence A in LF3 by PROB_1:4;
end;
suppose
A2: A <>{};
per cases;
suppose
not (for a,b,c be Real st [a,b,c] in A holds
ex Rx be real-membered set st Rx is non empty bounded_above
& Rx = {r where r is Real :0 < r
& [: ].a-r,a+r.[, ].b-r,b+r.[, ].c-r,c+r.[ :] c= A}); then
consider a,b,c be Real such that
A3: [a,b,c] in A
& not (ex Rx be real-membered set st Rx is non empty bounded_above
& Rx = {r where r is Real :0 < r
& [: ].a-r,a+r.[, ].b-r,b+r.[, ].c-r,c+r.[ :] c= A});
set Rx = {r where r is Real :0 < r
& [: ].a-r,a+r.[, ].b-r,b+r.[, ].c-r,c+r.[ :] c= A};
now let z be object;
assume z in Rx; then
ex r be Real st z=r & 0<r
& [: ].a-r,a+r.[, ].b-r,b+r.[, ].c-r,c+r.[ :] c= A;
hence z is real;
end; then
reconsider Rx as real-membered set by MEMBERED:def 3;
reconsider a1=a,b1=b,c1= c as Point of RNS_Real by XREAL_0:def 1;
reconsider x = [a1,b1,c1] as Point of [:RNS_Real,RNS_Real,RNS_Real:];
consider r0 being Real such that
A4: r0 > 0 & Ball (x,r0) c= A by A1,A3,NDIFF_8:20;
consider s be Real,aa,bb,cc be Real such that
A5: 0 < s & s < r0 & x=[aa,bb,cc]
& [: ].aa-s,aa+s .[, ].bb-s,bb+s.[, ].cc-s,cc+s.[ :] c= Ball(x,r0)
by A4,Th5;
A6: [: ].aa-s,aa+s.[, ].bb-s,bb+s.[, ].cc-s,cc+s.[ :] c= A by A5,A4;
a = aa & b = bb & c = cc by A5,XTUPLE_0:3; then
s in Rx by A5,A6; then
A7: not Rx is bounded_above by A3;
now let u be object;
assume u in [:REAL,REAL,REAL:]; then
consider xy1,z1 be object such that
A8: xy1 in [:REAL,REAL:] & z1 in REAL & u = [xy1,z1] by ZFMISC_1:def 2;
consider x1,y1 be object such that
A9: x1 in REAL & y1 in REAL & xy1 = [x1,y1] by A8,ZFMISC_1:def 2;
reconsider x1,y1,z1 as Real by A8,A9;
consider r1 be Real such that
A10: 0 < r1 & x1 in ].a-r1,a+r1.[ by Lm1;
consider r2 be Real such that
A11: 0 < r2 & y1 in ].b-r2,b+r2.[ by Lm1;
consider r3 be Real such that
A12: 0 < r3 & z1 in ].c-r3,c+r3.[ by Lm1;
set r = max(max(r1,r2),r3);
A13: r1 <= max(r1,r2) & r2 <= max(r1,r2) by XXREAL_0:25;
max(r1,r2) <= r & r3 <= r by XXREAL_0:25; then
A14: ].a-r1,a+r1.[ c= ].a-r,a+r.[ & ].b-r2,b+r2.[ c= ].b-r,b+r.[
& ].c-r3,c+r3.[ c= ].c-r,c+r.[ by Lm2,XXREAL_0:2,A13; then
[x1,y1] in [: ].a-r,a+r.[,].b-r,b+r.[ :] by A10,A11,ZFMISC_1:87; then
A15: u in [: ].a-r,a+r.[, ].b-r,b+r.[, ].c-r,c+r.[ :]
by A8,A9,A12,A14,ZFMISC_1:87;
not r is UpperBound of Rx by A7,XXREAL_2:def 10; then
consider s being ExtReal such that
A16: s in Rx & r < s by XXREAL_2:def 1;
reconsider s as Real by A16;
A17: ex s0 be Real st s = s0 & 0 < s0
& [: ].a-s0,a+s0.[, ].b-s0,b+s0.[, ].c-s0,c+s0.[ :] c= A by A16;
A18: ].a-r,a+r.[ c= ].a-s,a+s.[ & ].b-r,b+r.[ c= ].b-s,b+s.[
& ].c-r,c+r.[ c= ].c-s,c+s.[ by A16,Lm2; then
[: ].a-r,a+r.[, ].b-r,b+r.[ :] c= [: ].a-s,a+s.[, ].b-s,b+s.[ :]
by ZFMISC_1:96; then
[:[: ].a-r,a+r.[,].b-r,b+r.[ :], ].c-r,c+r.[ :]
c= [: ].a-s,a+s.[, ].b-s,b+s.[, ].c-s,c+s.[ :] by ZFMISC_1:96,A18;
hence u in A by A15,A17;
end; then
[:REAL,REAL,REAL:] c= A; then
A19: A = [:REAL,REAL,REAL:];
A20: REAL in L-Field & REAL in L-Field & REAL in L-Field by PROB_1:5; then
A21: [:REAL,REAL:] in measurable_rectangles(L-Field,L-Field);
measurable_rectangles(L-Field,L-Field) c= LF2 by PROB_1:def 9; then
A22: [:REAL,REAL,REAL:] in measurable_rectangles(LF2,L-Field) by A20,A21;
measurable_rectangles(LF2,L-Field) c= LF3 by PROB_1:def 9;
hence thesis by A19,A22;
end;
suppose
for a,b,c be Real st [a,b,c] in A holds
ex Rx be real-membered set st Rx is non empty bounded_above
& Rx = {r where r is Real : 0 < r & [: ].a-r,a+r.[, ].b-r,b+r.[,
].c-r,c+r.[ :] c= A}; then
consider F be Function of A,REAL such that
A23: for a,b,c be Real st [a,b,c] in A holds
ex Rx be real-membered set st Rx is non empty bounded_above
& Rx = {r where r is Real : 0 <r &
[: ].a-r,a+r.[, ].b-r,b+r.[, ].c-r,c+r.[ :] c= A}
& F.([a,b,c]) =(upper_bound Rx)/2 by Th6;
A /\ [:RAT,RAT,RAT:] <> {}
proof
consider v be object such that
A24: v in A by A2,XBOOLE_0:def 1;
reconsider u=v as Point of [:RNS_Real,RNS_Real,RNS_Real:] by A24;
consider e0 being Real such that
A25: e0 > 0 & Ball (u,e0) c= A by A24,A1,NDIFF_8:20;
set e1=e0/2;
A26: 0 < e1 & e1 < e0 by A25,XREAL_1:215,216;
set e = e1/3;
A27: 0 < e & e < e1 by A26,XREAL_1:221,222; then
A28: e < e0 by A26,XXREAL_0:2;
consider x1 be Point of RNS_Real, y1 be Point of RNS_Real,
z1 be Point of RNS_Real such that
A29: u = [x1,y1,z1] by PRVECT_4:9;
reconsider xx1=x1,yy1=y1,zz1=z1 as Real;
A30: xx1-e/3 < xx1 by A27,XREAL_1:222,XREAL_1:44;
xx1 < xx1 +e/3 by A27,XREAL_1:222,XREAL_1:29; then
xx1-e/3 < xx1 +e/3 by A30,XXREAL_0:2; then
consider qx1 be Rational such that
A31: xx1-e/3 < qx1 & qx1 < xx1+e/3 by RAT_1:7;
qx1 in ].xx1-e/3,xx1+e/3.[ by A31; then
A32: |.qx1-xx1.| < e/3 by RCOMP_1:1;
A33: yy1-e/3 < yy1 by A27,XREAL_1:222,XREAL_1:44;
yy1 < yy1 +e/3 by A27,XREAL_1:222,XREAL_1:29; then
yy1-e/3 < yy1 +e/3 by A33,XXREAL_0:2; then
consider qy1 be Rational such that
A34: yy1-e/3 < qy1 & qy1 < yy1+e/3 by RAT_1:7;
qy1 in ].yy1-e/3,yy1+e/3.[ by A34; then
A35: |.qy1-yy1.| < e/3 by RCOMP_1:1;
A36: zz1-e/3 < zz1 by A27,XREAL_1:222,XREAL_1:44;
zz1 < zz1 +e/3 by A27,XREAL_1:222,XREAL_1:29; then
zz1-e/3 < zz1 +e/3 by A36,XXREAL_0:2; then
consider qz1 be Rational such that
A37: zz1-e/3 < qz1 & qz1 < zz1+e/3 by RAT_1:7;
qz1 in ].zz1-e/3,zz1+e/3.[ by A37; then
A38: |.qz1-zz1.| < e/3 by RCOMP_1:1;
A39: qx1 in RAT & qy1 in RAT & qz1 in RAT by RAT_1:def 2;
reconsider dx1=qx1,dy1=qy1,dz1=qz1 as Point of RNS_Real
by XREAL_0:def 1;
dx1-x1 =qx1-xx1 & dy1-y1 =qy1-yy1 & dz1-z1 =qz1-zz1 by DUALSP03:4; then
A40: ||.dx1-x1.|| < e/3 & ||.dy1-y1.|| < e/3 & ||.dz1-z1.|| < e/3
by A32,A35,A38,EUCLID:def 2;
reconsider v = [dx1,dy1,dz1]
as Point of [:RNS_Real,RNS_Real,RNS_Real:];
A41: -v = [-dx1,-dy1,-dz1] by PRVECT_4:9;
u-v = [x1+-dx1,y1+-dy1,z1+-dz1] by A29,A41,PRVECT_4:9; then
||. u-v .|| <= ||.x1-dx1.|| + ||.y1-dy1.|| + ||.z1-dz1.|| by Th1; then
||. u-v .|| <= ||.dx1-x1.|| + ||.y1-dy1.|| + ||.z1-dz1.||
by NORMSP_1:7; then
||. u-v .|| <= ||.dx1-x1.|| + ||.dy1-y1.|| + ||.z1-dz1.||
by NORMSP_1:7; then
A42: ||. u-v .|| <= ||.dx1-x1.|| + ||.dy1-y1.|| + ||.dz1-z1.|| by NORMSP_1:7;
||.dx1-x1.|| + ||.dy1-y1.|| <= e/3 + e/3 by A40,XREAL_1:7; then
||.dx1-x1.|| + ||.dy1-y1.|| + ||.dz1-z1.|| <= e/3 + e/3 + e/3
by A40,XREAL_1:7; then
||. u-v .|| <= e by A42,XXREAL_0:2; then
||. u-v .|| < e0 by XXREAL_0:2,A28; then
A43: v in Ball(u,e0);
[qx1,qy1] in [:RAT,RAT:] by A39,ZFMISC_1:87; then
[qx1,qy1,qz1] in [:RAT,RAT,RAT:] by A39,ZFMISC_1:87;
hence thesis by A25,A43,XBOOLE_0:def 4;
end; then
consider p be sequence of [:REAL,REAL,REAL:] such that
A44: rng p = A /\ [:RAT,RAT,RAT:] by Lm3;
A45: for a,b,c be Real st [a,b,c] in A
ex r be Real st 0< r & r = F.([a,b,c])
& [: ].a-r,a+r.[, ].b-r,b+r.[, ].c-r,c+r.[ :] c= A
proof
let a,b,c be Real;
assume [a,b,c] in A; then
consider Rx be real-membered set such that
A46: Rx is non empty bounded_above
& Rx = {r where r is Real :0 < r
& [: ].a-r,a+r.[, ].b-r,b+r.[, ].c-r,c+r.[ :] c= A}
& F.([a,b,c]) =(upper_bound Rx)/2 by A23;
take r0 = F.([a,b,c]);
consider r1 be Real such that
A47: r1 in Rx by A46;
A48: ex r be Real st r1=r & 0 <r
& [: ].a-r,a+r.[, ].b-r,b+r.[, ].c-r,c+r.[ :] c= A by A46,A47;
A49: r1 <= upper_bound Rx by SEQ_4:def 1,A46,A47; then
0 < r0 & r0 < upper_bound Rx by A46,A48,XREAL_1:215,216; then
consider s be Real such that
A50: s in Rx & (upper_bound Rx) - r0 < s by A46,SEQ_4:def 1;
A51: ex r be Real st s=r & 0 < r
& [: ].a-r,a+r.[, ].b-r,b+r.[, ].c-r,c+r.[ :] c= A by A50,A46;
A52: ].a-r0,a+r0.[ c= ].a-s,a+s.[ & ].b-r0,b+r0.[ c= ].b-s,b+s.[
& ].c-r0,c+r0.[ c= ].c-s,c+s.[ by A50,A46,Lm2; then
[: ].a-r0,a+r0.[, ].b-r0,b+r0.[ :] c= [: ].a-s,a+s.[, ].b-s,b+s.[ :]
by ZFMISC_1:96; then
[:[: ].a-r0,a+r0.[, ].b-r0,b+r0.[ :], ].c-r0,c+r0.[ :]
c= [:[: ].a-s,a+s.[, ].b-s,b+s.[ :], ].c-s,c+s.[ :]
by A52,ZFMISC_1:96;
hence thesis by A49,A51,A46,A48,XREAL_1:215;
end;
defpred Q[object,object] means
ex a,b,c,r be Real, E be set st p.$1 =[a,b,c]
& a in RAT & b in RAT & c in RAT & 0 < r & r =F.( [a,b,c])
& E = $2 & E = [: ].a-r,a+r.[, ].b-r,b+r.[, ].c-r,c+r.[ :]
& E c= A;
A53: for i being object st i in NAT
ex y being object st y in bool [:REAL,REAL,REAL:] & Q[i,y]
proof
let i be object;
assume i in NAT; then
i in dom p by FUNCT_2:def 1; then
p.i in rng p by FUNCT_1:3; then
A54: p.i in A & p.i in [:RAT,RAT,RAT:] by A44,XBOOLE_0:def 4; then
consider ab,c be object such that
A55: ab in [:RAT,RAT:] & c in RAT & p.i = [ab,c] by ZFMISC_1:def 2;
consider a,b be object such that
A56: a in RAT & b in RAT & ab = [a,b] by A55,ZFMISC_1:def 2;
reconsider a,b,c as Real by A55,A56;
consider r be Real such that
A57: 0 < r & r = F.([a,b,c])
& [: ].a-r,a+r.[, ].b-r,b+r.[, ].c-r,c+r.[ :] c= A by A45,A54,A55,A56;
set E = [: ].a-r,a+r.[, ].b-r,b+r.[, ].c-r,c+r.[ :];
take y = E;
thus y in bool [:REAL,REAL,REAL:];
thus thesis by A55,A56,A57;
end;
consider B be Function of NAT,bool [:REAL,REAL,REAL:] such that
A58: for i being object st i in NAT holds Q[i,B.i] from FUNCT_2:sch 1(A53);
reconsider B as SetSequence of [:REAL,REAL,REAL:];
A59: for i be Nat holds
ex a,b,c,r be Real st p.i =[a,b,c] & a in RAT & b in RAT & c in RAT
& 0 < r & r =F.([a,b,c])
& B.i = [: ].a-r,a+r.[, ].b-r,b+r.[, ].c-r,c+r.[ :] & B.i c= A
proof
let i be Nat;
ex a,b,c,r be Real, E be set
st p.i =[a,b,c] & a in RAT & b in RAT & c in RAT
& 0 < r & r =F.([a,b,c]) & E = B.i
& E = [: ].a-r,a+r.[, ].b-r,b+r.[, ].c-r,c+r.[ :]
& E c= A by A58,ORDINAL1:def 12;
hence thesis;
end;
now let z be object;
assume z in rng B; then
consider i be Element of NAT such that
A60: i in dom B & z=B.i by PARTFUN1:3;
consider a,b,c,r be Real such that
A61: p.i =[a,b,c] & a in RAT & b in RAT & c in RAT & 0 < r & r =F.([a,b,c])
& B.i = [: ].a-r,a+r.[, ].b-r,b+r.[, ].c-r,c+r.[ :] & B.i c= A by A59;
A62: ].a-r,a+r.[ in L-Field & ].b-r,b+r.[ in L-Field
& ].c-r,c+r.[ in L-Field by MEASUR10:5,MEASUR12:75; then
A63: [: ].a-r,a+r.[, ].b-r,b+r.[ :]
in measurable_rectangles(L-Field,L-Field);
measurable_rectangles(L-Field,L-Field) c= LF2 by PROB_1:def 9; then
A64: B.i in measurable_rectangles(LF2,L-Field) by A62,A61,A63;
measurable_rectangles(LF2,L-Field) c= LF3 by PROB_1:def 9;
hence z in LF3 by A64,A60;
end; then
rng B c= LF3; then
reconsider B as SetSequence of LF3 by RELAT_1:def 19;
now let z be object;
assume z in union rng B; then
consider Y being set such that
A65: z in Y & Y in rng B by TARSKI:def 4;
consider i be Element of NAT such that
A66: i in dom B & Y =B.i by A65,PARTFUN1:3;
ex a,b,c,r be Real st p.i =[a,b,c] & a in RAT & b in RAT & c in RAT
& 0 < r & r =F.([a,b,c])
& B.i = [: ].a-r,a+r.[, ].b-r,b+r.[, ].c-r,c+r.[ :]
& B.i c= A by A59;
hence z in A by A65,A66;
end; then
A67: union rng B c= A;
now let z be object;
assume
A68: z in A; then
reconsider u=z as Point of [:RNS_Real,RNS_Real,RNS_Real:];
consider e0 being Real such that
A69: e0 > 0 & Ball (u,e0) c= A by A68,A1,NDIFF_8:20;
set e1=e0/2;
A70: 0 < e1 & e1 < e0 by A69,XREAL_1:215,216;
set e=e1/3;
0 < e & e < e1 by A70,XREAL_1:221,222; then
A71: e < e0 by A70,XXREAL_0:2; then
Ball(u,e) c= Ball(u,e0) by NDIFF_8:15; then
A72: 0 < e & Ball (u,e) c= A by A69,A70,XREAL_1:222;
consider x1 be Point of RNS_Real, y1 be Point of RNS_Real,
z1 be Point of RNS_Real such that
A73: u=[x1,y1,z1] by PRVECT_4:9;
reconsider xx1=x1,yy1=y1,zz1=z1 as Real;
A74: 0 < e/2 & e/2 < e by A72,XREAL_1:215,216;
A75: xx1-e/4 < xx1 by A72,XREAL_1:224,XREAL_1:44;
xx1 < xx1+e/4 by A72,XREAL_1:224,XREAL_1:29; then
xx1-e/4 < xx1 +e/4 by A75,XXREAL_0:2; then
consider qx1 be Rational such that
A76: xx1-e/4 < qx1 & qx1 < xx1+e/4 by RAT_1:7;
qx1 in ].xx1-e/4,xx1+e/4.[ by A76; then
A77: |.qx1-xx1.| < e/4 by RCOMP_1:1;
A78: yy1-e/4 < yy1 by A72,XREAL_1:224,XREAL_1:44;
yy1 < yy1 +e/4 by A72,XREAL_1:224,XREAL_1:29; then
yy1-e/4 < yy1 +e/4 by A78,XXREAL_0:2; then
consider qy1 be Rational such that
A79: yy1-e/4 < qy1 & qy1 < yy1+e/4 by RAT_1:7;
qy1 in ].yy1-e/4,yy1+e/4.[ by A79; then
A80: |.qy1-yy1.| < e/4 by RCOMP_1:1;
A81: zz1-e/4 < zz1 by A72,XREAL_1:224,XREAL_1:44;
zz1 < zz1 +e/4 by A72,XREAL_1:224,XREAL_1:29; then
zz1-e/4 < zz1 +e/4 by A81,XXREAL_0:2; then
consider qz1 be Rational such that
A82: zz1-e/4 < qz1 & qz1 < zz1+e/4 by RAT_1:7;
qz1 in ].zz1-e/4,zz1+e/4.[ by A82; then
A83: |.qz1-zz1.| < e/4 by RCOMP_1:1;
A84: qx1 in RAT & qy1 in RAT & qz1 in RAT by RAT_1:def 2;
reconsider dx1=qx1,dy1=qy1,dz1=qz1 as Point of RNS_Real
by XREAL_0:def 1;
dx1-x1 =qx1-xx1 by DUALSP03:4; then
A85: ||.dx1-x1.|| < e/4 by A77,EUCLID:def 2;
dy1-y1 =qy1-yy1 by DUALSP03:4; then
A86: ||.dy1-y1.|| < e/4 by A80,EUCLID:def 2;
dz1-z1 =qz1-zz1 by DUALSP03:4; then
A87: ||.dz1-z1.|| < e/4 by A83,EUCLID:def 2;
reconsider v = [dx1,dy1,dz1]
as Point of [:RNS_Real,RNS_Real,RNS_Real:];
A88: -v = [-dx1,-dy1,-dz1] by PRVECT_4:9;
u-v = [x1+-dx1,y1+-dy1,z1+-dz1] by A73,A88,PRVECT_4:9; then
||. u-v .|| <= ||.x1-dx1.|| +||.y1-dy1.|| +||.z1-dz1.|| by Th1; then
||. u-v .|| <= ||.dx1-x1.|| +||.y1-dy1.|| +||.z1-dz1.||
by NORMSP_1:7; then
||. u-v .|| <= ||.dx1-x1.|| +||.dy1-y1.|| +||.z1-dz1.||
by NORMSP_1:7; then
A89: ||. u-v .|| <= ||.dx1-x1.|| +||.dy1-y1.|| +||.dz1-z1.|| by NORMSP_1:7;
||.dx1-x1.|| +||.dy1-y1.|| <= e/4 + e/4 by A85,A86,XREAL_1:7; then
||.dx1-x1.|| +||.dy1-y1.|| + ||.dz1-z1.||
<= e/4 + e/4 + e/4 by A87,XREAL_1:7; then
||.dx1-x1.|| +||.dy1-y1.|| + ||.dz1-z1.||
<= e/4 + e/4 + e/4 + e/4 by A69,XREAL_1:38; then
||. u-v .|| <= e by A89,XXREAL_0:2; then
||. u-v .|| < e0 by XXREAL_0:2,A71; then
A90: v in Ball(u,e0);
[qx1,qy1] in [:RAT,RAT:] by A84,ZFMISC_1:87; then
[qx1,qy1,qz1] in [:RAT,RAT,RAT:] by A84,ZFMISC_1:87; then
[qx1,qy1,qz1] in rng p by A44,A69,A90,XBOOLE_0:def 4; then
consider k be Element of NAT such that
A91: k in dom p & p.k=[qx1,qy1,qz1] by PARTFUN1:3;
consider Rx be real-membered set such that
A92: Rx is non empty bounded_above
& Rx = {r where r is Real :0 <r &
[: ].qx1-r,qx1+r.[, ].qy1-r,qy1+r.[, ].qz1-r,qz1+r.[ :] c= A}
& F.([qx1,qy1,qz1]) =(upper_bound Rx)/2 by A69,A90,A23;
consider ak,bk,ck,rk be Real such that
A93: p.k =[ak,bk,ck] & ak in RAT & bk in RAT & ck in RAT
& 0 < rk & rk =F.([ak,bk,ck])
& B.k = [: ].ak-rk,ak+rk.[, ].bk-rk,bk+rk.[, ].ck-rk,ck+rk.[ :]
& B.k c= A by A59;
A94: ak=qx1 & bk=qy1 & ck=qz1 by A91,A93,XTUPLE_0:3; then
A95: |.xx1-ak.| < e/4 & |.yy1-bk.| < e/4 & |.zz1-ck.| < e/4
by A77,A80,A83,COMPLEX1:60;
set d=e/4;
now let z be object;
assume
z in [: ].ak-e/2,ak+e/2.[,].bk-e/2,bk+e/2.[,].ck-e/2,ck+e/2.[ :]; then
consider s1,v be object such that
A96: s1 in [: ].ak-e/2,ak+e/2.[ ,].bk-e/2,bk+e/2.[ :]
& v in ].ck-e/2,ck+e/2.[ & z =[s1,v] by ZFMISC_1:def 2;
consider s,t be object such that
A97: s in ].ak-e/2,ak+e/2.[ & t in ].bk-e/2,bk+e/2.[
& s1 =[s,t] by A96,ZFMISC_1:def 2;
reconsider s,t,v as Real by A96,A97;
reconsider ss=s,tt=t,vv=v as Point of RNS_Real by XREAL_0:def 1;
reconsider w = [ss,tt,vv] as Point of [:RNS_Real,RNS_Real,RNS_Real:];
|.s-ak.| < e/2 & |.t-bk.| < e/2 & |.v - ck.| < e/2
by A96,A97,RCOMP_1:1; then
A98: |.ak-s.| < e/2 & |.bk-t.| < e/2 & |.ck-v.| < e/2 by COMPLEX1:60;
(e/2)/2 < e/2 by A72,XREAL_1:215,216; then
A99: |.xx1-ak.| < e/2 & |.yy1-bk.| < e/2 & |.zz1-ck.| < e/2
by A95,XXREAL_0:2;
A100: |.xx1-s.| <= |.xx1-ak.| + |.ak-s.| by COMPLEX1:63;
|.xx1-ak.| + |.ak-s.| <= e/2 + e/2 by A98,A99,XREAL_1:7; then
A101: |.xx1-s.| <= e by A100,XXREAL_0:2;
A102: |.yy1-t.| <= |.yy1-bk.| + |.bk-t.| by COMPLEX1:63;
|.yy1-bk.| + |.bk-t.| <= e/2 + e/2 by A98,A99,XREAL_1:7; then
A103: |.yy1-t.| <= e by A102,XXREAL_0:2;
A104: |.zz1-v.| <=|.zz1-ck.| + |.ck-v.| by COMPLEX1:63;
|.zz1-ck.| + |.ck-v.| <= e/2 + e/2 by A98,A99,XREAL_1:7; then
A105: |.zz1-v.| <= e by A104,XXREAL_0:2;
x1-ss = xx1-s by DUALSP03:4; then
A106: ||.x1-ss.|| <= e by A101,EUCLID:def 2;
y1-tt = yy1-t by DUALSP03:4; then
A107: ||.y1-tt.|| <= e by A103,EUCLID:def 2;
z1-vv = zz1-v by DUALSP03:4; then
A108: ||.z1-vv.|| <= e by A105,EUCLID:def 2;
A109: -w = [-ss,-tt,-vv] by PRVECT_4:9;
u-w = [x1+-ss,y1+-tt,z1+-vv] by A109,A73,PRVECT_4:9; then
A110: ||. u-w .|| <= ||.x1-ss.|| +||.y1-tt.|| +||.z1-vv.|| by Th1;
||.x1-ss.|| +||.y1-tt.|| <= e + e by A106,A107,XREAL_1:7; then
||.x1-ss.|| +||.y1-tt.|| +||.z1-vv.|| <= e + e + e
by A108,XREAL_1:7; then
A111: ||. u-w .|| <= e0/2 by A110,XXREAL_0:2;
e0/2 < e0 by A69,XREAL_1:216; then
||. u-w .|| < e0 by A111,XXREAL_0:2; then
w in Ball(u,e0);
hence z in A by A96,A97,A69;
end; then
[: ].ak-e/2,ak+e/2.[,].bk-e/2,bk+e/2.[,].ck-e/2,ck+e/2.[ :] c= A; then
e/2 in Rx by A74,A92,A94; then
e/2 <= (upper_bound Rx) by A92,SEQ_4:def 1; then
(e/2)/2 <= (upper_bound Rx)/2 by XREAL_1:72; then
].ak-d,ak+d.[ c= ].ak-rk,ak+rk.[ & ].bk-d,bk+d.[ c= ].bk-rk,bk+rk.[
& ].ck-d,ck+d.[ c= ].ck-rk,ck+rk.[ by A92,A93,Lm2,A91; then
A112: x1 in ].ak-rk,ak+rk.[ & y1 in ].bk-rk,bk+rk.[
& z1 in ].ck-rk,ck+rk.[ by A95,RCOMP_1:1; then
[x1,y1] in [: ].ak-rk,ak+rk.[,].bk-rk,bk+rk.[ :] by ZFMISC_1:87; then
A113: u in B.k by A93,A73,A112,ZFMISC_1:87;
k in NAT; then
k in dom B by FUNCT_2:def 1; then
B.k in rng B by FUNCT_1:3;
hence z in union rng B by A113,TARSKI:def 4;
end; then
A c= union rng B; then
Union B = A by A67,CARD_3:def 4;
hence A in LF3 by PROB_1:17;
end;
end;
end;
theorem Th8:
for I,J,K be closed_interval Subset of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL st
f is_continuous_on [:[:I,J:],K:] & f = g holds
for e be Real st 0 < e ex r be Real st 0 < r
& for x1,x2,y1,y2,z1,z2 be Real st x1 in I & x2 in I & y1 in J & y2 in J
& z1 in K & z2 in K & |.x2-x1.| < r & |.y2-y1.| < r & |.z2-z1.| < r
holds |. g.([x2,y2,z2])-g.([x1,y1,z1]) .| < e
proof
let I,J,K be closed_interval Subset of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL;
assume that
A1: f is_continuous_on [:[:I,J:],K:] and
A2: f = g;
set E = [:[:I,J:],K:];
A3: f is_uniformly_continuous_on E by A1,Th2,NFCONT_2:10;
let e be Real;
assume 0 < e; then
consider r be Real such that
A4: 0 < r
& for x1,x2,y1,y2,z1,z2 be Real st [x1,y1,z1] in E & [x2,y2,z2] in E
& |.x2-x1.| < r & |.y2-y1.| < r & |.z2-z1.| < r holds
|. g.([x2,y2,z2])-g.([x1,y1,z1]) .| < e by A2,A3,Th3;
A5: for x1,x2,y1,y2,z1,z2 be Real st x1 in I & x2 in I & y1 in J & y2 in J
& z1 in K & z2 in K & |.x2-x1.| < r & |.y2-y1.| < r & |.z2-z1.| < r
holds |. g.([x2,y2,z2])-g.([x1,y1,z1]) .| < e
proof
let x1,x2,y1,y2,z1,z2 be Real;
assume that
A6: x1 in I & x2 in I & y1 in J & y2 in J & z1 in K & z2 in K and
A7: |.x2-x1.| < r & |.y2-y1.| < r & |.z2-z1.| < r;
[x1,y1] in [:I,J:] & [x2,y2] in [:I,J:] by A6,ZFMISC_1:87; then
[x1,y1,z1] in E & [x2,y2,z2] in E by A6,ZFMISC_1:87;
hence thesis by A4,A7;
end;
take r;
thus thesis by A4,A5;
end;
theorem Th9:
for f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL st f = g holds ||.f.|| = |.g.|
proof
let f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL;
assume
A1: f = g;
A2: dom ||.f.|| = dom f by NORMSP_0:def 3; then
A3: dom ||.f.|| = dom |.g.| by A1,VALUED_1:def 11;
for x be object st x in dom ||.f.|| holds (||.f.||).x = (|.g.|).x
proof
let x be object;
assume
A4: x in dom ||.f.||; then
A5: (||.f.||).x = ||. f/.x .|| by NORMSP_0:def 3;
f/.x = f.x by A4,A2,PARTFUN1:def 6; then
||. f/.x .|| = |. g.x .| by A1,EUCLID:def 2;
hence (||.f.||).x = (|.g.|).x by A3,A4,A5,VALUED_1:def 11;
end;
hence ||.f.|| = |.g.| by A3,FUNCT_1:2;
end;
theorem Th10:
for I,J,K be closed_interval Subset of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL
st f is_continuous_on [:[:I,J:],K:] & f = g
holds
for e be Real st 0 < e ex r be Real st 0 < r
& for x1,x2,y1,y2,z1,z2 be Real st x1 in I & x2 in I & y1 in J & y2 in J
& z1 in K & z2 in K & |.x2-x1.| < r & |.y2-y1.| < r & |.z2-z1.| < r
holds |. (|.g.|).([x2,y2,z2])-(|.g.|).([x1,y1,z1]) .| < e
proof
let I,J,K be closed_interval Subset of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL;
assume that
A1: f is_continuous_on [:[:I,J:],K:] and
A2: f = g;
reconsider f1 = ||.f.|| as
PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real;
||.f.|| = |.g.| by A2,Th9;
hence thesis by A1,Th8,MESFUN16:22;
end;
begin :: Properties on the projective function of a three-variable function
theorem Th11:
for f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL, x,y be Element of REAL
st f is_continuous_on dom f & f = g holds ProjPMap1(g,[x,y]) is continuous
proof
let f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL,
x,y be Element of REAL;
assume that
A1: f is_continuous_on dom f and
A2: f = g;
for z0 be Real st z0 in dom ProjPMap1(g,[x,y]) holds
ProjPMap1(g,[x,y]) is_continuous_in z0
proof
let z0 be Real;
assume z0 in dom ProjPMap1(g,[x,y]); then
A3: z0 in X-section(dom g,[x,y]) by MESFUN12:def 3;
A4: X-section(dom g,[x,y])
= {z where z is Element of REAL: [[x,y],z] in dom g}
by MEASUR11:def 4; then
A5: ex z be Element of REAL st z = z0 & [[x,y],z] in dom g by A3;
reconsider xx = x, yy = y as Point of RNS_Real;
reconsider zz0 = z0 as Point of RNS_Real by XREAL_0:def 1;
reconsider p0 = [xx,yy,zz0]
as Point of [:[:RNS_Real,RNS_Real:],RNS_Real:];
for r be Real st 0 < r ex s be Real st 0 < s
& for z1 be Real st z1 in dom ProjPMap1(g,[x,y]) & |. z1-z0 .| < s
holds |. ProjPMap1(g,[x,y]).z1 - ProjPMap1(g,[x,y]).z0 .| < r
proof
let r be Real;
assume 0 < r; then
consider s be Real such that
A6: 0 < s and
A7: for p1 be Point of [:[:RNS_Real,RNS_Real:],RNS_Real:]
st p1 in dom f & ||. p1-p0 .|| < s holds ||. f/.p1 - f/.p0 .|| < r
by A1,A2,A5,NFCONT_1:19;
now let z1 be Real;
assume that
A8: z1 in dom ProjPMap1(g,[x,y]) and
A9: |. z1-z0 .| < s;
z1 in X-section(dom g,[x,y]) by A8,MESFUN12:def 3; then
A10: ex z be Element of REAL st z = z1 & [[x,y],z] in dom g by A4;
reconsider zz1 = z1 as Point of RNS_Real by XREAL_0:def 1;
reconsider p1 = [xx,yy,zz1]
as Point of [:[:RNS_Real,RNS_Real:],RNS_Real:];
A11: zz1-zz0 = z1-z0 by DUALSP03:4;
p1-p0 = [xx,yy,zz1] + [-xx,-yy,-zz0] by PRVECT_4:9; then
p1-p0 = [xx-xx,yy-yy,zz1-zz0] by PRVECT_4:9; then
p1-p0 = [0.RNS_Real,yy-yy,zz1-zz0] by RLVECT_1:15; then
p1-p0 = [0.RNS_Real,0.RNS_Real,zz1-zz0] by RLVECT_1:15; then
||. p1-p0 .||
= sqrt(||. 0.RNS_Real .||^2 + ||. 0.RNS_Real .||^2 + ||. zz1-zz0 .||^2)
by PRVECT_4:9; then
||. p1-p0 .|| = ||. zz1-zz0 .|| by SQUARE_1:22; then
||. p1-p0 .|| = |. z1-z0 .| by A11,EUCLID:def 2; then
A12: ||. f/.p1-f/.p0 .|| < r by A9,A2,A10,A7;
ProjPMap1(g,[x,y]).z1 = g.([x,y],z1)
& ProjPMap1(g,[x,y]).z0 = g.([x,y],z0)
by A5,A10,MESFUN12:def 3; then
ProjPMap1(g,[x,y]).z1 = f/.p1 & ProjPMap1(g,[x,y]).z0 = f/.p0
by A2,A5,A10,PARTFUN1:def 6; then
ProjPMap1(g,[x,y]).z1 - ProjPMap1(g,[x,y]).z0 = f/.p1 - f/.p0
by DUALSP03:4;
hence |. ProjPMap1(g,[x,y]).z1 - ProjPMap1(g,[x,y]).z0 .| < r
by A12,EUCLID:def 2;
end;
hence thesis by A6;
end;
hence ProjPMap1(g,[x,y]) is_continuous_in z0 by FCONT_1:3;
end;
hence ProjPMap1(g,[x,y]) is continuous;
end;
theorem Th12:
for f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL,
p2 be PartFunc of [:RNS_Real,RNS_Real:],RNS_Real, z be Element of REAL
st f is_continuous_on dom f & f = g & p2 = ProjPMap2(g,z) holds
p2 is_continuous_on dom p2
proof
let f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL,
p2 be PartFunc of [:RNS_Real,RNS_Real:],RNS_Real, z be Element of REAL;
assume that
A1: f is_continuous_on dom f and
A2: f = g and
A3: p2 = ProjPMap2(g,z);
for xy0 be Point of [:RNS_Real,RNS_Real:] st xy0 in dom p2 holds
p2|(dom p2) is_continuous_in xy0
proof
let xy0 be Point of [:RNS_Real,RNS_Real:];
assume
A4: xy0 in dom p2; then
A5: xy0 in Y-section(dom g,z) by A3,MESFUN12:def 4;
A6: Y-section(dom g,z)
= {t where t is Element of [:RNS_Real,RNS_Real:] : [t,z] in dom g}
by MEASUR11:def 5; then
consider t be Element of [:RNS_Real,RNS_Real:] such that
A7: t = xy0 & [t,z] in dom g by A5;
consider xx0 be Point of RNS_Real, yy0 be Point of RNS_Real such that
A8: xy0 = [xx0,yy0] by PRVECT_3:18;
reconsider x0 = xx0, y0 = yy0 as Real;
reconsider zz=z as Point of RNS_Real;
reconsider v0 = [xx0,yy0,zz]
as Point of [:[:RNS_Real,RNS_Real:],RNS_Real:];
for r be Real st 0 < r
ex s be Real st 0 < s
& for xy1 be Point of [:RNS_Real,RNS_Real:] st xy1 in dom(p2|(dom p2))
& ||. xy1-xy0 .|| < s holds ||. p2/.xy1 - p2/.xy0 .|| < r
proof
let r be Real;
assume 0 < r; then
consider s be Real such that
A9: 0 < s and
A10: for v1 be Point of [:[:RNS_Real,RNS_Real:],RNS_Real:]
st v1 in dom f & ||. v1-v0 .|| < s holds ||. f/.v1 - f/.v0 .|| < r
by A1,A2,A7,A8,NFCONT_1:19;
now let xy1 be Point of [:RNS_Real,RNS_Real:];
assume that
A11: xy1 in dom(p2|(dom p2)) and
A12: ||. xy1-xy0 .|| < s;
xy1 in Y-section(dom g,z) by A3,A11,MESFUN12:def 4; then
A13: ex t be Element of [:RNS_Real,RNS_Real:] st t = xy1 & [t,z] in dom g
by A6;
consider xx1 be Point of RNS_Real, yy1 be Point of RNS_Real such that
A14: xy1 = [xx1,yy1] by PRVECT_3:18;
reconsider x1 = xx1, y1 = yy1 as Real;
reconsider v1 = [xx1,yy1,zz]
as Point of [:[:RNS_Real,RNS_Real:],RNS_Real:];
v1-v0 = [xx1,yy1,zz] + [-xx0,-yy0,-zz] by PRVECT_4:9; then
v1-v0 = [xx1-xx0,yy1-yy0,zz-zz] by PRVECT_4:9; then
v1-v0 = [xx1-xx0,yy1-yy0,0.RNS_Real] by RLVECT_1:15; then
A15: ||.v1-v0.||
= sqrt(||.xx1-xx0.||^2 + ||.yy1-yy0.||^2 + ||. 0.RNS_Real .||^2)
by PRVECT_4:9;
xy1-xy0 = [xx1,yy1] + [-xx0,-yy0] by A8,A14,PRVECT_3:18; then
xy1-xy0 = [xx1-xx0,yy1-yy0] by PRVECT_3:18; then
||.xy1-xy0.|| = sqrt(||.xx1-xx0.||^2 + ||.yy1-yy0.||^2)
by NDIFF_8:1; then
A16: ||. f/.v1 - f/.v0 .|| < r by A2,A10,A12,A13,A14,A15;
p2/.xy1 = ProjPMap2(g,z).xy1 by A3,A11,PARTFUN1:def 6; then
p2/.xy1 = g.([x1,y1],z) by A13,A14,MESFUN12:def 4; then
A17: p2/.xy1 = f/.v1 by A2,A13,A14,PARTFUN1:def 6;
p2/.xy0 = ProjPMap2(g,z).xy0 by A3,A4,PARTFUN1:def 6; then
p2/.xy0 = g.([x0,y0],z) by A7,A8,MESFUN12:def 4;
hence ||. p2/.xy1-p2/.xy0 .|| < r by A2,A7,A8,A16,A17,PARTFUN1:def 6;
end;
hence thesis by A9;
end;
hence p2|(dom p2) is_continuous_in xy0 by A4,NFCONT_1:7;
end;
hence p2 is_continuous_on dom p2;
end;
theorem Th13:
for f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL,
x,y be Element of REAL st f is_continuous_on dom f & f = g holds
ProjPMap1(|.g.|,[x,y]) is continuous
proof
let f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL,
x,y be Element of REAL;
assume that
A1: f is_continuous_on dom f and
A2: f = g;
set Y = dom ProjPMap1(g,[x,y]);
A3: Y = dom |. ProjPMap1(g,[x,y]) .| by VALUED_1:def 11;
ProjPMap1(g,[x,y])|Y is continuous by A1,A2,Th11; then
(abs ProjPMap1(g,[x,y]))|Y is continuous by FCONT_1:21;
hence ProjPMap1(|.g.|,[x,y]) is continuous by A3,MESFUN16:32;
end;
theorem Th14:
for f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL,
p2 be PartFunc of [:RNS_Real,RNS_Real:],RNS_Real,
z be Element of REAL st f is_continuous_on dom f & f = g
& p2 = ProjPMap2(|.g.|,z) holds p2 is_continuous_on dom p2
proof
let f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL,
p2 be PartFunc of [:RNS_Real,RNS_Real:],RNS_Real,
z be Element of REAL;
assume that
A1: f is_continuous_on dom f and
A2: f = g and
A3: p2 = ProjPMap2(|.g.|,z);
reconsider q2 = ProjPMap2(g,z)
as PartFunc of [:RNS_Real,RNS_Real:],RNS_Real;
A4: q2 is_continuous_on dom q2 by A1,A2,Th12;
A5: ProjPMap2(|.g.|,z) = |. ProjPMap2(g,z) .| by MESFUN16:32; then
p2 = ||.q2.|| by A3,MESFUN16:19; then
p2 is_continuous_on dom q2 by A4,MESFUN16:22;
hence p2 is_continuous_on dom p2 by A3,A5,VALUED_1:def 11;
end;
theorem
for f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL,
x,y be Element of REAL
st f is_uniformly_continuous_on dom f & f = g holds
ProjPMap1(g,[x,y]) is uniformly_continuous
proof
let f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL,
x,y be Element of REAL;
assume that
A1: f is_uniformly_continuous_on dom f and
A2: f = g;
for r be Real st 0 < r ex s be Real st 0 < s &
for z1,z2 be Real st z1 in dom ProjPMap1(g,[x,y])
& z2 in dom ProjPMap1(g,[x,y]) & |. z1-z2 .| < s
holds |. ProjPMap1(g,[x,y]).z1 - ProjPMap1(g,[x,y]).z2 .| < r
proof
let r be Real;
assume 0 < r; then
consider s be Real such that
A3: 0 < s and
A4: for p1,p2 be Point of [:[:RNS_Real,RNS_Real:],RNS_Real:]
st p1 in dom f & p2 in dom f & ||. p1-p2 .|| < s
holds ||. f/.p1 - f/.p2 .|| < r by A1;
now let z1,z2 be Real;
assume that
A5: z1 in dom ProjPMap1(g,[x,y]) and
A6: z2 in dom ProjPMap1(g,[x,y]) and
A7: |. z1-z2 .| < s;
A8: X-section(dom g,[x,y])
= {z where z is Element of REAL : [[x,y],z] in dom g}
by MEASUR11:def 4;
A9: z1 in X-section(dom g,[x,y]) & z2 in X-section(dom g,[x,y])
by A5,A6,MESFUN12:def 3; then
A10: ex z be Element of REAL st z = z1 & [[x,y],z] in dom g by A8;
A11: ex z be Element of REAL st z = z2 & [[x,y],z] in dom g by A8,A9;
reconsider xx = x, yy = y as Point of RNS_Real;
reconsider zz1 = z1 as Point of RNS_Real by XREAL_0:def 1;
reconsider zz2 = z2 as Point of RNS_Real by XREAL_0:def 1;
reconsider p1 = [xx,yy,zz1], p2 = [xx,yy,zz2]
as Point of [:[:RNS_Real,RNS_Real:],RNS_Real:];
A12: zz1-zz2 = z1-z2 by DUALSP03:4;
p1-p2 = [xx,yy,zz1] + [-xx,-yy,-zz2] by PRVECT_4:9; then
p1-p2 = [xx-xx,yy-yy,zz1-zz2] by PRVECT_4:9; then
p1-p2 = [0.RNS_Real,yy-yy,zz1-zz2] by RLVECT_1:15; then
p1-p2 = [0.RNS_Real,0.RNS_Real,zz1-zz2] by RLVECT_1:15; then
||. p1-p2 .||
= sqrt(||. 0.RNS_Real .||^2 +||. 0.RNS_Real .||^2 +||. zz1-zz2 .||^2)
by PRVECT_4:9; then
||. p1-p2 .|| = ||. zz1-zz2 .|| by SQUARE_1:22; then
||. p1-p2 .|| = |. z1-z2 .| by A12,EUCLID:def 2; then
A13: ||. f/.p1 - f/.p2 .|| < r by A4,A7,A2,A10,A11;
ProjPMap1(g,[x,y]).z1 = g.([x,y],z1)
& ProjPMap1(g,[x,y]).z2 = g.([x,y],z2) by A10,A11,MESFUN12:def 3; then
ProjPMap1(g,[x,y]).z1 = f/.p1 & ProjPMap1(g,[x,y]).z2 = f/.p2
by A2,A10,A11,PARTFUN1:def 6; then
ProjPMap1(g,[x,y]).z1 - ProjPMap1(g,[x,y]).z2 = f/.p1 - f/.p2
by DUALSP03:4;
hence |. ProjPMap1(g,[x,y]).z1 - ProjPMap1(g,[x,y]).z2 .| < r
by A13,EUCLID:def 2;
end;
hence thesis by A3;
end;
hence ProjPMap1(g,[x,y]) is uniformly_continuous by FCONT_2:def 1;
end;
theorem
for f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL,
p2 be PartFunc of [:RNS_Real,RNS_Real:],RNS_Real,
z be Element of REAL
st f is_uniformly_continuous_on dom f & f = g & p2 = ProjPMap2(g,z) holds
p2 is_uniformly_continuous_on dom p2
proof
let f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL,
p2 be PartFunc of [:RNS_Real,RNS_Real:],RNS_Real,
z be Element of REAL;
assume that
A1: f is_uniformly_continuous_on dom f and
A2: f = g and
A3: p2 = ProjPMap2(g,z);
reconsider zz=z as Point of RNS_Real;
A4: Y-section(dom g,z)
= {t where t is Element of [:RNS_Real,RNS_Real:] : [t,z] in dom g}
by MEASUR11:def 5;
now let r be Real;
assume 0 < r; then
consider s be Real such that
A5: 0 < s and
A6: for v1,v2 be Point of [:[:RNS_Real,RNS_Real:],RNS_Real:] st
v1 in dom f & v2 in dom f & ||. v1-v2 .|| < s holds
||. f/.v1 - f/.v2 .|| < r by A1;
take s;
thus 0 < s by A5;
hereby let xy1,xy2 be Point of [:RNS_Real,RNS_Real:];
assume that
A7: xy1 in dom p2 & xy2 in dom p2 and
A8: ||. xy1-xy2 .|| < s;
A9: xy1 in Y-section(dom g,z) & xy2 in Y-section(dom g,z)
by A3,A7,MESFUN12:def 4; then
A10: ex t1 be Element of [:RNS_Real,RNS_Real:] st t1 = xy1 & [t1,z] in dom g
by A4;
A11: ex t2 be Element of [:RNS_Real,RNS_Real:] st t2 = xy2 & [t2,z] in dom g
by A4,A9;
consider xx1 be Point of RNS_Real, yy1 be Point of RNS_Real such that
A12: xy1 = [xx1,yy1] by PRVECT_3:18;
consider xx2 be Point of RNS_Real, yy2 be Point of RNS_Real such that
A13: xy2 = [xx2,yy2] by PRVECT_3:18;
reconsider x1=xx1, y1=yy1, x2=xx2, y2=yy2 as Real;
reconsider v1 = [xx1,yy1,zz], v2 = [xx2,yy2,zz]
as Point of [:[:RNS_Real,RNS_Real:],RNS_Real:];
v1-v2 = [xx1,yy1,zz] + [-xx2,-yy2,-zz] by PRVECT_4:9; then
v1-v2 = [xx1-xx2,yy1-yy2,zz-zz] by PRVECT_4:9; then
v1-v2 = [xx1-xx2,yy1-yy2,0.RNS_Real] by RLVECT_1:15; then
A14: ||.v1-v2.||
= sqrt(||.xx1-xx2.||^2 + ||.yy1-yy2.||^2 + ||. 0.RNS_Real .||^2)
by PRVECT_4:9;
xy1-xy2 = [xx1,yy1] + [-xx2,-yy2] by A12,A13,PRVECT_3:18; then
xy1-xy2 = [xx1-xx2,yy1-yy2] by PRVECT_3:18; then
||.xy1-xy2.|| = sqrt(||.xx1-xx2.||^2 + ||.yy1-yy2.||^2)
by NDIFF_8:1; then
A15: ||. f/.v1 - f/.v2 .|| < r by A2,A6,A8,A10,A11,A12,A13,A14;
p2/.xy1 = ProjPMap2(g,z).xy1 by A3,A7,PARTFUN1:def 6; then
p2/.xy1 = g.([x1,y1],z) by A10,A12,MESFUN12:def 4; then
A16: p2/.xy1 = f/.v1 by A2,A10,A12,PARTFUN1:def 6;
p2/.xy2 = ProjPMap2(g,z).xy2 by A3,A7,PARTFUN1:def 6; then
p2/.xy2 = g.([x2,y2],z) by A13,A11,MESFUN12:def 4;
hence ||. p2/.xy1 - p2/.xy2 .|| < r by
A2,A11,A13,A15,A16,PARTFUN1:def 6;
end;
end;
hence p2 is_uniformly_continuous_on dom p2;
end;
theorem Th17:
for x,y be Element of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL, Pg1 be PartFunc of REAL,REAL
st f is_continuous_on dom f & f = g
& Pg1 = ProjPMap1(R_EAL g,[x,y]) holds Pg1 is continuous
proof
let x,y be Element of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL, Pg1 be PartFunc of REAL,REAL;
assume that
A1: f is_continuous_on dom f and
A2: f = g and
A3: Pg1 = ProjPMap1(R_EAL g,[x,y]);
Pg1 = R_EAL(ProjPMap1(g,[x,y])) by A3,MESFUN16:31; then
Pg1 = ProjPMap1(g,[x,y]) by MESFUNC5:def 7;
hence Pg1 is continuous by A1,A2,Th11;
end;
theorem Th18:
for z be Element of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL,
Pf2 be PartFunc of [:RNS_Real,RNS_Real:],RNS_Real
st f is_continuous_on dom f & f = g
& Pf2 = ProjPMap2(R_EAL g,z) holds Pf2 is_continuous_on dom Pf2
proof
let z be Element of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL,
Pf2 be PartFunc of [:RNS_Real,RNS_Real:],RNS_Real;
assume that
A1: f is_continuous_on dom f and
A2: f = g and
A3: Pf2 = ProjPMap2(R_EAL g,z);
Pf2 = R_EAL(ProjPMap2(g,z)) by A3,MESFUN16:31;
hence Pf2 is_continuous_on dom Pf2 by A1,A2,Th12,MESFUNC5:def 7;
end;
theorem Th19:
for x,y be Element of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL, Pg1 be PartFunc of REAL,REAL
st f is_continuous_on dom f & f = g
& Pg1 = ProjPMap1(|.R_EAL g.|,[x,y]) holds Pg1 is continuous
proof
let x,y be Element of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL, Pg1 be PartFunc of REAL,REAL;
assume that
A1: f is_continuous_on dom f and
A2: f = g and
A3: Pg1 = ProjPMap1(|.R_EAL g.|,[x,y]);
Pg1 = |. R_EAL(ProjPMap1(g,[x,y])) .| by A3,MESFUN16:31; then
Pg1 = R_EAL abs(ProjPMap1(g,[x,y])) by MESFUNC6:1; then
Pg1 = R_EAL ProjPMap1(|.g.|,[x,y]) by MESFUN16:32; then
Pg1 = ProjPMap1(|.g.|,[x,y]) by MESFUNC5:def 7;
hence Pg1 is continuous by A1,A2,Th13;
end;
theorem Th20:
for z be Element of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL,
Pf2 be PartFunc of [:RNS_Real,RNS_Real:],RNS_Real
st f is_continuous_on dom f & f = g
& Pf2 = ProjPMap2(|.R_EAL g.|,z) holds Pf2 is_continuous_on dom Pf2
proof
let z be Element of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL,
Pf2 be PartFunc of [:RNS_Real,RNS_Real:],RNS_Real;
assume that
A1: f is_continuous_on dom f and
A2: f = g and
A3: Pf2 = ProjPMap2(|.R_EAL g.|,z);
Pf2 = |. R_EAL(ProjPMap2(g,z)) .| by A3,MESFUN16:31; then
Pf2 = R_EAL abs(ProjPMap2(g,z)) by MESFUNC6:1; then
Pf2 = R_EAL ProjPMap2(|.g.|,z) by MESFUN16:32;
hence Pf2 is_continuous_on dom Pf2 by A1,A2,Th14,MESFUNC5:def 7;
end;
begin :: Integral of continuous three-variable functions
theorem Th21:
for I,J be Subset of REAL ,K be non empty closed_interval Subset of REAL,
x,y be Element of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL, Pg1 be PartFunc of REAL,REAL
st x in I & y in J & dom f = [:[:I,J:],K:] & f is_continuous_on [:[:I,J:],K:]
& f = g & Pg1 = ProjPMap1(R_EAL g,[x,y]) holds
Pg1|K is bounded & Pg1 is_integrable_on K
proof
let I,J be Subset of REAL ,K be non empty closed_interval Subset of REAL,
x,y be Element of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL,
Pg1 be PartFunc of REAL,REAL;
assume that
A1: x in I & y in J and
A2: dom f = [:[:I,J:],K:] and
A3: f is_continuous_on [:[:I,J:],K:] and
A4: f = g and
A5: Pg1 = ProjPMap1(R_EAL g,[x,y]);
[x,y] in [:I,J:] by A1,ZFMISC_1:87; then
dom Pg1 = K by A2,A4,A5,MESFUN16:27;
hence Pg1|K is bounded & Pg1 is_integrable_on K
by A2,A3,A4,A5,Th17,INTEGRA5:10,11;
end;
theorem Th22:
for I,J be Subset of REAL ,K be non empty closed_interval Subset of REAL,
x,y be Element of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL, Pg1 be PartFunc of REAL,REAL
st x in I & y in J & dom f = [:[:I,J:],K:] & f is_continuous_on [:[:I,J:],K:]
& f = g & Pg1 = ProjPMap1(R_EAL g,[x,y]) holds
Pg1 is_integrable_on L-Meas & integral(Pg1,K) = Integral(L-Meas,Pg1)
& integral(Pg1,K) = Integral(L-Meas,ProjPMap1(R_EAL g,[x,y]))
& integral(Pg1,K) = (Integral2(L-Meas,R_EAL g)).([x,y])
proof
let I,J be Subset of REAL ,K be non empty closed_interval Subset of REAL,
x,y be Element of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL,
Pg1 be PartFunc of REAL,REAL;
assume that
A1: x in I & y in J and
A2: dom f = [:[:I,J:],K:] and
A3: f is_continuous_on [:[:I,J:],K:] and
A4: f = g and
A5: Pg1 = ProjPMap1(R_EAL g,[x,y]);
A6: K is Element of L-Field by MEASUR10:5,MEASUR12:75;
A7: R_EAL(Pg1|K) = ProjPMap1(R_EAL g,[x,y])|K by A5,MESFUNC5:def 7;
[x,y] in [:I,J:] by A1,ZFMISC_1:87; then
A8: dom Pg1 = K by A2,A4,A5,MESFUN16:27;
Pg1|K is bounded & Pg1 is_integrable_on K by A1,A2,A3,A4,A5,Th21;
hence
Pg1 is_integrable_on L-Meas & integral(Pg1,K) = Integral(L-Meas,Pg1)
by A6,A8,MESFUN14:49;
hence thesis by A5,A8,A7,MESFUN12:def 8;
end;
theorem Th23:
for I,J be non empty closed_interval Subset of REAL, K be Subset of REAL,
z be Element of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL,
Pg2 be PartFunc of [:REAL,REAL:],REAL
st z in K & dom f = [:[:I,J:],K:] & f is_continuous_on [:[:I,J:],K:]
& f = g & Pg2 = ProjPMap2(R_EAL g,z) holds
Pg2 is_integrable_on Prod_Measure(L-Meas,L-Meas)
& Integral(Prod_Measure(L-Meas,L-Meas),Pg2)
= Integral(Prod_Measure(L-Meas,L-Meas),(ProjPMap2(R_EAL g,z)))
& Integral(Prod_Measure(L-Meas,L-Meas),Pg2)
= (Integral1(Prod_Measure(L-Meas,L-Meas),R_EAL g)).z
proof
let I,J be non empty closed_interval Subset of REAL, K be Subset of REAL,
z be Element of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL,
Pg2 be PartFunc of [:REAL,REAL:],REAL;
assume that
A1: z in K and
A2: dom f = [:[:I,J:],K:] and
A3: f is_continuous_on [:[:I,J:],K:] and
A4: f = g and
A5: Pg2 = ProjPMap2(R_EAL g,z);
reconsider Pf2 = Pg2 as PartFunc of [:RNS_Real,RNS_Real:],RNS_Real;
A6: dom Pf2 = [:I,J:] by A1,A2,A4,A5,MESFUN16:28; then
Pf2 is_continuous_on [:I,J:] by A2,A3,A4,A5,Th18;
hence Pg2 is_integrable_on Prod_Measure(L-Meas,L-Meas)
by A6,MESFUN16:57;
thus Integral(Prod_Measure(L-Meas,L-Meas),Pg2)
= Integral(Prod_Measure(L-Meas,L-Meas),(ProjPMap2(R_EAL g,z)))
by A5,MESFUNC5:def 7;
R_EAL Pg2 = ProjPMap2(R_EAL g,z) by A5,MESFUNC5:def 7;
hence Integral(Prod_Measure(L-Meas,L-Meas),Pg2)
= (Integral1(Prod_Measure(L-Meas,L-Meas),R_EAL g)).z by MESFUN12:def 7;
end;
theorem Th24:
for I,J be Subset of REAL, K be non empty closed_interval Subset of REAL,
x,y be Element of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL, Pg1 be PartFunc of REAL,REAL
st x in I & y in J & dom f = [:[:I,J:],K:] & f is_continuous_on [:[:I,J:],K:]
& f = g & Pg1 = ProjPMap1(|.R_EAL g.|,[x,y])
holds Pg1|K is bounded & Pg1 is_integrable_on K
proof
let I,J be Subset of REAL, K be non empty closed_interval Subset of REAL,
x,y be Element of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL,
Pg1 be PartFunc of REAL,REAL;
assume that
A1: x in I & y in J and
A2: dom f = [:[:I,J:],K:] and
A3: f is_continuous_on [:[:I,J:],K:] and
A4: f = g and
A5: Pg1 = ProjPMap1(|.R_EAL g.|,[x,y]);
[x,y] in [:I,J:] by A1,ZFMISC_1:87; then
dom Pg1 = K by A2,A4,A5,MESFUN16:27;
hence Pg1|K is bounded & Pg1 is_integrable_on K
by A2,A3,A4,A5,Th19,INTEGRA5:10,11;
end;
theorem Th25:
for I,J be Subset of REAL, K be non empty closed_interval Subset of REAL,
x,y be Element of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL,
Pg1 be PartFunc of REAL,REAL, E be Element of L-Field
st x in I & y in J & dom f = [:[:I,J:],K:] & f is_continuous_on [:[:I,J:],K:]
& f = g & Pg1 = ProjPMap1(|.R_EAL g.|,[x,y]) & E = K holds
Pg1 is E-measurable
proof
let I,J be Subset of REAL, K be non empty closed_interval Subset of REAL,
x,y be Element of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL,
Pg1 be PartFunc of REAL,REAL, E be Element of L-Field;
assume that
A1: x in I & y in J and
A2: dom f = [:[:I,J:],K:] and
A3: f is_continuous_on [:[:I,J:],K:] and
A4: f = g and
A5: Pg1 = ProjPMap1(|.R_EAL g.|,[x,y]) and
A6: E = K;
[x,y] in [:I,J:] by A1,ZFMISC_1:87; then
A7:dom Pg1 = K by A2,A4,A5,MESFUN16:27;
Pg1|K is bounded & Pg1 is_integrable_on K by A1,A2,A3,A4,A5,Th24;
hence Pg1 is E-measurable by A6,A7,MESFUN14:49;
end;
theorem Th26:
for I,J be Subset of REAL, K be non empty closed_interval Subset of REAL,
x,y be Element of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL, Pg1 be PartFunc of REAL,REAL
st x in I & y in J & dom f = [:[:I,J:],K:] & f is_continuous_on [:[:I,J:],K:]
& f = g & Pg1 = ProjPMap1(|.R_EAL g.|,[x,y])
holds
Pg1 is_integrable_on L-Meas
& integral(Pg1,K) = Integral(L-Meas,Pg1)
& integral(Pg1,K) = Integral(L-Meas,ProjPMap1(|.R_EAL g.|,[x,y]))
& integral(Pg1,K) = (Integral2(L-Meas,|.R_EAL g.|)).([x,y])
proof
let I,J be Subset of REAL, K be non empty closed_interval Subset of REAL,
x,y be Element of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL,
Pg1 be PartFunc of REAL,REAL;
assume that
A1: x in I & y in J and
A2: dom f = [:[:I,J:],K:] and
A3: f is_continuous_on [:[:I,J:],K:] and
A4: f = g and
A5: Pg1 = ProjPMap1(|.R_EAL g.|,[x,y]);
A6: K is Element of L-Field by MEASUR10:5,MEASUR12:75;
[x,y] in [:I,J:] by A1,ZFMISC_1:87; then
A7:dom Pg1 = K by A2,A4,A5,MESFUN16:27;
Pg1|K is bounded & Pg1 is_integrable_on K by A1,A2,A3,A4,A5,Th24;
hence
A8: Pg1 is_integrable_on L-Meas
& integral(Pg1,K) = Integral(L-Meas,Pg1) by A6,A7,MESFUN14:49;
R_EAL(Pg1) = ProjPMap1(|.R_EAL g.|,[x,y]) by A5,MESFUNC5:def 7;
hence thesis by A8,MESFUN12:def 8;
end;
theorem Th27:
for I,J be non empty closed_interval Subset of REAL, K be Subset of REAL,
z be Element of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL,
Pg2 be PartFunc of [:REAL,REAL:],REAL,
E be Element of sigma measurable_rectangles(L-Field,L-Field)
st z in K & dom f = [:[:I,J:],K:] & f is_continuous_on [:[:I,J:],K:]
& f = g & Pg2 = ProjPMap2(|.R_EAL g.|,z) & E = [:I,J:] holds
Pg2 is E-measurable
proof
let I,J be non empty closed_interval Subset of REAL, K be Subset of REAL,
z be Element of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL,
Pg2 be PartFunc of [:REAL,REAL:],REAL,
E be Element of sigma measurable_rectangles(L-Field,L-Field);
assume that
A1: z in K and
A2: dom f = [:[:I,J:],K:] and
A3: f is_continuous_on [:[:I,J:],K:] and
A4: f = g and
A5: Pg2 = ProjPMap2(|.R_EAL g.|,z) and
A6: E = [:I,J:];
reconsider Pf2 = Pg2 as PartFunc of [:RNS_Real,RNS_Real:],RNS_Real;
dom Pf2 = [:I,J:] by A1,A2,A4,A5,MESFUN16:28;
hence Pg2 is E-measurable by A2,A3,A4,A5,A6,Th20,MESFUN16:50;
end;
theorem Th28:
for I,J be non empty closed_interval Subset of REAL, K be Subset of REAL,
z be Element of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL,
Pg2 be PartFunc of [:REAL,REAL:],REAL
st z in K & dom f = [:[:I,J:],K:] & f is_continuous_on [:[:I,J:],K:]
& f = g & Pg2 = ProjPMap2(|.R_EAL g.|,z) holds
Pg2 is_integrable_on Prod_Measure(L-Meas,L-Meas)
& Integral(Prod_Measure(L-Meas,L-Meas),Pg2)
= Integral(Prod_Measure(L-Meas,L-Meas),(ProjPMap2(|.R_EAL g.|,z)))
& Integral(Prod_Measure(L-Meas,L-Meas),Pg2)
= (Integral1(Prod_Measure(L-Meas,L-Meas),|.R_EAL g.|)).z
proof
let I,J be non empty closed_interval Subset of REAL, K be Subset of REAL,
z be Element of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL,
Pg2 be PartFunc of [:REAL,REAL:],REAL;
assume that
A1: z in K and
A2: dom f = [:[:I,J:],K:] and
A3: f is_continuous_on [:[:I,J:],K:] and
A4: f = g and
A5: Pg2 = ProjPMap2(|.R_EAL g.|,z);
reconsider Pf2 = Pg2 as PartFunc of [:RNS_Real,RNS_Real:],RNS_Real;
A6: dom Pf2 = [:I,J:] by A1,A2,A4,A5,MESFUN16:28; then
Pf2 is_continuous_on [:I,J:] by A2,A3,A4,A5,Th20;
hence Pg2 is_integrable_on Prod_Measure(L-Meas,L-Meas)
by A6,MESFUN16:57;
thus Integral(Prod_Measure(L-Meas,L-Meas),Pg2)
= Integral(Prod_Measure(L-Meas,L-Meas),(ProjPMap2(|.R_EAL g.|,z)))
by A5,MESFUNC5:def 7;
R_EAL Pg2 = ProjPMap2(|.R_EAL g.|,z) by A5,MESFUNC5:def 7;
hence Integral(Prod_Measure(L-Meas,L-Meas),Pg2)
= (Integral1(Prod_Measure(L-Meas,L-Meas),|.R_EAL g.|)).z
by MESFUN12:def 7;
end;
theorem Th29:
for I,J,K be non empty closed_interval Subset of REAL,
f being PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL,
E be Element of sigma measurable_rectangles
(sigma measurable_rectangles(L-Field,L-Field),L-Field)
st [:[:I,J:],K:] = dom f & f is_continuous_on [:[:I,J:],K:] & f = g
& E = [:[:I,J:],K:] holds g is E-measurable
proof
let I,J,K be non empty closed_interval Subset of REAL,
f being PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL,
E be Element of sigma measurable_rectangles
(sigma measurable_rectangles(L-Field,L-Field),L-Field);
assume that
A1: [:[:I,J:],K:] = dom f and
A2: f is_continuous_on [:[:I,J:],K:] and
A3: f = g and
A4: E = [:[:I,J:],K:];
for r being Real holds E /\ (less_dom (g,r))
in sigma measurable_rectangles
(sigma measurable_rectangles(L-Field,L-Field),L-Field)
proof
let r be Real;
A5: less_dom(g,r) = g"(].-infty,r.[) by MESFUN16:17;
consider H be Subset of [:RNS_Real,RNS_Real,RNS_Real:] such that
A6: H /\ E = f"(].-infty,r.[) & H is open by A1,A2,A4,MESFUN16:24;
H in sigma measurable_rectangles
(sigma measurable_rectangles(L-Field,L-Field),L-Field)
by A6,Th7; then
f"(].-infty,r.[) in sigma measurable_rectangles
(sigma measurable_rectangles(L-Field,L-Field),L-Field)
by A6,FINSUB_1:def 2;
hence E /\ (less_dom (g,r)) in
sigma measurable_rectangles
(sigma measurable_rectangles(L-Field,L-Field),L-Field)
by A3,A5,FINSUB_1:def 2;
end;
hence g is E-measurable by MESFUNC6:12;
end;
theorem Th30:
for I,J,K be non empty closed_interval Subset of REAL, x,y be Element of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL
st [:[:I,J:],K:] = dom f & f is_continuous_on [:[:I,J:],K:] & f = g
holds for e be Real st 0 < e holds
ex r be Real st 0 < r
& for u1,u2 be Element of [:REAL,REAL:], x1,y1,x2,y2 be Real
st u1=[x1,y1] & u2=[x2,y2] & |.x2-x1.| < r & |.y2-y1.| < r
& u1 in [:I,J:] & u2 in [:I,J:] holds
for z be Element of REAL st z in K holds
|. ProjPMap1(|.R_EAL g.|,u2).z - ProjPMap1(|.R_EAL g.|,u1).z .| < e
proof
let I,J,K be non empty closed_interval Subset of REAL,
x,y be Element of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL;
assume that
A1: [:[:I,J:],K:] = dom f and
A2: f is_continuous_on [:[:I,J:],K:] and
A3: f = g;
dom(R_EAL g) = [:[:I,J:],K:] by A1,A3,MESFUNC5:def 7; then
A4: dom |. R_EAL g .| = [:[:I,J:],K:] by MESFUNC1:def 10;
A5:for x be Element of [:REAL,REAL:], y be Element of REAL
st x in [:I,J:] & y in K holds
(ProjPMap1(|.R_EAL g.|,x)).y =(|.R_EAL g.|).(x,y)
& (|.R_EAL g.|).(x,y) = (|.g.|).([x,y])
proof
let x be Element of [:REAL,REAL:], y be Element of REAL;
assume
A6: x in [:I,J:] & y in K;
hence (ProjPMap1(|.R_EAL g.|,x)).y =(|.R_EAL g.|).(x,y)
by A4,ZFMISC_1:87,MESFUN12:def 3;
[x,y] in dom g by A6,A1,A3,ZFMISC_1:87; then
A7: [x,y] in dom |.g.| by VALUED_1:def 11;
A8: (R_EAL g).([x,y]) = g.([x,y]) by MESFUNC5:def 7;
(|.R_EAL g.|).(x,y) = |.(R_EAL g).([x,y]).|
by A4,A6,ZFMISC_1:87,MESFUNC1:def 10; then
(|.R_EAL g.|).(x,y) = |. g.([x,y]) .| by A8,EXTREAL1:12;
hence (|.R_EAL g.|).(x,y) = (|.g.|).([x,y]) by VALUED_1:def 11,A7;
end;
let e be Real;
assume 0 < e; then
consider r be Real such that
A9: 0 < r
& for x1,x2,y1,y2,z1,z2 be Real st x1 in I & x2 in I & y1 in J & y2 in J
& z1 in K & z2 in K & |.x2-x1.| < r & |.y2-y1.| < r & |.z2-z1.| < r
holds |. (|.g.|).([x2,y2,z2])-(|.g.|).([x1,y1,z1]) .| < e
by A2,A3,Th10;
take r;
thus 0 < r by A9;
let u1,u2 be Element of [:REAL,REAL:], x1,y1,x2,y2 be Real;
assume
A10:u1=[x1,y1] & u2=[x2,y2] & |.x2-x1.| < r & |.y2-y1.| < r
& u1 in [:I,J:] & u2 in [:I,J:];
let z be Element of REAL;
A11:x1 in I & x2 in I & y1 in J & y2 in J by A10,ZFMISC_1:87;
assume
A12:z in K;
|. z-z .| < r by A9; then
|. (|.g.|).([x2,y2,z])-(|.g.|).([x1,y1,z]) .| < e by A9,A10,A11,A12; then
A13: |. (|.g.|).([u2,z])-(|.g.|).([ u1,z]).| < e by A10;
a13: (|.g.|).([u2,z])-(|.g.|).([ u1,z]) =
(|.g.|).([u2,z]) qua ExtReal -(|.g.|).([ u1,z]);
ProjPMap1(|.R_EAL g.|,u1).z = (|.R_EAL g.|).(u1,z)
& (|.R_EAL g.|).(u1,z) = (|.g.|).([u1,z])
& ProjPMap1(|.R_EAL g.|,u2).z = (|.R_EAL g.|).(u2,z)
& (|.R_EAL g.|).(u2,z) = (|.g.|).([u2,z]) by A5,A10,A12;
hence thesis by A13,a13,EXTREAL1:12;
end;
theorem Th31:
for I,J,K be non empty closed_interval Subset of REAL, x,y be Element of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL
st [:[:I,J:],K:] = dom f & f is_continuous_on [:[:I,J:],K:] & f = g
holds for e be Real st 0 < e holds
ex r be Real st 0 < r
& for u1,u2 be Element of [:REAL,REAL:], x1,y1,x2,y2 be Real
st u1=[x1,y1] & u2=[x2,y2] & |.x2-x1.| < r & |.y2-y1.| < r
& u1 in [:I,J:] & u2 in [:I,J:]
holds for z be Element of REAL st z in K
holds |. ProjPMap1(R_EAL g,u2).z-ProjPMap1(R_EAL g,u1).z .| < e
proof
let I,J,K be non empty closed_interval Subset of REAL,
x,y be Element of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL;
assume that
A1: [:[:I,J:],K:] = dom f and
A2: f is_continuous_on [:[:I,J:],K:] and
A3: f = g;
A4:dom(R_EAL g) = [:[:I,J:],K:] by A1,A3,MESFUNC5:def 7;
let e be Real;
assume 0 < e; then
consider r be Real such that
A5: 0 < r
& for x1,x2,y1,y2,z1,z2 be Real st x1 in I & x2 in I & y1 in J & y2 in J
& z1 in K & z2 in K & |.x2-x1.| < r & |.y2-y1.| < r & |.z2-z1.| < r
holds |. g.([x2,y2,z2])-g.([x1,y1,z1]) .| < e by A2,A3,Th8;
take r;
thus 0 < r by A5;
let u1,u2 be Element of [:REAL,REAL:], x1,y1,x2,y2 be Real;
assume
A6:u1=[x1,y1] & u2=[x2,y2] & |.x2-x1.| < r & |.y2-y1.| < r
& u1 in [:I,J:] & u2 in [:I,J:];
let z be Element of REAL;
A7:x1 in I & x2 in I & y1 in J & y2 in J by A6,ZFMISC_1:87;
assume
A8:z in K;
|. z-z .| < r by A5; then
|. g.([x2,y2,z])-g.([x1,y1,z]) .| < e by A5,A6,A7,A8; then
A9: |. g.([u2,z])-g.([u1,z]).| < e by A6;
a9: g.([u2,z])-g.([u1,z]) = g.([u2,z]) qua ExtReal -g.([u1,z]);
(ProjPMap1(R_EAL g,u1)).z = (R_EAL g).(u1,z)
& (R_EAL g).(u1,z) = g.([u1,z])
& (ProjPMap1(R_EAL g,u2)).z = (R_EAL g).(u2,z)
& (R_EAL g).(u2,z) = g.([u2,z])
by A4,A6,A8,ZFMISC_1:87,MESFUNC5:def 7,MESFUN12:def 3;
hence thesis by A9,a9,EXTREAL1:12;
end;
Lm4:
for I,J be non empty closed_interval Subset of REAL, K be Subset of REAL,
v be Element of [:REAL,REAL:],
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL
st [:[:I,J:],K:] = dom f & f = g & not v in [:I,J:]
holds Integral2(L-Meas,|.R_EAL g.|).v = 0
& Integral2(L-Meas,R_EAL g).v = 0
proof
let I,J be non empty closed_interval Subset of REAL,
K be Subset of REAL,
v be Element of [:REAL,REAL:],
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL;
assume that
A1: [:[:I,J:],K:] = dom f and
A2: f = g and
A3: not v in [:I,J:];
dom ProjPMap1(|.R_EAL g.|,v) = {} by A1,A2,A3,MESFUN16:27; then
Integral(L-Meas,ProjPMap1(|.R_EAL g.|,v)) = 0 by MESFUN16:1;
hence Integral2(L-Meas,|.R_EAL g.|).v = 0 by MESFUN12:def 8;
dom ProjPMap1(R_EAL g,v) = {} by A1,A2,A3,MESFUN16:27; then
Integral(L-Meas,ProjPMap1(R_EAL g,v)) = 0 by MESFUN16:1;
hence Integral2(L-Meas,R_EAL g).v = 0 by MESFUN12:def 8;
end;
Lm5:
for I,J be non empty closed_interval Subset of REAL, K be Subset of REAL,
z be Element of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL
st [:[:I,J:],K:] = dom f & f = g & not z in K
holds Integral1(Prod_Measure(L-Meas,L-Meas),|.R_EAL g.|).z = 0
& Integral1(Prod_Measure(L-Meas,L-Meas),R_EAL g).z = 0
proof
let I,J be non empty closed_interval Subset of REAL,
K be Subset of REAL, z be Element of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL;
assume that
A1: [:[:I,J:],K:] = dom f and
A2: f = g and
A3: not z in K;
dom ProjPMap2(|.R_EAL g.|,z) = {} by A1,A2,A3,MESFUN16:28; then
Integral(Prod_Measure(L-Meas,L-Meas),ProjPMap2(|.R_EAL g.|,z)) = 0
by MESFUN16:1;
hence Integral1(Prod_Measure(L-Meas,L-Meas),|.R_EAL g.|).z = 0
by MESFUN12:def 7;
dom ProjPMap2(R_EAL g,z) = {} by A1,A2,A3,MESFUN16:28; then
Integral(Prod_Measure(L-Meas,L-Meas),ProjPMap2(R_EAL g,z)) = 0
by MESFUN16:1;
hence Integral1(Prod_Measure(L-Meas,L-Meas),R_EAL g).z = 0
by MESFUN12:def 7;
end;
theorem Th32:
for I,J,K be non empty closed_interval Subset of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL
st [:[:I,J:],K:] = dom f & f is_continuous_on [:[:I,J:],K:] & f = g
holds
Integral2(L-Meas,|.R_EAL g.|) is Function of [:REAL,REAL:],REAL
& Integral2(L-Meas,|.R_EAL g.|)| [:I,J:] is PartFunc of [:REAL,REAL:],REAL
& Integral2(L-Meas,R_EAL g) is Function of [:REAL,REAL:],REAL
& Integral2(L-Meas,R_EAL g)| [:I,J:] is PartFunc of [:REAL,REAL:],REAL
proof
let I,J,K be non empty closed_interval Subset of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL;
assume that
A1: [:[:I,J:],K:] = dom f and
A2: f is_continuous_on [:[:I,J:],K:] and
A3: f = g;
set F = Integral2(L-Meas,|.R_EAL g.|);
set RF = Integral2(L-Meas,R_EAL g);
A4: dom F = [:REAL,REAL:] by FUNCT_2:def 1;
A5: dom RF = [:REAL,REAL:] by FUNCT_2:def 1;
now let q be object;
assume q in rng F; then
consider p be Element of [:REAL,REAL:] such that
A6: p in dom F & q=F.p by PARTFUN1:3;
consider x,y be object such that
A7: x in REAL & y in REAL & p = [x,y] by ZFMISC_1:84;
reconsider x,y as Element of REAL by A7;
reconsider Pg = ProjPMap1(|.R_EAL g.|,[x,y]) as PartFunc of REAL,REAL
by MESFUN16:30;
per cases;
suppose p in [:I,J:]; then
x in I & y in J by A7,ZFMISC_1:87; then
Integral2(L-Meas,|.R_EAL g.|).([x,y]) = integral(Pg,K) by A1,A2,A3,Th26;
hence q in REAL by A6,A7,XREAL_0:def 1;
end;
suppose not p in [:I,J:]; then
Integral2(L-Meas,|.R_EAL g.|).p = 0 by A1,A3,Lm4;
hence q in REAL by A6,XREAL_0:def 1;
end;
end; then
rng F c= REAL;
hence Integral2(L-Meas,|.R_EAL g.|)
is Function of [:REAL,REAL:],REAL by A4,RELSET_1:4;
hence Integral2(L-Meas,|.R_EAL g.|)| [:I,J:]
is PartFunc of [:REAL,REAL:],REAL by PARTFUN1:11;
now let q be object;
assume q in rng RF; then
consider p be Element of [:REAL,REAL:] such that
A8: p in dom RF & q=RF.p by PARTFUN1:3;
consider x,y be object such that
A9: x in REAL & y in REAL & p = [x,y] by ZFMISC_1:84;
reconsider x,y as Element of REAL by A9;
reconsider Pg = ProjPMap1(R_EAL g,[x,y]) as PartFunc of REAL,REAL
by MESFUN16:30;
per cases;
suppose p in [:I,J:]; then
x in I & y in J by A9,ZFMISC_1:87; then
Integral2(L-Meas,R_EAL g).([x,y]) = integral(Pg,K) by A1,A2,A3,Th22;
hence q in REAL by A8,A9,XREAL_0:def 1;
end;
suppose not p in [:I,J:]; then
Integral2(L-Meas,R_EAL g).p = 0 by A1,A3,Lm4;
hence q in REAL by A8,XREAL_0:def 1;
end;
end; then
rng RF c= REAL;
hence Integral2(L-Meas,R_EAL g) is Function of [:REAL,REAL:],REAL
by A5,RELSET_1:4;
hence thesis by PARTFUN1:11;
end;
theorem Th33:
for I,J,K be non empty closed_interval Subset of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL,
Fz be PartFunc of [:RNS_Real,RNS_Real:],RNS_Real
st [:[:I,J:],K:] = dom f & f is_continuous_on [:[:I,J:],K:] & f = g
& Fz = Integral2(L-Meas,|.R_EAL g.|)| [:I,J:] holds
Fz is_uniformly_continuous_on [:I,J:]
proof
let I,J,K be non empty closed_interval Subset of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL,
Fz be PartFunc of [:RNS_Real,RNS_Real:],RNS_Real;
assume that
A1: [:[:I,J:],K:] = dom f and
A2: f is_continuous_on [:[:I,J:],K:] and
A3: f = g and
A4: Fz = Integral2(L-Meas,|.R_EAL g.|)| [:I,J:];
dom Integral2(L-Meas,|.R_EAL g.|) = [:REAL,REAL:] by FUNCT_2:def 1; then
A5: dom Fz = [:I,J:] by A4;
reconsider G = Fz as PartFunc of [:REAL,REAL:],REAL;
consider s,t be Real such that
A6: K = [.s,t.] by MEASURE5:def 3;
A7: s <= t by A6,XXREAL_1:29;
A8: K = ['s,t'] by A6,INTEGRA5:def 3,XXREAL_1:29;
A9: s in K & t in K by A6,A7;
A10:K is Element of L-Field by MEASUR10:5,MEASUR12:75;
now let e be Real;
assume
A11: 0 < e;
per cases;
suppose
A12: s = t;
consider r be Real such that
A13: 0 < r
& for u1,u2 be Element of [:REAL,REAL:], x1,y1,x2,y2 be Real
st u1=[x1,y1] & u2=[x2,y2] & |.x2-x1.| < r & |.y2-y1.| < r
& u1 in [:I,J:] & u2 in [:I,J:] holds
for z be Element of REAL st z in K holds
|. ProjPMap1(|.R_EAL g.|,u2).z-ProjPMap1(|.R_EAL g.|,u1).z .|
< e by A1,A2,A3,A11,Th30;
take r;
thus 0 < r by A13;
thus for x1,x2,y1,y2 be Real st [x1,y1] in [:I,J:] & [x2,y2] in [:I,J:]
& |.x2-x1.| < r & |.y2-y1.| < r holds
|. G.([x2,y2])-G.([x1,y1]) .| < e
proof
let x1,x2,y1,y2 be Real;
assume
A14: [x1,y1] in [:I,J:] & [x2,y2] in [:I,J:] & |.x2-x1.| < r & |.y2-y1.| < r;
A15: x1 in I & x2 in I & y1 in J & y2 in J by A14,ZFMISC_1:87;
reconsider xx1=x1, xx2=x2, yy1=y1, yy2=y2
as Element of REAL by XREAL_0:def 1;
reconsider u1=[xx1,yy1] as Element of [:REAL,REAL:];
reconsider Pg0 = ProjPMap1(|.R_EAL g.|,u1) as PartFunc of REAL,REAL
by MESFUN16:30;
A16: dom Pg0 = K by A1,A3,A14,MESFUN16:27;
A17: Pg0 is continuous by A1,A2,A3,Th19;
A18: Pg0|K is bounded & Pg0 is_integrable_on K
by A1,A2,A3,A15,Th24; then
A19: Pg0 is_integrable_on L-Meas & integral(Pg0,K) = Integral(L-Meas,Pg0)
by A10,A16,MESFUN14:49;
R_EAL(Pg0) = ProjPMap1(|.R_EAL g.|,[xx1,yy1])
by MESFUNC5:def 7; then
Integral2(L-Meas,|.R_EAL g.|).([xx1,yy1]) = integral(Pg0,K)
by A19,MESFUN12:def 8; then
A20: G.u1 = integral(Pg0,K) by A4,A14,FUNCT_1:49;
reconsider xx2=x2,yy2=y2 as Element of REAL by XREAL_0:def 1;
reconsider u2=[xx2,yy2] as Element of [:REAL,REAL:];
reconsider Pg1 = ProjPMap1(|.R_EAL g.|,u2) as PartFunc of REAL,REAL
by MESFUN16:30;
A21: dom Pg1 = K by A1,A3,A14,MESFUN16:27;
A22: Pg1 is continuous by A1,A2,A3,Th19;
A23: Pg1|K is bounded & Pg1 is_integrable_on K
by A1,A2,A3,A15,Th24; then
A24: Pg1 is_integrable_on L-Meas & integral(Pg1,K) = Integral(L-Meas,Pg1)
by A10,A21,MESFUN14:49;
R_EAL(Pg1) = ProjPMap1(|.R_EAL g.|,[xx2,yy2])
by MESFUNC5:def 7; then
Integral2(L-Meas,|.R_EAL g.|).([xx2,yy2]) = integral(Pg1,K)
by A24,MESFUN12:def 8; then
G.u2 = integral(Pg1,K) by A4,A14,FUNCT_1:49; then
A25: |.G.u2-G.u1.| = |. integral(Pg1-Pg0,K) .|
by A21,A23,A16,A18,A20,INTEGRA6:11;
A26: dom(Pg1-Pg0) = dom Pg1 /\ dom Pg0 by VALUED_1:12; then
A27: (Pg1-Pg0)|K is bounded & (Pg1-Pg0) is_integrable_on K
by A16,A17,A21,A22,INTEGRA5:10,11;
for y be Real st y in K holds |. (Pg1-Pg0).y .| <= e
proof
let y be Real;
assume
A28: y in K; then
A29: |. ProjPMap1(|.R_EAL g.|,u2).y-ProjPMap1(|.R_EAL g.|,u1).y .| < e
by A13,A14;
A30: -(ProjPMap1(|.R_EAL g.|,u1)).y = -Pg0.y by XXREAL_3:def 3;
ProjPMap1(|.R_EAL g.|,u2).y-ProjPMap1(|.R_EAL g.|,u1).y
= ProjPMap1(|.R_EAL g.|,u2).y + -ProjPMap1(|.R_EAL g.|,u1).y
by XXREAL_3:def 4; then
ProjPMap1(|.R_EAL g.|,u2).y-ProjPMap1(|.R_EAL g.|,u1).y
= Pg1.y + -Pg0.y by A30,XXREAL_3:def 2
.= Pg1.y - Pg0.y
.= (Pg1-Pg0).y by A16,A21,A26,A28,VALUED_1:13;
hence |. (Pg1-Pg0).y .| <= e by A29,EXTREAL1:12;
end; then
|. integral(Pg1-Pg0,s,t) .| <= e * (t-s)
by A7,A8,A9,A16,A21,A26,A27,INTEGRA6:23;
hence |. G.([x2,y2])-G.([x1,y1]) .| < e
by A8,A12,A11,A25,INTEGRA5:def 4;
end;
end;
suppose s <> t; then
A31: s < t by A7,XXREAL_0:1;
set e1=e/2;
A32: 0 < e1 & e1 < e by A11,XREAL_1:215,216;
A33: 0 < t-s by A31,XREAL_1:50; then
consider r be Real such that
A34: 0 < r
& for u1,u2 be Element of [:REAL,REAL:], x1,y1,x2,y2 be Real
st u1=[x1,y1] & u2=[x2,y2] & |.x2-x1.| < r & |.y2-y1.| < r
& u1 in [:I,J:] & u2 in [:I,J:] holds
for z be Element of REAL st z in K holds
|. ProjPMap1(|.R_EAL g.|,u2).z-ProjPMap1(|.R_EAL g.|,u1).z .|
< e1 / (t-s) by A1,A2,A3,Th30,XREAL_1:139,A32;
take r;
thus 0 < r by A34;
let x1,x2,y1,y2 be Real;
assume
A35: [x1,y1] in [:I,J:] & [x2,y2] in [:I,J:] & |.x2-x1.| < r & |.y2-y1.| < r;
A36: x1 in I & x2 in I & y1 in J & y2 in J by A35,ZFMISC_1:87;
reconsider xx1=x1,yy1=y1 as Element of REAL by XREAL_0:def 1;
reconsider u1=[xx1,yy1] as Element of [:REAL,REAL:];
reconsider Pg0 = ProjPMap1(|.R_EAL g.|,u1) as PartFunc of REAL,REAL
by MESFUN16:30;
A37: dom Pg0 = K by A1,A3,A35,MESFUN16:27;
A38: Pg0 is continuous by A1,A2,A3,Th19;
A39: Pg0|K is bounded & Pg0 is_integrable_on K
by A1,A2,A3,A36,Th24; then
A40: Pg0 is_integrable_on L-Meas & integral(Pg0,K) = Integral(L-Meas,Pg0)
by A10,A37,MESFUN14:49;
R_EAL(Pg0) = ProjPMap1(|.R_EAL g.|,[xx1,yy1])
by MESFUNC5:def 7; then
Integral2(L-Meas,|.R_EAL g.|).([xx1,yy1]) = integral(Pg0,K)
by A40,MESFUN12:def 8; then
A41: G.u1 = integral(Pg0,K) by A4,A35,FUNCT_1:49;
reconsider xx2=x2,yy2=y2 as Element of REAL by XREAL_0:def 1;
reconsider u2=[xx2,yy2] as Element of [:REAL,REAL:];
reconsider Pg1 = ProjPMap1(|.R_EAL g.|,u2) as PartFunc of REAL,REAL
by MESFUN16:30;
A42: dom Pg1 = K by A1,A3,A35,MESFUN16:27;
A43: Pg1 is continuous by A1,A2,A3,Th19;
A44: Pg1|K is bounded & Pg1 is_integrable_on K by A1,A2,A3,A36,Th24; then
A45: Pg1 is_integrable_on L-Meas & integral(Pg1,K) = Integral(L-Meas,Pg1)
by A10,A42,MESFUN14:49;
R_EAL(Pg1) = ProjPMap1(|.R_EAL g.|,[xx2,yy2]) by MESFUNC5:def 7; then
Integral2(L-Meas,|.R_EAL g.|).([xx2,yy2]) = integral(Pg1,K)
by A45,MESFUN12:def 8; then
G.u2 = integral(Pg1,K) by A4,A35,FUNCT_1:49; then
A46: |.G.u2-G.u1.| = |. integral(Pg1-Pg0,K) .|
by A42,A44,A37,A39,A41,INTEGRA6:11;
A47: dom(Pg1-Pg0) = dom Pg1 /\ dom Pg0 by VALUED_1:12; then
A48: (Pg1-Pg0)|K is bounded & (Pg1-Pg0) is_integrable_on K
by A37,A38,A42,A43,INTEGRA5:10,11;
A49: s in ['s,t'] & t in ['s,t'] by A6,A7,A8;
for y be Real st y in K holds |. (Pg1-Pg0).y .| <= e1/(t-s)
proof
let y be Real;
assume
A50: y in K;
A51: |. ProjPMap1(|.R_EAL g.|,u2).y-ProjPMap1(|.R_EAL g.|,u1).y .|
< e1 / (t-s) by A34,A35,A50;
A52: - ProjPMap1(|.R_EAL g.|,u1).y = - Pg0.y by XXREAL_3:def 3;
ProjPMap1(|.R_EAL g.|,u2).y - ProjPMap1(|.R_EAL g.|,u1).y
= ProjPMap1(|.R_EAL g.|,u2).y + - ProjPMap1(|.R_EAL g.|,u1).y
by XXREAL_3:def 4
.= Pg1.y + -Pg0.y by A52,XXREAL_3:def 2
.= Pg1.y -Pg0.y
.= (Pg1-Pg0).y by A37,A42,A47,A50,VALUED_1:13;
hence thesis by A51,EXTREAL1:12;
end; then
|. integral(Pg1-Pg0,s,t) .| <= (e1/(t-s)) * (t-s)
by A7,A8,A37,A42,A47,A48,A49,INTEGRA6:23; then
|. integral(Pg1-Pg0,K) .| <= (e1/(t-s)) * (t-s)
by A6,A8,XXREAL_1:29,INTEGRA5:def 4; then
|. integral(Pg1-Pg0,K) .| <= e1 by A33,XCMPLX_1:87;
hence |. G.([x2,y2]) - G.([x1,y1]) .| < e by A32,A46,XXREAL_0:2;
end;
end;
hence Fz is_uniformly_continuous_on [:I,J:] by A5,MESFUN16:10;
end;
theorem Th34:
for I,J,K be non empty closed_interval Subset of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL,
Fz be PartFunc of [:RNS_Real,RNS_Real:],RNS_Real
st [:[:I,J:],K:] = dom f & f is_continuous_on [:[:I,J:],K:] & f = g
& Fz = Integral2(L-Meas,R_EAL g)| [:I,J:] holds
Fz is_uniformly_continuous_on [:I,J:]
proof
let I,J,K be non empty closed_interval Subset of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL,
Fz be PartFunc of [:RNS_Real,RNS_Real:],RNS_Real;
assume that
A1: [:[:I,J:],K:] = dom f and
A2: f is_continuous_on [:[:I,J:],K:] and
A3: f = g and
A4: Fz = Integral2(L-Meas,R_EAL g)| [:I,J:];
dom Integral2(L-Meas,R_EAL g) = [:REAL,REAL:] by FUNCT_2:def 1; then
A5: dom Fz = [:I,J:] by A4;
reconsider RG = Fz as PartFunc of [:REAL,REAL:],REAL;
consider s,t be Real such that
A6: K = [.s,t.] by MEASURE5:def 3;
A7: s <= t by A6,XXREAL_1:29;
A8: K = ['s,t'] by A6,INTEGRA5:def 3,XXREAL_1:29;
now let e be Real;
assume
A9: 0 < e;
per cases;
suppose
A10: s=t;
consider r be Real such that
A11: 0 < r
& for u1,u2 be Element of [:REAL,REAL:], x1,y1,x2,y2 be Real
st u1=[x1,y1] & u2=[x2,y2] & |.x2-x1.| < r & |.y2-y1.| < r
& u1 in [:I,J:] & u2 in [:I,J:] holds
for z be Element of REAL st z in K holds
|. (ProjPMap1(R_EAL g,u2)).z - (ProjPMap1(R_EAL g,u1)).z.| < e
by A1,A2,A3,A9,Th31;
take r;
thus 0 < r by A11;
thus for x1,x2,y1,y2 be Real st
[x1,y1] in [:I,J:] & [x2,y2] in [:I,J:] & |.x2-x1.| < r & |.y2-y1.| < r
holds |. RG.([x2,y2]) - RG.([x1,y1]) .| < e
proof
let x1,x2,y1,y2 be Real;
assume
A12: [x1,y1] in [:I,J:] & [x2,y2] in [:I,J:] & |.x2-x1.| < r & |.y2-y1.| < r;
A13: x1 in I & x2 in I & y1 in J & y2 in J by A12,ZFMISC_1:87;
reconsider xx1=x1, xx2=x2, yy1=y1, yy2=y2 as Element of REAL
by XREAL_0:def 1;
x1 in REAL & y1 in REAL by XREAL_0:def 1; then
reconsider u1=[x1,y1] as Element of [:REAL,REAL:] by ZFMISC_1:def 2;
reconsider Pg0 = ProjPMap1(R_EAL g,u1) as PartFunc of REAL,REAL
by MESFUN16:30;
A14: dom Pg0 = K by A1,A3,A12,MESFUN16:27;
A15: Pg0 is continuous by A1,A2,A3,A13,Th17;
A16: Pg0|K is bounded & Pg0 is_integrable_on K by A1,A2,A3,A13,Th21;
A17: Integral2(L-Meas,R_EAL g).([x1,y1]) = integral(Pg0,K)
by A1,A2,A3,A13,Th22;
x2 in REAL & y2 in REAL by XREAL_0:def 1; then
reconsider u2=[x2,y2] as Element of [:REAL,REAL:] by ZFMISC_1:def 2;
reconsider Pg1 = ProjPMap1(R_EAL g,u2) as PartFunc of REAL,REAL
by MESFUN16:30;
A18: dom Pg1 = K by A1,A3,A12,MESFUN16:27;
A19: Pg1 is continuous by A1,A2,A3,A13,Th17;
A20: Pg1|K is bounded & Pg1 is_integrable_on K by A1,A2,A3,A13,Th21;
A21: (Integral2(L-Meas,R_EAL g)).([x2,y2]) = integral(Pg1,K)
by A1,A2,A3,A13,Th22;
RG.u1 = integral(Pg0,K) & RG.u2 = integral(Pg1,K)
by A4,A12,A17,A21,FUNCT_1:49; then
A22: RG.u1 = integral(Pg0,s,t) & RG.u2 = integral(Pg1,s,t)
by A8,A6,XXREAL_1:29,INTEGRA5:def 4;
A23: dom(Pg1-Pg0) = (dom Pg1) /\ (dom Pg0) by VALUED_1:12; then
A24: (Pg1-Pg0)| ['s,t'] is bounded & (Pg1-Pg0) is_integrable_on ['s,t']
by A8,A14,A15,A18,A19,INTEGRA5:10,11;
A25: s in ['s,t'] & t in ['s,t'] by A6,A7,A8;
for y be Real st y in [' s,t '] holds |.(Pg1-Pg0).y.| <= e
proof
let y be Real;
assume
A26: y in [' s,t ']; then
A27: |. (ProjPMap1(R_EAL g,u2)).y - (ProjPMap1(R_EAL g,u1)).y.|
< e by A8,A11,A12;
A28: -(ProjPMap1(R_EAL g,u1)).y = -Pg0.y by XXREAL_3:def 3;
(ProjPMap1(R_EAL g,u2)).y - (ProjPMap1(R_EAL g,u1)).y
= (ProjPMap1(R_EAL g,u2)).y + -(ProjPMap1(R_EAL g,u1)).y
by XXREAL_3:def 4
.= Pg1.y + -Pg0.y by A28,XXREAL_3:def 2
.= Pg1.y -Pg0.y
.= (Pg1-Pg0).y by A8,A14,A18,A23,A26,VALUED_1:13;
hence thesis by A27,EXTREAL1:12;
end; then
|. integral(Pg1-Pg0,s,t) .| <= e * (t-s)
by A7,A8,A14,A18,A23,A24,A25,INTEGRA6:23;
hence |. RG.([x2,y2]) - RG.([x1,y1]) .| < e by
A10,A9,A22,A8,INTEGRA6:12,A14,A16,A18,A20;
end;
end;
suppose s<>t; then
A29: s < t by A7,XXREAL_0:1;
set e1=e/2;
A30: 0 < e1 & e1 < e by A9,XREAL_1:215,216;
A31: 0 < t-s by A29,XREAL_1:50; then
consider r be Real such that
A32: 0 < r
& for u1,u2 be Element of [:REAL,REAL:], x1,y1,x2,y2 be Real
st u1=[x1,y1] & u2=[x2,y2] & |.x2-x1.| < r & |.y2-y1.| < r
& u1 in [:I,J:] & u2 in [:I,J:] holds
for z be Element of REAL st z in K holds
|. (ProjPMap1(R_EAL g,u2)).z - (ProjPMap1(R_EAL g,u1)).z.| < e1/(t-s)
by A1,A2,A3,A30,Th31,XREAL_1:139;
take r;
thus 0 < r by A32;
let x1,x2,y1,y2 be Real;
assume
A33: [x1,y1] in [:I,J:] & [x2,y2] in [:I,J:] & |.x2-x1.| < r & |.y2-y1.| < r;
then
A34: x1 in I & x2 in I & y1 in J & y2 in J by ZFMISC_1:87;
reconsider xx1=x1, xx2=x2, yy1=y1, yy2=y2 as Element of REAL
by XREAL_0:def 1;
x1 in REAL & y1 in REAL by XREAL_0:def 1; then
reconsider u1=[x1,y1] as Element of [:REAL,REAL:] by ZFMISC_1:def 2;
reconsider Pg0 = ProjPMap1(R_EAL g,u1) as PartFunc of REAL,REAL
by MESFUN16:30;
A35: dom Pg0 = K
& Pg0 is continuous & Pg0|K is bounded & Pg0 is_integrable_on K
& (Integral2(L-Meas,R_EAL g)).([x1,y1]) = integral(Pg0,K)
by A1,A2,A3,A34,A33,Th17,Th21,Th22,MESFUN16:27;
x2 in REAL & y2 in REAL by XREAL_0:def 1; then
reconsider u2=[x2,y2] as Element of [:REAL,REAL:] by ZFMISC_1:def 2;
reconsider Pg1 = ProjPMap1(R_EAL g,u2) as PartFunc of REAL,REAL
by MESFUN16:30;
A36: dom Pg1 = K
& Pg1 is continuous & Pg1|K is bounded & Pg1 is_integrable_on K
& (Integral2(L-Meas,R_EAL g)).([x2,y2]) = integral(Pg1,K)
by A1,A2,A3,A34,A33,Th17,Th21,Th22,MESFUN16:27; then
RG.u1 = integral(Pg0,K) & RG.u2 = integral(Pg1,K)
by A4,A33,A35,FUNCT_1:49; then
RG.u1 = integral(Pg0,s,t) & RG.u2 = integral(Pg1,s,t)
by A8,A6,XXREAL_1:29,INTEGRA5:def 4; then
A37: |.RG.u2-RG.u1.|
= |. integral(Pg1-Pg0,s,t) .| by A8,A7,INTEGRA6:12,A36,A35;
A38: dom(Pg1-Pg0) = (dom Pg1) /\ (dom Pg0) by VALUED_1:12; then
A39: (Pg1-Pg0)| ['s,t'] is bounded & (Pg1-Pg0) is_integrable_on ['s,t']
by A8,A35,A36,INTEGRA5:10,11;
A40: s in ['s,t'] & t in ['s,t'] by A6,A8,A7;
for y be Real st y in [' s,t '] holds |.(Pg1-Pg0).y.| <= e1/(t-s)
proof
let y be Real;
assume
A41: y in [' s,t ']; then
A42: |. (ProjPMap1(R_EAL g,u2)).y - (ProjPMap1(R_EAL g,u1)).y.|
< e1/(t-s) by A8,A32,A33;
A43: -(ProjPMap1(R_EAL g,u1)).y = -Pg0.y by XXREAL_3:def 3;
(ProjPMap1(R_EAL g,u2)).y - (ProjPMap1(R_EAL g,u1)).y
= (ProjPMap1(R_EAL g,u2)).y + -(ProjPMap1(R_EAL g,u1)).y
by XXREAL_3:def 4
.= Pg1.y + -Pg0.y by A43,XXREAL_3:def 2
.= Pg1.y -Pg0.y
.= (Pg1-Pg0).y by A8,A35,A36,A38,A41,VALUED_1:13;
hence thesis by A42,EXTREAL1:12;
end; then
|. integral(Pg1-Pg0,s,t) .| <= (e1/(t-s)) * (t-s)
by A7,A8,A35,A36,A38,A39,A40,INTEGRA6:23; then
|. integral(Pg1-Pg0,s,t) .| <= e1 by A31,XCMPLX_1:87;
hence |. RG.([x2,y2]) - RG.([x1,y1]) .| < e by A30,A37,XXREAL_0:2;
end;
end;
hence Fz is_uniformly_continuous_on [:I,J:] by A5,MESFUN16:10;
end;
theorem Th35:
for I,J,K be non empty closed_interval Subset of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL
st [:[:I,J:],K:] = dom f & f is_continuous_on [:[:I,J:],K:] & f = g
holds
Integral1(Prod_Measure(L-Meas,L-Meas),|.R_EAL g.|) is Function of REAL,REAL
& Integral1(Prod_Measure(L-Meas,L-Meas),|.R_EAL g.|)|K is PartFunc of REAL,REAL
& Integral1(Prod_Measure(L-Meas,L-Meas),R_EAL g) is Function of REAL,REAL
& Integral1(Prod_Measure(L-Meas,L-Meas),R_EAL g)|K is PartFunc of REAL,REAL
proof
let I,J,K be non empty closed_interval Subset of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL;
assume that
A1: [:[:I,J:],K:] = dom f and
A2: f is_continuous_on [:[:I,J:],K:] and
A3: f = g;
set F = Integral1(Prod_Measure(L-Meas,L-Meas),|.R_EAL g.|);
set RF = Integral1(Prod_Measure(L-Meas,L-Meas),R_EAL g);
A4: dom F = REAL by FUNCT_2:def 1;
A5: dom RF = REAL by FUNCT_2:def 1;
now let q be object;
assume q in rng F; then
consider z be Element of REAL such that
A6: z in dom F & q = F.z by PARTFUN1:3;
reconsider Pg = ProjPMap2(|.R_EAL g.|,z)
as PartFunc of [:REAL,REAL:],REAL by MESFUN16:30;
reconsider Pf = Pg as PartFunc of [:RNS_Real,RNS_Real:],RNS_Real;
per cases;
suppose A7: z in K; then
A8: dom Pf = [:I,J:] by A1,A3,MESFUN16:28; then
Pf is_continuous_on [:I,J:] by A1,A2,A3,Th20; then
reconsider G2 = Integral2(L-Meas,R_EAL Pg)|I
as PartFunc of REAL,REAL by A8,MESFUN16:51;
Integral1(Prod_Measure(L-Meas,L-Meas),|.R_EAL g.|).z
= Integral(Prod_Measure(L-Meas,L-Meas),Pg) by A1,A2,A3,A7,Th28
.= integral(G2,I) by A1,A2,A3,A8,Th20,MESFUN16:58;
hence q in REAL by A6,XREAL_0:def 1;
end;
suppose not z in K; then
dom ProjPMap2(|.R_EAL g.|,z) = {} by A1,A3,MESFUN16:28; then
Integral(Prod_Measure(L-Meas,L-Meas),ProjPMap2(|.R_EAL g.|,z)) = 0
by MESFUN16:1; then
Integral1(Prod_Measure(L-Meas,L-Meas),|.R_EAL g.|).z = 0
by MESFUN12:def 7;
hence q in REAL by A6,XREAL_0:def 1;
end;
end; then
rng F c= REAL;
hence Integral1(Prod_Measure(L-Meas,L-Meas),|.R_EAL g.|)
is Function of REAL,REAL by A4,RELSET_1:4;
hence Integral1(Prod_Measure(L-Meas,L-Meas),|.R_EAL g.|)|K
is PartFunc of REAL,REAL by PARTFUN1:11;
now let q be object;
assume q in rng RF; then
consider z be Element of REAL such that
A9: z in dom RF & q = RF.z by PARTFUN1:3;
reconsider Pg = ProjPMap2(R_EAL g,z)
as PartFunc of [:REAL,REAL:],REAL by MESFUN16:30;
reconsider Pf = Pg as PartFunc of [:RNS_Real,RNS_Real:],RNS_Real;
per cases;
suppose A10: z in K; then
A11: dom Pf = [:I,J:] by A1,A3,MESFUN16:28; then
Pf is_continuous_on [:I,J:] by A1,A2,A3,Th18; then
reconsider G2 = Integral2(L-Meas,R_EAL Pg)|I
as PartFunc of REAL,REAL by A11,MESFUN16:51;
Integral1(Prod_Measure(L-Meas,L-Meas),R_EAL g).z
= Integral(Prod_Measure(L-Meas,L-Meas),Pg) by A1,A2,A3,A10,Th23
.= integral(G2,I) by A1,A2,A3,A11,Th18,MESFUN16:58;
hence q in REAL by A9,XREAL_0:def 1;
end;
suppose not z in K; then
dom ProjPMap2(R_EAL g,z) = {} by A1,A3,MESFUN16:28; then
Integral(Prod_Measure(L-Meas,L-Meas),ProjPMap2(R_EAL g,z)) = 0
by MESFUN16:1; then
Integral1(Prod_Measure(L-Meas,L-Meas),R_EAL g).z = 0 by MESFUN12:def 7;
hence q in REAL by A9,XREAL_0:def 1;
end;
end; then
rng RF c= REAL;
hence Integral1(Prod_Measure(L-Meas,L-Meas),R_EAL g)
is Function of REAL,REAL by A5,RELSET_1:4;
hence Integral1(Prod_Measure(L-Meas,L-Meas),R_EAL g)|K
is PartFunc of REAL,REAL by PARTFUN1:11;
end;
Lm6:
for a,b be Real, x,y be ExtReal st a = x & b = y holds a-b = x-y
proof
let a,b be Real, x,y be ExtReal;
assume
A1: a = x & b = y;
reconsider c = -y as Real by A1;
A2: c = -b by A1,XXREAL_3:def 3;
x - y = x + (-y) by XXREAL_3:def 4; then
x - y = a + c by A1,XXREAL_3:def 2;
hence thesis by A2;
end;
theorem Th36:
for I,J,K be non empty closed_interval Subset of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL,
Gxy be PartFunc of REAL,REAL
st [:[:I,J:],K:] = dom f & f is_continuous_on [:[:I,J:],K:] & f = g
& Gxy = Integral1(Prod_Measure(L-Meas,L-Meas),|.R_EAL g.|)|K holds
Gxy is continuous
proof
let I,J,K be non empty closed_interval Subset of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL,
Gxy be PartFunc of REAL,REAL;
assume that
A1: [:[:I,J:],K:] = dom f and
A2: f is_continuous_on [:[:I,J:],K:] and
A3: f = g and
A4: Gxy = Integral1(Prod_Measure(L-Meas,L-Meas),|.R_EAL g.|)|K;
consider a,b be Real such that
A5: I = [.a,b.] by MEASURE5:def 3;
A6: a <= b by A5,XXREAL_1:29; then
A7: a in I & b in I by A5;
A8: [.a,b.] = ['a,b'] by A5,XXREAL_1:29,INTEGRA5:def 3;
consider c,d be Real such that
A9: J = [.c,d.] by MEASURE5:def 3;
A10:c <= d by A9,XXREAL_1:29; then
A11:c in J & d in J by A9;
A12: [.c,d.] = ['c,d'] by A9,XXREAL_1:29,INTEGRA5:def 3;
A13:for e be Real st 0 < e holds ex r be Real st 0 < r
& for z1,z2 be Real st |.z2-z1.| < r & z1 in K & z2 in K
holds for x,y be Real st x in I & y in J holds
|. (|.g.|).([x,y,z2])-(|.g.|).([x,y,z1]) .| < e
proof
let e be Real;
assume 0 < e; then
consider r be Real such that
A14: 0 < r
& for x1,x2,y1,y2,z1,z2 be Real st
x1 in I & x2 in I & y1 in J & y2 in J & z1 in K & z2 in K
& |.x2-x1.| < r & |.y2-y1.| < r & |.z2-z1.| < r holds
|. (|.g.|).([x2,y2,z2])-(|.g.|).([x1,y1,z1]) .| < e by A2,A3,Th10;
take r;
thus 0 < r by A14;
let z1,z2 be Real;
assume
A15: |.z2-z1.| < r & z1 in K & z2 in K;
let x,y be Real;
assume A16: x in I & y in J;
|.x-x.| < r & |.y-y.| < r by A14;
hence |. (|.g.|).([x,y,z2])-(|.g.|).([x,y,z1]) .| < e by A14,A15,A16;
end;
set Rg =R_EAL g;
dom |.Rg.| = dom Rg by MESFUNC1:def 10; then
A17:dom |.Rg.| = [:[:I,J:],K:] by A1,A3,MESFUNC5:def 7;
A18:for x,y,z be Element of REAL st x in I & y in J & z in K holds
(ProjPMap2(|.Rg.|,z)).(x,y) =(|.Rg.|).([x,y],z)
& (|.Rg.|).([x,y],z) = |. g.([x,y,z]) .|
& (|.Rg.|).([x,y],z) = (|.g.|).([x,y,z])
proof
let x,y,z be Element of REAL;
assume
A19: x in I & y in J & z in K; then
A20: [x,y] in [:I,J:] by ZFMISC_1:87;
hence (ProjPMap2(|.Rg.|,z)).(x,y) =(|.Rg.|).([x,y],z)
by A17,A19,ZFMISC_1:87,MESFUN12:def 4;
[x,y,z] in dom g by A19,A20,A1,A3,ZFMISC_1:87; then
A21: [x,y,z] in dom |.g.| by VALUED_1:def 11;
A22: Rg.([x,y],z) = g.([x,y,z]) by MESFUNC5:def 7;
(|.Rg.|).([x,y],z) = |. Rg.([x,y,z]) .|
by A19,A20,A17,ZFMISC_1:87,MESFUNC1:def 10;
hence (|.Rg.|).([x,y],z) = |.g.([x,y,z]).| by A22,EXTREAL1:12;
hence (|.Rg.|).([x,y],z) = (|.g.|).([x,y,z]) by VALUED_1:def 11,A21;
end;
A23:for e be Real st 0 < e holds ex r be Real st 0 < r
& for z1,z2 be Element of REAL st |.z2-z1.| < r & z1 in K
& z2 in K holds
for x,y be Element of REAL st x in I & y in J holds
|. (ProjPMap1(ProjPMap2(|.Rg.|,z2),x)).y
-(ProjPMap1(ProjPMap2(|.Rg.|,z1),x)).y .| < e
proof
let e be Real;
assume 0 < e; then
consider r be Real such that
A24: 0 < r
& for z1,z2 be Real st |.z2-z1.| < r & z1 in K & z2 in K
holds for x,y be Real st x in I & y in J holds
|. (|.g.|).([x,y,z2])-(|.g.|).([x,y,z1]) .| < e by A13;
take r;
thus 0 < r by A24;
let z1,z2 be Element of REAL;
assume
A25: |.z2-z1.| < r & z1 in K & z2 in K;
let x,y be Element of REAL;
assume
A26: x in I & y in J; then
A27: |. (|.g.|).([x,y,z2])-(|.g.|).([x,y,z1]) .| < e by A24,A25;
a27: (|.g.|).([x,y,z2])-(|.g.|).([x,y,z1]) =
(|.g.|).([x,y,z2]) qua ExtReal -(|.g.|).([x,y,z1]);
dom ProjPMap2(|.Rg.|,z1) = [:I,J:] by A25,A1,A3,MESFUN16:28; then
A28: (ProjPMap1(ProjPMap2(|.Rg.|,z1),x)).y
= ProjPMap2(|.Rg.|,z1).(x,y) by A26,ZFMISC_1:87,MESFUN12:def 3;
dom ProjPMap2(|.Rg.|,z2) = [:I,J:] by A25,A1,A3,MESFUN16:28; then
A29: (ProjPMap1(ProjPMap2(|.Rg.|,z2),x)).y
= ProjPMap2(|.Rg.|,z2).(x,y) by A26,ZFMISC_1:87,MESFUN12:def 3;
(ProjPMap2(|.Rg.|,z1)).(x,y) =(|.Rg.|).([x,y],z1)
& (|.Rg.|).([x,y],z1) = (|.g.|).([x,y,z1])
& (ProjPMap2(|.Rg.|,z2)).(x,y) =(|.Rg.|).([x,y],z2)
& (|.Rg.|).([x,y],z2) = (|.g.|).([x,y,z2]) by A18,A25,A26;
hence thesis by A27,a27,A28,A29,EXTREAL1:12;
end;
A30:dom Integral1(Prod_Measure(L-Meas,L-Meas),|.Rg.|) = REAL by FUNCT_2:def 1;
for z0,r be Real st z0 in K & 0 < r
ex s be Real st 0<s & for z1 be Real
st z1 in K & |.z1-z0.| < s holds |.Gxy.z1-Gxy.z0.| < r
proof
let zz0,r be Real;
assume
A31: zz0 in K & 0 < r;
reconsider z0=zz0 as Element of REAL by XREAL_0:def 1;
reconsider Pg20 = ProjPMap2(|.Rg.|,z0) as PartFunc of [:REAL,REAL:],REAL
by MESFUN16:30;
reconsider Pf20 = Pg20 as PartFunc of [:RNS_Real,RNS_Real:],RNS_Real;
A32: dom Pg20 = [:I,J:] by A31,A1,A3,MESFUN16:28; then
A33: Pf20 is_continuous_on [:I,J:] by A1,A2,A3,Th20; then
reconsider Pg0 = Integral2(L-Meas,R_EAL Pg20)|I
as PartFunc of REAL,REAL by A32,MESFUN16:51;
A34: dom Integral2(L-Meas,R_EAL Pg20) = REAL by FUNCT_2:def 1; then
A35: dom Pg0 = I;
A36: Pg0 is continuous by A1,A2,A3,A32,Th20,MESFUN16:53; then
A37: Pg0|I is bounded & Pg0 is_integrable_on I by A34,INTEGRA5:10,11;
(Integral1(Prod_Measure(L-Meas,L-Meas),|.Rg.|)).z0
= Integral(Prod_Measure(L-Meas,L-Meas),Pg20) by A31,A1,A2,A3,Th28
.= Integral(Prod_Measure(L-Meas,L-Meas),R_EAL Pg20); then
(Integral1(Prod_Measure(L-Meas,L-Meas),|.Rg.|)).z0
= integral(Pg0,I) by A1,A2,A3,A32,Th20,MESFUN16:58; then
Gxy.zz0 = integral(Pg0,I) by A4,A31,FUNCT_1:49; then
A38: Gxy.zz0 = integral(Pg0,a,b) by A5,A8,XXREAL_1:29,INTEGRA5:def 4;
per cases;
suppose A39: a = b & c = d;
consider s be Real such that
A40: 0 < s
& for z1,z2 be Element of REAL st |.z2-z1.| < s & z1 in K & z2 in K holds
for x,y be Element of REAL st x in I & y in J holds
|. (ProjPMap1(ProjPMap2(|.Rg.|,z2),x)).y
-(ProjPMap1(ProjPMap2(|.Rg.|,z1),x)).y .| < r by A23,A31;
for z1 be Real st z1 in K & |.z1-z0.| < s holds |.Gxy.z1-Gxy.zz0 .| < r
proof
let zz1 be Real;
assume
A41: zz1 in K & |.zz1-z0.| < s;
reconsider z1=zz1 as Element of REAL by XREAL_0:def 1;
reconsider Pg21 = ProjPMap2(|.Rg.|,z1) as PartFunc of [:REAL,REAL:],REAL
by MESFUN16:30;
reconsider Pf21 = Pg21 as PartFunc of [:RNS_Real,RNS_Real:],RNS_Real;
A42: dom Pg21 = [:I,J:] by A41,A1,A3,MESFUN16:28; then
A43: Pf21 is_continuous_on [:I,J:] by A1,A2,A3,Th20; then
reconsider Pg1 = Integral2(L-Meas,R_EAL Pg21)|I
as PartFunc of REAL,REAL by A42,MESFUN16:51;
A44: dom Integral2(L-Meas,R_EAL Pg21) = REAL by FUNCT_2:def 1; then
A45: dom Pg1 = I;
A46: Pg1 is continuous by A1,A2,A3,A42,Th20,MESFUN16:53; then
A47: Pg1|I is bounded & Pg1 is_integrable_on I by A44,INTEGRA5:10,11;
(Integral1(Prod_Measure(L-Meas,L-Meas),|.Rg.|)).z1
= Integral(Prod_Measure(L-Meas,L-Meas),Pg21) by A41,A1,A2,A3,Th28
.= Integral(Prod_Measure(L-Meas,L-Meas),R_EAL Pg21); then
(Integral1(Prod_Measure(L-Meas,L-Meas),|.Rg.|)).z1
= integral(Pg1,I) by A1,A2,A3,A42,Th20,MESFUN16:58; then
Gxy.zz1 = integral(Pg1,I) by A4,A41,FUNCT_1:49; then
A48: Gxy.zz1 = integral(Pg1,a,b) by A5,A8,XXREAL_1:29,INTEGRA5:def 4;
A49: dom(Pg1-Pg0) = I /\ I by A35,A45,VALUED_1:12; then
A50: Pg1-Pg0 is_integrable_on I & (Pg1-Pg0)|I is bounded
by A36,A46,INTEGRA5:10,11;
for x be Element of REAL st x in I holds |. (Pg1-Pg0).x .| <= r
proof
let x be Element of REAL;
assume
A51: x in I;
reconsider Pg120 = ProjPMap1(Pg20,x) as PartFunc of REAL,REAL;
A52: dom Pg120 = J by A51,A32,MESFUN16:25;
ProjPMap1(R_EAL Pg20,x) = R_EAL ProjPMap1(Pg20,x)
by MESFUN16:31; then
A53: Pg120 = ProjPMap1(R_EAL Pg20,x) by MESFUNC5:def 7;
A54: Pg120 is continuous by A32,A33,MESFUN16:33;
A55: Pg120|J is bounded & Pg120 is_integrable_on J
by A32,A33,A51,A53,MESFUN16:40;
reconsider Pg121 = ProjPMap1(Pg21,x) as PartFunc of REAL,REAL;
A56: dom Pg121 = J by A51,A42,MESFUN16:25;
ProjPMap1(R_EAL Pg21,x) = R_EAL ProjPMap1(Pg21,x)
by MESFUN16:31; then
A57: Pg121 = ProjPMap1(R_EAL Pg21,x) by MESFUNC5:def 7;
A58: Pg121 is continuous by A42,A43,MESFUN16:33;
A59: Pg121|J is bounded & Pg121 is_integrable_on J
by A42,A43,A51,A57,MESFUN16:40;
Pg0.x = Integral2(L-Meas,R_EAL Pg20).x by A51,FUNCT_1:49; then
Pg0.x = Integral(L-Meas,ProjPMap1(R_EAL Pg20,x))
by MESFUN12:def 8; then
Pg0.x = Integral(L-Meas,Pg120) by MESFUN16:31; then
A60: Pg0.x = integral(Pg120,c,d) by A9,A12,A52,A55,XXREAL_1:29,MESFUN14:50;
Pg1.x = Integral2(L-Meas,R_EAL Pg21).x by A51,FUNCT_1:49; then
Pg1.x = Integral(L-Meas,ProjPMap1(R_EAL Pg21,x))
by MESFUN12:def 8; then
Pg1.x = Integral(L-Meas,Pg121) by MESFUN16:31; then
Pg1.x = integral(Pg121,c,d)
by A9,A12,A56,A59,XXREAL_1:29,MESFUN14:50; then
A61: Pg1.x - Pg0.x = integral(Pg121-Pg120,c,d)
by A9,A10,A12,A55,A59,A56,A52,A60,INTEGRA6:12;
A62: dom(Pg121-Pg120) = J /\ J by A52,A56,VALUED_1:12; then
A63: (Pg121-Pg120)|J is bounded & (Pg121-Pg120) is_integrable_on J
by A54,A58,INTEGRA5:10,11;
for y be Real st y in J holds |. (Pg121-Pg120).y .| <= r
proof
let y be Real;
assume
A64: y in J;
reconsider yy=y as Element of REAL by XREAL_0:def 1;
A65: Pg120.y = (ProjPMap1(ProjPMap2(|.Rg.|,z0),x)).yy
by A53,MESFUNC5:def 7;
A66: Pg121.y = (ProjPMap1(ProjPMap2(|.Rg.|,z1),x)).yy
by A57,MESFUNC5:def 7;
A67: (Pg121-Pg120).y = Pg121.y - Pg120.y by A62,A64,VALUED_1:13
.= (ProjPMap1(ProjPMap2(|.Rg.|,z1),x)).yy
- (ProjPMap1(ProjPMap2(|.Rg.|,z0),x)).yy by A66,A65,Lm6;
|. (ProjPMap1(ProjPMap2(|.Rg.|,z1),x)).yy
-(ProjPMap1(ProjPMap2(|.Rg.|,z0),x)).yy .| < r
by A31,A41,A51,A64,A40;
hence |. (Pg121-Pg120).y .| <= r by A67,EXTREAL1:12;
end; then
|. integral(Pg121-Pg120,c,d) .| <= r * (d-c)
by A9,A10,A11,A12,A62,A63,INTEGRA6:23;
hence |. (Pg1-Pg0).x .| <= r by A31,A39,A49,A51,A61,VALUED_1:13;
end; then
for x be Real st x in ['a,b'] holds |.(Pg1-Pg0).x .| <= r by A5,A8; then
|. integral(Pg1-Pg0,a,b) .| <= r * (b-a)
by A5,A6,A7,A8,A49,A50,INTEGRA6:23;
hence |. Gxy.zz1-Gxy.zz0 .| < r
by A5,A8,A31,A39,A35,A37,A45,A47,A38,A48,INTEGRA6:12;
end;
hence ex s be Real st 0<s & for z1 be Real
st z1 in K & |.z1-zz0.| < s holds |.Gxy.z1-Gxy.zz0.| < r by A40;
end;
suppose A68: a <> b & c = d; then
a < b by A6,XXREAL_0:1; then
A69: 0 < b-a by XREAL_1:50;
set r1=r/2;
A70: 0 < r1 & r1 < r by A31,XREAL_1:215,216; then
A71: 0 < r1/(b-a) by A69,XREAL_1:139;
consider s be Real such that
A72: 0 < s
& for z1,z2 be Element of REAL st |.z2-z1.| < s & z1 in K & z2 in K holds
for x,y be Element of REAL st x in I & y in J holds
|. (ProjPMap1(ProjPMap2(|.Rg.|,z2),x)).y
-(ProjPMap1(ProjPMap2(|.Rg.|,z1),x)).y .| < r1/(b-a)
by A23,A69,A70,XREAL_1:139;
for z1 be Real st z1 in K & |.z1-z0.| < s holds |.Gxy.z1-Gxy.zz0 .| < r
proof
let zz1 be Real;
assume
A73: zz1 in K & |.zz1-z0.| < s;
reconsider z1=zz1 as Element of REAL by XREAL_0:def 1;
reconsider Pg21 = ProjPMap2(|.Rg.|,z1) as PartFunc of [:REAL,REAL:],REAL
by MESFUN16:30;
reconsider Pf21 = Pg21 as PartFunc of [:RNS_Real,RNS_Real:],RNS_Real;
A74: dom Pg21 = [:I,J:] by A73,A1,A3,MESFUN16:28; then
A75: Pf21 is_continuous_on [:I,J:] by A1,A2,A3,Th20; then
reconsider Pg1 = Integral2(L-Meas,R_EAL Pg21)|I
as PartFunc of REAL,REAL by A74,MESFUN16:51;
A76: dom Integral2(L-Meas,R_EAL Pg21) = REAL by FUNCT_2:def 1; then
A77: dom Pg1 = I;
A78: Pg1 is continuous by A1,A2,A3,A74,Th20,MESFUN16:53; then
A79: Pg1|I is bounded & Pg1 is_integrable_on I by A76,INTEGRA5:10,11;
(Integral1(Prod_Measure(L-Meas,L-Meas),|.Rg.|)).z1
= Integral(Prod_Measure(L-Meas,L-Meas),Pg21) by A73,A1,A2,A3,Th28
.= Integral(Prod_Measure(L-Meas,L-Meas),R_EAL Pg21); then
(Integral1(Prod_Measure(L-Meas,L-Meas),|.Rg.|)).z1
= integral(Pg1,I) by A1,A2,A3,A74,Th20,MESFUN16:58; then
Gxy.zz1 = integral(Pg1,I) by A4,A73,FUNCT_1:49; then
A80: Gxy.zz1 = integral(Pg1,a,b) by A5,A8,XXREAL_1:29,INTEGRA5:def 4;
A81: dom(Pg1-Pg0) = I /\ I by A35,A77,VALUED_1:12; then
A82: Pg1-Pg0 is_integrable_on I & (Pg1-Pg0)|I is bounded
by A36,A78,INTEGRA5:10,11;
for x be Element of REAL st x in I holds |. (Pg1-Pg0).x .| <= r1/(b-a)
proof
let x be Element of REAL;
assume
A83: x in I;
reconsider Pg120 = ProjPMap1(Pg20,x) as PartFunc of REAL,REAL;
A84: dom Pg120 = J by A83,A32,MESFUN16:25;
ProjPMap1(R_EAL Pg20,x) = R_EAL ProjPMap1(Pg20,x)
by MESFUN16:31; then
A85: Pg120 = ProjPMap1(R_EAL Pg20,x) by MESFUNC5:def 7;
A86: Pg120 is continuous by A32,A33,MESFUN16:33;
A87: Pg120|J is bounded & Pg120 is_integrable_on J
by A32,A33,A83,A85,MESFUN16:40;
reconsider Pg121 = ProjPMap1(Pg21,x) as PartFunc of REAL,REAL;
A88: dom Pg121 = J by A83,A74,MESFUN16:25;
ProjPMap1(R_EAL Pg21,x) = R_EAL ProjPMap1(Pg21,x) by MESFUN16:31; then
A89: Pg121 = ProjPMap1(R_EAL Pg21,x) by MESFUNC5:def 7;
A90: Pg121 is continuous by A74,A75,MESFUN16:33;
A91: Pg121|J is bounded & Pg121 is_integrable_on J
by A74,A75,A83,A89,MESFUN16:40;
Pg0.x = Integral2(L-Meas,R_EAL Pg20).x by A83,FUNCT_1:49; then
Pg0.x = Integral(L-Meas,ProjPMap1(R_EAL Pg20,x))
by MESFUN12:def 8; then
Pg0.x = Integral(L-Meas,Pg120) by MESFUN16:31; then
A92: Pg0.x = integral(Pg120,c,d) by A9,A12,A84,A87,XXREAL_1:29,MESFUN14:50;
Pg1.x = Integral2(L-Meas,R_EAL Pg21).x by A83,FUNCT_1:49; then
Pg1.x = Integral(L-Meas,ProjPMap1(R_EAL Pg21,x))
by MESFUN12:def 8; then
Pg1.x = Integral(L-Meas,Pg121) by MESFUN16:31; then
Pg1.x = integral(Pg121,c,d)
by A9,A12,A88,A91,XXREAL_1:29,MESFUN14:50; then
A93: Pg1.x - Pg0.x = integral(Pg121-Pg120,c,d)
by A9,A10,A12,A87,A91,A88,A84,A92,INTEGRA6:12;
A94: dom(Pg121-Pg120) = J /\ J by A84,A88,VALUED_1:12; then
A95: (Pg121-Pg120)|J is bounded & (Pg121-Pg120) is_integrable_on J
by A86,A90,INTEGRA5:10,11;
for y be Real st y in J holds |. (Pg121-Pg120).y .| <= r1/(b-a)
proof
let y be Real;
assume
A96: y in J;
reconsider yy=y as Element of REAL by XREAL_0:def 1;
A97: Pg120.y = (ProjPMap1(ProjPMap2(|.Rg.|,z0),x)).yy
& Pg121.y = (ProjPMap1(ProjPMap2(|.Rg.|,z1),x)).yy
by A85,A89,MESFUNC5:def 7;
A98: (Pg121-Pg120).y = Pg121.y - Pg120.y by A94,A96,VALUED_1:13
.= (ProjPMap1(ProjPMap2(|.Rg.|,z1),x)).yy
- (ProjPMap1(ProjPMap2(|.Rg.|,z0),x)).yy by A97,Lm6;
|. (ProjPMap1(ProjPMap2(|.Rg.|,z1),x)).yy
-(ProjPMap1(ProjPMap2(|.Rg.|,z0),x)).yy .| < r1/(b-a)
by A31,A73,A83,A96,A72;
hence |. (Pg121-Pg120).y .| <= r1/(b-a) by A98,EXTREAL1:12;
end; then
|. integral(Pg121-Pg120,c,d) .| <= r1/(b-a) * (d-c)
by A9,A10,A11,A12,A94,A95,INTEGRA6:23;
hence |. (Pg1-Pg0).x .| <= r1/(b-a)
by A68,A93,A71,A81,A83,VALUED_1:13;
end; then
for x be Real st x in ['a,b'] holds |. (Pg1-Pg0).x .| <= r1/(b-a)
by A5,A8; then
|. integral(Pg1-Pg0,a,b) .| <= r1/(b-a) * (b-a)
by A5,A6,A7,A8,A81,A82,INTEGRA6:23; then
|. integral(Pg1-Pg0,a,b) .| <= r1 by A69,XCMPLX_1:87; then
|. integral(Pg1-Pg0,a,b) .| < r by A70,XXREAL_0:2;
hence |. Gxy.zz1-Gxy.zz0 .| < r
by A5,A6,A8,A35,A37,A77,A79,A38,A80,INTEGRA6:12;
end;
hence ex s be Real st 0<s & for z1 be Real
st z1 in K & |.z1-zz0.| < s holds |.Gxy.z1-Gxy.zz0.| < r by A72;
end;
suppose A99: a = b & c <> d; then
c < d by A10,XXREAL_0:1; then
A100: 0 < d-c by XREAL_1:50;
set r1=r/2;
0 < r1 & r1 < r by A31,XREAL_1:215,216; then
consider s be Real such that
A101: 0 < s
& for z1,z2 be Element of REAL st |.z2-z1.| < s & z1 in K & z2 in K holds
for x,y be Element of REAL st x in I & y in J holds
|. (ProjPMap1(ProjPMap2(|.Rg.|,z2),x)).y
-(ProjPMap1(ProjPMap2(|.Rg.|,z1),x)).y .| < r1/(d-c)
by A23,A100,XREAL_1:139;
for z1 be Real st z1 in K & |.z1-z0.| < s holds |.Gxy.z1-Gxy.zz0 .| < r
proof
let zz1 be Real;
assume
A102: zz1 in K & |.zz1-z0.| < s;
reconsider z1=zz1 as Element of REAL by XREAL_0:def 1;
reconsider Pg21 = ProjPMap2(|.Rg.|,z1) as PartFunc of [:REAL,REAL:],REAL
by MESFUN16:30;
reconsider Pf21 = Pg21 as PartFunc of [:RNS_Real,RNS_Real:],RNS_Real;
A103: dom Pg21 = [:I,J:] by A102,A1,A3,MESFUN16:28; then
A104: Pf21 is_continuous_on [:I,J:] by A1,A2,A3,Th20; then
reconsider Pg1 = Integral2(L-Meas,R_EAL Pg21)|I
as PartFunc of REAL,REAL by A103,MESFUN16:51;
A105: dom Integral2(L-Meas,R_EAL Pg21) = REAL by FUNCT_2:def 1; then
A106: dom Pg1 = I;
A107: Pg1 is continuous by A1,A2,A3,A103,Th20,MESFUN16:53; then
A108: Pg1|I is bounded & Pg1 is_integrable_on I by A105,INTEGRA5:10,11;
(Integral1(Prod_Measure(L-Meas,L-Meas),|.Rg.|)).z1
= Integral(Prod_Measure(L-Meas,L-Meas),Pg21) by A102,A1,A2,A3,Th28
.= Integral(Prod_Measure(L-Meas,L-Meas),R_EAL Pg21); then
(Integral1(Prod_Measure(L-Meas,L-Meas),|.Rg.|)).z1
= integral(Pg1,I) by A1,A2,A3,A103,Th20,MESFUN16:58; then
Gxy.zz1 = integral(Pg1,I) by A4,A102,FUNCT_1:49; then
A109: Gxy.zz1 = integral(Pg1,a,b) by A5,A8,XXREAL_1:29,INTEGRA5:def 4;
A110: dom(Pg1-Pg0) = I /\ I by A35,A106,VALUED_1:12; then
A111: Pg1-Pg0 is_integrable_on I & (Pg1-Pg0)|I is bounded
by A36,A107,INTEGRA5:10,11;
for x be Element of REAL st x in I holds |. (Pg1-Pg0).x .| <= r1
proof
let x be Element of REAL;
assume
A112: x in I;
reconsider Pg120 = ProjPMap1(Pg20,x) as PartFunc of REAL,REAL;
A113: dom Pg120 = J by A112,A32,MESFUN16:25;
ProjPMap1(R_EAL Pg20,x) = R_EAL ProjPMap1(Pg20,x)
by MESFUN16:31; then
A114: Pg120 = ProjPMap1(R_EAL Pg20,x) by MESFUNC5:def 7;
A115: Pg120 is continuous by A32,A33,MESFUN16:33;
A116: Pg120|J is bounded & Pg120 is_integrable_on J
by A32,A33,A112,A114,MESFUN16:40;
reconsider Pg121 = ProjPMap1(Pg21,x) as PartFunc of REAL,REAL;
A117: dom Pg121 = J by A112,A103,MESFUN16:25;
ProjPMap1(R_EAL Pg21,x) = R_EAL ProjPMap1(Pg21,x)
by MESFUN16:31; then
A118: Pg121 = ProjPMap1(R_EAL Pg21,x) by MESFUNC5:def 7;
A119: Pg121 is continuous by A103,A104,MESFUN16:33;
A120: Pg121|J is bounded & Pg121 is_integrable_on J
by A103,A104,A112,A118,MESFUN16:40;
Pg0.x = Integral2(L-Meas,R_EAL Pg20).x by A112,FUNCT_1:49; then
Pg0.x = Integral(L-Meas,ProjPMap1(R_EAL Pg20,x))
by MESFUN12:def 8; then
Pg0.x = Integral(L-Meas,Pg120) by MESFUN16:31; then
A121: Pg0.x = integral(Pg120,c,d)
by A9,A12,A113,A116,XXREAL_1:29,MESFUN14:50;
Pg1.x = Integral2(L-Meas,R_EAL Pg21).x by A112,FUNCT_1:49; then
Pg1.x = Integral(L-Meas,ProjPMap1(R_EAL Pg21,x))
by MESFUN12:def 8; then
Pg1.x = Integral(L-Meas,Pg121) by MESFUN16:31; then
Pg1.x = integral(Pg121,c,d)
by A9,A12,A117,A120,XXREAL_1:29,MESFUN14:50; then
Pg1.x - Pg0.x = integral(Pg121-Pg120,c,d)
by A9,A10,A12,A116,A120,A117,A113,A121,INTEGRA6:12; then
A122: (Pg1-Pg0).x = integral(Pg121-Pg120,c,d) by A110,A112,VALUED_1:13;
A123: dom(Pg121-Pg120) = J /\ J by A113,A117,VALUED_1:12; then
A124: (Pg121-Pg120)|J is bounded & (Pg121-Pg120) is_integrable_on J
by A115,A119,INTEGRA5:10,11;
for y be Real st y in J holds |. (Pg121-Pg120).y .| <= r1/(d-c)
proof
let y be Real;
assume
A125: y in J;
reconsider yy=y as Element of REAL by XREAL_0:def 1;
A126: Pg120.y = (ProjPMap1(ProjPMap2(|.Rg.|,z0),x)).yy
& Pg121.y = (ProjPMap1(ProjPMap2(|.Rg.|,z1),x)).yy
by A114,A118,MESFUNC5:def 7;
A127: (Pg121-Pg120).y = Pg121.y - Pg120.y by A123,A125,VALUED_1:13
.= (ProjPMap1(ProjPMap2(|.Rg.|,z1),x)).yy
- (ProjPMap1(ProjPMap2(|.Rg.|,z0),x)).yy by A126,Lm6;
|. (ProjPMap1(ProjPMap2(|.Rg.|,z1),x)).yy
-(ProjPMap1(ProjPMap2(|.Rg.|,z0),x)).yy .| < r1/(d-c)
by A31,A102,A112,A125,A101;
hence |. (Pg121-Pg120).y .| <= r1/(d-c) by A127,EXTREAL1:12;
end; then
|. integral(Pg121-Pg120,c,d) .| <= r1/(d-c) * (d-c)
by A9,A10,A11,A12,A123,A124,INTEGRA6:23;
hence |. (Pg1-Pg0).x .| <= r1 by A122,A100,XCMPLX_1:87;
end; then
for x be Real st x in ['a,b'] holds |. (Pg1-Pg0).x .| <= r1
by A5,A8; then
|. integral(Pg1-Pg0,a,b) .| <= r1 * (b-a)
by A5,A6,A7,A8,A110,A111,INTEGRA6:23;
hence |. Gxy.zz1-Gxy.zz0 .| < r
by A5,A8,A99,A35,A37,A106,A108,A38,A109,A31,INTEGRA6:12;
end;
hence ex s be Real st 0<s & for z1 be Real
st z1 in K & |.z1-zz0.| < s holds |.Gxy.z1-Gxy.zz0.| < r by A101;
end;
suppose a <> b & c <> d; then
a < b & c < d by A6,A10,XXREAL_0:1; then
A128: 0 < b-a & 0 < d-c by XREAL_1:50;
set r1=r/2;
A129: 0 < r1 & r1 < r by A31,XREAL_1:215,216; then
0 < r1/(b-a) by A128,XREAL_1:139; then
consider s be Real such that
A130: 0 < s
& for z1,z2 be Element of REAL st |.z2-z1.| < s & z1 in K & z2 in K holds
for x,y be Element of REAL st x in I & y in J holds
|. (ProjPMap1(ProjPMap2(|.Rg.|,z2),x)).y
-(ProjPMap1(ProjPMap2(|.Rg.|,z1),x)).y .| < r1/(b-a)/(d-c)
by A23,A128,XREAL_1:139;
for z1 be Real st z1 in K & |.z1-z0.| < s holds |.Gxy.z1-Gxy.zz0 .| < r
proof
let zz1 be Real;
assume
A131: zz1 in K & |.zz1-z0.| < s;
reconsider z1=zz1 as Element of REAL by XREAL_0:def 1;
reconsider Pg21 = ProjPMap2(|.Rg.|,z1) as PartFunc of [:REAL,REAL:],REAL
by MESFUN16:30;
reconsider Pf21 = Pg21 as PartFunc of [:RNS_Real,RNS_Real:],RNS_Real;
A132: dom Pg21 = [:I,J:] by A131,A1,A3,MESFUN16:28; then
A133: Pf21 is_continuous_on [:I,J:] by A1,A2,A3,Th20; then
reconsider Pg1 = Integral2(L-Meas,R_EAL Pg21)|I
as PartFunc of REAL,REAL by A132,MESFUN16:51;
A134: dom Integral2(L-Meas,R_EAL Pg21) = REAL by FUNCT_2:def 1; then
A135: dom Pg1 = I;
A136: Pg1 is continuous by A1,A2,A3,A132,Th20,MESFUN16:53; then
A137: Pg1|I is bounded & Pg1 is_integrable_on I by A134,INTEGRA5:10,11;
(Integral1(Prod_Measure(L-Meas,L-Meas),|.Rg.|)).z1
= Integral(Prod_Measure(L-Meas,L-Meas),Pg21) by A131,A1,A2,A3,Th28
.= Integral(Prod_Measure(L-Meas,L-Meas),R_EAL Pg21); then
(Integral1(Prod_Measure(L-Meas,L-Meas),|.Rg.|)).z1
= integral(Pg1,I) by A1,A2,A3,A132,Th20,MESFUN16:58; then
Gxy.zz1 = integral(Pg1,I) by A4,A131,FUNCT_1:49; then
A138: Gxy.zz1 = integral(Pg1,a,b) by A5,A8,XXREAL_1:29,INTEGRA5:def 4;
A139: dom(Pg1-Pg0) = I /\ I by A35,A135,VALUED_1:12; then
A140: Pg1-Pg0 is_integrable_on I & (Pg1-Pg0)|I is bounded
by A36,A136,INTEGRA5:10,11;
for x be Element of REAL st x in I holds |. (Pg1-Pg0).x .| <= r1/(b-a)
proof
let x be Element of REAL;
assume
A141: x in I;
reconsider Pg120 = ProjPMap1(Pg20,x) as PartFunc of REAL,REAL;
A142: dom Pg120 = J by A141,A32,MESFUN16:25;
ProjPMap1(R_EAL Pg20,x) = R_EAL ProjPMap1(Pg20,x)
by MESFUN16:31; then
A143: Pg120 = ProjPMap1(R_EAL Pg20,x) by MESFUNC5:def 7;
A144: Pg120 is continuous by A32,A33,MESFUN16:33;
A145: Pg120|J is bounded & Pg120 is_integrable_on J
by A32,A33,A141,A143,MESFUN16:40;
reconsider Pg121 = ProjPMap1(Pg21,x) as PartFunc of REAL,REAL;
A146: dom Pg121 = J by A141,A132,MESFUN16:25;
ProjPMap1(R_EAL Pg21,x) = R_EAL ProjPMap1(Pg21,x)
by MESFUN16:31; then
A147: Pg121 = ProjPMap1(R_EAL Pg21,x) by MESFUNC5:def 7;
A148: Pg121 is continuous by A132,A133,MESFUN16:33;
A149: Pg121|J is bounded & Pg121 is_integrable_on J
by A132,A133,A141,A147,MESFUN16:40;
Pg0.x = Integral2(L-Meas,R_EAL Pg20).x by A141,FUNCT_1:49; then
Pg0.x = Integral(L-Meas,ProjPMap1(R_EAL Pg20,x))
by MESFUN12:def 8; then
Pg0.x = Integral(L-Meas,Pg120) by MESFUN16:31; then
A150: Pg0.x = integral(Pg120,c,d)
by A9,A12,A142,A145,XXREAL_1:29,MESFUN14:50;
Pg1.x = Integral2(L-Meas,R_EAL Pg21).x by A141,FUNCT_1:49; then
Pg1.x = Integral(L-Meas,ProjPMap1(R_EAL Pg21,x))
by MESFUN12:def 8; then
Pg1.x = Integral(L-Meas,Pg121) by MESFUN16:31; then
Pg1.x = integral(Pg121,c,d)
by A9,A12,A146,A149,XXREAL_1:29,MESFUN14:50; then
Pg1.x - Pg0.x = integral(Pg121-Pg120,c,d)
by A9,A10,A12,A145,A149,A146,A142,A150,INTEGRA6:12; then
A151: (Pg1-Pg0).x = integral(Pg121-Pg120,c,d) by A139,A141,VALUED_1:13;
A152: dom(Pg121-Pg120) = J /\ J by A142,A146,VALUED_1:12; then
A153: (Pg121-Pg120)|J is bounded & (Pg121-Pg120) is_integrable_on J
by A144,A148,INTEGRA5:10,11;
for y be Real st y in J holds |. (Pg121-Pg120).y .| <= r1/(b-a)/(d-c)
proof
let y be Real;
assume
A154: y in J;
reconsider yy=y as Element of REAL by XREAL_0:def 1;
A155: Pg120.y = (ProjPMap1(ProjPMap2(|.Rg.|,z0),x)).yy
& Pg121.y = (ProjPMap1(ProjPMap2(|.Rg.|,z1),x)).yy
by A143,A147,MESFUNC5:def 7;
A156: (Pg121-Pg120).y = Pg121.y - Pg120.y by A152,A154,VALUED_1:13
.= (ProjPMap1(ProjPMap2(|.Rg.|,z1),x)).yy
- (ProjPMap1(ProjPMap2(|.Rg.|,z0),x)).yy by A155,Lm6;
|. (ProjPMap1(ProjPMap2(|.Rg.|,z1),x)).yy
-(ProjPMap1(ProjPMap2(|.Rg.|,z0),x)).yy .| < r1/(b-a)/(d-c)
by A31,A131,A141,A154,A130;
hence |. (Pg121-Pg120).y .| <= r1/(b-a)/(d-c) by A156,EXTREAL1:12;
end; then
|. integral(Pg121-Pg120,c,d) .| <= r1/(b-a)/(d-c) * (d-c)
by A9,A10,A11,A12,A152,A153,INTEGRA6:23;
hence |. (Pg1-Pg0).x .| <= r1/(b-a) by A151,A128,XCMPLX_1:87;
end; then
for x be Real st x in ['a,b'] holds |. (Pg1-Pg0).x .| <= r1/(b-a)
by A5,A8; then
|. integral(Pg1-Pg0,a,b) .| <= r1/(b-a) * (b-a)
by A5,A6,A7,A8,A139,A140,INTEGRA6:23; then
|. integral(Pg1-Pg0,a,b) .| <= r1 by A128,XCMPLX_1:87; then
|. integral(Pg1-Pg0,a,b) .| < r by A129,XXREAL_0:2;
hence |. Gxy.zz1-Gxy.zz0 .| < r
by A5,A6,A8,A35,A37,A135,A137,A38,A138,INTEGRA6:12;
end;
hence ex s be Real st 0<s & for z1 be Real
st z1 in K & |.z1-zz0.| < s holds |.Gxy.z1-Gxy.zz0.| < r by A130;
end;
end; then
Gxy|K is continuous by A4,A30,FCONT_1:14;
hence Gxy is continuous by A4;
end;
theorem Th37:
for I,J,K be non empty closed_interval Subset of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL,
Gxy be PartFunc of REAL,REAL
st [:[:I,J:],K:] = dom f & f is_continuous_on [:[:I,J:],K:] & f = g
& Gxy = Integral1(Prod_Measure(L-Meas,L-Meas),R_EAL g)|K holds
Gxy is continuous
proof
let I,J,K be non empty closed_interval Subset of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL,
Gxy be PartFunc of REAL,REAL;
assume that
A1: [:[:I,J:],K:] = dom f and
A2: f is_continuous_on [:[:I,J:],K:] and
A3: f = g and
A4: Gxy = Integral1(Prod_Measure(L-Meas,L-Meas),R_EAL g)|K;
consider a,b be Real such that
A5: I = [.a,b.] by MEASURE5:def 3;
A6: a <= b by A5,XXREAL_1:29; then
A7: a in I & b in I by A5;
A8: [.a,b.] = ['a,b'] by A5,XXREAL_1:29,INTEGRA5:def 3;
consider c,d be Real such that
A9: J = [.c,d.] by MEASURE5:def 3;
A10:c <= d by A9,XXREAL_1:29; then
A11:c in J & d in J by A9;
A12: [.c,d.] = ['c,d'] by A9,XXREAL_1:29,INTEGRA5:def 3;
A13:for e be Real st 0 < e holds ex r be Real st 0 < r
& for z1,z2 be Real st |.z2-z1.| < r & z1 in K & z2 in K
holds for x,y be Real st x in I & y in J holds
|. g.([x,y,z2]) - g.([x,y,z1]) .| < e
proof
let e be Real;
assume 0 < e; then
consider r be Real such that
A14: 0 < r
& for x1,x2,y1,y2,z1,z2 be Real st
x1 in I & x2 in I & y1 in J & y2 in J & z1 in K & z2 in K
& |.x2-x1.| < r & |.y2-y1.| < r & |.z2-z1.| < r holds
|. g.([x2,y2,z2]) - g.([x1,y1,z1]) .| < e by A2,A3,Th8;
take r;
thus 0 < r by A14;
let z1,z2 be Real;
assume
A15: |.z2-z1.| < r & z1 in K & z2 in K;
let x,y be Real;
assume A16: x in I & y in J;
|.x-x.| < r & |.y-y.| < r by A14;
hence |. g.([x,y,z2]) - g.([x,y,z1]) .| < e by A14,A15,A16;
end;
set Rg =R_EAL g;
A17:dom Rg = [:[:I,J:],K:] by A1,A3,MESFUNC5:def 7;
A18:for x,y,z be Element of REAL st x in I & y in J & z in K holds
(ProjPMap2(Rg,z)).(x,y) = Rg.([x,y],z)
& Rg.([x,y],z) = g.([x,y,z]) & Rg.([x,y],z) = g.([x,y,z])
proof
let x,y,z be Element of REAL;
assume
A19: x in I & y in J & z in K; then
[x,y] in [:I,J:] by ZFMISC_1:87;
hence (ProjPMap2(Rg,z)).(x,y) =Rg.([x,y],z)
by A17,A19,ZFMISC_1:87,MESFUN12:def 4;
thus Rg.([x,y],z) = g.([x,y,z]) by MESFUNC5:def 7;
thus Rg.([x,y],z) = g.([x,y,z]) by MESFUNC5:def 7;
end;
A20:for e be Real st 0 < e holds ex r be Real st 0 < r
& for z1,z2 be Element of REAL st |.z2-z1.| < r & z1 in K & z2 in K holds
for x,y be Element of REAL st x in I & y in J holds
|. (ProjPMap1(ProjPMap2(Rg,z2),x)).y
-(ProjPMap1(ProjPMap2(Rg,z1),x)).y .| < e
proof
let e be Real;
assume 0 < e; then
consider r be Real such that
A21: 0 < r
& for z1,z2 be Real st |.z2-z1.| < r & z1 in K & z2 in K
holds for x,y be Real st x in I & y in J holds
|. g.([x,y,z2]) - g.([x,y,z1]) .| < e by A13;
take r;
thus 0 < r by A21;
let z1,z2 be Element of REAL;
assume
A22: |.z2-z1.| < r & z1 in K & z2 in K;
let x,y be Element of REAL;
assume
A23: x in I & y in J; then
A24: |. g.([x,y,z2]) - g.([x,y,z1]) .| < e by A21,A22;
a24: g.([x,y,z2]) - g.([x,y,z1]) = g.([x,y,z2]) qua ExtReal - g.([x,y,z1]);
dom ProjPMap2(Rg,z1) = [:I,J:] by A22,A1,A3,MESFUN16:28; then
A25: (ProjPMap1(ProjPMap2(Rg,z1),x)).y
= ProjPMap2(Rg,z1).(x,y) by A23,ZFMISC_1:87,MESFUN12:def 3;
dom ProjPMap2(Rg,z2) = [:I,J:] by A22,A1,A3,MESFUN16:28; then
A26: (ProjPMap1(ProjPMap2(Rg,z2),x)).y
= ProjPMap2(Rg,z2).(x,y) by A23,ZFMISC_1:87,MESFUN12:def 3;
(ProjPMap2(Rg,z1)).(x,y) = Rg.([x,y],z1)
& Rg.([x,y],z1) = g.([x,y,z1])
& (ProjPMap2(Rg,z2)).(x,y) = Rg.([x,y],z2)
& Rg.([x,y],z2) = g.([x,y,z2]) by A18,A22,A23;
hence thesis by A24,a24,A25,A26,EXTREAL1:12;
end;
A27:dom Integral1(Prod_Measure(L-Meas,L-Meas),Rg) = REAL by FUNCT_2:def 1;
for z0,r be Real st z0 in K & 0 < r
ex s be Real st 0<s & for z1 be Real
st z1 in K & |.z1-z0.| < s holds |.Gxy.z1-Gxy.z0.| < r
proof
let zz0,r be Real;
assume
A28: zz0 in K & 0 < r;
reconsider z0=zz0 as Element of REAL by XREAL_0:def 1;
reconsider Pg20 = ProjPMap2(Rg,z0) as PartFunc of [:REAL,REAL:],REAL
by MESFUN16:30;
reconsider Pf20 = Pg20 as PartFunc of [:RNS_Real,RNS_Real:],RNS_Real;
A29: dom Pg20 = [:I,J:] by A28,A1,A3,MESFUN16:28; then
A30: Pf20 is_continuous_on [:I,J:] by A1,A2,A3,Th18; then
reconsider Pg0 = Integral2(L-Meas,R_EAL Pg20)|I
as PartFunc of REAL,REAL by A29,MESFUN16:51;
A31: dom Integral2(L-Meas,R_EAL Pg20) = REAL by FUNCT_2:def 1; then
A32: dom Pg0 = I;
A33: Pg0 is continuous by A1,A2,A3,A29,Th18,MESFUN16:53; then
A34: Pg0|I is bounded & Pg0 is_integrable_on I by A31,INTEGRA5:10,11;
(Integral1(Prod_Measure(L-Meas,L-Meas),Rg)).z0
= Integral(Prod_Measure(L-Meas,L-Meas),Pg20) by A28,A1,A2,A3,Th23
.= Integral(Prod_Measure(L-Meas,L-Meas),R_EAL Pg20); then
(Integral1(Prod_Measure(L-Meas,L-Meas),Rg)).z0
= integral(Pg0,I) by A1,A2,A3,A29,Th18,MESFUN16:58; then
Gxy.zz0 = integral(Pg0,I) by A4,A28,FUNCT_1:49; then
A35: Gxy.zz0 = integral(Pg0,a,b) by A5,A8,XXREAL_1:29,INTEGRA5:def 4;
per cases;
suppose A36: a = b & c = d;
consider s be Real such that
A37: 0 < s
& for z1,z2 be Element of REAL st |.z2-z1.| < s & z1 in K & z2 in K holds
for x,y be Element of REAL st x in I & y in J holds
|. (ProjPMap1(ProjPMap2(Rg,z2),x)).y
-(ProjPMap1(ProjPMap2(Rg,z1),x)).y .| < r by A20,A28;
for z1 be Real st z1 in K & |.z1-z0.| < s holds |.Gxy.z1-Gxy.zz0 .| < r
proof
let zz1 be Real;
assume
A38: zz1 in K & |.zz1-z0.| < s;
reconsider z1=zz1 as Element of REAL by XREAL_0:def 1;
reconsider Pg21 = ProjPMap2(Rg,z1) as PartFunc of [:REAL,REAL:],REAL
by MESFUN16:30;
reconsider Pf21 = Pg21 as PartFunc of [:RNS_Real,RNS_Real:],RNS_Real;
A39: dom Pg21 = [:I,J:] by A38,A1,A3,MESFUN16:28; then
A40: Pf21 is_continuous_on [:I,J:] by A1,A2,A3,Th18; then
reconsider Pg1 = Integral2(L-Meas,R_EAL Pg21)|I
as PartFunc of REAL,REAL by A39,MESFUN16:51;
A41: dom Integral2(L-Meas,R_EAL Pg21) = REAL by FUNCT_2:def 1; then
A42: dom Pg1 = I;
A43: Pg1 is continuous by A1,A2,A3,A39,Th18,MESFUN16:53; then
A44: Pg1|I is bounded & Pg1 is_integrable_on I by A41,INTEGRA5:10,11;
(Integral1(Prod_Measure(L-Meas,L-Meas),Rg)).z1
= Integral(Prod_Measure(L-Meas,L-Meas),Pg21) by A38,A1,A2,A3,Th23
.= Integral(Prod_Measure(L-Meas,L-Meas),R_EAL Pg21); then
(Integral1(Prod_Measure(L-Meas,L-Meas),Rg)).z1
= integral(Pg1,I) by A1,A2,A3,A39,Th18,MESFUN16:58; then
Gxy.zz1 = integral(Pg1,I) by A4,A38,FUNCT_1:49; then
A45: Gxy.zz1 = integral(Pg1,a,b) by A5,A8,XXREAL_1:29,INTEGRA5:def 4;
A46: dom(Pg1-Pg0) = I /\ I by A32,A42,VALUED_1:12; then
A47: Pg1-Pg0 is_integrable_on I & (Pg1-Pg0)|I is bounded
by A33,A43,INTEGRA5:10,11;
for x be Element of REAL st x in I holds |. (Pg1-Pg0).x .| <= r
proof
let x be Element of REAL;
assume
A48: x in I;
reconsider Pg120 = ProjPMap1(Pg20,x) as PartFunc of REAL,REAL;
A49: dom Pg120 = J by A48,A29,MESFUN16:25;
ProjPMap1(R_EAL Pg20,x) = R_EAL ProjPMap1(Pg20,x)
by MESFUN16:31; then
A50: Pg120 = ProjPMap1(R_EAL Pg20,x) by MESFUNC5:def 7;
A51: Pg120 is continuous by A29,A30,MESFUN16:33;
A52: Pg120|J is bounded & Pg120 is_integrable_on J
by A29,A30,A48,A50,MESFUN16:40;
reconsider Pg121 = ProjPMap1(Pg21,x) as PartFunc of REAL,REAL;
A53: dom Pg121 = J by A48,A39,MESFUN16:25;
ProjPMap1(R_EAL Pg21,x) = R_EAL ProjPMap1(Pg21,x)
by MESFUN16:31; then
A54: Pg121 = ProjPMap1(R_EAL Pg21,x) by MESFUNC5:def 7;
A55: Pg121 is continuous by A39,A40,MESFUN16:33;
A56: Pg121|J is bounded & Pg121 is_integrable_on J
by A39,A40,A48,A54,MESFUN16:40;
Pg0.x = Integral2(L-Meas,R_EAL Pg20).x by A48,FUNCT_1:49; then
Pg0.x = Integral(L-Meas,ProjPMap1(R_EAL Pg20,x))
by MESFUN12:def 8; then
Pg0.x = Integral(L-Meas,Pg120) by MESFUN16:31; then
A57: Pg0.x = integral(Pg120,c,d) by A9,A12,A49,A52,XXREAL_1:29,MESFUN14:50;
Pg1.x = Integral2(L-Meas,R_EAL Pg21).x by A48,FUNCT_1:49; then
Pg1.x = Integral(L-Meas,ProjPMap1(R_EAL Pg21,x))
by MESFUN12:def 8; then
Pg1.x = Integral(L-Meas,Pg121) by MESFUN16:31; then
Pg1.x = integral(Pg121,c,d)
by A9,A12,A53,A56,XXREAL_1:29,MESFUN14:50; then
A58: Pg1.x - Pg0.x = integral(Pg121-Pg120,c,d)
by A9,A10,A12,A52,A56,A53,A49,A57,INTEGRA6:12;
A59: dom(Pg121-Pg120) = J /\ J by A49,A53,VALUED_1:12; then
A60: (Pg121-Pg120)|J is bounded & (Pg121-Pg120) is_integrable_on J
by A51,A55,INTEGRA5:10,11;
for y be Real st y in J holds |. (Pg121-Pg120).y .| <= r
proof
let y be Real;
assume
A61: y in J;
reconsider yy=y as Element of REAL by XREAL_0:def 1;
A62: Pg120.y = (ProjPMap1(ProjPMap2(Rg,z0),x)).yy
& Pg121.y = (ProjPMap1(ProjPMap2(Rg,z1),x)).yy
by A50,A54,MESFUNC5:def 7;
A63: (Pg121-Pg120).y = Pg121.y - Pg120.y by A59,A61,VALUED_1:13
.= (ProjPMap1(ProjPMap2(Rg,z1),x)).yy
- (ProjPMap1(ProjPMap2(Rg,z0),x)).yy by A62,Lm6;
|. (ProjPMap1(ProjPMap2(Rg,z1),x)).yy
-(ProjPMap1(ProjPMap2(Rg,z0),x)).yy .| < r
by A28,A38,A48,A61,A37;
hence |. (Pg121-Pg120).y .| <= r by A63,EXTREAL1:12;
end; then
|. integral(Pg121-Pg120,c,d) .| <= r * (d-c)
by A9,A10,A11,A12,A59,A60,INTEGRA6:23;
hence |. (Pg1-Pg0).x .| <= r by A28,A36,A46,A48,A58,VALUED_1:13;
end; then
for x be Real st x in ['a,b'] holds |. (Pg1-Pg0).x .| <= r
by A5,A8; then
|. integral(Pg1-Pg0,a,b) .| <= r * (b-a)
by A5,A6,A7,A8,A46,A47,INTEGRA6:23;
hence |. Gxy.zz1-Gxy.zz0 .| < r
by A5,A8,A28,A32,A34,A36,A42,A44,A35,A45,INTEGRA6:12;
end;
hence ex s be Real st 0<s & for z1 be Real
st z1 in K & |.z1-zz0.| < s holds |.Gxy.z1-Gxy.zz0.| < r by A37;
end;
suppose A64: a <> b & c = d; then
a < b by A6,XXREAL_0:1; then
A65: 0 < b-a by XREAL_1:50;
set r1=r/2;
A66: 0 < r1 & r1 < r by A28,XREAL_1:215,216; then
A67: 0 < r1/(b-a) by A65,XREAL_1:139;
consider s be Real such that
A68: 0 < s
& for z1,z2 be Element of REAL st |.z2-z1.| < s & z1 in K & z2 in K holds
for x,y be Element of REAL st x in I & y in J holds
|. (ProjPMap1(ProjPMap2(Rg,z2),x)).y
-(ProjPMap1(ProjPMap2(Rg,z1),x)).y .| < r1/(b-a)
by A20,A65,A66,XREAL_1:139;
for z1 be Real st z1 in K & |.z1-z0.| < s holds |.Gxy.z1-Gxy.zz0 .| < r
proof
let zz1 be Real;
assume
A69: zz1 in K & |.zz1-z0.| < s;
reconsider z1=zz1 as Element of REAL by XREAL_0:def 1;
reconsider Pg21 = ProjPMap2(Rg,z1) as PartFunc of [:REAL,REAL:],REAL
by MESFUN16:30;
reconsider Pf21 = Pg21 as PartFunc of [:RNS_Real,RNS_Real:],RNS_Real;
A70: dom Pg21 = [:I,J:] by A69,A1,A3,MESFUN16:28; then
A71: Pf21 is_continuous_on [:I,J:] by A1,A2,A3,Th18; then
reconsider Pg1 = Integral2(L-Meas,R_EAL Pg21)|I
as PartFunc of REAL,REAL by A70,MESFUN16:51;
A72: dom Integral2(L-Meas,R_EAL Pg21) = REAL by FUNCT_2:def 1; then
A73: dom Pg1 = I;
A74: Pg1 is continuous by A1,A2,A3,A70,Th18,MESFUN16:53; then
A75: Pg1|I is bounded & Pg1 is_integrable_on I by A72,INTEGRA5:10,11;
(Integral1(Prod_Measure(L-Meas,L-Meas),Rg)).z1
= Integral(Prod_Measure(L-Meas,L-Meas),Pg21) by A69,A1,A2,A3,Th23
.= Integral(Prod_Measure(L-Meas,L-Meas),R_EAL Pg21); then
(Integral1(Prod_Measure(L-Meas,L-Meas),Rg)).z1
= integral(Pg1,I) by A1,A2,A3,A70,Th18,MESFUN16:58; then
Gxy.zz1 = integral(Pg1,I) by A4,A69,FUNCT_1:49; then
A76: Gxy.zz1 = integral(Pg1,a,b) by A5,A8,XXREAL_1:29,INTEGRA5:def 4;
A77: dom(Pg1-Pg0) = I /\ I by A32,A73,VALUED_1:12; then
A78: Pg1-Pg0 is_integrable_on I & (Pg1-Pg0)|I is bounded
by A33,A74,INTEGRA5:10,11;
for x be Element of REAL st x in I holds |. (Pg1-Pg0).x .| <= r1/(b-a)
proof
let x be Element of REAL;
assume
A79: x in I;
reconsider Pg120 = ProjPMap1(Pg20,x) as PartFunc of REAL,REAL;
A80: dom Pg120 = J by A79,A29,MESFUN16:25;
ProjPMap1(R_EAL Pg20,x) = R_EAL ProjPMap1(Pg20,x)
by MESFUN16:31; then
A81: Pg120 = ProjPMap1(R_EAL Pg20,x) by MESFUNC5:def 7;
A82: Pg120 is continuous by A29,A30,MESFUN16:33;
A83: Pg120|J is bounded & Pg120 is_integrable_on J
by A29,A30,A79,A81,MESFUN16:40;
reconsider Pg121 = ProjPMap1(Pg21,x) as PartFunc of REAL,REAL;
A84: dom Pg121 = J by A79,A70,MESFUN16:25;
ProjPMap1(R_EAL Pg21,x) = R_EAL ProjPMap1(Pg21,x) by MESFUN16:31; then
A85: Pg121 = ProjPMap1(R_EAL Pg21,x) by MESFUNC5:def 7;
A86: Pg121 is continuous by A70,A71,MESFUN16:33;
A87: Pg121|J is bounded & Pg121 is_integrable_on J
by A70,A71,A79,A85,MESFUN16:40;
Pg0.x = Integral2(L-Meas,R_EAL Pg20).x by A79,FUNCT_1:49; then
Pg0.x = Integral(L-Meas,ProjPMap1(R_EAL Pg20,x))
by MESFUN12:def 8; then
Pg0.x = Integral(L-Meas,Pg120) by MESFUN16:31; then
A88: Pg0.x = integral(Pg120,c,d) by A9,A12,A80,A83,XXREAL_1:29,MESFUN14:50;
Pg1.x = Integral2(L-Meas,R_EAL Pg21).x by A79,FUNCT_1:49; then
Pg1.x = Integral(L-Meas,ProjPMap1(R_EAL Pg21,x))
by MESFUN12:def 8; then
Pg1.x = Integral(L-Meas,Pg121) by MESFUN16:31; then
Pg1.x = integral(Pg121,c,d)
by A9,A12,A84,A87,XXREAL_1:29,MESFUN14:50; then
A89: Pg1.x - Pg0.x = integral(Pg121-Pg120,c,d)
by A9,A10,A12,A83,A87,A84,A80,A88,INTEGRA6:12;
A90: dom(Pg121-Pg120) = J /\ J by A80,A84,VALUED_1:12; then
A91: (Pg121-Pg120)|J is bounded & (Pg121-Pg120) is_integrable_on J
by A82,A86,INTEGRA5:10,11;
for y be Real st y in J holds |. (Pg121-Pg120).y .| <= r1/(b-a)
proof
let y be Real;
assume
A92: y in J;
reconsider yy=y as Element of REAL by XREAL_0:def 1;
A93: Pg120.y = (ProjPMap1(ProjPMap2(Rg,z0),x)).yy
& Pg121.y = (ProjPMap1(ProjPMap2(Rg,z1),x)).yy
by A81,A85,MESFUNC5:def 7;
A94: (Pg121-Pg120).y = Pg121.y - Pg120.y by A90,A92,VALUED_1:13
.= (ProjPMap1(ProjPMap2(Rg,z1),x)).yy
- (ProjPMap1(ProjPMap2(Rg,z0),x)).yy by A93,Lm6;
|. (ProjPMap1(ProjPMap2(Rg,z1),x)).yy
-(ProjPMap1(ProjPMap2(Rg,z0),x)).yy .| < r1/(b-a)
by A28,A69,A79,A92,A68;
hence |. (Pg121-Pg120).y .| <= r1/(b-a) by A94,EXTREAL1:12;
end; then
|. integral(Pg121-Pg120,c,d) .| <= r1/(b-a) * (d-c)
by A9,A10,A11,A12,A90,A91,INTEGRA6:23;
hence |. (Pg1-Pg0).x .| <= r1/(b-a)
by A64,A77,A79,A89,A67,VALUED_1:13;
end; then
for x be Real st x in ['a,b'] holds |. (Pg1-Pg0).x .| <= r1/(b-a)
by A5,A8; then
|. integral(Pg1-Pg0,a,b) .| <= r1/(b-a) * (b-a)
by A5,A6,A7,A8,A77,A78,INTEGRA6:23; then
|. integral(Pg1-Pg0,a,b) .| <= r1 by A65,XCMPLX_1:87; then
|. integral(Pg1-Pg0,a,b) .| < r by A66,XXREAL_0:2;
hence |. Gxy.zz1-Gxy.zz0 .| < r
by A5,A6,A8,A32,A34,A73,A75,A35,A76,INTEGRA6:12;
end;
hence ex s be Real st 0<s & for z1 be Real
st z1 in K & |.z1-zz0.| < s holds |.Gxy.z1-Gxy.zz0.| < r by A68;
end;
suppose A95: a = b & c <> d; then
c < d by A10,XXREAL_0:1; then
A96: 0 < d-c by XREAL_1:50;
set r1=r/2;
0 < r1 & r1 < r by A28,XREAL_1:215,216; then
consider s be Real such that
A97: 0 < s
& for z1,z2 be Element of REAL st |.z2-z1.| < s & z1 in K & z2 in K holds
for x,y be Element of REAL st x in I & y in J holds
|. (ProjPMap1(ProjPMap2(Rg,z2),x)).y
-(ProjPMap1(ProjPMap2(Rg,z1),x)).y .| < r1/(d-c)
by A20,A96,XREAL_1:139;
for z1 be Real st z1 in K & |.z1-z0.| < s holds |.Gxy.z1-Gxy.zz0 .| < r
proof
let zz1 be Real;
assume
A98: zz1 in K & |.zz1-z0.| < s;
reconsider z1=zz1 as Element of REAL by XREAL_0:def 1;
reconsider Pg21 = ProjPMap2(Rg,z1) as PartFunc of [:REAL,REAL:],REAL
by MESFUN16:30;
reconsider Pf21 = Pg21 as PartFunc of [:RNS_Real,RNS_Real:],RNS_Real;
A99: dom Pg21 = [:I,J:] by A98,A1,A3,MESFUN16:28; then
A100: Pf21 is_continuous_on [:I,J:] by A1,A2,A3,Th18; then
reconsider Pg1 = Integral2(L-Meas,R_EAL Pg21)|I
as PartFunc of REAL,REAL by A99,MESFUN16:51;
A101: dom Integral2(L-Meas,R_EAL Pg21) = REAL by FUNCT_2:def 1; then
A102: dom Pg1 = I;
A103: Pg1 is continuous by A1,A2,A3,A99,Th18,MESFUN16:53; then
A104: Pg1|I is bounded & Pg1 is_integrable_on I by A101,INTEGRA5:10,11;
(Integral1(Prod_Measure(L-Meas,L-Meas),Rg)).z1
= Integral(Prod_Measure(L-Meas,L-Meas),Pg21) by A98,A1,A2,A3,Th23
.= Integral(Prod_Measure(L-Meas,L-Meas),R_EAL Pg21); then
(Integral1(Prod_Measure(L-Meas,L-Meas),Rg)).z1
= integral(Pg1,I) by A1,A2,A3,A99,Th18,MESFUN16:58; then
Gxy.zz1 = integral(Pg1,I) by A4,A98,FUNCT_1:49; then
A105: Gxy.zz1 = integral(Pg1,a,b) by A5,A8,XXREAL_1:29,INTEGRA5:def 4;
A106: dom(Pg1-Pg0) = I /\ I by A32,A102,VALUED_1:12; then
A107: Pg1-Pg0 is_integrable_on I & (Pg1-Pg0)|I is bounded
by A33,A103,INTEGRA5:10,11;
for x be Element of REAL st x in I holds |. (Pg1-Pg0).x .| <= r1
proof
let x be Element of REAL;
assume
A108: x in I;
reconsider Pg120 = ProjPMap1(Pg20,x) as PartFunc of REAL,REAL;
A109: dom Pg120 = J by A108,A29,MESFUN16:25;
ProjPMap1(R_EAL Pg20,x) = R_EAL ProjPMap1(Pg20,x) by MESFUN16:31; then
A110: Pg120 = ProjPMap1(R_EAL Pg20,x) by MESFUNC5:def 7;
A111: Pg120 is continuous by A29,A30,MESFUN16:33;
A112: Pg120|J is bounded & Pg120 is_integrable_on J
by A29,A30,A108,A110,MESFUN16:40;
reconsider Pg121 = ProjPMap1(Pg21,x) as PartFunc of REAL,REAL;
A113: dom Pg121 = J by A108,A99,MESFUN16:25;
ProjPMap1(R_EAL Pg21,x) = R_EAL ProjPMap1(Pg21,x) by MESFUN16:31; then
A114: Pg121 = ProjPMap1(R_EAL Pg21,x) by MESFUNC5:def 7;
A115: Pg121 is continuous by A99,A100,MESFUN16:33;
A116: Pg121|J is bounded & Pg121 is_integrable_on J
by A99,A100,A108,A114,MESFUN16:40;
Pg0.x = Integral2(L-Meas,R_EAL Pg20).x by A108,FUNCT_1:49; then
Pg0.x = Integral(L-Meas,ProjPMap1(R_EAL Pg20,x))
by MESFUN12:def 8; then
Pg0.x = Integral(L-Meas,Pg120) by MESFUN16:31; then
A117: Pg0.x = integral(Pg120,c,d)
by A9,A12,A109,A112,XXREAL_1:29,MESFUN14:50;
Pg1.x = Integral2(L-Meas,R_EAL Pg21).x by A108,FUNCT_1:49; then
Pg1.x = Integral(L-Meas,ProjPMap1(R_EAL Pg21,x))
by MESFUN12:def 8; then
Pg1.x = Integral(L-Meas,Pg121) by MESFUN16:31; then
Pg1.x = integral(Pg121,c,d)
by A9,A12,A113,A116,XXREAL_1:29,MESFUN14:50; then
Pg1.x - Pg0.x = integral(Pg121-Pg120,c,d)
by A9,A10,A12,A112,A116,A113,A109,A117,INTEGRA6:12; then
A118: (Pg1-Pg0).x = integral(Pg121-Pg120,c,d) by A106,A108,VALUED_1:13;
A119: dom(Pg121-Pg120) = J /\ J by A109,A113,VALUED_1:12; then
A120: (Pg121-Pg120)|J is bounded & (Pg121-Pg120) is_integrable_on J
by A111,A115,INTEGRA5:10,11;
for y be Real st y in J holds |. (Pg121-Pg120).y .| <= r1/(d-c)
proof
let y be Real;
assume
A121: y in J;
reconsider yy=y as Element of REAL by XREAL_0:def 1;
A122: Pg120.y = (ProjPMap1(ProjPMap2(Rg,z0),x)).yy
& Pg121.y = (ProjPMap1(ProjPMap2(Rg,z1),x)).yy
by A110,A114,MESFUNC5:def 7;
A123: (Pg121-Pg120).y = Pg121.y - Pg120.y by A119,A121,VALUED_1:13
.= (ProjPMap1(ProjPMap2(Rg,z1),x)).yy
- (ProjPMap1(ProjPMap2(Rg,z0),x)).yy by A122,Lm6;
|. (ProjPMap1(ProjPMap2(Rg,z1),x)).yy
-(ProjPMap1(ProjPMap2(Rg,z0),x)).yy .| < r1/(d-c)
by A28,A98,A108,A121,A97;
hence |. (Pg121-Pg120).y .| <= r1/(d-c) by A123,EXTREAL1:12;
end; then
|. integral(Pg121-Pg120,c,d) .| <= r1/(d-c) * (d-c)
by A9,A10,A11,A12,A119,A120,INTEGRA6:23;
hence |. (Pg1-Pg0).x .| <= r1 by A118,A96,XCMPLX_1:87;
end; then
for x be Real st x in ['a,b'] holds |. (Pg1-Pg0).x .| <= r1
by A5,A8; then
|. integral(Pg1-Pg0,a,b) .| <= r1 * (b-a)
by A5,A6,A7,A8,A106,A107,INTEGRA6:23;
hence |. Gxy.zz1-Gxy.zz0 .| < r
by A5,A8,A32,A34,A95,A102,A104,A35,A105,A28,INTEGRA6:12;
end;
hence ex s be Real st 0<s & for z1 be Real
st z1 in K & |.z1-zz0.| < s holds |.Gxy.z1-Gxy.zz0.| < r by A97;
end;
suppose a <> b & c <> d; then
a < b & c < d by A6,A10,XXREAL_0:1; then
A124: 0 < b-a & 0 < d-c by XREAL_1:50;
set r1=r/2;
A125: 0 < r1 & r1 < r by A28,XREAL_1:215,216; then
0 < r1/(b-a) by A124,XREAL_1:139; then
consider s be Real such that
A126: 0 < s
& for z1,z2 be Element of REAL st |.z2-z1.| < s & z1 in K & z2 in K holds
for x,y be Element of REAL st x in I & y in J holds
|. (ProjPMap1(ProjPMap2(Rg,z2),x)).y
-(ProjPMap1(ProjPMap2(Rg,z1),x)).y .| < r1/(b-a)/(d-c)
by A20,A124,XREAL_1:139;
for z1 be Real st z1 in K & |.z1-z0.| < s holds |.Gxy.z1-Gxy.zz0 .| < r
proof
let zz1 be Real;
assume
A127: zz1 in K & |.zz1-z0.| < s;
reconsider z1=zz1 as Element of REAL by XREAL_0:def 1;
reconsider Pg21 = ProjPMap2(Rg,z1) as PartFunc of [:REAL,REAL:],REAL
by MESFUN16:30;
reconsider Pf21 = Pg21 as PartFunc of [:RNS_Real,RNS_Real:],RNS_Real;
A128: dom Pg21 = [:I,J:] by A127,A1,A3,MESFUN16:28; then
A129: Pf21 is_continuous_on [:I,J:] by A1,A2,A3,Th18; then
reconsider Pg1 = Integral2(L-Meas,R_EAL Pg21)|I
as PartFunc of REAL,REAL by A128,MESFUN16:51;
A130: dom Integral2(L-Meas,R_EAL Pg21) = REAL by FUNCT_2:def 1; then
A131: dom Pg1 = I;
A132: Pg1 is continuous by A1,A2,A3,A128,Th18,MESFUN16:53; then
A133: Pg1|I is bounded & Pg1 is_integrable_on I by A130,INTEGRA5:10,11;
(Integral1(Prod_Measure(L-Meas,L-Meas),Rg)).z1
= Integral(Prod_Measure(L-Meas,L-Meas),Pg21) by A127,A1,A2,A3,Th23
.= Integral(Prod_Measure(L-Meas,L-Meas),R_EAL Pg21); then
(Integral1(Prod_Measure(L-Meas,L-Meas),Rg)).z1
= integral(Pg1,I) by A1,A2,A3,A128,Th18,MESFUN16:58; then
Gxy.zz1 = integral(Pg1,I) by A4,A127,FUNCT_1:49; then
A134: Gxy.zz1 = integral(Pg1,a,b) by A5,A8,XXREAL_1:29,INTEGRA5:def 4;
A135: dom(Pg1-Pg0) = I /\ I by A32,A131,VALUED_1:12; then
A136: Pg1-Pg0 is_integrable_on I & (Pg1-Pg0)|I is bounded
by A33,A132,INTEGRA5:10,11;
for x be Element of REAL st x in I holds |. (Pg1-Pg0).x .| <= r1/(b-a)
proof
let x be Element of REAL;
assume
A137: x in I;
reconsider Pg120 = ProjPMap1(Pg20,x) as PartFunc of REAL,REAL;
A138: dom Pg120 = J by A137,A29,MESFUN16:25;
ProjPMap1(R_EAL Pg20,x) = R_EAL ProjPMap1(Pg20,x)
by MESFUN16:31; then
A139: Pg120 = ProjPMap1(R_EAL Pg20,x) by MESFUNC5:def 7;
A140: Pg120 is continuous by A29,A30,MESFUN16:33;
A141: Pg120|J is bounded & Pg120 is_integrable_on J
by A29,A30,A137,A139,MESFUN16:40;
reconsider Pg121 = ProjPMap1(Pg21,x) as PartFunc of REAL,REAL;
A142: dom Pg121 = J by A137,A128,MESFUN16:25;
ProjPMap1(R_EAL Pg21,x) = R_EAL ProjPMap1(Pg21,x)
by MESFUN16:31; then
A143: Pg121 = ProjPMap1(R_EAL Pg21,x) by MESFUNC5:def 7;
A144: Pg121 is continuous by A128,A129,MESFUN16:33;
A145: Pg121|J is bounded & Pg121 is_integrable_on J
by A128,A129,A137,A143,MESFUN16:40;
Pg0.x = Integral2(L-Meas,R_EAL Pg20).x by A137,FUNCT_1:49; then
Pg0.x = Integral(L-Meas,ProjPMap1(R_EAL Pg20,x))
by MESFUN12:def 8; then
Pg0.x = Integral(L-Meas,Pg120) by MESFUN16:31; then
A146: Pg0.x = integral(Pg120,c,d)
by A9,A12,A138,A141,XXREAL_1:29,MESFUN14:50;
Pg1.x = Integral2(L-Meas,R_EAL Pg21).x by A137,FUNCT_1:49; then
Pg1.x = Integral(L-Meas,ProjPMap1(R_EAL Pg21,x))
by MESFUN12:def 8; then
Pg1.x = Integral(L-Meas,Pg121) by MESFUN16:31; then
Pg1.x = integral(Pg121,c,d)
by A9,A12,A142,A145,XXREAL_1:29,MESFUN14:50; then
Pg1.x - Pg0.x = integral(Pg121-Pg120,c,d)
by A9,A10,A12,A141,A145,A142,A138,A146,INTEGRA6:12; then
A147: (Pg1-Pg0).x = integral(Pg121-Pg120,c,d) by A135,A137,VALUED_1:13;
A148: dom(Pg121-Pg120) = J /\ J by A138,A142,VALUED_1:12; then
A149: (Pg121-Pg120)|J is bounded & (Pg121-Pg120) is_integrable_on J
by A140,A144,INTEGRA5:10,11;
for y be Real st y in J holds |. (Pg121-Pg120).y .| <= r1/(b-a)/(d-c)
proof
let y be Real;
assume
A150: y in J;
reconsider yy=y as Element of REAL by XREAL_0:def 1;
A151: Pg120.y = (ProjPMap1(ProjPMap2(Rg,z0),x)).yy
& Pg121.y = (ProjPMap1(ProjPMap2(Rg,z1),x)).yy
by A139,A143,MESFUNC5:def 7;
A152: (Pg121-Pg120).y = Pg121.y - Pg120.y by A148,A150,VALUED_1:13
.= (ProjPMap1(ProjPMap2(Rg,z1),x)).yy
- (ProjPMap1(ProjPMap2(Rg,z0),x)).yy by A151,Lm6;
|. (ProjPMap1(ProjPMap2(Rg,z1),x)).yy
-(ProjPMap1(ProjPMap2(Rg,z0),x)).yy .| < r1/(b-a)/(d-c)
by A28,A127,A137,A150,A126;
hence |. (Pg121-Pg120).y .| <= r1/(b-a)/(d-c) by A152,EXTREAL1:12;
end; then
|. integral(Pg121-Pg120,c,d) .| <= r1/(b-a)/(d-c) * (d-c)
by A9,A10,A11,A12,A148,A149,INTEGRA6:23;
hence |. (Pg1-Pg0).x .| <= r1/(b-a) by A147,A124,XCMPLX_1:87;
end; then
for x be Real st x in ['a,b'] holds |. (Pg1-Pg0).x .| <= r1/(b-a)
by A5,A8; then
|. integral(Pg1-Pg0,a,b) .| <= r1/(b-a) * (b-a)
by A5,A6,A7,A8,A135,A136,INTEGRA6:23; then
|. integral(Pg1-Pg0,a,b) .| <= r1 by A124,XCMPLX_1:87; then
|. integral(Pg1-Pg0,a,b) .| < r by A125,XXREAL_0:2;
hence |. Gxy.zz1-Gxy.zz0 .| < r
by A5,A6,A8,A32,A34,A131,A133,A35,A134,INTEGRA6:12;
end;
hence ex s be Real st 0<s & for z1 be Real
st z1 in K & |.z1-zz0.| < s holds |.Gxy.z1-Gxy.zz0.| < r by A126;
end;
end; then
Gxy|K is continuous by A4,A27,FCONT_1:14;
hence Gxy is continuous by A4;
end;
theorem Th38:
for I,J,K be non empty closed_interval Subset of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g being PartFunc of [:[:REAL,REAL:],REAL:],REAL
st [:[:I,J:],K:] = dom f & f is_continuous_on [:[:I,J:],K:] & f = g
holds Integral2(L-Meas,|.R_EAL g.|) is nonnegative
proof
let I,J,K be non empty closed_interval Subset of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL;
assume that
A1: [:[:I,J:],K:] = dom f and
A2: f is_continuous_on [:[:I,J:],K:] and
A3: f = g;
dom(R_EAL g) = [:[:I,J:],K:] by A1,A3,MESFUNC5:def 7; then
A4: dom |.R_EAL g.| = [:[:I,J:],K:] by MESFUNC1:def 10;
now let p be Element of [:REAL,REAL:];
per cases;
suppose
A5: p in [:I,J:];
consider x1,y1 be object such that
A6: x1 in REAL & y1 in REAL & p = [x1,y1] by ZFMISC_1:84;
reconsider x1,y1 as Element of REAL by A6;
A7: x1 in I & y1 in J by A5,A6,ZFMISC_1:87;
reconsider Pg = ProjPMap1(|.R_EAL g.|,p)
as PartFunc of REAL,REAL by MESFUN16:30;
reconsider K0 = K as Element of L-Field by MEASUR10:5,MEASUR12:75;
A8: K is Element of L-Field by MEASUR10:5,MEASUR12:75;
A9: dom Pg = K by A1,A3,A5,MESFUN16:27;
A10: Pg|K is bounded & Pg is_integrable_on K by A7,A1,A2,A3,A6,Th24;
A11: Pg is_integrable_on L-Meas & integral(Pg,K) = Integral(L-Meas,Pg)
by A8,A9,A10,MESFUN14:49;
R_EAL Pg = ProjPMap1(|.R_EAL g.|,p) by MESFUNC5:def 7; then
A12: Integral2(L-Meas,|.R_EAL g.|).p = integral(Pg,K) by A11,MESFUN12:def 8;
A13: Pg is K0-measurable by A1,A2,A3,A6,A7,Th25;
for y being object st y in dom(Pg|K) holds 0 <= (Pg|K).y
proof
let y be object;
assume
A14: y in dom(Pg|K); then
y in K; then
reconsider y as Element of REAL;
A15: (ProjPMap1(|.R_EAL g.|,p)).y = (|.R_EAL g.|).(p,y)
by A5,A14,A4,ZFMISC_1:87,MESFUN12:def 3;
A16: (R_EAL g).([p,y]) = g.([p,y]) by MESFUNC5:def 7;
(|.R_EAL g.|).(p,y) = |.(R_EAL g).([p,y]).|
by A4,A5,A14,ZFMISC_1:87,MESFUNC1:def 10; then
(|.R_EAL g.|).(p,y) = |. g.([p,y]) .| by A16,EXTREAL1:12;
hence thesis by A14,A15,FUNCT_1:49;
end;
hence 0 <= Integral2(L-Meas,|.R_EAL g.|).p
by A9,A11,A12,A13,MESFUNC6:52,84;
end;
suppose not p in [:I,J:];
hence 0 <= Integral2(L-Meas,|.R_EAL g.|).p by A1,A3,Lm4;
end;
end;
hence thesis;
end;
theorem Th39:
for I,J,K be non empty closed_interval Subset of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g being PartFunc of [:[:REAL,REAL:],REAL:],REAL
st [:[:I,J:],K:] = dom f & f is_continuous_on [:[:I,J:],K:] & f = g
holds Integral1(Prod_Measure(L-Meas,L-Meas),|.R_EAL g.|) is nonnegative
proof
let I,J,K be non empty closed_interval Subset of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g being PartFunc of [:[:REAL,REAL:],REAL:],REAL;
assume that
A1: [:[:I,J:],K:] = dom f and
A2: f is_continuous_on [:[:I,J:],K:] and
A3: f = g;
dom(R_EAL g) = [:[:I,J:],K:] by A1,A3,MESFUNC5:def 7; then
A4: dom |.R_EAL g.| = [:[:I,J:],K:] by MESFUNC1:def 10;
now let z be Element of REAL;
per cases;
suppose
A5: z in K;
reconsider Pg = ProjPMap2(|.R_EAL g.|,z)
as PartFunc of [:REAL,REAL:],REAL by MESFUN16:30;
reconsider Pf = Pg as PartFunc of [:RNS_Real,RNS_Real:],RNS_Real;
reconsider IJ = [:I,J:] as
Element of sigma measurable_rectangles(L-Field,L-Field) by MESFUN16:11;
A6: dom Pf = [:I,J:] by A1,A3,A5,MESFUN16:28;
Pf is_continuous_on dom Pf by A1,A2,A3,Th20; then
A7: Pg is_integrable_on Prod_Measure(L-Meas,L-Meas)
& Integral(Prod_Measure(L-Meas,L-Meas),Pg)
= Integral(L-Meas,Integral2(L-Meas,R_EAL Pg)) by A6,MESFUN16:57;
R_EAL Pg = ProjPMap2(|.R_EAL g.|,z) by MESFUNC5:def 7; then
A8: Integral1(Prod_Measure(L-Meas,L-Meas),|.R_EAL g.|).z
= Integral(Prod_Measure(L-Meas,L-Meas),R_EAL Pg) by MESFUN12:def 7;
A9: Pg is IJ-measurable by A1,A2,A3,A5,Th27;
for u being object st u in dom(Pg|IJ) holds 0 <= (Pg|IJ).u
proof
let u be object;
assume
A10: u in dom(Pg|IJ); then
u in IJ; then
reconsider u as Element of [:REAL,REAL:];
A11: (ProjPMap2(|.R_EAL g.|,z)).u = (|.R_EAL g.|).(u,z)
by A5,A10,A4,ZFMISC_1:87,MESFUN12:def 4;
A12: (R_EAL g).([u,z]) = g.([u,z]) by MESFUNC5:def 7;
(|.R_EAL g.|).(u,z) = |.(R_EAL g).([u,z]).|
by A4,A5,A10,ZFMISC_1:87,MESFUNC1:def 10; then
(|.R_EAL g.|).(u,z) = |. g.([u,z]) .| by A12,EXTREAL1:12;
hence thesis by A10,A11,FUNCT_1:49;
end;
hence 0 <= Integral1(Prod_Measure(L-Meas,L-Meas),|.R_EAL g.|).z
by A6,A7,A8,A9,MESFUNC6:52,84;
end;
suppose not z in K;
hence 0 <= Integral1(Prod_Measure(L-Meas,L-Meas),|.R_EAL g.|).z
by A1,A3,Lm5;
end;
end;
hence thesis;
end;
theorem Th40:
for I,J,K be non empty closed_interval Subset of REAL,
u be Element of [:REAL,REAL:],
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g being PartFunc of [:[:REAL,REAL:],REAL:],REAL
st [:[:I,J:],K:] = dom f & f is_continuous_on [:[:I,J:],K:] & f = g
holds Integral2(L-Meas,|.R_EAL g.|).u < +infty
proof
let I,J,K be non empty closed_interval Subset of REAL,
u be Element of [:REAL,REAL:],
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL;
assume that
A1: [:[:I,J:],K:] = dom f and
A2: f is_continuous_on [:[:I,J:],K:] and
A3: f = g;
dom(Integral2(L-Meas,|.R_EAL g.|)) = [:REAL,REAL:] by FUNCT_2:def 1; then
A4: dom(Integral2(L-Meas,|.R_EAL g.|)| [: I,J:]) = [:I,J:];
reconsider G = Integral2(L-Meas,|.R_EAL g.|)| [:I,J:]
as PartFunc of [:REAL,REAL:],REAL by A1,A2,A3,Th32;
per cases;
suppose
A5: u in [:I,J:]; then
Integral2(L-Meas,|.R_EAL g.|).u = G.u by FUNCT_1:49; then
Integral2(L-Meas,|.R_EAL g.|).u in rng G by A5,A4,FUNCT_1:3;
hence Integral2(L-Meas,|.R_EAL g.|).u < +infty by XXREAL_0:9;
end;
suppose not u in [:I,J:]; then
Integral2(L-Meas,|.R_EAL g.|).u = 0 by A1,A3,Lm4;
hence Integral2(L-Meas,|.R_EAL g.|).u < +infty
by XREAL_0:def 1,XXREAL_0:9;
end;
end;
theorem Th41:
for I,J,K be non empty closed_interval Subset of REAL,
z be Element of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g being PartFunc of [:[:REAL,REAL:],REAL:],REAL
st [:[:I,J:],K:] = dom f & f is_continuous_on [:[:I,J:],K:] & f = g
holds Integral1(Prod_Measure(L-Meas,L-Meas),|.R_EAL g.|).z < +infty
proof
let I,J,K be non empty closed_interval Subset of REAL,
y be Element of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL;
assume that
A1: [:[:I,J:],K:] = dom f and
A2: f is_continuous_on [:[:I,J:],K:] and
A3: f = g;
dom(Integral1(Prod_Measure(L-Meas,L-Meas),|.R_EAL g.|)) = REAL
by FUNCT_2:def 1; then
A4: dom(Integral1(Prod_Measure(L-Meas,L-Meas),|.R_EAL g.|)|K) = K;
reconsider G = Integral1(Prod_Measure(L-Meas,L-Meas),|.R_EAL g.|)|K
as PartFunc of REAL,REAL by A1,A2,A3,Th35;
per cases;
suppose
A5: y in K; then
Integral1(Prod_Measure(L-Meas,L-Meas),|.R_EAL g.|).y = G.y
by FUNCT_1:49; then
Integral1(Prod_Measure(L-Meas,L-Meas),|.R_EAL g.|).y in rng G
by A4,A5,FUNCT_1:3;
hence Integral1(Prod_Measure(L-Meas,L-Meas),|.R_EAL g.|).y < +infty
by XXREAL_0:9;
end;
suppose not y in K; then
dom ProjPMap2(|.R_EAL g.|,y) = {} by A1,A3,MESFUN16:28; then
Integral(Prod_Measure(L-Meas,L-Meas),ProjPMap2(|.R_EAL g.|,y)) = 0
by MESFUN16:1; then
Integral1(Prod_Measure(L-Meas,L-Meas),|.R_EAL g.|).y = 0
by MESFUN12:def 7;
hence Integral1(Prod_Measure(L-Meas,L-Meas),|.R_EAL g.|).y < +infty
by XREAL_0:def 1,XXREAL_0:9;
end;
end;
theorem Th42:
for I,J,K be non empty closed_interval Subset of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL,
E be Element of sigma measurable_rectangles(L-Field,L-Field)
st [:[:I,J:],K:] = dom f & f is_continuous_on [:[:I,J:],K:] & f = g
holds Integral2(L-Meas,|.R_EAL g.|) is E-measurable
proof
let I,J,K be non empty closed_interval Subset of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL,
E be Element of sigma measurable_rectangles(L-Field,L-Field);
assume that
A1: [:[:I,J:],K:] = dom f and
A2: f is_continuous_on [:[:I,J:],K:] and
A3: f = g;
set F = Integral2(L-Meas,|.R_EAL g.|);
set RF = Integral2(L-Meas,R_EAL g);
set IJ = [:I,J:];
A4: dom F = [:REAL,REAL:] by FUNCT_2:def 1; then
A5: dom(F| [: I,J:]) =[:I,J:];
A6: dom RF = [:REAL,REAL:] by FUNCT_2:def 1;
set F0 = F|IJ;
set RF0 = RF|IJ;
reconsider K0 = K as Element of L-Field by MEASUR10:5,MEASUR12:75;
reconsider G = Integral2(L-Meas,|.R_EAL g.|)|IJ
as PartFunc of [:REAL,REAL:],REAL by A1,A2,A3,Th32;
reconsider RG = Integral2(L-Meas,R_EAL g)|IJ
as PartFunc of [:REAL,REAL:],REAL by A1,A2,A3,Th32;
I in L-Field & J in L-Field by MEASUR10:5,MEASUR12:75; then
A7: [:I,J:] in measurable_rectangles(L-Field,L-Field);
measurable_rectangles(L-Field,L-Field)
c= sigma measurable_rectangles(L-Field,L-Field) by PROB_1:def 9;
then
reconsider AB = [:I,J:] as Element of
sigma measurable_rectangles(L-Field,L-Field) by A7;
reconsider GG = G as PartFunc of [:RNS_Real,RNS_Real:],RNS_Real;
reconsider RGG = RG as PartFunc of [:RNS_Real,RNS_Real:],RNS_Real;
GG is_uniformly_continuous_on [:I,J:] by A1,A2,A3,Th33; then
GG is_continuous_on [:I,J:] by NFCONT_2:7; then
G is_integrable_on Prod_Measure(L-Meas,L-Meas)
by A4,MESFUN16:57; then
A8: F0 is_integrable_on Prod_Measure(L-Meas,L-Meas) by MESFUNC5:def 7;
RGG is_uniformly_continuous_on [:I,J:] by A1,A2,A3,Th34; then
A9:RGG is_continuous_on [:I,J:] by NFCONT_2:7;
reconsider RG1 = Integral2(L-Meas,R_EAL RG)|I as PartFunc of REAL,REAL
by A6,A9,MESFUN16:51;
[:REAL,REAL:] in sigma measurable_rectangles(L-Field,L-Field)
by PROB_1:5; then
reconsider NAB = [:REAL,REAL:] \ AB
as Element of sigma measurable_rectangles(L-Field,L-Field) by PROB_1:6;
A10:AB \/ NAB = [:REAL,REAL:] by XBOOLE_1:45;
A11:F is nonnegative by A1,A2,A3,Th38;
reconsider H = [:REAL,REAL:]
as Element of sigma measurable_rectangles(L-Field,L-Field) by PROB_1:5;
for r being Real holds H /\ (less_dom(F,r))
in sigma measurable_rectangles(L-Field,L-Field)
proof
let r be Real;
consider H0 being Element of sigma measurable_rectangles(L-Field,L-Field)
such that
A12:H0 = dom F0 & F0 is H0 -measurable by A8,MESFUNC5:def 17;
per cases;
suppose
A13: r <= 0;
now assume less_dom(F,r) <> {}; then
consider x be object such that
A14: x in less_dom(F,r) by XBOOLE_0:def 1;
x in dom F & F.x < r by MESFUNC1:def 11,A14;
hence contradiction by A11,A13;
end;
hence H /\ less_dom(F,r) in sigma measurable_rectangles(L-Field,L-Field)
by PROB_1:4;
end;
suppose
A15: 0 < r;
A16: H0 /\ less_dom (F0,r) in sigma measurable_rectangles(L-Field,L-Field)
by A12;
for z be object holds z in less_dom(F,r) iff z in less_dom(F0,r) \/ NAB
proof
let z be object;
hereby assume
A17: z in less_dom(F,r); then
A18: z in dom F & F.z < r by MESFUNC1:def 11;
per cases by A17,A10,XBOOLE_0:def 3;
suppose
A19: z in AB; then
F0.z < r by FUNCT_1:49,A18; then
z in less_dom(F0,r) by A19,A5,MESFUNC1:def 11;
hence z in less_dom(F0,r) \/ NAB by XBOOLE_0:def 3;
end;
suppose z in NAB;
hence z in less_dom(F0,r) \/ NAB by XBOOLE_0:def 3;
end;
end;
assume z in less_dom (F0,r) \/ NAB; then
per cases by XBOOLE_0:def 3;
suppose
A20: z in less_dom(F0,r); then
A21: z in dom F0 & F0.z < r by MESFUNC1:def 11;
A22: F.z < r by A4,A21,FUNCT_1:49;
dom F = [:REAL,REAL:] by FUNCT_2:def 1;
hence z in less_dom(F,r) by A20,A22,MESFUNC1:def 11;
end;
suppose
A23: z in NAB; then
reconsider x=z as Element of [:REAL,REAL:];
not z in AB by A23,XBOOLE_0:def 5; then
A24: F.x < r by A15,A1,A3,Lm4;
dom F = [:REAL,REAL:] by FUNCT_2:def 1;
hence z in less_dom(F,r) by A24,MESFUNC1:def 11;
end;
end; then
less_dom(F,r) = less_dom(F0,r) \/ NAB by TARSKI:2; then
A25: H /\ less_dom(F,r)
= AB /\ (less_dom(F0,r) \/ NAB) \/ NAB /\ (less_dom(F0,r) \/ NAB)
by A10,XBOOLE_1:23;
A26: AB /\ (less_dom(F0,r) \/ NAB) = AB /\ less_dom(F0,r) by XBOOLE_1:78,85;
less_dom(F0,r) c= AB by A5,MESFUNC1:def 11; then
NAB misses less_dom(F0,r); then
NAB /\ (less_dom(F0,r) \/ NAB) = NAB /\ NAB by XBOOLE_1:78;
hence H /\ less_dom(F,r) in sigma measurable_rectangles(L-Field,L-Field)
by A16,A4,A12,A25,A26,PROB_1:3;
end;
end; then
F is H-measurable;
hence thesis by MESFUNC1:30;
end;
theorem Th43:
for I,J,K be non empty closed_interval Subset of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL
st [:[:I,J:],K:] = dom f & f is_continuous_on [:[:I,J:],K:] & f = g
holds
g is_integrable_on Prod_Measure(Prod_Measure(L-Meas,L-Meas),L-Meas)
& (for u being Element of [:REAL,REAL:]
holds ProjPMap1(R_EAL g,u) is_integrable_on L-Meas)
& (for U being Element of sigma measurable_rectangles(L-Field,L-Field)
holds Integral2(L-Meas,R_EAL g) is U-measurable)
& Integral2(L-Meas,R_EAL g) is_integrable_on Prod_Measure(L-Meas,L-Meas)
& Integral(Prod_Measure(Prod_Measure(L-Meas,L-Meas),L-Meas),g)
= Integral(Prod_Measure(L-Meas,L-Meas),Integral2(L-Meas,R_EAL g))
proof
let I,J,K be non empty closed_interval Subset of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL;
assume that
A1: [:[:I,J:],K:] = dom f and
A2: f is_continuous_on [:[:I,J:],K:] and
A3: f = g;
set F = Integral2(L-Meas,|.R_EAL g.|);
set RF = Integral2(L-Meas,R_EAL g);
set IJ = [:I,J:];
A4: dom (R_EAL g) = dom f by A3,MESFUNC5:def 7;
A5: dom F = [:REAL,REAL:] by FUNCT_2:def 1;
A6: dom RF = [:REAL,REAL:] by FUNCT_2:def 1;
set F0 = F|IJ;
set RF0 = RF|IJ;
reconsider K0 = K as Element of L-Field by MEASUR10:5,MEASUR12:75;
reconsider G = Integral2(L-Meas,|.R_EAL g.|)|IJ
as PartFunc of [:REAL,REAL:],REAL by A1,A2,A3,Th32;
reconsider RG = Integral2(L-Meas,R_EAL g)|IJ
as PartFunc of [:REAL,REAL:],REAL by A1,A2,A3,Th32;
I in L-Field & J in L-Field by MEASUR10:5,MEASUR12:75; then
A7: [:I,J:] in measurable_rectangles(L-Field,L-Field);
measurable_rectangles(L-Field,L-Field)
c= sigma measurable_rectangles(L-Field,L-Field) by PROB_1:def 9;
then
reconsider AB = [:I,J:] as Element of
sigma measurable_rectangles(L-Field,L-Field) by A7;
reconsider GG = G as PartFunc of [:RNS_Real,RNS_Real:],RNS_Real;
reconsider RGG = RG as PartFunc of [:RNS_Real,RNS_Real:],RNS_Real;
GG is_uniformly_continuous_on [:I,J:] by A1,A2,A3,Th33; then
GG is_continuous_on [:I,J:] by NFCONT_2:7; then
G is_integrable_on Prod_Measure(L-Meas,L-Meas)
by A5,MESFUN16:57; then
F0 is_integrable_on Prod_Measure(L-Meas,L-Meas) by MESFUNC5:def 7; then
A8:Integral(Prod_Measure(L-Meas,L-Meas),F0) < +infty by MESFUNC5:96;
RGG is_uniformly_continuous_on [:I,J:] by A1,A2,A3,Th34; then
A9:RGG is_continuous_on [:I,J:] by NFCONT_2:7;
reconsider RG1 = Integral2(L-Meas,R_EAL RG)|I as PartFunc of REAL,REAL
by A6,A9,MESFUN16:51;
[:REAL,REAL:] in sigma measurable_rectangles(L-Field,L-Field)
by PROB_1:5; then
reconsider NAB = [:REAL,REAL:] \ AB
as Element of sigma measurable_rectangles(L-Field,L-Field) by PROB_1:6;
A10:AB \/ NAB = [:REAL,REAL:] by XBOOLE_1:45;
A11:F is nonnegative by A1,A2,A3,Th38;
reconsider H = [:REAL,REAL:]
as Element of sigma measurable_rectangles(L-Field,L-Field) by PROB_1:5;
A12:F is H-measurable by A1,A2,A3,Th42;
set F1 = F|NAB;
F|(AB \/ NAB) = F by A10; then
A13:
Integral(Prod_Measure(L-Meas,L-Meas),F)
= Integral(Prod_Measure(L-Meas,L-Meas),F0)
+Integral(Prod_Measure(L-Meas,L-Meas),F1)
by A5,A12,A11,MESFUNC5:91,XBOOLE_1:79;
for x being object st x in dom F1 holds F1.x = 0
proof
let x be object;
assume
A14: x in dom F1; then
reconsider r=x as Element of [:REAL,REAL:] by A5;
not x in AB by A14,XBOOLE_0:def 5; then
(Integral2(L-Meas,|.R_EAL g.|)).r = 0 by A1,A3,Lm4;
hence thesis by FUNCT_1:49,A14;
end; then
Integral(Prod_Measure(L-Meas,L-Meas),F1)
= 0 * (Prod_Measure(L-Meas,L-Meas).(dom F1)) by A5,MEASUR10:27; then
A15: Integral(Prod_Measure(L-Meas,L-Meas),F0)
= Integral(Prod_Measure(L-Meas,L-Meas),F) by A13,XXREAL_3:4;
reconsider KK = [:[:I,J:],K:] as Element of sigma measurable_rectangles(
sigma measurable_rectangles(L-Field,L-Field),L-Field) by Th4;
A16: g is KK-measurable by A1,A2,A3,Th29;
hence g is_integrable_on Prod_Measure(Prod_Measure(L-Meas,L-Meas),L-Meas)
by A1,A4,A15,A8,MESFUN13:11,MESFUN16:5,6;
A17:
R_EAL g is_integrable_on Prod_Measure(Prod_Measure(L-Meas,L-Meas),L-Meas)
by A16,MESFUN13:11,A1,A4,A15,A8,MESFUN16:5,6;
for x being Element of [:REAL,REAL:] holds
Integral2(L-Meas,|.R_EAL g.|).x < +infty by A1,A2,A3,Th40;
hence
(for x being Element of [:REAL,REAL:] holds
ProjPMap1(R_EAL g,x) is_integrable_on L-Meas)
& (for U being Element of sigma measurable_rectangles(L-Field,L-Field)
holds Integral2(L-Meas,R_EAL g) is U-measurable)
& Integral2(L-Meas,R_EAL g) is_integrable_on Prod_Measure(L-Meas,L-Meas)
& Integral(Prod_Measure(Prod_Measure(L-Meas,L-Meas),L-Meas),g)
= Integral(Prod_Measure(L-Meas,L-Meas),Integral2(L-Meas,R_EAL g))
by A17,MESFUN13:32,MESFUN16:5,6;
end;
theorem
for I,J,K be non empty closed_interval Subset of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL
st [:[:I,J:],K:] = dom f & f is_continuous_on [:[:I,J:],K:] & f = g
holds
(for z being Element of REAL
holds ProjPMap2(R_EAL g,z) is_integrable_on Prod_Measure(L-Meas,L-Meas))
& (for V being Element of L-Field
holds Integral1(Prod_Measure(L-Meas,L-Meas),R_EAL g) is V-measurable)
& Integral1(Prod_Measure(L-Meas,L-Meas),R_EAL g) is_integrable_on L-Meas
& Integral(Prod_Measure(Prod_Measure(L-Meas,L-Meas),L-Meas),g)
= Integral(L-Meas,Integral1(Prod_Measure(L-Meas,L-Meas),R_EAL g))
proof
let I,J,K be non empty closed_interval Subset of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL;
assume that
A1: [:[:I,J:],K:] = dom f and
A2: f is_continuous_on [:[:I,J:],K:] and
A3: f = g;
A4:g is_integrable_on Prod_Measure(Prod_Measure(L-Meas,L-Meas),L-Meas)
by A1,A2,A3,Th43;
for z being Element of REAL holds
Integral1(Prod_Measure(L-Meas,L-Meas),|.R_EAL g.|).z < +infty
by A1,A2,A3,Th41;
hence
(for z being Element of REAL holds
ProjPMap2(R_EAL g,z) is_integrable_on Prod_Measure(L-Meas,L-Meas))
& (for V being Element of L-Field
holds Integral1(Prod_Measure(L-Meas,L-Meas),R_EAL g) is V-measurable)
& Integral1(Prod_Measure(L-Meas,L-Meas),R_EAL g) is_integrable_on L-Meas
& Integral(Prod_Measure(Prod_Measure(L-Meas,L-Meas),L-Meas),g)
= Integral(L-Meas,Integral1(Prod_Measure(L-Meas,L-Meas),R_EAL g))
by A4,MESFUN13:33,MESFUN16:5,6;
end;
theorem Th45:
for I,J,K be non empty closed_interval Subset of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL,
x be Element of REAL, E be Element of L-Field
st [:[:I,J:],K:] = dom f & f is_continuous_on [:[:I,J:],K:] & f = g & x in I
holds ProjPMap1(|.Integral2(L-Meas,R_EAL g).|,x) is E-measurable
proof
let I,J,K be non empty closed_interval Subset of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL,
x be Element of REAL, E be Element of L-Field;
assume that
A1: [:[:I,J:],K:] = dom f and
A2: f is_continuous_on [:[:I,J:],K:] and
A3: f = g and
A4: x in I;
A5: dom(R_EAL g) = [:[:I,J:],K:] by A1,A3,MESFUNC5:def 7;
A6: [#]REAL = REAL by SUBSET_1:def 3;
set Fz = Integral2(L-Meas,R_EAL g);
reconsider Gz = Integral2(L-Meas,R_EAL g)
as Function of [:REAL,REAL:],REAL by A1,A2,A3,Th32;
reconsider G = Gz| [:I,J:] as PartFunc of [:REAL,REAL:],REAL;
reconsider F = G as PartFunc of [:RNS_Real,RNS_Real:],RNS_Real;
A7: dom Gz = [:REAL,REAL:] by FUNCT_2:def 1;
F is_uniformly_continuous_on [:I,J:] by A1,A2,A3,Th34; then
A8: F is_continuous_on [:I,J:] by NFCONT_2:7;
dom Fz = [:REAL,REAL:] by FUNCT_2:def 1; then
dom |.Fz.| = [:REAL,REAL:] by MESFUNC1:def 10; then
A9:dom ProjPMap1(|.Fz.|,x) = REAL by A6,MESFUN16:25;
A10:J is Element of L-Field by MEASUR10:5,MEASUR12:75;
REAL in L-Field by PROB_1:5; then
reconsider NJ = REAL \ J as Element of L-Field by A10,PROB_1:6;
A11:J \/ NJ = REAL by XBOOLE_1:45;
A12:J /\ NJ = {} by XBOOLE_1:85,XBOOLE_0:def 7;
set Fz1 = ProjPMap1(|.Fz.|,x);
set L0 = Fz1|J;
set L1 = Fz1|NJ;
A13:dom(Fz1|J) = J by A9;
A14:now let y be Element of REAL;
assume
A15: y in dom L1; then
A16: y in REAL & not y in J by XBOOLE_0:def 5;
[x,y] in [:REAL,REAL:]; then
[x,y] in dom Fz by FUNCT_2:def 1; then
A17: [x,y] in dom |.Fz.| by MESFUNC1:def 10;
L1.y = ProjPMap1(|.Fz.|,x).y by A15,FUNCT_1:49; then
L1.y = |.Fz.| . (x,y) by A17,MESFUN12:def 3; then
A18: L1.y =|. Fz.(x,y) .| by A17,MESFUNC1:def 10;
A19: Fz.(x,y) = Integral(L-Meas,ProjPMap1(R_EAL g,[x,y])) by MESFUN12:def 8;
not [x,y] in [:I,J:] by A16,ZFMISC_1:87; then
dom ProjPMap1(R_EAL g,[x,y]) = {} by A5,MESFUN16:25;
hence L1.y = 0 by A18,A19,EXTREAL1:16,MESFUN16:1;
end;
A20:for t be Element of REAL st t in J holds 0 <= L0.t
proof
let t be Element of REAL;
assume
A21: t in J;
[x,t] in [:REAL,REAL:]; then
[x,t] in dom Fz by FUNCT_2:def 1; then
A22: [x,t] in dom |.Fz.| by MESFUNC1:def 10;
L0.t = ProjPMap1(|.Fz.|,x).t by FUNCT_1:49,A21; then
L0.t = (|.Fz.|).(x,t) by A22,MESFUN12:def 3; then
L0.t = |. Fz.(x,t) .| by A22,MESFUNC1:def 10;
hence 0 <= L0.t by EXTREAL1:14;
end;
Fz = R_EAL Gz by MESFUNC5:def 7; then
A23:|.Fz.| = R_EAL |.Gz.| by MESFUNC6:44; then
A24:|.Fz.| = |.Gz.| by MESFUNC5:def 7;
reconsider AFz = |.Fz.| as PartFunc of [:REAL,REAL:],REAL
by A23,MESFUNC5:def 7;
R_EAL AFz = |.Fz.| by MESFUNC5:def 7; then
R_EAL ProjPMap1(AFz,x) = ProjPMap1(|.Fz.|,x) by MESFUN16:31; then
ProjPMap1(AFz,x) = ProjPMap1(|.Fz.|,x) by MESFUNC5:def 7; then
reconsider Gz1 = ProjPMap1(|.Fz.|,x)|J
as PartFunc of REAL,REAL by PARTFUN1:11;
A25:ProjPMap1(|.G.|,x) is continuous by A7,A8,MESFUN16:34;
A26:J is Element of L-Field by MEASUR10:5,MEASUR12:75;
A27:dom Gz1 = J by A9;
J = X-section([:I,J:],x) by A4,MEASUR11:22; then
A28:Gz1 = ProjPMap1(|.Fz.| | [:I,J:],x) by MESFUN12:34;
|.Fz.| | [:I,J:] = |.G.| by A24,RFUNCT_1:46; then
|.Fz.| | [:I,J:] = R_EAL |.G.| by MESFUNC5:def 7; then
Gz1 = R_EAL ProjPMap1(|.G.|,x) by A28,MESFUN16:31; then
Gz1 is continuous by A25,MESFUNC5:def 7; then
Gz1||J is bounded & Gz1 is_integrable_on J by A9,INTEGRA5:10,11; then
Gz1 is_integrable_on L-Meas by A26,A27,MESFUN14:49; then
A29:L0 is_integrable_on L-Meas by MESFUNC5:def 7;
reconsider H=REAL as Element of L-Field by PROB_1:5;
for r being Real holds H /\ (less_dom(Fz1,r)) in L-Field
proof
let r be Real;
consider H0 being Element of L-Field such that
A30: H0 = dom L0 & L0 is H0 -measurable by A29,MESFUNC5:def 17;
per cases;
suppose
A31: r <= 0;
less_dom(Fz1,r) = {}
proof
assume less_dom(Fz1,r) <> {}; then
consider x be object such that
A32: x in less_dom(Fz1,r) by XBOOLE_0:def 1;
A33: Fz1.x < r by MESFUNC1:def 11,A32;
per cases;
suppose
A34: x in J; then
0 <= L0.x by A20;
hence contradiction by A34,A31,A33,FUNCT_1:49;
end;
suppose not x in J; then
A35: x in NJ by A32,XBOOLE_0:def 5; then
Fz1.x = L1.x by FUNCT_1:49;
hence contradiction by A14,A9,A35,A31,A33;
end;
end;
hence H /\ (less_dom(Fz1,r)) in L-Field by PROB_1:4;
end;
suppose
A36: 0 < r;
A37: for z be object holds z in less_dom(Fz1,r) iff z in less_dom (L0,r) \/ NJ
proof
let z be object;
hereby assume
A38: z in less_dom(Fz1,r); then
A39: z in dom Fz1 & Fz1.z < r by MESFUNC1:def 11;
per cases by A38,A11,XBOOLE_0:def 3;
suppose
A40: z in J; then
L0.z < r by FUNCT_1:49,A39; then
z in less_dom (L0,r) by A13,A40,MESFUNC1:def 11;
hence z in less_dom (L0,r) \/ NJ by XBOOLE_0:def 3;
end;
suppose z in NJ;
hence z in less_dom (L0,r) \/ NJ by XBOOLE_0:def 3;
end;
end;
assume z in less_dom (L0,r) \/ NJ; then
per cases by XBOOLE_0:def 3;
suppose
A41: z in less_dom (L0,r); then
z in dom L0 & L0.z < r by MESFUNC1:def 11; then
Fz1.z < r by FUNCT_1:49;
hence z in less_dom(Fz1,r) by A9,A41,MESFUNC1:def 11;
end;
suppose
A42: z in NJ; then
reconsider u=z as Element of REAL;
Fz1.u = L1.z by A42,FUNCT_1:49; then
Fz1.u = 0 by A14,A42,A9;
hence z in less_dom(Fz1,r) by A9,A36,MESFUNC1:def 11;
end;
end;
A43: H /\ less_dom(Fz1,r) = (J \/ NJ) /\ less_dom (Fz1,r) by XBOOLE_1:45
.= (J \/ NJ) /\ (less_dom (L0,r) \/ NJ) by A37,TARSKI:2
.= J /\ (less_dom (L0,r) \/ NJ )
\/ NJ /\ (less_dom (L0,r) \/ NJ) by XBOOLE_1:23;
J /\ (less_dom (L0,r) \/ NJ)
= J /\ less_dom (L0,r) \/ {} by A12,XBOOLE_1:23; then
A44: J /\ (less_dom (L0,r) \/ NJ) in L-Field by A9,A30;
A45: less_dom (L0,r) c= J by A13,MESFUNC1:def 11;
NJ /\ (less_dom (L0,r) \/ NJ)
= (NJ /\ less_dom (L0,r) ) \/ (NJ /\ NJ) by XBOOLE_1:23; then
NJ /\ (less_dom (L0,r) \/ NJ) = {} \/ (NJ /\ NJ) by A45;
hence H /\ less_dom(Fz1,r) in L-Field by A43,A44,PROB_1:3;
end;
end; then
Fz1 is H -measurable;
hence thesis by MESFUNC1:30;
end;
theorem Th46:
for I,J,K be non empty closed_interval Subset of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL
st [:[:I,J:],K:] = dom f & f is_continuous_on [:[:I,J:],K:] & f = g
holds
(for x being Element of REAL holds
Integral2(L-Meas,|.Integral2(L-Meas,R_EAL g).|).x < +infty)
& (for x being Element of REAL holds
ProjPMap1(Integral2(L-Meas,R_EAL g),x) is_integrable_on L-Meas)
proof
let I,J,K be non empty closed_interval Subset of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL;
assume that
A1: [:[:I,J:],K:] = dom f and
A2: f is_continuous_on [:[:I,J:],K:] and
A3: f = g;
A4: dom(R_EAL g) = [:[:I,J:],K:] by A1,A3,MESFUNC5:def 7;
A5: [#]REAL = REAL by SUBSET_1:def 3;
A6: REAL in L-Field by PROB_1:5;
set Fz = Integral2(L-Meas,R_EAL g);
reconsider Gz = Integral2(L-Meas,R_EAL g)
as Function of [:REAL,REAL:],REAL by A1,A2,A3,Th32;
reconsider G = Gz| [:I,J:] as PartFunc of [:REAL,REAL:],REAL;
reconsider F = G as PartFunc of [:RNS_Real,RNS_Real:],RNS_Real;
A7: dom Gz = [:REAL,REAL:] by FUNCT_2:def 1;
F is_uniformly_continuous_on [:I,J:] by A1,A2,A3,Th34; then
A8: F is_continuous_on [:I,J:] by NFCONT_2:7;
thus
A9: for x being Element of REAL holds
Integral2(L-Meas,|.Integral2(L-Meas,R_EAL g).|).x < +infty
proof
let x be Element of REAL;
dom Fz = [:REAL,REAL:] by FUNCT_2:def 1; then
dom |.Fz.| = [:REAL,REAL:] by MESFUNC1:def 10; then
A10: dom ProjPMap1(|.Fz.|,x) = REAL by A5,MESFUN16:25;
per cases;
suppose
A11: x in I;
A12: J misses (REAL \ J) by XBOOLE_1:79;
A13: J is Element of L-Field by MEASUR10:5,MEASUR12:75;
REAL in L-Field by PROB_1:5; then
reconsider NJ = REAL \ J as Element of L-Field by A13,PROB_1:6;
A14: J \/ NJ = REAL by XBOOLE_1:45;
set Fz1 = ProjPMap1(|.Fz.|,x);
set L0 = Fz1|J;
set L1 = Fz1|NJ;
A15: now let y be Element of REAL;
assume
A16: y in dom L1; then
A17: y in REAL & not y in J by XBOOLE_0:def 5;
[x,y] in [:REAL,REAL:]; then
[x,y] in dom Fz by FUNCT_2:def 1; then
A18: [x,y] in dom |.Fz.| by MESFUNC1:def 10;
L1.y = ProjPMap1(|.Fz.|,x).y by A16,FUNCT_1:49; then
L1.y = |.Fz.| . (x,y) by A18,MESFUN12:def 3; then
A19: L1.y =|. Fz.(x,y) .| by A18,MESFUNC1:def 10;
A20: Fz.(x,y) = Integral(L-Meas,ProjPMap1(R_EAL g,[x,y])) by MESFUN12:def 8;
not [x,y] in [:I,J:] by A17,ZFMISC_1:87; then
dom ProjPMap1(R_EAL g,[x,y]) = {} by A4,MESFUN16:25;
hence L1.y = 0 by A19,A20,EXTREAL1:16,MESFUN16:1;
end; then
A21: Integral(L-Meas,L1) = 0 by A10,MESFUN12:57;
A22: for t be Element of REAL st t in J holds 0 <= L0.t
proof
let t be Element of REAL;
assume
A23: t in J;
[x,t] in [:REAL,REAL:]; then
[x,t] in dom Fz by FUNCT_2:def 1; then
A24: [x,t] in dom |.Fz.| by MESFUNC1:def 10;
L0.t = ProjPMap1(|.Fz.|,x).t by FUNCT_1:49,A23; then
L0.t = (|.Fz.|).(x,t) by A24,MESFUN12:def 3; then
L0.t = |. Fz.(x,t) .| by A24,MESFUNC1:def 10;
hence 0 <= L0.t by EXTREAL1:14;
end;
Fz = R_EAL Gz by MESFUNC5:def 7; then
A25: |.Fz.| = R_EAL |.Gz.| by MESFUNC6:44; then
A26: |.Fz.| = |.Gz.| by MESFUNC5:def 7;
reconsider AFz = |.Fz.| as PartFunc of [:REAL,REAL:],REAL
by A25,MESFUNC5:def 7;
R_EAL AFz = |.Fz.| by MESFUNC5:def 7; then
R_EAL ProjPMap1(AFz,x) = ProjPMap1(|.Fz.|,x) by MESFUN16:31; then
ProjPMap1(AFz,x) = ProjPMap1(|.Fz.|,x) by MESFUNC5:def 7; then
reconsider Gz1 = ProjPMap1(|.Fz.|,x)|J
as PartFunc of REAL,REAL by PARTFUN1:11;
A27: ProjPMap1(|.G.|,x) is continuous by A7,A8,MESFUN16:34;
A28: J is Element of L-Field by MEASUR10:5,MEASUR12:75;
A29: dom Gz1 = J by A10;
J = X-section([:I,J:],x) by A11,MEASUR11:22; then
A30: Gz1 = ProjPMap1(|.Fz.| | [:I,J:],x) by MESFUN12:34;
|.Fz.| | [:I,J:] = |.G.| by A26,RFUNCT_1:46; then
|.Fz.| | [:I,J:] = R_EAL |.G.| by MESFUNC5:def 7; then
Gz1 = R_EAL ProjPMap1(|.G.|,x) by A30,MESFUN16:31; then
Gz1 is continuous by A27,MESFUNC5:def 7; then
Gz1||J is bounded & Gz1 is_integrable_on J by A10,INTEGRA5:10,11; then
Gz1 is_integrable_on L-Meas by A28,A29,MESFUN14:49; then
L0 is_integrable_on L-Meas by MESFUNC5:def 7; then
A31: Integral(L-Meas,L0) < +infty by MESFUNC5:96;
A32: for r being Element of REAL holds 0. <= Fz1.r
proof
let r be Element of REAL;
per cases by A14,XBOOLE_0:def 3;
suppose
A33: r in J; then
0 <= L0.r by A22;
hence 0 <= Fz1.r by A33,FUNCT_1:49;
end;
suppose
A34: r in NJ; then
Fz1.r = L1.r by FUNCT_1:49;
hence 0 <= Fz1.r by A15,A10,A34;
end;
end;
reconsider H=REAL as Element of L-Field by PROB_1:5;
A35: Fz1 is H -measurable by A1,A2,A3,A11,Th45;
A36: Fz1|(J \/ NJ) = Fz1 by A14;
Integral(L-Meas,Fz1) = Integral(L-Meas,L0) + Integral(L-Meas,L1)
by A10,A13,A32,A35,A12,A36,SUPINF_2:39,MESFUNC5:91; then
Integral(L-Meas,L0) = Integral(L-Meas,Fz1) by A21,XXREAL_3:4;
hence Integral2(L-Meas,|.Fz.|).x < +infty by A31,MESFUN12:def 8;
end;
suppose
A37: not x in I;
now let y be Element of REAL;
assume y in dom ProjPMap1(|.Fz.|,x);
[x,y] in [:REAL,REAL:]; then
[x,y] in dom Fz by FUNCT_2:def 1; then
A38: [x,y] in dom |.Fz.| by MESFUNC1:def 10; then
ProjPMap1(|.Fz.|,x).y = (|.Fz.|).(x,y) by MESFUN12:def 3; then
A39: ProjPMap1(|.Fz.|,x).y = |. Fz.(x,y) .| by A38,MESFUNC1:def 10;
A40: Fz.(x,y) = Integral(L-Meas,ProjPMap1(R_EAL g,[x,y])) by MESFUN12:def 8;
not [x,y] in [:I,J:] by A37,ZFMISC_1:87; then
dom ProjPMap1(R_EAL g,[x,y]) = {} by A4,MESFUN16:25;
hence ProjPMap1(|.Fz.|,x).y = 0 by A39,A40,EXTREAL1:16,MESFUN16:1;
end; then
Integral(L-Meas,ProjPMap1(|.Fz.|,x)) = 0 by A10,A6,MESFUN12:57; then
Integral2(L-Meas,|.Fz.|).x = 0 by MESFUN12:def 8;
hence Integral2(L-Meas,|.Fz.|).x < +infty by XREAL_0:def 1,XXREAL_0:9;
end;
end;
Integral2(L-Meas,R_EAL g) is_integrable_on Prod_Measure(L-Meas,L-Meas)
by A1,A2,A3,Th43;
hence for x being Element of REAL holds
ProjPMap1(Integral2(L-Meas,R_EAL g),x) is_integrable_on L-Meas
by A9,MESFUN13:32,MESFUN16:5;
end;
theorem Th47:
for I,J,K be non empty closed_interval Subset of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL,
y be Element of REAL, E be Element of L-Field
st [:[:I,J:],K:] = dom f & f is_continuous_on [:[:I,J:],K:] & f = g & y in J
holds ProjPMap2(|.Integral2(L-Meas,R_EAL g).|,y) is E-measurable
proof
let I,J,K be non empty closed_interval Subset of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL,
y be Element of REAL, E be Element of L-Field;
assume that
A1: [:[:I,J:],K:] = dom f and
A2: f is_continuous_on [:[:I,J:],K:] and
A3: f = g and
A4: y in J;
A5: dom(R_EAL g) = [:[:I,J:],K:] by A1,A3,MESFUNC5:def 7;
A6: [#]REAL = REAL by SUBSET_1:def 3;
set Fz = Integral2(L-Meas,R_EAL g);
reconsider Gz = Integral2(L-Meas,R_EAL g)
as Function of [:REAL,REAL:],REAL by A1,A2,A3,Th32;
reconsider G = Gz| [:I,J:] as PartFunc of [:REAL,REAL:],REAL;
reconsider F = G as PartFunc of [:RNS_Real,RNS_Real:],RNS_Real;
A7: dom Gz = [:REAL,REAL:] by FUNCT_2:def 1;
F is_uniformly_continuous_on [:I,J:] by A1,A2,A3,Th34; then
A8: F is_continuous_on [:I,J:] by NFCONT_2:7;
dom Fz = [:REAL,REAL:] by FUNCT_2:def 1; then
dom |.Fz.| = [:REAL,REAL:] by MESFUNC1:def 10; then
A9: dom ProjPMap2(|.Fz.|,y) = REAL by A6,MESFUN16:26;
A10: I is Element of L-Field by MEASUR10:5,MEASUR12:75;
REAL in L-Field by PROB_1:5; then
reconsider NI = REAL \ I as Element of L-Field by A10,PROB_1:6;
A11: I \/ NI = REAL by XBOOLE_1:45;
A12: I /\ NI = {} by XBOOLE_1:85,XBOOLE_0:def 7;
set Fz2 = ProjPMap2(|.Fz.|,y);
set L0 = Fz2|I;
set L1 = Fz2|NI;
A13: dom(Fz2|I) = I by A9;
A14: now let x be Element of REAL;
assume
A15: x in dom L1; then
A16: x in REAL & not x in I by XBOOLE_0:def 5;
[x,y] in [:REAL,REAL:]; then
[x,y] in dom Fz by FUNCT_2:def 1; then
A17: [x,y] in dom |.Fz.| by MESFUNC1:def 10;
L1.x = ProjPMap2(|.Fz.|,y).x by A15,FUNCT_1:49; then
L1.x = |.Fz.| . (x,y) by A17,MESFUN12:def 4; then
A18: L1.x =|. Fz.(x,y) .| by A17,MESFUNC1:def 10;
A19: Fz.(x,y) = Integral(L-Meas,ProjPMap1(R_EAL g,[x,y])) by MESFUN12:def 8;
not [x,y] in [:I,J:] by A16,ZFMISC_1:87; then
dom ProjPMap1(R_EAL g,[x,y]) = {} by A5,MESFUN16:25;
hence L1.x = 0 by A18,A19,EXTREAL1:16,MESFUN16:1;
end;
A20: for t be Element of REAL st t in I holds 0 <= L0.t
proof
let t be Element of REAL;
assume
A21: t in I;
[t,y] in [:REAL,REAL:]; then
[t,y] in dom Fz by FUNCT_2:def 1; then
A22: [t,y] in dom |.Fz.| by MESFUNC1:def 10;
L0.t = ProjPMap2(|.Fz.|,y).t by FUNCT_1:49,A21; then
L0.t = (|.Fz.|).(t,y) by A22,MESFUN12:def 4; then
L0.t = |. Fz.(t,y) .| by A22,MESFUNC1:def 10;
hence 0 <= L0.t by EXTREAL1:14;
end;
Fz = R_EAL Gz by MESFUNC5:def 7; then
A23: |.Fz.| = R_EAL |.Gz.| by MESFUNC6:44; then
A24: |.Fz.| = |.Gz.| by MESFUNC5:def 7;
reconsider AFz = |.Fz.| as PartFunc of [:REAL,REAL:],REAL
by A23,MESFUNC5:def 7;
R_EAL AFz = |.Fz.| by MESFUNC5:def 7; then
R_EAL ProjPMap2(AFz,y) = ProjPMap2(|.Fz.|,y) by MESFUN16:31; then
ProjPMap2(AFz,y) = ProjPMap2(|.Fz.|,y) by MESFUNC5:def 7; then
reconsider Gz2 = ProjPMap2(|.Fz.|,y)|I
as PartFunc of REAL,REAL by PARTFUN1:11;
A25: ProjPMap2(|.G.|,y) is continuous by A7,A8,MESFUN16:34;
A26: I is Element of L-Field by MEASUR10:5,MEASUR12:75;
A27: dom Gz2 = I by A9;
I = Y-section([:I,J:],y) by A4,MEASUR11:22; then
A28: Gz2 = ProjPMap2(|.Fz.| | [:I,J:],y) by MESFUN12:34;
|.Fz.| | [:I,J:] = |.G.| by A24,RFUNCT_1:46; then
|.Fz.| | [:I,J:] = R_EAL |.G.| by MESFUNC5:def 7; then
Gz2 = R_EAL ProjPMap2(|.G.|,y) by A28,MESFUN16:31; then
Gz2 is continuous by A25,MESFUNC5:def 7; then
Gz2||I is bounded & Gz2 is_integrable_on I by A9,INTEGRA5:10,11; then
Gz2 is_integrable_on L-Meas by A26,A27,MESFUN14:49; then
A29: L0 is_integrable_on L-Meas by MESFUNC5:def 7;
A30: for r being Element of REAL holds 0. <= Fz2.r
proof
let r be Element of REAL;
per cases by A11,XBOOLE_0:def 3;
suppose
A31: r in I; then
0 <= L0.r by A20;
hence 0 <= Fz2.r by A31,FUNCT_1:49;
end;
suppose
A32: r in NI; then
Fz2.r = L1.r by FUNCT_1:49;
hence 0 <= Fz2.r by A14,A9,A32;
end;
end;
reconsider H=REAL as Element of L-Field by PROB_1:5;
for r being Real holds H /\ (less_dom(Fz2,r)) in L-Field
proof
let r be Real;
consider H0 being Element of L-Field such that
A33: H0 = dom L0 & L0 is H0 -measurable by A29,MESFUNC5:def 17;
per cases;
suppose
A34: r <= 0;
less_dom(Fz2,r) = {}
proof
assume less_dom(Fz2,r) <> {}; then
consider y be object such that
A35: y in less_dom(Fz2,r) by XBOOLE_0:def 1;
y in dom Fz2 & Fz2.y < r by MESFUNC1:def 11,A35;
hence contradiction by A30,A34;
end;
hence H /\ (less_dom(Fz2,r)) in L-Field by PROB_1:4;
end;
suppose
A36: 0 < r;
A37: for z be object holds
z in less_dom(Fz2,r) iff z in less_dom (L0,r) \/ NI
proof
let z be object;
hereby assume
A38: z in less_dom(Fz2,r); then
A39: z in dom Fz2 & Fz2.z < r by MESFUNC1:def 11;
per cases by A38,A11,XBOOLE_0:def 3;
suppose
A40: z in I; then
L0.z < r by FUNCT_1:49,A39; then
z in less_dom (L0,r) by A13,A40,MESFUNC1:def 11;
hence z in less_dom (L0,r) \/ NI by XBOOLE_0:def 3;
end;
suppose z in NI;
hence z in less_dom (L0,r) \/ NI by XBOOLE_0:def 3;
end;
end;
assume z in less_dom (L0,r) \/ NI; then
per cases by XBOOLE_0:def 3;
suppose
A41: z in less_dom (L0,r); then
z in dom L0 & L0.z < r by MESFUNC1:def 11; then
Fz2.z < r by FUNCT_1:49;
hence z in less_dom(Fz2,r) by A9,A41,MESFUNC1:def 11;
end;
suppose
A42: z in NI; then
reconsider u=z as Element of REAL;
Fz2.u = L1.z by A42,FUNCT_1:49; then
Fz2.u = 0 by A14,A42,A9;
hence z in less_dom(Fz2,r) by A9,A36,MESFUNC1:def 11;
end;
end;
A43: H /\ less_dom(Fz2,r) = (I \/ NI) /\ less_dom (Fz2,r) by XBOOLE_1:45
.= (I \/ NI) /\ (less_dom (L0,r) \/ NI) by A37,TARSKI:2
.= I /\ (less_dom (L0,r) \/ NI )
\/ NI /\ (less_dom (L0,r) \/ NI) by XBOOLE_1:23;
I /\ (less_dom (L0,r) \/ NI)
= I /\ less_dom (L0,r) \/ {} by A12,XBOOLE_1:23; then
A44: I /\ (less_dom (L0,r) \/ NI) in L-Field by A9,A33;
A45: less_dom (L0,r) c= I by A13,MESFUNC1:def 11;
NI /\ (less_dom (L0,r) \/ NI)
= (NI /\ less_dom (L0,r) ) \/ (NI /\ NI) by XBOOLE_1:23; then
NI /\ (less_dom (L0,r) \/ NI) = {} \/ (NI /\ NI) by A45;
hence H /\ less_dom(Fz2,r) in L-Field by A43,A44,PROB_1:3;
end;
end; then
Fz2 is H -measurable;
hence thesis by MESFUNC1:30;
end;
theorem Th48:
for I,J,K be non empty closed_interval Subset of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL
st [:[:I,J:],K:] = dom f & f is_continuous_on [:[:I,J:],K:] & f = g
holds
(for y being Element of REAL holds
Integral1(L-Meas,|.Integral2(L-Meas,R_EAL g).|).y < +infty)
& (for y being Element of REAL holds
ProjPMap2(Integral2(L-Meas,R_EAL g),y) is_integrable_on L-Meas)
proof
let I,J,K be non empty closed_interval Subset of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL;
assume that
A1: [:[:I,J:],K:] = dom f and
A2: f is_continuous_on [:[:I,J:],K:] and
A3: f = g;
A4: dom(R_EAL g) = [:[:I,J:],K:] by A1,A3,MESFUNC5:def 7;
A5: [#]REAL = REAL by SUBSET_1:def 3;
A6: REAL in L-Field by PROB_1:5;
set Fz = Integral2(L-Meas,R_EAL g);
reconsider Gz = Integral2(L-Meas,R_EAL g)
as Function of [:REAL,REAL:],REAL by A1,A2,A3,Th32;
reconsider G = Gz| [:I,J:] as PartFunc of [:REAL,REAL:],REAL;
reconsider F = G as PartFunc of [:RNS_Real,RNS_Real:],RNS_Real;
A7: dom Gz = [:REAL,REAL:] by FUNCT_2:def 1;
F is_uniformly_continuous_on [:I,J:] by A1,A2,A3,Th34; then
A8: F is_continuous_on [:I,J:] by NFCONT_2:7;
thus
A9: for y being Element of REAL holds
Integral1(L-Meas,|.Integral2(L-Meas,R_EAL g).|).y < +infty
proof
let y be Element of REAL;
dom Fz = [:REAL,REAL:] by FUNCT_2:def 1; then
dom |.Fz.| = [:REAL,REAL:] by MESFUNC1:def 10; then
A10: dom ProjPMap2(|.Fz.|,y) = REAL by A5,MESFUN16:26;
per cases;
suppose
A11: y in J;
A12: I misses (REAL \ I) by XBOOLE_1:79;
A13: I is Element of L-Field by MEASUR10:5,MEASUR12:75;
REAL in L-Field by PROB_1:5; then
reconsider NI = REAL \ I as Element of L-Field by A13,PROB_1:6;
A14: I \/ NI = REAL by XBOOLE_1:45;
set Fz2 = ProjPMap2(|.Fz.|,y);
set L0 = Fz2|I;
set L1 = Fz2|NI;
A16: now let x be Element of REAL;
assume
A17: x in dom L1; then
A18: x in REAL & not x in I by XBOOLE_0:def 5;
[x,y] in [:REAL,REAL:]; then
[x,y] in dom Fz by FUNCT_2:def 1; then
A19: [x,y] in dom |.Fz.| by MESFUNC1:def 10;
L1.x = ProjPMap2(|.Fz.|,y).x by A17,FUNCT_1:49; then
L1.x = |.Fz.| . (x,y) by A19,MESFUN12:def 4; then
A20: L1.x =|. Fz.(x,y) .| by A19,MESFUNC1:def 10;
A21: Fz.(x,y) = Integral(L-Meas,ProjPMap1(R_EAL g,[x,y])) by MESFUN12:def 8;
not [x,y] in [:I,J:] by A18,ZFMISC_1:87; then
dom ProjPMap1(R_EAL g,[x,y]) = {} by A4,MESFUN16:25;
hence L1.x = 0 by A20,A21,EXTREAL1:16,MESFUN16:1;
end; then
A22: Integral(L-Meas,L1) = 0 by A10,MESFUN12:57;
A23: for t be Element of REAL st t in I holds 0 <= L0.t
proof
let t be Element of REAL;
assume
A24: t in I;
[t,y] in [:REAL,REAL:]; then
[t,y] in dom Fz by FUNCT_2:def 1; then
A25: [t,y] in dom |.Fz.| by MESFUNC1:def 10;
L0.t = ProjPMap2(|.Fz.|,y).t by FUNCT_1:49,A24; then
L0.t = (|.Fz.|).(t,y) by A25,MESFUN12:def 4; then
L0.t = |. Fz.(t,y) .| by A25,MESFUNC1:def 10;
hence 0 <= L0.t by EXTREAL1:14;
end;
Fz = R_EAL Gz by MESFUNC5:def 7; then
A26: |.Fz.| = R_EAL |.Gz.| by MESFUNC6:44; then
A27: |.Fz.| = |.Gz.| by MESFUNC5:def 7;
reconsider AFz = |.Fz.| as PartFunc of [:REAL,REAL:],REAL
by A26,MESFUNC5:def 7;
R_EAL AFz = |.Fz.| by MESFUNC5:def 7; then
R_EAL ProjPMap2(AFz,y) = ProjPMap2(|.Fz.|,y) by MESFUN16:31; then
ProjPMap2(AFz,y) = ProjPMap2(|.Fz.|,y) by MESFUNC5:def 7; then
reconsider Gz2 = ProjPMap2(|.Fz.|,y)|I
as PartFunc of REAL,REAL by PARTFUN1:11;
A28: ProjPMap2(|.G.|,y) is continuous by A7,A8,MESFUN16:34;
A29: I is Element of L-Field by MEASUR10:5,MEASUR12:75;
A30: dom Gz2 = I by A10;
I = Y-section([:I,J:],y) by A11,MEASUR11:22; then
A31: Gz2 = ProjPMap2(|.Fz.| | [:I,J:],y) by MESFUN12:34;
|.Fz.| | [:I,J:] = |.G.| by A27,RFUNCT_1:46; then
|.Fz.| | [:I,J:] = R_EAL |.G.| by MESFUNC5:def 7; then
Gz2 = R_EAL ProjPMap2(|.G.|,y) by A31,MESFUN16:31; then
Gz2 is continuous by A28,MESFUNC5:def 7; then
Gz2||I is bounded & Gz2 is_integrable_on I by A10,INTEGRA5:10,11; then
Gz2 is_integrable_on L-Meas by A29,A30,MESFUN14:49; then
L0 is_integrable_on L-Meas by MESFUNC5:def 7; then
A32: Integral(L-Meas,L0) < +infty by MESFUNC5:96;
A33: for r being Element of REAL holds 0. <= Fz2.r
proof
let r be Element of REAL;
per cases by A14,XBOOLE_0:def 3;
suppose
A34: r in I; then
0 <= L0.r by A23;
hence 0 <= Fz2.r by A34,FUNCT_1:49;
end;
suppose
A35: r in NI; then
Fz2.r = L1.r by FUNCT_1:49;
hence 0 <= Fz2.r by A16,A10,A35;
end;
end;
reconsider H=REAL as Element of L-Field by PROB_1:5;
A36: Fz2 is H -measurable by A1,A2,A3,A11,Th47;
A37: Fz2|(I \/ NI) = Fz2 by A14;
Integral(L-Meas,Fz2) = Integral(L-Meas,L0) + Integral(L-Meas,L1)
by A10,A13,A33,A36,A12,A37,SUPINF_2:39,MESFUNC5:91; then
Integral(L-Meas,L0) = Integral(L-Meas,Fz2) by A22,XXREAL_3:4;
hence Integral1(L-Meas,|.Fz.|).y < +infty by A32,MESFUN12:def 7;
end;
suppose
A38: not y in J;
now let x be Element of REAL;
assume x in dom ProjPMap2(|.Fz.|,y);
[x,y] in [:REAL,REAL:]; then
[x,y] in dom Fz by FUNCT_2:def 1; then
A39: [x,y] in dom |.Fz.| by MESFUNC1:def 10; then
ProjPMap2(|.Fz.|,y).x = (|.Fz.|).(x,y) by MESFUN12:def 4; then
A40: ProjPMap2(|.Fz.|,y).x = |. Fz.(x,y) .| by A39,MESFUNC1:def 10;
A41: Fz.(x,y) = Integral(L-Meas,ProjPMap1(R_EAL g,[x,y])) by MESFUN12:def 8;
not [x,y] in [:I,J:] by A38,ZFMISC_1:87; then
dom ProjPMap1(R_EAL g,[x,y]) = {} by A4,MESFUN16:25;
hence ProjPMap2(|.Fz.|,y).x = 0 by A40,A41,EXTREAL1:16,MESFUN16:1;
end; then
Integral(L-Meas,ProjPMap2(|.Fz.|,y)) = 0 by A10,A6,MESFUN12:57; then
Integral1(L-Meas,|.Fz.|).y = 0 by MESFUN12:def 7;
hence Integral1(L-Meas,|.Fz.|).y < +infty by XREAL_0:def 1,XXREAL_0:9;
end;
end;
Integral2(L-Meas,R_EAL g) is_integrable_on Prod_Measure(L-Meas,L-Meas)
by A1,A2,A3,Th43;
hence for y being Element of REAL holds
ProjPMap2(Integral2(L-Meas,R_EAL g),y) is_integrable_on L-Meas
by A9,MESFUN13:33,MESFUN16:5;
end;
theorem
for I,J,K be non empty closed_interval Subset of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g being PartFunc of [:[:REAL,REAL:],REAL:],REAL,
E be Element of sigma measurable_rectangles(L-Field,L-Field)
st [:[:I,J:],K:] = dom f & f is_continuous_on [:[:I,J:],K:] & f = g
holds Integral2(L-Meas,|.R_EAL g.|) is E-measurable
proof
let I,J,K be non empty closed_interval Subset of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL,
E be Element of sigma measurable_rectangles(L-Field,L-Field);
assume that
A1: [:[:I,J:],K:] = dom f and
A2: f is_continuous_on [:[:I,J:],K:] and
A3: f = g;
set F = Integral2(L-Meas,|.R_EAL g.|);
set F0 = F| [:I,J:];
A4: dom F = [:REAL,REAL:] by FUNCT_2:def 1; then
A5: dom F0 = [:I,J:];
reconsider G = F0 as PartFunc of [:REAL,REAL:],REAL by A1,A2,A3,Th32;
reconsider GG = G as PartFunc of [:RNS_Real,RNS_Real:],RNS_Real;
GG is_uniformly_continuous_on [:I,J:] by A1,A2,A3,Th33; then
GG is_continuous_on [:I,J:] by NFCONT_2:7; then
G is_integrable_on Prod_Measure(L-Meas,L-Meas) by A4,MESFUN16:57; then
A6: F0 is_integrable_on Prod_Measure(L-Meas,L-Meas) by MESFUNC5:def 7;
reconsider IJ = [:I,J:] as
Element of sigma measurable_rectangles(L-Field,L-Field) by MESFUN16:11;
reconsider R2 = [:REAL,REAL:]
as Element of sigma measurable_rectangles(L-Field,L-Field) by PROB_1:5;
set NIJ = R2 \ IJ;
A7: IJ \/ NIJ = [:REAL,REAL:] by XBOOLE_1:45;
A8:IJ /\ NIJ = {} by XBOOLE_1:85,XBOOLE_0:def 7;
A9:F is nonnegative by A1,A2,A3,Th38;
for r being Real holds R2 /\ (less_dom(F,r))
in sigma measurable_rectangles(L-Field,L-Field)
proof
let r be Real;
A10: ex E be Element of sigma measurable_rectangles(L-Field,L-Field)
st E = dom F0 & F0 is E-measurable by A6,MESFUNC5:def 17;
per cases;
suppose
A11: r <= 0;
less_dom(F,r) = {}
proof
assume less_dom(F,r) <> {}; then
consider x be object such that
A12: x in less_dom(F,r) by XBOOLE_0:def 1;
x in dom F & F.x < r by A12,MESFUNC1:def 11;
hence contradiction by A9,A11;
end;
hence R2 /\ less_dom(F,r) in sigma measurable_rectangles(L-Field,L-Field)
by PROB_1:4;
end;
suppose
A13: 0 < r;
for z be object holds z in less_dom(F,r) iff z in less_dom(F0,r) \/ NIJ
proof
let z be object;
hereby assume
A14: z in less_dom(F,r); then
A15: F.z < r by MESFUNC1:def 11;
A16: z in NIJ implies z in less_dom(F0,r) \/ NIJ by XBOOLE_0:def 3;
now assume
A17: z in IJ; then
F0.z < r by A15,FUNCT_1:49; then
z in less_dom(F0,r) by A5,A17,MESFUNC1:def 11;
hence z in less_dom(F0,r) \/ NIJ by XBOOLE_0:def 3;
end;
hence z in less_dom(F0,r) \/ NIJ by A7,A14,A16,XBOOLE_0:def 3;
end;
assume z in less_dom (F0,r) \/ NIJ; then
per cases by XBOOLE_0:def 3;
suppose
A18: z in less_dom(F0,r); then
z in dom F0 & F0.z < r by MESFUNC1:def 11; then
F.z < r by A4,FUNCT_1:49;
hence z in less_dom(F,r) by A4,A18,MESFUNC1:def 11;
end;
suppose
A19: z in NIJ; then
not z in IJ by XBOOLE_0:def 5; then
F.z < r by A13,A1,A3,A19,Lm4;
hence z in less_dom(F,r) by A4,A19,MESFUNC1:def 11;
end;
end; then
less_dom(F,r) = less_dom(F0,r) \/ NIJ by TARSKI:2; then
A20: R2 /\ less_dom(F,r)
= IJ /\ (less_dom(F0,r) \/ NIJ) \/ NIJ /\ (less_dom(F0,r) \/ NIJ)
by A7,XBOOLE_1:23;
IJ /\ (less_dom(F0,r) \/ NIJ)
= IJ /\ less_dom(F0,r) \/ (IJ /\ NIJ) by XBOOLE_1:23; then
A21: IJ /\ (less_dom(F0,r) \/ NIJ)
in sigma measurable_rectangles(L-Field,L-Field) by A4,A8,A10;
A22: less_dom(F0,r) c= IJ by A5,MESFUNC1:def 11;
NIJ /\ (less_dom(F0,r) \/ NIJ)
= (NIJ /\ less_dom(F0,r)) \/ (NIJ /\ NIJ) by XBOOLE_1:23; then
NIJ /\ (less_dom(F0,r) \/ NIJ)
= {} \/ (NIJ /\ NIJ) by A22;
hence R2 /\ less_dom(F,r) in sigma measurable_rectangles(L-Field,L-Field)
by A20,A21,PROB_1:3;
end;
end; then
F is R2-measurable;
hence F is E-measurable by MESFUNC1:30;
end;
theorem
for I,J,K be non empty closed_interval Subset of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g being PartFunc of [:[:REAL,REAL:],REAL:],REAL,
E be Element of L-Field
st [:[:I,J:],K:] = dom f & f is_continuous_on [:[:I,J:],K:] & f = g
holds Integral1(Prod_Measure(L-Meas,L-Meas),|.R_EAL g.|) is E-measurable
proof
let I,J,K be non empty closed_interval Subset of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL,
E be Element of L-Field;
assume that
A1: [:[:I,J:],K:] = dom f and
A2: f is_continuous_on [:[:I,J:],K:] and
A3: f = g;
set F = Integral1(Prod_Measure(L-Meas,L-Meas),|.R_EAL g.|);
set F0 = F|K;
A4: dom F = REAL by FUNCT_2:def 1; then
A5: dom F0 = K;
reconsider G = F0 as PartFunc of REAL,REAL by A1,A2,A3,Th35;
reconsider GG = G as PartFunc of RNS_Real,RNS_Real;
A6: K is Element of L-Field by MEASUR10:5,MEASUR12:75;
G|K is bounded & G is_integrable_on K
by A1,A2,A3,A5,Th36,INTEGRA5:10,11; then
G is_integrable_on L-Meas by A5,A6,MESFUN14:49; then
A7: F0 is_integrable_on L-Meas by MESFUNC5:def 7;
reconsider R = REAL as Element of L-Field by PROB_1:5;
set NK = R \ K;
A8: NK is Element of L-Field by A6,PROB_1:6;
A9: K \/ NK = REAL by XBOOLE_1:45;
A10: K /\ NK = {} by XBOOLE_1:85,XBOOLE_0:def 7;
A11: F is nonnegative by A1,A2,A3,Th39;
for r being Real holds R /\ (less_dom(F,r)) in L-Field
proof
let r be Real;
A12: ex E be Element of L-Field
st E = dom F0 & F0 is E-measurable by A7,MESFUNC5:def 17;
per cases;
suppose
A13: r <= 0;
less_dom(F,r) = {}
proof
assume less_dom(F,r) <> {}; then
consider x be object such that
A14: x in less_dom(F,r) by XBOOLE_0:def 1;
x in dom F & F.x < r by A14,MESFUNC1:def 11;
hence contradiction by A11,A13;
end;
hence R /\ less_dom(F,r) in L-Field by PROB_1:4;
end;
suppose
A15: 0 < r;
for z be object holds z in less_dom(F,r) iff z in less_dom(F0,r) \/ NK
proof
let z be object;
hereby assume
A16: z in less_dom(F,r); then
A17: F.z < r by MESFUNC1:def 11;
A18: z in NK implies z in less_dom(F0,r) \/ NK by XBOOLE_0:def 3;
now assume
A19: z in K; then
F0.z < r by A17,FUNCT_1:49; then
z in less_dom(F0,r) by A5,A19,MESFUNC1:def 11;
hence z in less_dom(F0,r) \/ NK by XBOOLE_0:def 3;
end;
hence z in less_dom(F0,r) \/ NK by A9,A16,A18,XBOOLE_0:def 3;
end;
assume z in less_dom (F0,r) \/ NK; then
per cases by XBOOLE_0:def 3;
suppose
A20: z in less_dom(F0,r); then
z in dom F0 & F0.z < r by MESFUNC1:def 11; then
F.z < r by FUNCT_1:49;
hence z in less_dom(F,r) by A4,A20,MESFUNC1:def 11;
end;
suppose
A21: z in NK; then
not z in K by XBOOLE_0:def 5; then
F.z < r by A15,A1,A3,A21,Lm5;
hence z in less_dom(F,r) by A4,A21,MESFUNC1:def 11;
end;
end; then
less_dom(F,r) = less_dom(F0,r) \/ NK by TARSKI:2; then
A22: R /\ less_dom(F,r)
= K /\ (less_dom(F0,r) \/ NK) \/ NK /\ (less_dom(F0,r) \/ NK)
by A9,XBOOLE_1:23;
K /\ (less_dom(F0,r) \/ NK)
= K /\ less_dom(F0,r) \/ (K /\ NK) by XBOOLE_1:23; then
A23: K /\ (less_dom(F0,r) \/ NK)
in L-Field by A4,A10,A12;
A24: less_dom(F0,r) c= K by A5,MESFUNC1:def 11;
NK /\ (less_dom(F0,r) \/ NK)
= (NK /\ less_dom(F0,r)) \/ (NK /\ NK) by XBOOLE_1:23; then
NK /\ (less_dom(F0,r) \/ NK)
= {} \/ (NK /\ NK) by A24;
hence R /\ less_dom(F,r) in L-Field by A8,A22,A23,PROB_1:3;
end;
end; then
F is R-measurable;
hence F is E-measurable by MESFUNC1:30;
end;
theorem
for I,J,K be non empty closed_interval Subset of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g being PartFunc of [:[:REAL,REAL:],REAL:],REAL,
x be Element of REAL
st [:[:I,J:],K:] = dom f & f is_continuous_on [:[:I,J:],K:] & f = g
holds
ProjPMap1(Integral2(L-Meas,R_EAL g),x) is Function of REAL,REAL
& ProjPMap1(|.Integral2(L-Meas,R_EAL g).|,x) is Function of REAL,REAL
proof
let I,J,K be non empty closed_interval Subset of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL,
x be Element of REAL;
assume that
A1: [:[:I,J:],K:] = dom f and
A2: f is_continuous_on [:[:I,J:],K:] and
A3: f = g;
reconsider F2 = Integral2(L-Meas,R_EAL g)
as Function of [:REAL,REAL:],REAL by A1,A2,A3,Th32;
A4: dom Integral2(L-Meas,R_EAL g) = [:REAL,REAL:] by FUNCT_2:def 1; then
A5: dom |.Integral2(L-Meas,R_EAL g).| = [:REAL,REAL:] by MESFUNC1:def 10;
dom F2 = [:REAL,REAL:] by FUNCT_2:def 1; then
A6: dom |.F2.| = [:REAL,REAL:] by VALUED_1:def 11;
A7: [#]REAL = REAL by SUBSET_1:def 3; then
A8: dom ProjPMap1(Integral2(L-Meas,R_EAL g),x) = REAL by A4,MESFUN16:25;
A9: dom ProjPMap1(|.Integral2(L-Meas,R_EAL g).|,x) = REAL by A7,A5,MESFUN16:25;
A10:dom ProjPMap1(F2,x) = REAL by A7,A4,MESFUN16:25;
A11:dom ProjPMap1(|.F2.|,x) = REAL by A6,A7,MESFUN16:25;
now let r be object;
assume r in rng ProjPMap1(Integral2(L-Meas,R_EAL g),x); then
consider y be Element of REAL such that
A12: y in dom ProjPMap1(Integral2(L-Meas,R_EAL g),x)
& r = (ProjPMap1(Integral2(L-Meas,R_EAL g),x)).y by PARTFUN1:3;
A13: [x,y] in [:REAL,REAL:]; then
[x,y] in dom Integral2(L-Meas,R_EAL g) by FUNCT_2:def 1; then
A14: r = F2.(x,y) by A12,MESFUN12:def 3;
[x,y] in dom F2 by A13,FUNCT_2:def 1; then
r = ProjPMap1(F2,x).y by A14,MESFUN12:def 3; then
r in rng ProjPMap1(F2,x) by A10,FUNCT_1:3;
hence r in REAL;
end; then
rng ProjPMap1(Integral2(L-Meas,R_EAL g),x) c= REAL;
hence ProjPMap1(Integral2(L-Meas,R_EAL g),x) is Function of REAL,REAL
by A8,FUNCT_2:2;
now let r be object;
assume r in rng ProjPMap1(|.Integral2(L-Meas,R_EAL g).|,x); then
consider y be Element of REAL such that
A15: y in dom ProjPMap1(|.Integral2(L-Meas,R_EAL g).|,x)
& r = (ProjPMap1(|.Integral2(L-Meas,R_EAL g).|,x)).y by PARTFUN1:3;
[x,y] in [:REAL,REAL:]; then
A16: [x,y] in dom Integral2(L-Meas,R_EAL g) by FUNCT_2:def 1; then
A17: [x,y] in dom |.Integral2(L-Meas,R_EAL g).| by MESFUNC1:def 10; then
r = (|.Integral2(L-Meas,R_EAL g).|).(x,y) by A15,MESFUN12:def 3; then
A18: r = |. Integral2(L-Meas,R_EAL g).(x,y) .| by A17,MESFUNC1:def 10;
set p = [x,y];
reconsider p as Element of [:REAL,REAL:];
A19: p in dom |.F2.| by A16,VALUED_1:def 11;
r = |. F2.p .| by A18,EXTREAL1:12; then
r = (|.F2.|).(x,y) by A19,VALUED_1:def 11; then
r = ProjPMap1(|.F2.|,x).y by A19,MESFUN12:def 3; then
r in rng ProjPMap1(|.F2.|,x) by A11,FUNCT_1:3;
hence r in REAL;
end; then
rng ProjPMap1(|.Integral2(L-Meas,R_EAL g).|,x) c= REAL;
hence ProjPMap1(|.Integral2(L-Meas,R_EAL g).|,x) is Function of REAL,REAL
by A9,FUNCT_2:2;
end;
theorem
for I,J,K be non empty closed_interval Subset of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL,
y be Element of REAL
st [:[:I,J:],K:] = dom f & f is_continuous_on [:[:I,J:],K:] & f = g
holds
ProjPMap2(Integral2(L-Meas,R_EAL g),y) is Function of REAL,REAL
& ProjPMap2(|.Integral2(L-Meas,R_EAL g).|,y) is Function of REAL,REAL
proof
let I,J,K be non empty closed_interval Subset of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL,
y be Element of REAL;
assume that
A1: [:[:I,J:],K:] = dom f and
A2: f is_continuous_on [:[:I,J:],K:] and
A3: f = g;
reconsider F2 = Integral2(L-Meas,R_EAL g)
as Function of [:REAL,REAL:],REAL by A1,A2,A3,Th32;
A4: dom Integral2(L-Meas,R_EAL g) = [:REAL,REAL:] by FUNCT_2:def 1; then
A5: dom |.Integral2(L-Meas,R_EAL g).| = [:REAL,REAL:] by MESFUNC1:def 10;
dom F2 = [:REAL,REAL:] by FUNCT_2:def 1; then
A6: dom |.F2.| = [:REAL,REAL:] by VALUED_1:def 11;
A7: [#]REAL = REAL by SUBSET_1:def 3; then
A8: dom ProjPMap2(Integral2(L-Meas,R_EAL g),y) = REAL by A4,MESFUN16:26;
A9: dom ProjPMap2(|.Integral2(L-Meas,R_EAL g).|,y) = REAL by A7,A5,MESFUN16:26;
A10:dom ProjPMap2(F2,y) = REAL by A7,A4,MESFUN16:26;
A11:dom ProjPMap2(|.F2.|,y) = REAL by A6,A7,MESFUN16:26;
now let r be object;
assume r in rng ProjPMap2(Integral2(L-Meas,R_EAL g),y); then
consider x be Element of REAL such that
A12: x in dom ProjPMap2(Integral2(L-Meas,R_EAL g),y)
& r = (ProjPMap2(Integral2(L-Meas,R_EAL g),y)).x by PARTFUN1:3;
A13: [x,y] in [:REAL,REAL:]; then
[x,y] in dom Integral2(L-Meas,R_EAL g) by FUNCT_2:def 1; then
A14: r = F2.(x,y) by A12,MESFUN12:def 4;
[x,y] in dom F2 by A13,FUNCT_2:def 1; then
r = ProjPMap2(F2,y).x by A14,MESFUN12:def 4; then
r in rng ProjPMap2(F2,y) by A10,FUNCT_1:3;
hence r in REAL;
end; then
rng ProjPMap2(Integral2(L-Meas,R_EAL g),y) c= REAL;
hence ProjPMap2(Integral2(L-Meas,R_EAL g),y) is Function of REAL,REAL
by A8,FUNCT_2:2;
now let r be object;
assume r in rng ProjPMap2(|.Integral2(L-Meas,R_EAL g).|,y); then
consider x be Element of REAL such that
A15: x in dom ProjPMap2(|.Integral2(L-Meas,R_EAL g).|,y)
& r = (ProjPMap2(|.Integral2(L-Meas,R_EAL g).|,y)).x by PARTFUN1:3;
[x,y] in [:REAL,REAL:]; then
A16: [x,y] in dom Integral2(L-Meas,R_EAL g) by FUNCT_2:def 1; then
A17: [x,y] in dom |.Integral2(L-Meas,R_EAL g).| by MESFUNC1:def 10; then
r = (|.Integral2(L-Meas,R_EAL g).|).(x,y) by A15,MESFUN12:def 4; then
A18: r = |. Integral2(L-Meas,R_EAL g).(x,y) .| by A17,MESFUNC1:def 10;
set p = [x,y];
reconsider p as Element of [:REAL,REAL:];
A19: p in dom |.F2.| by A16,VALUED_1:def 11;
r = |. F2.p .| by A18,EXTREAL1:12; then
r = (|.F2.|).(x,y) by A19,VALUED_1:def 11; then
r = ProjPMap2(|.F2.|,y).x by A19,MESFUN12:def 4; then
r in rng ProjPMap2(|.F2.|,y) by A11,FUNCT_1:3;
hence r in REAL;
end; then
rng ProjPMap2(|.Integral2(L-Meas,R_EAL g).|,y) c= REAL;
hence ProjPMap2(|.Integral2(L-Meas,R_EAL g).|,y) is Function of REAL,REAL
by A9,FUNCT_2:2;
end;
theorem
for I,J,K be non empty closed_interval Subset of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL
st [:[:I,J:],K:] = dom f & f is_continuous_on [:[:I,J:],K:] & f = g
holds
|.Integral1(Prod_Measure(L-Meas,L-Meas),R_EAL g).| is Function of REAL,REAL
proof
let I,J,K be non empty closed_interval Subset of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL;
assume that
A1: [:[:I,J:],K:] = dom f and
A2: f is_continuous_on [:[:I,J:],K:] and
A3: f = g;
set Fxy = Integral1(Prod_Measure(L-Meas,L-Meas),R_EAL g);
A4: Fxy is Function of REAL,REAL by A1,A2,A3,Th35;
dom Fxy = REAL by FUNCT_2:def 1; then
A5: dom |.Integral1(Prod_Measure(L-Meas,L-Meas),R_EAL g).| = REAL
by MESFUNC1:def 10;
now let r be object;
assume
r in REAL; then
reconsider r1=r as Element of REAL;
A6: |.Integral1(Prod_Measure(L-Meas,L-Meas),R_EAL g).| .r
= |. Fxy.r1 .| by A5,MESFUNC1:def 10;
reconsider y = Fxy.r1 as Element of REAL by A4,FUNCT_2:5;
|.Integral1(Prod_Measure(L-Meas,L-Meas),R_EAL g).| .r = |. y .|
by A6,EXTREAL1:12;
hence |.Integral1(Prod_Measure(L-Meas,L-Meas),R_EAL g).| .r in REAL
by XREAL_0:def 1;
end;
hence thesis by A5,FUNCT_2:3;
end;
theorem Th54:
for x be Element of REAL, I,J,K be non empty closed_interval Subset of REAL,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL st [:[:I,J:],K:] = dom g
holds Integral(L-Meas,ProjPMap1(Integral2(L-Meas,R_EAL g),x)|(REAL\J)) = 0
proof
let x be Element of REAL;
let I,J,K be non empty closed_interval Subset of REAL,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL;
assume
A1: [:[:I,J:],K:] = dom g;
set Rf = R_EAL g;
set F2 = Integral2(L-Meas,Rf);
A2: dom Rf = [:[:I,J:],K:] by A1,MESFUNC5:def 7;
A3: dom F2 = [:REAL,REAL:] by FUNCT_2:def 1;
[#]REAL = REAL by SUBSET_1:def 3; then
A4: dom ProjPMap1(F2,x) = REAL by A3,MESFUN16:25;
A5: J is Element of L-Field by MEASUR10:5,MEASUR12:75;
set NJ = REAL \ J;
REAL in L-Field by PROB_1:5; then
A6: NJ is Element of L-Field by A5,PROB_1:6;
set RL = ProjPMap1(F2,x);
reconsider RL0 = RL|J as PartFunc of REAL,ExtREAL;
reconsider RL1=RL| NJ as PartFunc of REAL,ExtREAL;
now let y be Element of REAL;
assume
A7: y in dom RL1;
y in REAL & not y in J by A4,A7,XBOOLE_0:def 5; then
not [x,y] in [:I,J:] by ZFMISC_1:87; then
A8: dom ProjPMap1(Rf,[x,y]) = {} by A2,MESFUN16:25;
[x,y] in [:REAL,REAL:]; then
A9: [x,y] in dom F2 by FUNCT_2:def 1;
RL1.y = ProjPMap1(F2,x).y by A4,A7,FUNCT_1:49; then
A10: RL1.y = F2.(x,y) by A9,MESFUN12:def 3;
F2.(x,y) = Integral(L-Meas,ProjPMap1(Rf,[x,y])) by MESFUN12:def 8;
hence RL1.y = 0 by A8,A10,MESFUN16:1;
end;
hence thesis by A4,A6,MESFUN12:57;
end;
theorem Th55:
for y be Element of REAL, I,J,K be non empty closed_interval Subset of REAL,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL st [:[:I,J:],K:] = dom g
holds Integral(L-Meas,ProjPMap2(Integral2(L-Meas,R_EAL g),y)|(REAL\I)) = 0
proof
let y be Element of REAL;
let I,J,K be non empty closed_interval Subset of REAL,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL;
assume
A1: [:[:I,J:],K:] = dom g;
set Rf = R_EAL g;
set F2 = Integral2(L-Meas,Rf);
A2: dom Rf = [:[:I,J:],K:] by A1,MESFUNC5:def 7;
A3: dom F2 = [:REAL,REAL:] by FUNCT_2:def 1;
[#]REAL = REAL by SUBSET_1:def 3; then
A4: dom ProjPMap2(F2,y) = REAL by A3,MESFUN16:26;
A5: I is Element of L-Field by MEASUR10:5,MEASUR12:75;
set NI = REAL \ I;
REAL in L-Field by PROB_1:5; then
A6: NI is Element of L-Field by A5,PROB_1:6;
set RL = ProjPMap2(F2,y);
reconsider RL1=RL| NI as PartFunc of REAL,ExtREAL;
now let x be Element of REAL;
assume
A7: x in dom RL1;
x in REAL & not x in I by A4,A7,XBOOLE_0:def 5; then
not [x,y] in [:I,J:] by ZFMISC_1:87; then
A8: dom ProjPMap1(Rf,[x,y]) = {} by A2,MESFUN16:25;
[x,y] in [:REAL,REAL:]; then
A9: [x,y] in dom F2 by FUNCT_2:def 1;
RL1.x = ProjPMap2(F2,y).x by A4,A7,FUNCT_1:49; then
A10: RL1.x = F2.(x,y) by A9,MESFUN12:def 4;
F2.(x,y) = Integral(L-Meas,ProjPMap1(Rf,[x,y])) by MESFUN12:def 8;
hence RL1.x = 0 by A8,A10,MESFUN16:1;
end;
hence thesis by A4,A6,MESFUN12:57;
end;
theorem
for I,J,K be non empty closed_interval Subset of REAL,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL st [:[:I,J:],K:] = dom g
holds
Integral(L-Meas,Integral1(Prod_Measure(L-Meas,L-Meas),R_EAL g)|(REAL\K)) = 0
proof
let I,J,K be non empty closed_interval Subset of REAL,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL;
assume
A1: [:[:I,J:],K:] = dom g;
set Rf = R_EAL g;
set F1 = Integral1(Prod_Measure(L-Meas,L-Meas),Rf);
A2: dom Rf = [:[:I,J:],K:] by A1,MESFUNC5:def 7;
A3: dom F1 = REAL by FUNCT_2:def 1;
A4: K is Element of L-Field by MEASUR10:5,MEASUR12:75;
set NK = REAL \ K;
REAL in L-Field by PROB_1:5; then
A5: NK is Element of L-Field by A4,PROB_1:6;
reconsider RL1 = F1|NK as PartFunc of REAL,ExtREAL;
now let z be Element of REAL;
assume
A6: z in dom RL1; then
z in REAL & not z in K by A3,XBOOLE_0:def 5; then
A7: dom ProjPMap2(Rf,z) = {} by A2,MESFUN16:26;
A8: RL1.z = F1.z by A6,FUNCT_1:47;
F1.z = Integral(Prod_Measure(L-Meas,L-Meas),ProjPMap2(Rf,z))
by MESFUN12:def 7;
hence RL1.z = 0 by A7,A8,MESFUN16:1;
end;
hence thesis by A3,A5,MESFUN12:57;
end;
theorem
for x be Element of REAL, I,J,K be non empty closed_interval Subset of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL,
P1Gz be PartFunc of REAL,REAL st
x in I & [:[:I,J:],K:] = dom f & f is_continuous_on [:[:I,J:],K:] & f = g
& P1Gz = ProjPMap1(Integral2(L-Meas,R_EAL g),x)|J holds P1Gz is continuous
proof
let x be Element of REAL;
let I,J,K be non empty closed_interval Subset of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL,
P1Gz be PartFunc of REAL,REAL;
assume that
A1: x in I and
A2: [:[:I,J:],K:] = dom f and
A3: f is_continuous_on [:[:I,J:],K:] and
A4: f = g and
A5: P1Gz = ProjPMap1(Integral2(L-Meas,R_EAL g),x)|J;
reconsider F2 = Integral2(L-Meas,R_EAL g)| [:I,J:]
as PartFunc of [:RNS_Real,RNS_Real:],RNS_Real by A2,A3,A4,Th32;
reconsider G2 = F2 as PartFunc of [:REAL,REAL:],REAL;
A6: dom(Integral2(L-Meas,R_EAL g)) = [:REAL,REAL:] by FUNCT_2:def 1;
X-section([:I,J:],x) = J by A1,MEASUR11:22; then
A7: ProjPMap1(Integral2(L-Meas,R_EAL g)| [:I,J:],x)
= ProjPMap1(Integral2(L-Meas,R_EAL g),x)|J by MESFUN12:34;
A8: Integral2(L-Meas,R_EAL g)| [:I,J:] = R_EAL (G2| [:I,J:])
by MESFUNC5:def 7;
F2 is_uniformly_continuous_on [:I,J:] by A2,A3,A4,Th34;
hence P1Gz is continuous by A5,A7,A8,A6,MESFUN16:36,NFCONT_2:7;
end;
theorem
for y be Element of REAL, I,J,K be non empty closed_interval Subset of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL,
P2Gz be PartFunc of REAL,REAL st
y in J & [:[:I,J:],K:] = dom f & f is_continuous_on [:[:I,J:],K:] & f = g
& P2Gz = ProjPMap2(Integral2(L-Meas,R_EAL g),y)|I holds P2Gz is continuous
proof
let y be Element of REAL;
let I,J,K be non empty closed_interval Subset of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL,
P2Gz be PartFunc of REAL,REAL;
assume that
A1: y in J and
A2: [:[:I,J:],K:] = dom f and
A3: f is_continuous_on [:[:I,J:],K:] and
A4: f = g and
A5: P2Gz = ProjPMap2(Integral2(L-Meas,R_EAL g),y)|I;
reconsider F2 = Integral2(L-Meas,R_EAL g)| [:I,J:]
as PartFunc of [:RNS_Real,RNS_Real:],RNS_Real by A2,A3,A4,Th32;
reconsider G2 = F2 as PartFunc of [:REAL,REAL:],REAL;
A6: dom(Integral2(L-Meas,R_EAL g)) = [:REAL,REAL:] by FUNCT_2:def 1;
Y-section([:I,J:],y) = I by A1,MEASUR11:22; then
A7: ProjPMap2(Integral2(L-Meas,R_EAL g)| [:I,J:],y)
= ProjPMap2(Integral2(L-Meas,R_EAL g),y)|I by MESFUN12:34;
A8: Integral2(L-Meas,R_EAL g)| [:I,J:] = R_EAL (G2| [:I,J:])
by MESFUNC5:def 7;
F2 is_uniformly_continuous_on [:I,J:] by A2,A3,A4,Th34;
hence P2Gz is continuous by A5,A7,A8,A6,MESFUN16:37,NFCONT_2:7;
end;
theorem Th59:
for x be Element of REAL, I,J,K be non empty closed_interval Subset of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL,
P1Gz be PartFunc of REAL,REAL st
x in I & [:[:I,J:],K:] = dom f & f is_continuous_on [:[:I,J:],K:] & f = g
& P1Gz = ProjPMap1(Integral2(L-Meas,R_EAL g),x)|J
holds P1Gz||J is bounded & P1Gz is_integrable_on J
proof
let x be Element of REAL;
let I,J,K be non empty closed_interval Subset of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL,
P1Gz be PartFunc of REAL,REAL;
assume that
A1: x in I and
A2: [:[:I,J:],K:] = dom f and
A3: f is_continuous_on [:[:I,J:],K:] and
A4: f = g and
A5: P1Gz = ProjPMap1(Integral2(L-Meas,R_EAL g),x)|J;
reconsider F2 = Integral2(L-Meas,R_EAL g)| [:I,J:]
as PartFunc of [:RNS_Real,RNS_Real:],RNS_Real by A2,A3,A4,Th32;
reconsider G2 = F2 as PartFunc of [:REAL,REAL:],REAL;
A6: dom(Integral2(L-Meas,R_EAL g)) = [:REAL,REAL:] by FUNCT_2:def 1;
X-section([:I,J:],x) = J by A1,MEASUR11:22; then
A7: ProjPMap1(Integral2(L-Meas,R_EAL g)| [:I,J:],x)
= ProjPMap1(Integral2(L-Meas,R_EAL g),x)|J by MESFUN12:34;
A8: Integral2(L-Meas,R_EAL g)| [:I,J:] = R_EAL (G2| [:I,J:]) by MESFUNC5:def 7;
F2 is_uniformly_continuous_on [:I,J:] by A2,A3,A4,Th34; then
F2 is_continuous_on [:I,J:] by NFCONT_2:7;
hence P1Gz||J is bounded & P1Gz is_integrable_on J
by A1,A5,A6,A7,A8,MESFUN16:40;
end;
theorem Th60:
for y be Element of REAL, I,J,K be non empty closed_interval Subset of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL,
P2Gz be PartFunc of REAL,REAL st
y in J & [:[:I,J:],K:] = dom f & f is_continuous_on [:[:I,J:],K:] & f = g
& P2Gz = ProjPMap2(Integral2(L-Meas,R_EAL g),y)|I
holds P2Gz||I is bounded & P2Gz is_integrable_on I
proof
let y be Element of REAL;
let I,J,K be non empty closed_interval Subset of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL,
P2Gz be PartFunc of REAL,REAL;
assume that
A1: y in J and
A2: [:[:I,J:],K:] = dom f and
A3: f is_continuous_on [:[:I,J:],K:] and
A4: f = g and
A5: P2Gz = ProjPMap2(Integral2(L-Meas,R_EAL g),y)|I;
reconsider F2 = Integral2(L-Meas,R_EAL g)| [:I,J:]
as PartFunc of [:RNS_Real,RNS_Real:],RNS_Real by A2,A3,A4,Th32;
reconsider G2 = F2 as PartFunc of [:REAL,REAL:],REAL;
A6: dom(Integral2(L-Meas,R_EAL g)) = [:REAL,REAL:] by FUNCT_2:def 1;
Y-section([:I,J:],y) = I by A1,MEASUR11:22; then
A7: ProjPMap2(Integral2(L-Meas,R_EAL g)| [:I,J:],y)
= ProjPMap2(Integral2(L-Meas,R_EAL g),y)|I by MESFUN12:34;
A8: Integral2(L-Meas,R_EAL g)| [:I,J:] = R_EAL (G2| [:I,J:]) by MESFUNC5:def 7;
F2 is_uniformly_continuous_on [:I,J:] by A2,A3,A4,Th34; then
F2 is_continuous_on [:I,J:] by NFCONT_2:7;
hence P2Gz||I is bounded & P2Gz is_integrable_on I
by A1,A5,A6,A7,A8,MESFUN16:42;
end;
theorem
for I,J,K be non empty closed_interval Subset of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL,
Gxy be PartFunc of REAL,REAL st
[:[:I,J:],K:] = dom f & f is_continuous_on [:[:I,J:],K:] & f = g
& Gxy = (Integral1(Prod_Measure(L-Meas,L-Meas),R_EAL g))|K
holds Gxy||K is bounded & Gxy is_integrable_on K
proof
let I,J,K be non empty closed_interval Subset of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL,
Gxy be PartFunc of REAL,REAL;
assume that
A1: [:[:I,J:],K:] = dom f and
A2: f is_continuous_on [:[:I,J:],K:] and
A3: f = g and
A4: Gxy = (Integral1(Prod_Measure(L-Meas,L-Meas),R_EAL g))|K;
dom Integral1(Prod_Measure(L-Meas,L-Meas),R_EAL g) = REAL
by FUNCT_2:def 1; then
dom Gxy = K by A4;
hence thesis by A1,A2,A3,A4,Th37,INTEGRA5:10,11;
end;
theorem
for x be Element of REAL, I,J,K be non empty closed_interval Subset of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL,
P1Gz be PartFunc of REAL,REAL st
x in I & [:[:I,J:],K:] = dom f & f is_continuous_on [:[:I,J:],K:] & f = g
& P1Gz = ProjPMap1(Integral2(L-Meas,R_EAL g),x)|J holds
ProjPMap1(Integral2(L-Meas,R_EAL g),x)|J is_integrable_on L-Meas
& integral(P1Gz,J) =Integral(L-Meas,ProjPMap1(Integral2(L-Meas,R_EAL g),x)|J)
& integral(P1Gz,J) = Integral(L-Meas,ProjPMap1(Integral2(L-Meas,R_EAL g),x))
& integral(P1Gz,J) = (Integral2(L-Meas,Integral2(L-Meas,R_EAL g))).x
proof
let x be Element of REAL;
let I,J,K be non empty closed_interval Subset of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL,
P1Gz be PartFunc of REAL,REAL;
assume that
A1: x in I and
A2: [:[:I,J:],K:] = dom f and
A3: f is_continuous_on [:[:I,J:],K:] and
A4: f = g and
A5: P1Gz = ProjPMap1(Integral2(L-Meas,R_EAL g),x)|J;
set Gz = Integral2(L-Meas,R_EAL g);
A6: J is Element of L-Field by MEASUR10:5,MEASUR12:75;
A7: ProjPMap1(Gz,x) is_integrable_on L-Meas by A2,A3,A4,Th46;
hence ProjPMap1(Integral2(L-Meas,R_EAL g),x)|J is_integrable_on L-Meas
by A6,MESFUNC5:97;
A8: dom(Integral2(L-Meas,R_EAL g)) = [:REAL,REAL:] by FUNCT_2:def 1;
[#]REAL = REAL by SUBSET_1:def 3; then
dom(ProjPMap1(Integral2(L-Meas,R_EAL g),x)) = REAL by A8,MESFUN16:25; then
A9: dom P1Gz = J by A5;
P1Gz||J is bounded & P1Gz is_integrable_on J by A1,A2,A3,A4,A5,Th59; then
P1Gz|J is_integrable_on L-Meas
& Integral(L-Meas,P1Gz|J) = integral(P1Gz||J) by A6,A9,MESFUN14:49;
hence
A10: integral(P1Gz,J)
= Integral(L-Meas,ProjPMap1(Integral2(L-Meas,R_EAL g),x)|J)
by A5,MESFUNC5:def 7;
REAL in L-Field by PROB_1:5; then
reconsider NJ = REAL \ J as Element of L-Field by A6,PROB_1:6;
set PGz10 = ProjPMap1(Gz,x)|J;
set PGz11 = ProjPMap1(Gz,x)|NJ;
A11:Integral(L-Meas,PGz11) = 0 by A2,A4,Th54;
J \/ NJ = REAL by XBOOLE_1:45; then
ProjPMap1(Gz,x)|(J \/ NJ) = ProjPMap1(Gz,x); then
Integral(L-Meas,ProjPMap1(Gz,x))
= Integral(L-Meas,PGz10) + Integral(L-Meas,PGz11)
by A6,A7,XBOOLE_1:85,MESFUNC5:98;
hence integral(P1Gz,J) = Integral(L-Meas,ProjPMap1(Gz,x))
by A10,A11,XXREAL_3:4;
hence integral(P1Gz,J) = (Integral2(L-Meas,Integral2(L-Meas,R_EAL g))).x
by MESFUN12:def 8;
end;
theorem
for y be Element of REAL, I,J,K be non empty closed_interval Subset of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL,
P2Gz be PartFunc of REAL,REAL st
y in J & [:[:I,J:],K:] = dom f & f is_continuous_on [:[:I,J:],K:] & f = g
& P2Gz = ProjPMap2(Integral2(L-Meas,R_EAL g),y)|I holds
ProjPMap2(Integral2(L-Meas,R_EAL g),y)|I is_integrable_on L-Meas
& integral(P2Gz,I) = Integral(L-Meas,ProjPMap2(Integral2(L-Meas,R_EAL g),y)|I)
& integral(P2Gz,I) = Integral(L-Meas,ProjPMap2(Integral2(L-Meas,R_EAL g),y))
& integral(P2Gz,I) = (Integral1(L-Meas,Integral2(L-Meas,R_EAL g))).y
proof
let y be Element of REAL;
let I,J,K be non empty closed_interval Subset of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL,
P2Gz be PartFunc of REAL,REAL;
assume that
A1: y in J and
A2: [:[:I,J:],K:] = dom f and
A3: f is_continuous_on [:[:I,J:],K:] and
A4: f = g and
A5: P2Gz = ProjPMap2(Integral2(L-Meas,R_EAL g),y)|I;
set Gz = Integral2(L-Meas,R_EAL g);
A6: I is Element of L-Field by MEASUR10:5,MEASUR12:75;
A7: ProjPMap2(Gz,y) is_integrable_on L-Meas by A2,A3,A4,Th48;
hence ProjPMap2(Integral2(L-Meas,R_EAL g),y)|I is_integrable_on L-Meas
by A6,MESFUNC5:97;
A8: dom(Integral2(L-Meas,R_EAL g)) = [:REAL,REAL:] by FUNCT_2:def 1;
[#]REAL = REAL by SUBSET_1:def 3; then
dom(ProjPMap2(Integral2(L-Meas,R_EAL g),y)) = REAL by A8,MESFUN16:26; then
A9: dom P2Gz = I by A5;
P2Gz||I is bounded & P2Gz is_integrable_on I by A1,A2,A3,A4,A5,Th60; then
P2Gz|I is_integrable_on L-Meas
& Integral(L-Meas,P2Gz|I) = integral(P2Gz||I) by A6,A9,MESFUN14:49;
hence
A10: integral(P2Gz,I)
= Integral(L-Meas,ProjPMap2(Integral2(L-Meas,R_EAL g),y)|I)
by A5,MESFUNC5:def 7;
REAL in L-Field by PROB_1:5; then
reconsider NI = REAL \ I as Element of L-Field by A6,PROB_1:6;
set PGz20 = ProjPMap2(Gz,y)|I;
set PGz21 = ProjPMap2(Gz,y)|NI;
A11:Integral(L-Meas,PGz21) = 0 by A2,A4,Th55;
I \/ NI = REAL by XBOOLE_1:45; then
ProjPMap2(Gz,y)|(I \/ NI) = ProjPMap2(Gz,y); then
Integral(L-Meas,ProjPMap2(Gz,y))
= Integral(L-Meas,PGz20) + Integral(L-Meas,PGz21)
by A6,A7,XBOOLE_1:85,MESFUNC5:98;
hence integral(P2Gz,I) = Integral(L-Meas,ProjPMap2(Gz,y))
by A10,A11,XXREAL_3:4;
hence integral(P2Gz,I) = (Integral1(L-Meas,Integral2(L-Meas,R_EAL g))).y
by MESFUN12:def 7;
end;
theorem
for I,J,K be non empty closed_interval Subset of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL
st [:[:I,J:],K:] = dom f & f is_continuous_on [:[:I,J:],K:] & f = g
holds
(for U being Element of L-Field
holds Integral2(L-Meas,Integral2(L-Meas,R_EAL g)) is U-measurable)
& Integral2(L-Meas,Integral2(L-Meas,R_EAL g)) is_integrable_on L-Meas
& Integral(Prod_Measure(L-Meas,L-Meas),Integral2(L-Meas,R_EAL g))
= Integral(L-Meas,Integral2(L-Meas,Integral2(L-Meas,R_EAL g)))
& Integral(Prod_Measure(Prod_Measure(L-Meas,L-Meas),L-Meas),g)
= Integral(L-Meas,Integral2(L-Meas,Integral2(L-Meas,R_EAL g)))
& Integral2(L-Meas,R_EAL g)| [:I,J:]
is_integrable_on Prod_Measure(L-Meas,L-Meas)
& Integral(Prod_Measure(L-Meas,L-Meas),Integral2(L-Meas,R_EAL g)| [:I,J:])
= Integral(L-Meas,Integral2(L-Meas,Integral2(L-Meas,R_EAL g)| [:I,J:]) )
proof
let I,J,K be non empty closed_interval Subset of REAL;
let f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real;
let g be PartFunc of [:[:REAL,REAL:],REAL:],REAL;
assume that
A1: [:[:I,J:],K:] = dom f and
A2: f is_continuous_on [:[:I,J:],K:] and
A3: f = g;
set RF = Integral2(L-Meas,R_EAL g);
A4: dom RF = [:REAL,REAL:] by FUNCT_2:def 1;
reconsider RG = RF| [:I,J:] as PartFunc of [:REAL,REAL:],REAL
by A1,A2,A3,Th32;
reconsider RGG = RG as PartFunc of [:RNS_Real,RNS_Real:],RNS_Real;
A5:Integral2(L-Meas,R_EAL g) is_integrable_on Prod_Measure(L-Meas,L-Meas)
by A1,A2,A3,Th43;
A6:for x being Element of REAL holds
Integral2(L-Meas,|.Integral2(L-Meas,R_EAL g).|).x < +infty
by A1,A2,A3,Th46;
hence
(for U being Element of L-Field
holds Integral2(L-Meas,Integral2(L-Meas,R_EAL g)) is U-measurable)
& Integral2(L-Meas,Integral2(L-Meas,R_EAL g)) is_integrable_on L-Meas
& Integral(Prod_Measure(L-Meas,L-Meas),Integral2(L-Meas,R_EAL g))
= Integral(L-Meas,Integral2(L-Meas,Integral2(L-Meas,R_EAL g)))
by A5,MESFUN13:32,MESFUN16:5;
A7:g is_integrable_on Prod_Measure(Prod_Measure(L-Meas,L-Meas),L-Meas)
by A1,A2,A3,Th43;
for x being Element of [:REAL,REAL:] holds
Integral2(L-Meas,|.R_EAL g.|).x < +infty by A1,A2,A3,Th40; then
Integral(Prod_Measure(Prod_Measure(L-Meas,L-Meas),L-Meas),R_EAL g)
= Integral(Prod_Measure(L-Meas,L-Meas),Integral2(L-Meas,R_EAL g))
by A7,MESFUN13:32,MESFUN16:5,6;
hence Integral(Prod_Measure(Prod_Measure(L-Meas,L-Meas),L-Meas),g)
= Integral(L-Meas,Integral2(L-Meas,Integral2(L-Meas,R_EAL g)))
by A5,A6,MESFUN13:32,MESFUN16:5;
A8:Integral2(L-Meas,R_EAL g)| [:I,J:] = R_EAL RG by MESFUNC5:def 7;
RGG is_uniformly_continuous_on [:I,J:] by A1,A2,A3,Th34; then
RGG is_continuous_on [:I,J:] by NFCONT_2:7; then
RG is_integrable_on Prod_Measure(L-Meas,L-Meas)
& Integral(Prod_Measure(L-Meas,L-Meas),RG)
= Integral(L-Meas,Integral2(L-Meas,R_EAL RG)) by A4,MESFUN16:57;
hence Integral2(L-Meas,R_EAL g)| [:I,J:]
is_integrable_on Prod_Measure(L-Meas,L-Meas)
& Integral(Prod_Measure(L-Meas,L-Meas),Integral2(L-Meas,R_EAL g)| [:I,J:])
= Integral(L-Meas,Integral2(L-Meas,Integral2(L-Meas,R_EAL g)| [:I,J:]))
by A8;
end;
theorem
for I,J,K be non empty closed_interval Subset of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL
st [:[:I,J:],K:] = dom f & f is_continuous_on [:[:I,J:],K:] & f = g
holds
(for V being Element of L-Field
holds Integral1(L-Meas,Integral2(L-Meas,R_EAL g)) is V-measurable)
& Integral1(L-Meas,Integral2(L-Meas,R_EAL g)) is_integrable_on L-Meas
& Integral(Prod_Measure(L-Meas,L-Meas),Integral2(L-Meas,R_EAL g))
= Integral(L-Meas,Integral1(L-Meas,Integral2(L-Meas,R_EAL g)))
& Integral(Prod_Measure(Prod_Measure(L-Meas,L-Meas),L-Meas),g)
= Integral(L-Meas,Integral1(L-Meas,Integral2(L-Meas,R_EAL g)))
& Integral(Prod_Measure(L-Meas,L-Meas),Integral2(L-Meas,R_EAL g)| [:I,J:])
= Integral(L-Meas,Integral1(L-Meas,Integral2(L-Meas,R_EAL g)| [:I,J:]) )
proof
let I,J,K be non empty closed_interval Subset of REAL;
let f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real;
let g be PartFunc of [:[:REAL,REAL:],REAL:],REAL;
assume that
A1: [:[:I,J:],K:] = dom f and
A2: f is_continuous_on [:[:I,J:],K:] and
A3: f = g;
set RF = Integral2(L-Meas,R_EAL g);
A4: dom RF = [:REAL,REAL:] by FUNCT_2:def 1;
reconsider RG = RF| [:I,J:] as PartFunc of [:REAL,REAL:],REAL
by A1,A2,A3,Th32;
reconsider RGG = RG as PartFunc of [:RNS_Real,RNS_Real:],RNS_Real;
A5:Integral2(L-Meas,R_EAL g) is_integrable_on Prod_Measure(L-Meas,L-Meas)
by A1,A2,A3,Th43;
A6:for y being Element of REAL holds
Integral1(L-Meas,|.Integral2(L-Meas,R_EAL g).|).y < +infty
by A1,A2,A3,Th48;
hence
(for V being Element of L-Field
holds Integral1(L-Meas,Integral2(L-Meas,R_EAL g)) is V-measurable)
& Integral1(L-Meas,Integral2(L-Meas,R_EAL g)) is_integrable_on L-Meas
& Integral(Prod_Measure(L-Meas,L-Meas),Integral2(L-Meas,R_EAL g))
= Integral(L-Meas,Integral1(L-Meas,Integral2(L-Meas,R_EAL g)))
by A5,MESFUN13:33,MESFUN16:5;
A7:g is_integrable_on Prod_Measure(Prod_Measure(L-Meas,L-Meas),L-Meas)
by A1,A2,A3,Th43;
for u being Element of [:REAL,REAL:] holds
Integral2(L-Meas,|.R_EAL g.|).u < +infty by A1,A2,A3,Th40; then
Integral(Prod_Measure(Prod_Measure(L-Meas,L-Meas),L-Meas),R_EAL g)
= Integral(Prod_Measure(L-Meas,L-Meas),Integral2(L-Meas,R_EAL g))
by A7,MESFUN13:32,MESFUN16:5,6;
hence Integral(Prod_Measure(Prod_Measure(L-Meas,L-Meas),L-Meas),g)
= Integral(L-Meas,Integral1(L-Meas,Integral2(L-Meas,R_EAL g)))
by A5,A6,MESFUN13:33,MESFUN16:5;
A8:Integral2(L-Meas,R_EAL g)| [:I,J:] = R_EAL RG by MESFUNC5:def 7;
RGG is_uniformly_continuous_on [:I,J:] by A1,A2,A3,Th34; then
RGG is_continuous_on [:I,J:] by NFCONT_2:7; then
RG is_integrable_on Prod_Measure(L-Meas,L-Meas)
& Integral(Prod_Measure(L-Meas,L-Meas),RG)
= Integral(L-Meas,Integral1(L-Meas,R_EAL RG)) by A4,MESFUN16:57;
hence
Integral(Prod_Measure(L-Meas,L-Meas),Integral2(L-Meas,R_EAL g)| [:I,J:])
= Integral(L-Meas,Integral1(L-Meas,Integral2(L-Meas,R_EAL g)| [:I,J:]) )
by A8;
end;
theorem
for x be Element of REAL, I,J,K be non empty closed_interval Subset of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL,
P1Gz be PartFunc of REAL,REAL st
x in I & [:[:I,J:],K:] = dom f & f is_continuous_on [:[:I,J:],K:] & f = g
& P1Gz = ProjPMap1(Integral2(L-Meas,R_EAL g)| [:I,J:],x)
holds
P1Gz is continuous
& dom ProjPMap1(Integral2 (L-Meas,R_EAL g)| [:I,J:],x) = J
& P1Gz|J is bounded & P1Gz is_integrable_on J
& integral(P1Gz,J)
= Integral(L-Meas,(ProjPMap1(Integral2(L-Meas,R_EAL g)| [:I,J:],x)))
& integral(P1Gz,J)
= (Integral2(L-Meas,Integral2(L-Meas,R_EAL g)| [:I,J:])).x
& ProjPMap1(Integral2(L-Meas,R_EAL g)| [:I,J:],x) is_integrable_on L-Meas
proof
let x be Element of REAL,
I,J,K be non empty closed_interval Subset of REAL;
let f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real;
let g be PartFunc of [:[:REAL,REAL:],REAL:],REAL;
let P1Gz be PartFunc of REAL,REAL;
assume that
A1:x in I and
A2: [:[:I,J:],K:] = dom f and
A3: f is_continuous_on [:[:I,J:],K:] and
A4: f = g and
A5: P1Gz = ProjPMap1(Integral2(L-Meas,R_EAL g)| [:I,J:],x);
reconsider Gz = Integral2(L-Meas,R_EAL g)| [:I,J:]
as PartFunc of [:REAL,REAL:],REAL by A2,A3,A4,Th32;
reconsider Fz = Gz as PartFunc of [:RNS_Real,RNS_Real:],RNS_Real;
A6: dom Integral2(L-Meas,R_EAL g) = [:REAL,REAL:] by FUNCT_2:def 1;
A7: P1Gz = ProjPMap1(R_EAL Gz,x) by A5,MESFUNC5:def 7;
A8: Fz is_uniformly_continuous_on [:I,J:] by A2,A3,A4,Th34;
hence P1Gz is continuous by A6,A7,NFCONT_2:7,MESFUN16:36;
dom ProjPMap1(R_EAL Gz,x) = J by A6,A1,A8,MESFUN16:27;
hence dom ProjPMap1(Integral2 (L-Meas,R_EAL g)| [:I,J:],x) = J
by MESFUNC5:def 7;
A9: Fz is_continuous_on [:I,J:] by A8,NFCONT_2:7;
hence P1Gz|J is bounded & P1Gz is_integrable_on J by A6,A7,A1,MESFUN16:40;
A10: P1Gz is_integrable_on L-Meas
& integral(P1Gz,J) = Integral(L-Meas,(ProjPMap1(R_EAL Gz,x)))
& (Integral2(L-Meas,R_EAL Gz)).x = integral(P1Gz,J)
by A6,A7,A9,A1,MESFUN16:41;
hence
integral(P1Gz,J)
= Integral(L-Meas,ProjPMap1(Integral2(L-Meas,R_EAL g)| [:I,J:],x))
& integral(P1Gz,J) = (Integral2(L-Meas,Integral2(L-Meas,R_EAL g)| [:I,J:])).x
by MESFUNC5:def 7;
ProjPMap1(R_EAL Gz,x) is_integrable_on L-Meas by A10,A7,MESFUNC5:def 7;
hence ProjPMap1(Integral2(L-Meas,R_EAL g)| [:I,J:],x)
is_integrable_on L-Meas by MESFUNC5:def 7;
end;
theorem
for y be Element of REAL, I,J,K be non empty closed_interval Subset of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL,
P2Gz be PartFunc of REAL,REAL st
y in J & [:[:I,J:],K:] = dom f & f is_continuous_on [:[:I,J:],K:] & f = g
& P2Gz = ProjPMap2(Integral2(L-Meas,R_EAL g)| [:I,J:],y)
holds
P2Gz is continuous
& dom ProjPMap2(Integral2 (L-Meas,R_EAL g)| [:I,J:],y) = I
& P2Gz|I is bounded & P2Gz is_integrable_on I
& integral(P2Gz,I)
= Integral(L-Meas,(ProjPMap2(Integral2(L-Meas,R_EAL g)| [:I,J:],y)))
& integral(P2Gz,I)
= (Integral1(L-Meas,Integral2(L-Meas,R_EAL g)| [:I,J:])).y
& ProjPMap2(Integral2(L-Meas,R_EAL g)| [:I,J:],y) is_integrable_on L-Meas
proof
let y be Element of REAL,
I,J,K be non empty closed_interval Subset of REAL;
let f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real;
let g be PartFunc of [:[:REAL,REAL:],REAL:],REAL;
let P2Gz be PartFunc of REAL,REAL;
assume that
A1: y in J and
A2: [:[:I,J:],K:] = dom f and
A3: f is_continuous_on [:[:I,J:],K:] and
A4: f = g and
A5: P2Gz = ProjPMap2(Integral2(L-Meas,R_EAL g)| [:I,J:],y);
reconsider Gz = Integral2(L-Meas,R_EAL g)| [:I,J:]
as PartFunc of [:REAL,REAL:],REAL by A2,A3,A4,Th32;
reconsider Fz = Gz as PartFunc of [:RNS_Real,RNS_Real:],RNS_Real;
A6: dom Integral2(L-Meas,R_EAL g) = [:REAL,REAL:] by FUNCT_2:def 1;
A7: P2Gz = ProjPMap2(R_EAL Gz,y) by A5,MESFUNC5:def 7;
A8: Fz is_uniformly_continuous_on [:I,J:] by A2,A3,A4,Th34;
hence P2Gz is continuous by A6,A7,NFCONT_2:7,MESFUN16:37;
dom ProjPMap2(R_EAL Gz,y) = I by A6,A1,A8,MESFUN16:28;
hence dom ProjPMap2(Integral2 (L-Meas,R_EAL g)| [:I,J:],y) = I
by MESFUNC5:def 7;
A9: Fz is_continuous_on [:I,J:] by A8,NFCONT_2:7;
hence P2Gz|I is bounded & P2Gz is_integrable_on I by A6,A7,A1,MESFUN16:42;
A10: P2Gz is_integrable_on L-Meas
& integral(P2Gz,I) = Integral(L-Meas,(ProjPMap2(R_EAL Gz,y)))
& (Integral1(L-Meas,R_EAL Gz)).y = integral(P2Gz,I)
by A6,A7,A9,A1,MESFUN16:43;
hence
integral(P2Gz,I)
= Integral(L-Meas,ProjPMap2(Integral2(L-Meas,R_EAL g)| [:I,J:],y))
& integral(P2Gz,I) = (Integral1(L-Meas,Integral2(L-Meas,R_EAL g)| [:I,J:])).y
by MESFUNC5:def 7;
ProjPMap2(R_EAL Gz,y) is_integrable_on L-Meas by A10,A7,MESFUNC5:def 7;
hence ProjPMap2(Integral2(L-Meas,R_EAL g)| [:I,J:],y)
is_integrable_on L-Meas by MESFUNC5:def 7;
end;
theorem
for I,J,K be non empty closed_interval Subset of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL,
Gzy be PartFunc of REAL,REAL
st [:[:I,J:],K:] = dom f & f is_continuous_on [:[:I,J:],K:] & f = g
& Gzy = Integral2(L-Meas,Integral2(L-Meas,R_EAL g)| [:I,J:])|I
holds
dom Gzy = I
& Gzy is continuous
& Gzy|| I is bounded & Gzy is_integrable_on I
& Integral2(L-Meas,Integral2(L-Meas,R_EAL g)| [:I,J:])| I
is_integrable_on L-Meas
& Integral(L-Meas,Integral2(L-Meas,Integral2(L-Meas,R_EAL g)| [:I,J:])| I)
= integral(Gzy,I)
& Integral(Prod_Measure(L-Meas,L-Meas),Integral2(L-Meas,R_EAL g)| [:I,J:])
= integral(Gzy,I)
proof
let I,J,K be non empty closed_interval Subset of REAL;
let f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real;
let g be PartFunc of [:[:REAL,REAL:],REAL:],REAL;
let Gzy be PartFunc of REAL,REAL;
assume that
A1: [:[:I,J:],K:] = dom f and
A2: f is_continuous_on [:[:I,J:],K:] and
A3: f = g and
A4: Gzy = Integral2(L-Meas,Integral2(L-Meas,R_EAL g)| [:I,J:])|I;
A5: dom Integral2(L-Meas,R_EAL g) = [:REAL,REAL:] by FUNCT_2:def 1;
reconsider Gz = Integral2(L-Meas,R_EAL g)| [:I,J:]
as PartFunc of [:REAL,REAL:],REAL by A1,A2,A3,Th32;
reconsider Fz = Gz as PartFunc of [:RNS_Real,RNS_Real:],RNS_Real;
A6: Fz is_uniformly_continuous_on [:I,J:] by A1,A2,A3,Th34; then
A7: Fz is_continuous_on [:I,J:] by NFCONT_2:7;
A8: Gzy = Integral2(L-Meas,R_EAL Gz)|I by A4,MESFUNC5:def 7;
A9:dom(Integral2(L-Meas,R_EAL Gz)) = REAL by FUNCT_2:def 1;
hence
A10:dom Gzy = I by A8; then
A11:Gzy||I is bounded & Gzy is_integrable_on I
& Integral(Prod_Measure(L-Meas,L-Meas),R_EAL Gz) = integral(Gzy,I)
by A7,A5,A8,MESFUN16:53,58,INTEGRA5:10,11;
thus
Gzy is continuous by A6,A5,A8,NFCONT_2:7,MESFUN16:53;
hence Gzy||I is bounded & Gzy is_integrable_on I by A9,A8,INTEGRA5:10,11;
I in L-Field & J in L-Field by MEASUR10:5,MEASUR12:75; then
Gzy is_integrable_on L-Meas & Integral(L-Meas,Gzy|I) = integral(Gzy,I)
by A10,A11,MESFUN14:49;
hence
Integral2(L-Meas,Integral2(L-Meas,R_EAL g)| [:I,J:])|I
is_integrable_on L-Meas
& Integral(L-Meas,Integral2(L-Meas,Integral2(L-Meas,R_EAL g)| [:I,J:])|I)
= integral(Gzy,I) by A4,MESFUNC5:def 7;
thus
Integral(Prod_Measure(L-Meas,L-Meas),Integral2(L-Meas,R_EAL g)| [:I,J:])
= integral(Gzy,I) by A11,MESFUNC5:def 7;
end;
theorem
for I,J,K be non empty closed_interval Subset of REAL,
f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
g be PartFunc of [:[:REAL,REAL:],REAL:],REAL,
Gzx be PartFunc of REAL,REAL
st [:[:I,J:],K:] = dom f & f is_continuous_on [:[:I,J:],K:] & f = g
& Gzx = Integral1(L-Meas,Integral2(L-Meas,R_EAL g)| [:I,J:])|J
holds
dom Gzx = J
& Gzx is continuous
& Gzx|| J is bounded & Gzx is_integrable_on J
& Integral1(L-Meas,Integral2(L-Meas,R_EAL g)| [:I,J:])| J
is_integrable_on L-Meas
& Integral(L-Meas,Integral1(L-Meas,Integral2(L-Meas,R_EAL g)| [:I,J:])| J)
= integral(Gzx,J)
& Integral(Prod_Measure(L-Meas,L-Meas),Integral2(L-Meas,R_EAL g)| [:I,J:])
= integral(Gzx,J)
proof
let I,J,K be non empty closed_interval Subset of REAL;
let f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real;
let g be PartFunc of [:[:REAL,REAL:],REAL:],REAL;
let Gzx be PartFunc of REAL,REAL;
assume that
A1: [:[:I,J:],K:] = dom f and
A2: f is_continuous_on [:[:I,J:],K:] and
A3: f = g and
A4: Gzx = Integral1(L-Meas,Integral2(L-Meas,R_EAL g)| [:I,J:])|J;
A5: dom Integral2(L-Meas,R_EAL g) = [:REAL,REAL:] by FUNCT_2:def 1;
reconsider Gz = Integral2(L-Meas,R_EAL g)| [:I,J:]
as PartFunc of [:REAL,REAL:],REAL by A1,A2,A3,Th32;
reconsider Fz = Gz as PartFunc of [:RNS_Real,RNS_Real:],RNS_Real;
A6: Fz is_uniformly_continuous_on [:I,J:] by A1,A2,A3,Th34; then
A7: Fz is_continuous_on [:I,J:] by NFCONT_2:7;
A8: Gzx = Integral1(L-Meas,R_EAL Gz)|J by A4,MESFUNC5:def 7;
A9: dom(Integral1(L-Meas,R_EAL Gz)) = REAL by FUNCT_2:def 1;
hence
A10:dom Gzx = J by A8; then
A11:Gzx||J is bounded & Gzx is_integrable_on J
& Integral(Prod_Measure(L-Meas,L-Meas),R_EAL Gz) = integral(Gzx,J)
by A7,A5,A8,MESFUN16:56,59,INTEGRA5:10,11;
thus
Gzx is continuous by A6,A5,A8,NFCONT_2:7,MESFUN16:56;
hence Gzx||J is bounded & Gzx is_integrable_on J by A9,A8,INTEGRA5:10,11;
I in L-Field & J in L-Field by MEASUR10:5,MEASUR12:75; then
Gzx is_integrable_on L-Meas & Integral(L-Meas,Gzx|J) = integral(Gzx,J)
by A10,A11,MESFUN14:49;
hence
Integral1(L-Meas,Integral2(L-Meas,R_EAL g)| [:I,J:])|J
is_integrable_on L-Meas
& Integral(L-Meas,Integral1(L-Meas,Integral2(L-Meas,R_EAL g)| [:I,J:])|J)
= integral(Gzx,J) by A4,MESFUNC5:def 7;
thus
Integral(Prod_Measure(L-Meas,L-Meas),Integral2(L-Meas,R_EAL g)| [:I,J:])
= integral(Gzx,J) by A11,MESFUNC5:def 7;
end;