:: Surreal Numbers and Conway Names: A Formal Introduction to Their
:: Interrelations
:: by Karol P\kak
::
:: Received September 6, 2026
:: Copyright (c) 2026 Association of Mizar Users
:: (Stowarzyszenie Uzytkownikow Mizara, Bialystok, Poland).
:: This code can be distributed under the GNU General Public Licence
:: version 3.0 or later, or the Creative Commons Attribution-ShareAlike
:: License version 4.0 or later, subject to the binding interpretation
:: detailed in file COPYING.interpretation.
:: See COPYING.GPL and COPYING.CC-BY-SA for the full text of these
:: licenses, or see http://www.gnu.org/licenses/gpl.html and
:: http://creativecommons.org/licenses/by-sa/4.0/.
environ
vocabularies NUMBERS, NAT_1, XBOOLE_0, VECTSP_1, SUBSET_1, FUNCT_1, ARYTM_3,
XXREAL_0, TARSKI, CARD_1, FINSET_1, ORDINAL1, RELAT_1, SETWISEO, BINOP_1,
STRUCT_0, GROUP_1, ARYTM_1, FINSUB_1, INT_1, CARD_3, ORDINAL4, ZFMISC_1,
AFINSQ_1, SERIES_1, FINSEQ_4, VALUED_1, ORDINAL3, RFINSEQ, ARROW,
ZFREFLE1, GLIB_000, WAYBEL_3, SURREAL0, XREAL_0, COMPLEX1, SURREALN,
SURREALC, SURREALO, MEMBER_1, WELLORD1, MATHMORP, REAL_1, NEWTON,
ORDINAL2, GROUP_9, VALUED_0, ORDERS_5, PROB_1, RELAT_2, ORDERS_2,
WELLFND1, WELLORD2, YELLOW_0, AOFA_I00, BINOP_2, SURREAL1;
notations TARSKI, XBOOLE_0, SUBSET_1, ZFMISC_1, RELAT_1, FUNCT_1, FINSUB_1,
RELSET_1, FINSET_1, FUNCT_2, BINOP_1, SETWISEO, ORDINAL1, NUMBERS,
XCMPLX_0, XXREAL_0, BINOP_2, INT_1, ORDINAL2, ORDINAL3, ORDINAL4,
ORDINAL5, ORDINAL7, SURREAL0, SURREALO, SURREALR, SURREALI, SURREALN,
SURREALC, XREAL_0, NEWTON, NAT_1, AFINSQ_1, STRUCT_0, WELLORD1, ORDERS_2,
RELAT_2, WELLFND1, WELLORD2, YELLOW_0, VALUED_0, VALUED_1, WAYBEL_0;
constructors RELSET_1, SETWISEO, AFINSQ_1, BINOP_2, NEWTON, ORDINAL3,
ORDINAL7, SURREALR, SURREALI, SURREALC, REALSET1, WAYBEL_0, WELLFND1,
TOLER_1;
registrations XBOOLE_0, RELAT_1, FUNCT_1, SUBSET_1, ORDINAL1, FUNCT_2,
FINSET_1, NUMBERS, FINSUB_1, XXREAL_0, XREAL_0, NAT_1, STRUCT_0,
VALUED_1, CARD_1, RELSET_1, INT_1, XTUPLE_0, SURREAL0, SURREALO,
SURREALR, SURREALC, SURREALN, NEWTON, XCMPLX_0, RAT_1, MEMBERED,
ORDINAL3, AFINSQ_1, VALUED_0, WELLORD1, WELLORD2, WELLFND1, ORDERS_2,
ORDINAL5, AFINSQ_2, SURREALI, BINOP_2, POLYNOM9;
requirements ARITHM, NUMERALS, REAL, BOOLE, SUBSET;
definitions TARSKI, RELAT_2, FUNCT_1, SURREALC, SURREAL0, SURREALO;
equalities ORDINAL1, SURREAL0, SURREALR;
expansions TARSKI, XBOOLE_0, SURREAL0, SURREALO, SURREALI;
theorems TARSKI, FUNCT_2, NAT_1, FUNCT_1, SETWISEO, ZFMISC_1, SETWOP_2,
FINSUB_1, RELAT_1, XBOOLE_0, XBOOLE_1, XREAL_1, ORDINAL1, CARD_1,
WELLORD2, XXREAL_0, XTUPLE_0, BINOP_2, XREAL_0, ORDINAL5, ORDINAL4,
ORDINAL3, ORDINAL2, SURREAL0, SURREALO, SURREALR, SURREALI, SURREALN,
SURREALC, XCMPLX_1, WELLORD1, YELLOW_0, ORDERS_1, ORDERS_2, VALUED_0,
BAGORDER, FINSET_1, TOPMETR4, WAYBEL_0, RELSET_1, AFINSQ_1, ORDINAL7,
WELLFND1, RELAT_2, VALUED_1, PCOMPS_2, FUNCT_3, BINOP_1, VALUED_2;
schemes NAT_1, SETWISEO, SURREALC, ORDINAL1, RECDEF_1, CLASSES1, RELSET_1,
FUNCT_3;
begin :: Transfinite Shifting of a Sequence
reserve A,B,C for Ordinal,
f,g for Sequence;
theorem Th1:
f^{} = f
proof
reconsider E={} as Sequence;
dom E=0;
then
A1: dom (f^{}) = (dom f) +^ 0 = dom f by ORDINAL2:27,ORDINAL4:def 1;
for x being object st x in dom f holds f.x = (f^E).x by ORDINAL4:def 1;
hence thesis by A1,FUNCT_1:2;
end;
theorem Th2:
A c= dom f implies (f^g) | A = f|A
proof
assume
A1: A c= dom f;
dom (f^g) = (dom f)+^(dom g) by ORDINAL4:def 1;
then dom f c= dom (f^g) by ORDINAL3:24;
then A c= dom (f^g) by A1;
then
A2:dom ((f^g) |A) = A = dom (f|A) by A1,RELAT_1:62;
for x being object st x in A holds ((f^g) | A).x = (f|A).x
proof
let x be object such that
A3: x in A;
thus ((f^g) | A).x = (f^g).x by A3,FUNCT_1:49
.= f.x by A1,A3,ORDINAL4:def 1
.= (f|A).x by A3,FUNCT_1:49;
end;
hence thesis by A2,FUNCT_1:2;
end;
theorem Th3:
A c= B implies B = A+^(B-^A)
proof
assume A1: A c= B;
per cases;
suppose A2:A=B;
then B-^A = 0 by ORDINAL3:54;
hence thesis by A2,ORDINAL2:27;
end;
suppose A<>B;
then A c< B by A1;
hence thesis by ORDINAL1:11,ORDINAL3:51;
end;
end;
theorem
dom f c= A implies (f^g) | A = f ^ (g | (A-^dom f))
proof
assume
A1: dom f c= A;
per cases;
suppose
A2: A c= dom (f^g);
then
A3: dom ((f^g) |A) = A by RELAT_1:62;
set B=A-^dom f;
A4: dom (f^g) = (dom f)+^(dom g) by ORDINAL4:def 1;
B c= dom (f^g) -^dom f = dom g by A4,A2,ORDINAL3:52,59;
then
A5: dom (g | B) = B by RELAT_1:62;
then
A6: dom (f ^ (g|B)) = (dom f) +^ B = A by A1,ORDINAL4:def 1,Th3;
for x being object st x in A holds ((f^g) | A).x = (f ^ (g | (A-^dom f))).x
proof
let x be object such that
A7: x in A;
reconsider X=x as Ordinal by A7;
A8: ((f^g) | A).x = (f^g).x by A7,FUNCT_1:49;
per cases;
suppose x in dom f;
then (f^g).x = f.x = (f ^ (g | (A-^dom f))).x by ORDINAL4:def 1;
hence thesis by A7,FUNCT_1:49;
end;
suppose not x in dom f;
then
A9: dom f c= X by ORDINAL1:16;
then X-^dom f in B & (dom f)+^(X-^dom f) = x by A7,ORDINAL3:53,Th3;
then
A10: (f ^ (g | B)).x = (g|B).(X-^dom f) = g.(X-^dom f)
by FUNCT_1:49,A5,ORDINAL4:def 1;
X-^dom f in dom (f^g)-^dom f = dom g &
dom f+^ (X-^dom f) = X by A9,A4,A2,A7,Th3,ORDINAL3:52,53;
hence thesis by A8,A10,ORDINAL4:def 1;
end;
end;
hence thesis by A3,A6,FUNCT_1:2;
end;
suppose
A11:dom (f^g) c= A;
then
A12:(f^g) |A = f^g by RELAT_1:68;
dom (f^g) = (dom f)+^(dom g) by ORDINAL4:def 1;
then dom g= (dom f)+^(dom g) -^ dom f c= A-^dom f by A11,ORDINAL3:52,59;
hence thesis by A12,RELAT_1:68;
end;
end;
theorem Th5:
for g1,g2 being Sequence st f^g1 = f^g2 holds g1=g2
proof
let g1,g2 be Sequence such that
A1:f^g1 = f^g2;
dom (f^g2) = (dom f)+^(dom g2) &
dom (f^g1) = (dom f)+^(dom g1) by ORDINAL4:def 1;
then
A2:dom g1 = (dom f)+^(dom g2)-^(dom f) by A1,ORDINAL3:52
.= dom g2 by ORDINAL3:52;
for x being object st x in dom g1 holds g1.x = g2.x
proof
let x be object such that
A3: x in dom g1;
reconsider X=x as Ordinal by A3;
thus g1.x = (f^g1).(dom f+^X) by A3,ORDINAL4:def 1
.= g2.x by A1,A2,A3,ORDINAL4:def 1;
end;
hence thesis by A2,FUNCT_1:2;
end;
definition
let f be Sequence;
let A be Ordinal;
func f /^ A -> Sequence means :Def1:
dom it = (dom f) -^ A & f = (f|A)^it;
existence
proof
set B = (dom f) -^ A;
per cases;
suppose A c= dom f;
then dom f = A +^ B by ORDINAL3:def 5;
then consider S1,S2 be Sequence such that
A1: f = S1^S2 & dom S1 = A & dom S2 = B by ORDINAL5:2;
take S2;
f|dom S1 = S1|dom S1 by A1,Th2;
hence thesis by A1;
end;
suppose
A2: not A c= dom f;
take g={};
f^g=f by Th1;
hence thesis by RELAT_1:68,A2,ORDINAL3:def 5;
end;
end;
uniqueness by Th5;
end;
theorem Th6:
dom (f/^A) c= dom f
proof
0 c= A;
then dom (f/^A) = (dom f) -^ A c= (dom f) -^ 0 by Def1,ORDINAL3:58;
hence thesis by ORDINAL3:56;
end;
theorem Th7:
A c= B implies
f.B = (f/^A).(B-^A) &
(B in dom f iff B-^A in dom (f/^A))
proof
assume A1: A c= B;
A2:f = (f|A)^(f/^A) by Def1;
A3:B in dom f iff B-^A in dom (f/^A)
proof
hereby assume B in dom f;
then B-^A in dom f -^ A by A1,ORDINAL3:53;
hence B-^A in dom (f/^A) by Def1;
end;
assume B-^A in dom (f/^A);
then B-^A in (dom f) -^ A & not B-^A in B-^A by Def1;
then not (dom f) -^ A c= B-^A;
hence B in dom f by ORDINAL1:16,ORDINAL3:59;
end;
f.B = (f/^A).(B-^A)
proof
per cases;
suppose
A4: B in dom f;
then A in dom f by A1,ORDINAL1:12;
then A c= dom f by ORDINAL1:12;
then dom (f|A) = A by RELAT_1:62;
then f.(A+^(B-^A)) = (f/^A).(B-^A) by A2,A3,A4,ORDINAL4:def 1;
hence thesis by A1,Th3;
end;
suppose not B in dom f;
then f.B = {} = (f/^A).(B-^A) by A3,FUNCT_1:def 2;
hence thesis;
end;
end;
hence thesis by A3;
end;
theorem Th8:
f.(A+^B) = (f/^A).B & ((A+^B) in dom f iff B in dom (f/^A))
proof
A1:A c= A+^B by ORDINAL3:24;
A+^B-^A=B by ORDINAL3:52;
hence thesis by A1,Th7;
end;
registration
let D be set;
let f be Sequence of D;
let A be Ordinal;
cluster f/^A -> D-valued;
coherence
proof
f = (f|A)^(f/^A) by Def1;
then rng (f/^A) c= rng f c= D by ORDINAL4:40;
then rng (f/^A) c= D;
hence thesis by RELAT_1:def 19;
end;
end;
theorem Th9:
succ A c= dom f implies (f|succ A) /^ A = <%f.A%>
proof
assume
A1:succ A c= dom f;
set fsA = f|succ A;
dom fsA = succ A by A1,RELAT_1:62;
then
A2:dom (fsA/^A) = succ A -^ A by Def1
.= A+^1 -^A by ORDINAL2:31
.= 1 by ORDINAL3:52;
A+^0 = A by ORDINAL2:27;
then (fsA/^A).0 = fsA.A by Th8
.= f.A by ORDINAL1:6,FUNCT_1:49;
hence thesis by A2,AFINSQ_1:def 4;
end;
begin :: Preliminaries on Monotone Sequences in Well-Founded Structures
theorem Th10:
for R being RelStr
for X being Subset of R holds
X is well_founded iff subrelstr X is well_founded
proof
let R be RelStr;
let X be Subset of R;
set S = subrelstr X;
set I = the InternalRel of R,
I2 = I |_2 X;
A1: the carrier of S = X by YELLOW_0:def 15;
then
A2:the InternalRel of S = I2 by YELLOW_0:def 14;
hereby assume
A3: X is well_founded;
for Y being set st Y c= X & Y <> {} ex a being object
st a in Y & I2-Seg a misses Y
proof
let Y be set such that
A4: Y c= X & Y <> {};
consider a be object such that
A5: a in Y & I-Seg a misses Y by A4,A3,WELLFND1:def 3,
WELLORD1:def 3;
I2-Seg a misses Y by A5,XBOOLE_1:63,WELLORD1:14;
hence thesis by A5;
end;
hence S is well_founded by A2,A1,WELLFND1:def 2,WELLORD1:def 3;
end;
assume
A6:S is well_founded;
for Y being set st Y c= X & Y <> {} ex a being object
st a in Y & I-Seg a misses Y
proof
let Y be set such that
A7: Y c= X & Y <> {};
consider a be object such that
A8: a in Y & I2-Seg a misses Y
by A7,A6,A2,A1,WELLFND1:def 2,WELLORD1:def 3;
take a;
thus a in Y by A8;
assume I-Seg a meets Y;
then consider b be object such that
A9: b in I-Seg a & b in Y by XBOOLE_0:3;
A10:b <>a & [b,a] in I by A9,WELLORD1:1;
[b,a] in [:X,X:] by A8,A7,A9,ZFMISC_1:87;
then [b,a] in I/\[:X,X:] by A10,XBOOLE_0:def 4;
then [b,a] in I2 by WELLORD1:def 6;
then b in I2-Seg a by A10,WELLORD1:1;
hence thesis by A8,A9,XBOOLE_0:3;
end;
hence thesis by WELLFND1:def 3,WELLORD1:def 3;
end;
theorem Th11:
for R being RelStr holds {}R is well_founded
proof
let R be RelStr;
set I = the InternalRel of R;
for Y being set st Y c= {}R & Y <> {}
ex a being object st a in Y & I-Seg a misses Y;
hence thesis by WELLFND1:def 3,WELLORD1:def 3;
end;
theorem Th12:
for R being non empty RelStr
for X being Subset of R holds
X is well_founded iff not ex f being sequence of R st
rng f c= X & f is descending
proof
let R be non empty RelStr;
let X be Subset of R;
per cases;
suppose X = {};
then X = {}R;
hence thesis by Th11;
end;
suppose
A1: X <> {};
set S = subrelstr X;
set I = the InternalRel of R,
I2 = I |_2 X;
A2: the carrier of S = X by YELLOW_0:def 15;
then
A3: the InternalRel of S = I2 by YELLOW_0:def 14;
hereby assume X is well_founded;
then
A4: S is well_founded by Th10;
given f be sequence of R such that
A5: rng f c= X & f is descending;
A6: dom f = NAT by FUNCT_2:def 1;
then reconsider F=f as sequence of S by A2,A5,FUNCT_2:2;
A7: S is non empty by A1,YELLOW_0:def 15;
for n being Nat holds F.(n+1) <> F.n &
[F.(n+1), F.n] in I2
proof
let n be Nat;
thus F.(n+1) <> F.n by A5,WELLFND1:def 6;
A8: [f.(n+1), f.n] in I by A5,WELLFND1:def 6;
n in NAT & n+1 in NAT by ORDINAL1:def 12;
then f.n in rng f & f.(n+1) in rng f by A6,FUNCT_1:def 3;
then [f.(n+1), f.n] in [:X,X:] by A5,ZFMISC_1:87;
then [F.(n+1), F.n] in I /\ [:X,X:] by A8,XBOOLE_0:def 4;
hence thesis by WELLORD1:def 6;
end;
hence contradiction by A7,A4,A3,WELLFND1:def 6,14;
end;
assume
A9:not ex f being sequence of R st
rng f c= X & f is descending;
assume not X is well_founded;
then not S is well_founded by Th10;
then consider f be sequence of S such that
A10: f is descending by A1,A2,WELLFND1:14;
A11: rng f c= X by A2;
A12: rng f c= the carrier of R by A2,XBOOLE_1:1;
dom f = NAT by A1,A2,FUNCT_2:def 1;
then reconsider F=f as sequence of R by A12,FUNCT_2:2;
for n being Nat holds F.(n+1) <> F.n &
[F.(n+1), F.n] in I
proof
let n be Nat;
thus F.(n+1) <> F.n by A10,WELLFND1:def 6;
[f.(n+1), f.n] in I2 by A3,A10,WELLFND1:def 6;
then [f.(n+1), f.n] in I /\ [:X,X:] by WELLORD1:def 6;
hence thesis by XBOOLE_0:def 4;
end;
hence thesis by A9,A11,WELLFND1:def 6;
end;
end;
theorem Th13:
for R being non empty antisymmetric transitive RelStr
for f being sequence of R st f is descending
for s being subsequence of f holds s is descending
proof
let R be non empty antisymmetric transitive RelStr;
let f be sequence of R such that A1: f is descending;
let s be subsequence of f;
for n being Nat holds s.(n+1) <> s.n &
[s.(n+1), s.n] in the InternalRel of R
proof
let n be Nat;
set n1=n+1;
consider N be increasing sequence of NAT such that
A2: s = f * N by VALUED_0:def 17;
A3: dom N = NAT by FUNCT_2:def 1;
A4: n in NAT by ORDINAL1:def 12;
A5: s.n = f.(N.n) & s.n1 = f.(N.n1) by A2,ORDINAL1:def 12,FUNCT_2:15;
n < n1 by NAT_1:13;
then N.n < N.n1 by A4,A3,VALUED_0:def 13;
hence thesis by A5,A1,BAGORDER:8;
end;
hence thesis by WELLFND1:def 6;
end;
registration
let R be non empty antisymmetric transitive RelStr;
cluster descending -> one-to-one for sequence of R;
coherence
proof
let S be sequence of R;
assume
A1: S is descending;
for x1,x2 being object st
x1 in dom S & x2 in dom S & S.x1=S.x2 holds x1=x2
proof
let x1,x2 be object such that
A2: x1 in dom S & x2 in dom S & S.x1=S.x2 & x1<>x2;
reconsider x1,x2 as Nat by A2;
x1 < x2 or x2 < x1 by A2,XXREAL_0:1;
hence thesis by A2,A1,BAGORDER:8;
end;
hence thesis by FUNCT_1:def 4;
end;
end;
theorem Th14:
for R being non empty RelStr
for f being sequence of R
for X being Subset of R st X/\rng f is infinite
ex s being subsequence of f st rng s c= X
proof
let R be non empty RelStr;
let f be sequence of R;
let X be Subset of R such that
A1: X/\rng f is infinite;
f"(X/\rng f) is infinite by A1,FINSET_1:9,XBOOLE_1:17;
then consider N be increasing sequence of NAT such that
A2: rng N c= f"(X/\rng f) by TOPMETR4:2;
reconsider fN=f*N as subsequence of f;
rng fN = f.:(rng N) c= f.: f"(X/\rng f) c= X/\rng f
by A2,RELAT_1:127,123,FUNCT_1:75;
then rng fN c= X/\rng f c= X by XBOOLE_1:17;
then rng fN c= X;
hence thesis;
end;
theorem Th15:
for R being RelStr
for X,Y being Subset of R st X c= Y & Y is well_founded
holds X is well_founded
proof
let R be RelStr;
let X,Y be Subset of R such that A1:
X c= Y & Y is well_founded;
assume
A2:not X is well_founded;
then X <>{}R by Th11;
then
A3:R is non empty;
then consider f be sequence of R such that
A4:rng f c= X & f is descending by A2,Th12;
rng f c= Y by A1,A4;
hence thesis by A3,A4,A1,Th12;
end;
theorem Th16:
for R being antisymmetric transitive RelStr
for X being Subset of R st X is finite
holds X is well_founded
proof
let R be antisymmetric transitive RelStr;
let X be Subset of R such that A1:X is finite;
assume A2:not X is well_founded;
then X <>{}R by Th11;
then A3:R is non empty;
then consider f be sequence of R such that
A4:rng f c= X & f is descending by A2,Th12;
dom f = NAT by A3,FUNCT_2:def 1;
hence thesis by A4,A1,A3,CARD_1:59;
end;
theorem Th17:
for R being antisymmetric transitive RelStr
for X,Y being well_founded Subset of R holds X\/Y is well_founded
proof
let R be antisymmetric transitive RelStr;
let X,Y be well_founded Subset of R;
assume A1:not X\/Y is well_founded;
then reconsider Rn=R as non empty antisymmetric transitive RelStr;
reconsider X,Y as well_founded Subset of Rn;
consider f be sequence of Rn such that
A2:rng f c= X\/Y & f is descending by A1,Th12;
rng f/\ (X\/Y)=rng f by A2,XBOOLE_1:28;
then A3: (rng f /\X) \/(rng f /\Y) = rng f by XBOOLE_1:23;
dom f=NAT by FUNCT_2:def 1;
then per cases by A3,A2,CARD_1:59;
suppose rng f /\X is infinite;
then consider s be subsequence of f such that
A4:rng s c= X by Th14;
s is descending by A2,Th13;
hence thesis by A4,Th12;
end;
suppose rng f /\Y is infinite;
then consider s be subsequence of f such that
A5:rng s c= Y by Th14;
s is descending by A2,Th13;
hence thesis by A5,Th12;
end;
end;
definition
let R be non empty RelStr, s be sequence of R;
attr s is non-descending means
for n being Nat holds [s.n,s.(n+1)] in the InternalRel of R;
end;
theorem Th18:
for R being non empty transitive RelStr, f being sequence of R
st f is non-descending holds for i,j being Nat st i<j
holds [f.i,f.j] in the InternalRel of R
proof
let R be non empty transitive RelStr, f be sequence of R such that
A1: f is non-descending;
set I = the InternalRel of R,
CR = the carrier of R;
defpred P[Nat] means for i being Nat st i < $1
holds [f.i, f.$1] in I;
A2: P[ 0 ];
A3: for j being Nat st P[j] holds P[j+1]
proof
let j be Nat such that
A4: P[j];
let i be Nat;
assume i < j+1;
then i <=j by NAT_1:13;
then per cases by XXREAL_0:1;
suppose i = j;
hence [f.i, f.(j+1)] in I by A1;
end;
suppose i < j;
then
A5: [f.i, f.j] in I by A4;
[f.j, f.(j+1)] in I by A1;
hence [f.i,f.(j+1)] in I by ORDERS_2:def 3,A5,RELAT_2:def 8;
end;
end;
for j being Nat holds P[j] from NAT_1:sch 2(A2,A3);
hence thesis;
end;
theorem Th19:
for R being non empty reflexive RelStr,
f being sequence of R st R is connected
for X being Subset of R st rng f c= X & X is well_founded
ex s being subsequence of f st s is non-descending
proof
let R be non empty reflexive RelStr, f be sequence of R such that
A1:R is connected;
let X be Subset of R such that A2: rng f c= X & X is well_founded;
set I=the InternalRel of R;
consider m be object such that
A3: m in rng f & I-Seg m misses rng f by A2,WELLFND1:def 3,WELLORD1:def 3;
reconsider m as Element of R by A3;
consider a be object such that
A4: a in dom f & f.a = m by A3,FUNCT_1:def 3;
A5: dom f = NAT by FUNCT_2:def 1;
reconsider a as Nat by A4;
defpred P[Nat,set,set] means
for i being Nat st i = $2 holds $3 is Nat &
for j being Nat st j=$3 holds
i < j & f.j in rng (f^\(i+1)) &
I-Seg (f.j) misses rng (f^\(i+1));
A6:for n being Nat for x being set ex y being set st P[n,x,y ]
proof
let n be Nat, x be set;
per cases;
suppose
A7: not x is Nat;
take a;
thus thesis by A7;
end;
suppose x is Nat;
then reconsider i=x as Nat;
set i1=i+1;
rng (f^\i1) c= rng f by NAT_1:55;
then rng (f^\i1) c= X by A2;
then consider a be object such that
A8: a in rng (f^\i1) & I-Seg a misses rng (f^\i1)
by A2,WELLFND1:def 3,WELLORD1:def 3;
consider j be object such that
A9: j in dom (f^\i1) & (f^\i1).j =a by A8,FUNCT_1:def 3;
reconsider j as Nat by A9;
take J=j+i1;
let X be Nat such that
A10: X = x;
thus J is Nat;
let j1 be Nat such that
A11: j1=J;
i1 <= J by NAT_1:11;
hence thesis by A8,A10,A11,A9,NAT_1:13,def 3;
end;
end;
consider N be Function such that
A12:dom N = NAT & N.0 = a and
A13:for n being Nat holds P[n,N.n,N.(n+1)] from RECDEF_1:sch 1(A6);
defpred P[Nat] means N.$1 is Nat;
A14: P[0] by A12;
A15: for j being Nat st P[j] holds P[j+1] by A13;
A16:for j being Nat holds P[j] from NAT_1:sch 2(A14,A15);
rng N c= NAT
proof
let b be object such that
A17:b in rng N;
consider a be object such that
A18:a in dom N & N.a=b by A17,FUNCT_1:def 3;
reconsider a as Nat by A12,A18;
N.a is Nat by A16;
hence thesis by A18,ORDINAL1:def 12;
end;
then reconsider N as sequence of NAT by A12,FUNCT_2:2;
for n being Nat holds N.n < N.(n+1) by A13;
then reconsider N as increasing sequence of NAT
by VALUED_1:def 13;
reconsider fN=f*N as subsequence of f;
take fN;
defpred R[Nat] means [fN.$1,fN.($1+1)] in I &
I-Seg (fN.($1+1)) misses rng (f^\((N.$1)+1));
A20:R[0]
proof
A21: fN.0 = m & fN.1 = f.(N.1) by A4,A12,FUNCT_2:15;
A22: f.(N.1) in rng f by A5,FUNCT_1:def 3;
reconsider fN1=fN.1 as Element of R;
not fN1 in I-Seg m by A21,A22,A3,XBOOLE_0:3;
then per cases by WELLORD1:1;
suppose m = fN1;
hence thesis by A13,A21,ORDERS_2:def 2,RELAT_2:def 1;
end;
suppose not [fN1,m] in I;
then not fN1 <=m by ORDERS_2:def 5;
then m <= fN1 by A1,WAYBEL_0:def 29;
hence thesis by A13,A21,ORDERS_2:def 5;
end;
end;
A23: for n being Nat st R[n] holds R[n+1]
proof
let n be Nat such that
A24: R[n];
set n1=n+1,
n2=n1+1;
A25: fN.n1 = f.(N.n1) & fN.n2 = f.(N.n2) by FUNCT_2:15;
reconsider fN1=fN.n1, fN2=fN.n2 as Element of R;
N.n < N.n1 by A13;
then reconsider K=(N.n1)-N.n as Nat by NAT_1:21;
(N.n1)+1 = (N.n)+1 +K;
then f^\((N.n1)+1) = f^\((N.n)+1) ^\ K by NAT_1:48;
then
A26: rng (f^\((N.n1)+1)) c= rng (f^\((N.n)+1)) by NAT_1:55;
A27: fN2 in rng (f^\((N.n1)+1)) by A25,A13;
not fN2 in I-Seg fN1 by A24,A26,A27,XBOOLE_0:3;
then per cases by WELLORD1:1;
suppose fN1 = fN2;
hence thesis by A25,A13,ORDERS_2:def 2,RELAT_2:def 1;
end;
suppose not [fN2,fN1] in I;
then not fN2 <=fN1 by ORDERS_2:def 5;
then fN1 <= fN2 by A1,WAYBEL_0:def 29;
hence thesis by A25,A13,ORDERS_2:def 5;
end;
end;
for n being Nat holds R[n] from NAT_1:sch 2(A20,A23);
hence thesis;
end;
theorem Th20:
for R being non empty transitive RelStr
for f being sequence of R st f is non-descending
for s being subsequence of f
holds s is non-descending
proof
let R be non empty transitive RelStr;
let f be sequence of R such that
A1: f is non-descending;
let s be subsequence of f;
for n being Nat holds [s.n,s.(n+1)] in the InternalRel of R
proof
let n be Nat;
set n1=n+1;
consider N be increasing sequence of NAT such that
A2: s = f * N by VALUED_0:def 17;
A3: dom N = NAT by FUNCT_2:def 1;
A4: n in NAT & n in NAT by ORDINAL1:def 12;
A5: s.n = f.(N.n) & s.n1 = f.(N.n1) by ORDINAL1:def 12,A2,FUNCT_2:15;
n < n1 by NAT_1:13;
hence thesis by A5,A1,A4,A3,VALUED_0:def 13,Th18;
end;
hence thesis;
end;
definition
let R be Relation, s be Sequence of field R;
attr s is increasing means
for A,B being Ordinal st A in B in dom s holds
s.A <> s.B & [s.A,s.B] in R;
end;
registration
let R be Relation;
cluster increasing -> one-to-one for Sequence of field R;
coherence
proof
let s be Sequence of field R;
assume
A1: s is increasing;
let x1,x2 be object such that
A2: x1 in dom s & x2 in dom s and
A3: s.x1=s.x2 & x1<>x2;
reconsider x1,x2 as Ordinal by A2;
x1 in x2 or x2 in x1 by A3,ORDINAL1:14;
hence contradiction by A2,A1,A3;
end;
end;
theorem Th21:
for R being Relation, X being set st X = field (R|_2 X)
holds
(R|_2 X is reflexive implies R is_reflexive_in X) &
(R|_2 X is connected implies R is_connected_in X) &
(R|_2 X is well_founded implies R is_well_founded_in X)
proof
let R be Relation, X be set such that
A1:X = field (R|_2 X);
set R2=R|_2 X;
A2: R2 = R/\[:X,X:] by WELLORD1:def 6;
hereby assume
A3:R2 is reflexive;
now let x be object;
assume x in X;
then [x,x] in R2 by A1,A3,RELAT_2:def 9,RELAT_2:def 1;
hence [x,x] in R by A2,XBOOLE_0:def 4;
end;
hence R is_reflexive_in X by RELAT_2:def 1;
end;
hereby
assume
A4: R2 is connected;
now let x,y be object such that
A5: x in X & y in X & x <>y;
[x,y] in R2 or [y,x] in R2 by A5,A1,A4,RELAT_2:def 14,RELAT_2:def 6;
hence [x,y] in R or [y,x] in R by A2,XBOOLE_0:def 4;
end;
hence R is_connected_in X by RELAT_2:def 6;
end;
assume
A6:R2 is well_founded;
for Y being set st Y c= X & Y <> {} ex a being object st
a in Y & R-Seg a misses Y
proof
let Y be set such that
A7: Y c= X & Y <> {};
consider a be object such that
A8: a in Y & R2-Seg a misses Y by A6,A7,A1,WELLORD1:3,def 3;
take a;
thus a in Y by A8;
assume R-Seg a meets Y;
then consider b be object such that
A9: b in R-Seg a & b in Y by XBOOLE_0:3;
A10:b <> a & [b,a] in R by A9,WELLORD1:1;
[b,a] in [:X,X:] by A7,A8,A9,ZFMISC_1:87;
then [b,a] in R2 by A2,A10,XBOOLE_0:def 4;
then b in R2-Seg a by A10,WELLORD1:1;
hence contradiction by A8,A9,XBOOLE_0:3;
end;
hence thesis by WELLORD1:def 3;
end;
theorem Th22:
for R being Relation, X being set holds
(R|_2 X is transitive implies R is_transitive_in X) &
(R|_2 X is antisymmetric implies R is_antisymmetric_in X)
proof
let R be Relation, X be set;
set R2=R|_2 X;
A1: R2 = R/\[:X,X:] by WELLORD1:def 6;
hereby assume
A2:R2 is transitive;
now let x,y,z be object;
assume
A3: x in X & y in X & z in X & [x,y] in R & [y,z] in R;
then [x,y] in [:X,X:] & [y,z] in [:X,X:] by ZFMISC_1:87;
then
A4: [x,y] in R2 & [y,z] in R2 by A3,A1,XBOOLE_0:def 4;
then x in field R2 & y in field R2 & z in field R2 by RELAT_1:15;
then [x,z] in R2 by A4,A2,RELAT_2:def 16,def 8;
hence [x,z] in R by A1,XBOOLE_0:def 4;
end;
hence R is_transitive_in X by RELAT_2:def 8;
end;
assume
A5:R2 is antisymmetric;
now let x,y be object;
assume
A6: x in X & y in X & [x,y] in R & [y,x] in R;
then [x,y] in [:X,X:] & [y,x] in [:X,X:] by ZFMISC_1:87;
then
A7: [x,y] in R2 & [y,x] in R2 by A6,A1,XBOOLE_0:def 4;
then x in field R2 & y in field R2 by RELAT_1:15;
hence x=y by A7,A5, RELAT_2:def 12,def 4;
end;
hence R is_antisymmetric_in X by RELAT_2:def 4;
end;
theorem Th23:
for R being Relation
for X being Subset of field R st
R|_2 X is_reflexive_in X &
R|_2 X is_antisymmetric_in X
for s being Sequence of field R st rng s = X & s is increasing
holds s is_isomorphism_of RelIncl dom s,R|_2 X
proof
let R be Relation;
let X be Subset of field R;
set R2=R|_2 X;
assume
A1:R2 is_reflexive_in X & R2 is_antisymmetric_in X;
A2: X c= field R2
proof
let a be object;
assume a in X;
then [a,a] in R2 by A1,RELAT_2:def 1;
hence thesis by RELAT_1:15;
end;
let s be Sequence of field R such that
A3: rng s = X & s is increasing;
set O = dom s,
RO=RelIncl O;
A4: field RO = dom s by WELLORD2:def 1;
A5: dom s = field RO by WELLORD2:def 1;
A6: rng s = field R2 by A3,A2,WELLORD1:13;
for a,b being object holds
[a,b] in RO iff a in field RO & b in field RO & [s.a,s.b] in R2
proof
let a,b be object;
thus [a,b] in RO implies a in field RO & b in field RO & [s.a,s.b] in R2
proof
assume
A7: [a,b] in RO;
hence
A8: a in field RO & b in field RO by RELAT_1:15;
reconsider a,b as Ordinal by A8,A4;
per cases by A8,A7,A4,WELLORD2:def 1;
suppose
A9: a = b;
s.a in rng s by A5,A8,FUNCT_1:def 3;
hence thesis by A9,A3,A1,RELAT_2:def 1;
end;
suppose a c< b;
then a in b by ORDINAL1:11;
then
A10: [s.a,s.b] in R by A3,A5,A8;
s.a in rng s & s.b in rng s by A5,A8,FUNCT_1:def 3;
then [s.a,s.b] in [:X,X:] by A3,ZFMISC_1:87;
then [s.a,s.b] in R/\[:X,X:] by A10,XBOOLE_0:def 4;
hence thesis by WELLORD1:def 6;
end;
end;
assume
A11: a in field RO & b in field RO &
[s.a,s.b] in R2 & not [a,b] in RO;
then reconsider a,b as Ordinal by A4;
not a c= b by A11,A5,WELLORD2:def 1;
then b in a by ORDINAL1:16;
then
A12:s.b<> s.a & [s.b,s.a] in R by A3,A11,A5;
A13:s.a in X & s.b in X by A3,A11,A5,FUNCT_1:def 3;
then [s.b,s.a] in [:X,X:] by ZFMISC_1:87;
then [s.b,s.a] in R/\[:X,X:] by A12,XBOOLE_0:def 4;
then [s.b,s.a] in R2 by WELLORD1:def 6;
hence thesis by A12,A11,A13,A1,RELAT_2:def 4;
end;
hence thesis by A5,A6,A3,WELLORD1:def 7;
end;
theorem Th24:
for R being Relation
for X being Subset of field R holds
R well_orders X iff
R|_2 X is_reflexive_in X & R|_2 X is_antisymmetric_in X
& ex s being Sequence of field R st rng s = X & s is increasing
proof
let R be Relation;
let X be Subset of field R;
set R2=R|_2 X;
thus R well_orders X implies R2 is_reflexive_in X & R2 is_antisymmetric_in X
& ex s being Sequence of field R st rng s = X & s is increasing
proof
set O=order_type_of R2,
RO=RelIncl O;
assume R well_orders X;
then
A1:R2 well_orders X & X = field R2 by PCOMPS_2:1;
then R2 is well-ordering by WELLORD1:4;
then R2,RO are_isomorphic by WELLORD2:def 2;
then consider f be Function such that
A2: f is_isomorphism_of RO,R2 by WELLORD1:40,def 8;
field RO=O & rng f = X by A2,A1,WELLORD1:def 7,WELLORD2:def 1;
then
A3:dom f = O & rng f c= field R by A2,WELLORD1:def 7;
then reconsider f as Sequence of field R by RELAT_1:def 19,ORDINAL1:def 7;
reconsider f as Sequence of field R;
thus R2 is_reflexive_in X & R2 is_antisymmetric_in X
by A1,WELLORD1:def 5;
take f;
thus rng f = X by A2,A1,WELLORD1:def 7;
let A,B be Ordinal such that
A4: A in B in dom f;
A5: A c= B by A4,ORDINAL1:def 2;
A6: A in dom f by A4,ORDINAL1:10;
then [A,B] in RO by A4,A3,A5,WELLORD2:def 1;
then
A7: [f.A,f.B] in R2=R/\[:X,X:] by A2, WELLORD1:def 6,def 7;
A8: f is one-to-one by A2,WELLORD1:def 7;
A<>B by A4;
hence thesis by A7,A6,A4,A8,FUNCT_1:def 4,XBOOLE_0:def 4;
end;
assume
A9:R2 is_reflexive_in X & R2 is_antisymmetric_in X;
X c= field R2
proof
let a be object;
assume a in X;
then [a,a] in R2 by A9,RELAT_2:def 1;
hence thesis by RELAT_1:15;
end;
then
A10: X = field R2 by WELLORD1:13;
given s be Sequence of field R such that
A11: rng s = X & s is increasing;
set O = dom s,
RO=RelIncl O;
A12: s is_isomorphism_of RO,R2 by A11,Th23,A9;
R2 is well-ordering by A12,WELLORD1:44;
then R is_reflexive_in X & R is_transitive_in X &
R is_antisymmetric_in X & R is_connected_in X &
R is_well_founded_in X by A10,Th21,Th22;
hence R well_orders X by WELLORD1:def 5;
end;
theorem Th25:
for R being Relation
for X being Subset of field R st
R|_2 X is_reflexive_in X &
R|_2 X is_antisymmetric_in X
for s,t being Sequence of field R st
rng s = X = rng t & s is increasing & t is increasing
holds s = t
proof
let R be Relation;
let X be Subset of field R such that
A1: R|_2 X is_reflexive_in X & R|_2 X is_antisymmetric_in X;
let s,t be Sequence of field R such that
A2: rng s = X = rng t & s is increasing & t is increasing;
A3:s is_isomorphism_of RelIncl dom s,R|_2 X &
t is_isomorphism_of RelIncl dom t,R|_2 X by A1,A2,Th23;
RelIncl dom s,R|_2 X are_isomorphic & RelIncl dom t,R|_2 X are_isomorphic
by A1,A2,Th23,WELLORD1:def 8;
then R|_2 X,RelIncl dom s are_isomorphic &
R|_2 X,RelIncl dom t are_isomorphic by WELLORD1:40;
then dom t=dom s by WELLORD2:11;
hence thesis by A3,WELLORD1:45;
end;
definition
let R be RelStr;
let A be Subset of R;
attr A is well-ordering means
the InternalRel of R well_orders A;
end;
registration
let R be RelStr;
cluster {}R -> well-ordering;
coherence
proof
set I = the InternalRel of R;
A1:I is_reflexive_in {}
proof
let x be object;
thus thesis;
end;
A2: I is_transitive_in {}
proof
let x,y,z be object;
thus thesis;
end;
A3: I is_antisymmetric_in {}
proof
let x,y be object;
thus thesis;
end;
A4: I is_connected_in {}
proof
let x,y be object;
thus thesis;
end;
{}R is well_founded by Th11;
hence thesis by A1,A2,A3,A4,WELLORD1:def 5,WELLFND1:def 3;
end;
end;
theorem Th26:
for R being RelStr
for X,Y being Subset of R st X c= Y & Y is well-ordering
holds X is well-ordering
proof
let R be RelStr;
let X,Y be Subset of R such that
A1: X c= Y & Y is well-ordering;
set I=the InternalRel of R;
A2: I is_reflexive_in Y & I is_transitive_in Y
& I is_antisymmetric_in Y & I is_connected_in Y & I is_well_founded_in Y
by A1,WELLORD1:def 5;
then X is well_founded by A1,Th15,WELLFND1:def 3;
then I is_reflexive_in X & I is_transitive_in X
& I is_antisymmetric_in X & I is_connected_in X & I is_well_founded_in X
by A2,A1,ORDERS_1:8,9,10,76,WELLFND1:def 3;
hence thesis by WELLORD1:def 5;
end;
theorem Th27:
for X being Subset of A
ex s being Ordinal-Sequence st s is increasing & rng s = X
proof
let X be Subset of A;
consider B be Ordinal such that
A1: RelIncl X,RelIncl B are_isomorphic by WELLORD2:8,13;
consider F be Function such that
A2: F is_isomorphism_of RelIncl B,RelIncl X
by A1,WELLORD1:40,def 8;
field RelIncl B = B by WELLORD2:def 1;
then
A3:dom F= B by A2,WELLORD1:def 7;
then reconsider F as Sequence by ORDINAL1:def 7;
A4:rng F = field RelIncl X = X by A2,WELLORD2:def 1,WELLORD1:def 7;
then reconsider F as Ordinal-Sequence by ORDINAL2:def 4;
take F;
now let a,b be Ordinal such that
A5:a in b in dom F;
A6:a c= b by A5,ORDINAL1:10;
A7:a in dom F by A5,ORDINAL1:10;
then
A8:[a,b] in RelIncl B by A3,A5,A6,WELLORD2:def 1;
A9:F.a in X & F.b in X by A4,A5,A7,FUNCT_1:def 3;
a<>b by A5;
then [F.a,F.b] in RelIncl X & F.a<>F.b by A8,A2,WELLORD1:36;
then F.a c< F.b by A9,WELLORD2:def 1;
hence F.a in F.b by A9,ORDINAL1:11;
end;
hence thesis by A4,ORDINAL2:def 12;
end;
begin :: Selected Properties of Operators on Sequences of Surreal Numbers
reserve s,x,x1,x2,y,y1,y2,z for Surreal,
r,r1,r2,e for Real,
S,T for surreal-membered set;
theorem Th28:
x1 == x2 & y1 == y2 implies x1-y1 == x2-y2
proof
assume
A1: x1==x2 & y1==y2;
-y1==-y2 by A1,SURREALR:65;
hence thesis by A1,SURREALR:66;
end;
theorem Th29:
x1 == x2 & y1 == y2 implies x1 * y1 == x2 * y2
proof
assume x1==x2 & y1==y2;
then x1 * y1 == x2 * y1 == x2 * y2 by SURREALR:54;
hence thesis by SURREALO:4;
end;
Lm1: s + uReal.(r+e)* z == s + uReal.r*z + uReal.e * z
proof
uReal.(r+e)* z == (uReal.r + uReal.e) * z ==
uReal.(r)*z + uReal.e * z by SURREALN:55,SURREALR:54,67;
then uReal.(r+e)* z ==
uReal.(r)*z + uReal.e * z by SURREALO:9;
then s + uReal.(r+e)* z == s + (uReal.(r)*z + uReal.e * z )
by SURREALR:43;
hence thesis by SURREALR:37;
end;
theorem Th30:
s + uReal.(r+e)* z == s + uReal.r*z + uReal.e * z &
s + uReal.(r-e)* z == s + uReal.r*z - uReal.e * z
proof
thus s + uReal.(r+e)* z == s + uReal.r*z + uReal.e * z by Lm1;
A1:s + uReal.(r+-e)* z == s + uReal.r*z + uReal.(-e) * z by Lm1;
z*uReal.(-e) == z* (- uReal.e) = - z * uReal.e
by SURREALR:54,58,SURREALN:56;
then s + uReal.r*z + uReal.(-e) * z ==
s + uReal.r*z + - uReal.e * z by SURREALR:43;
hence thesis by A1,SURREALO:10;
end;
Lm2: -x <= |.x.|
proof
-x <= |.-x.| == |.x.| by SURREALC:34,40;
hence thesis by SURREALO:9;
end;
theorem Th31:
0_No <= x infinitely< y implies |.uReal.r* x.| infinitely< y
proof
assume
A1: 0_No <= x infinitely< y;
per cases;
suppose
A2: r >0;
then uReal.r >= 0_No by SURREALN:47,51;
then uReal.r* x >= 0_No * x by A1,SURREALR:75;
then |.uReal.r* x.| = uReal.r* x by SURREALC:def 6;
hence thesis by A1,A2,SURREALC:13;
end;
suppose
A3: r <0;
then uReal.-r >= 0_No by SURREALN:47,51;
then uReal.(-r)* x >= 0_No * x by A1,SURREALR:75;
then |.uReal.(-r)* x.| = uReal.(-r)* x by SURREALC:def 6;
then
A4: |.uReal.(-r)* x.| infinitely< y by A1,A3,SURREALC:13;
uReal.(-r)* x == (- uReal.(r))*x by SURREALR:54,SURREALN:56;
then uReal.(-r)* x == - (uReal.(r)* x) by SURREALR:58;
then |.uReal.(-r)* x.| == |.-(uReal.(r)* x).| ==
|.(uReal.(r)* x).| by SURREALC:40,48;
then |.uReal.(-r)* x.| == |.(uReal.(r)* x).| by SURREALO:9;
hence thesis by A4,SURREALC:17;
end;
suppose
A5: r=0;
0_No infinitely< y
proof
let e be positive Real;
thus thesis by A1,SURREALC:9,SURREALO:9;
end;
hence thesis by A5,SURREALN:47,SURREALC:def 6;
end;
end;
theorem Th32:
uReal.r1 - uReal.r2 == uReal.(r1-r2)
proof
- uReal.r2 == uReal.-r2 by SURREALN:56;
then uReal.(r1+-r2) == uReal.(r1)+uReal.(-r2) == uReal.(r1)+-uReal.(r2)
by SURREALN:55,SURREALR:43;
hence thesis by SURREALO:9;
end;
theorem Th33:
x*uReal.r == - x*uReal.(-r)
proof
(-x)* uReal.(- r) == (-x) *(- uReal.r) by SURREALN:56,SURREALR:54;
then (-x)* uReal.(- r) == x *uReal.r by SURREALR:58;
hence thesis by SURREALR:58;
end;
theorem Th34:
for X1,X2,Y1,Y2 being set st X1 c= X2 & Y1 c= Y2 holds
X1 ++ Y1 c= X2 ++ Y2
proof
let X1,X2,Y1,Y2 be set such that
A1: X1 c= X2 & Y1 c= Y2;
X2 = X1 \/(X2 \ X1) by A1,XBOOLE_1:45;
then X2 ++ Y1 = (X1 ++ Y1) \/ ((X2 \ X1) ++ Y1) by SURREALR:33;
then
A2: X1 ++ Y1 c= X2 ++ Y1 by XBOOLE_1:7;
Y2 = Y1 \/(Y2 \ Y1) by A1,XBOOLE_1:45;
then X2 ++ Y2 = (X2 ++ Y1) \/ (X2 ++ (Y2\Y1)) by SURREALR:33;
then X2 ++ Y1 c= X2 ++ Y2 by XBOOLE_1:7;
hence thesis by A2;
end;
definition
let o be object;
let f be surreal-valued Function;
assume A1:o in dom f;
func f .. o -> Surreal equals :Def5:
f.o;
coherence
proof
f.o in rng f by A1,FUNCT_1:def 3;
hence thesis by SURREAL0:def 16;
end;
end;
definition
let S be Surreal-Sequence;
redefine attr S is positive means :Def6: :: redefines positive (SURREALC, definition)
for A st A in dom S holds S .. A is positive;
compatibility
proof
hereby assume
A1: S is positive;
let A be Ordinal such that
A2: A in dom S;
S.A = S..A by A2,Def5;
hence S .. A is positive by A1,A2,SURREALC:def 15;
end;
assume
A3:for A st A in dom S holds S .. A is positive;
let A be Ordinal such that A4: A in dom S;
let sa be Surreal such that A5: sa = S.A;
S.A = S..A by A4,Def5;
hence thesis by A4,A5,A3;
end;
end;
definition
let S be Surreal-Sequence;
redefine attr S is decreasing_infinitely means :Def7: :: redefines decreasing_infinitely (SURREALC, definition)
for A,B st A in B in dom S holds
S..B infinitely< S..A;
compatibility
proof
hereby assume
A1: S is decreasing_infinitely;
let A,B be Ordinal such that
A2: A in B in dom S;
S..A = S.A & S..B=S.B by A2,Def5,ORDINAL1:10;
hence S..B infinitely< S..A by A2,A1,SURREALC:def 16;
end;
assume
A3: for A,B being Ordinal st A in B in dom S
holds S..B infinitely< S..A;
let A,B be Ordinal such that A4:A in B in dom S;
let sa,sb be Surreal such that A5: sa=S.A & sb=S.B;
S..A = S.A & S..B=S.B by A4,Def5,ORDINAL1:10;
hence thesis by A3,A4,A5;
end;
end;
registration
cluster decreasing_infinitely -> one-to-one for Surreal-Sequence;
coherence
proof
let S be Surreal-Sequence such that
A1:S is decreasing_infinitely;
let x1,x2 be object such that
A2:x1 in dom S & x2 in dom S & S.x1=S.x2 & x1<>x2;
reconsider x1,x2 as Ordinal by A2;
A3: S.x1 = S..x1 & S.x2 = S..x2 by A2,Def5;
per cases by A2,ORDINAL1:14;
suppose x1 in x2;
then S..x1 < S..x1 by A1,A2,A3,SURREALC:9;
hence thesis by SURREALO:3;
end;
suppose x2 in x1;
then S..x1 infinitely< S..x2 by A1,A2;
hence thesis by A2,A3,SURREALC:9,SURREALO:3;
end;
end;
end;
registration
let f be Surreal-Sequence;
let A be Ordinal;
cluster f/^A -> surreal-valued;
coherence
proof
let o be object;
assume o in rng (f/^A);
then consider B be object such that
A1: B in dom (f/^A) & (f/^A).B = o by FUNCT_1:def 3;
reconsider B as Ordinal by A1;
A+^B in dom f & o = f.(A+^B) by A1,Th8;
then o in rng f by FUNCT_1:def 3;
hence thesis by SURREAL0:def 16;
end;
end;
theorem Th35:
for f being Surreal-Sequence st A c= B in dom f holds
f..B = (f/^A) .. (B-^A)
proof
let f be Surreal-Sequence such that
A1: A c= B in dom f;
A2: B-^A in dom (f/^A) by A1,Th7;
f..B = f.B = (f/^A).(B-^A) by A1,Def5,Th7;
hence thesis by A2,Def5;
end;
theorem Th36:
for f being Surreal-Sequence st A+^ B in dom f or B in dom (f/^A) holds
f..(A+^B) = (f/^A)..B
proof
let f be Surreal-Sequence such that
A1: A+^ B in dom f or B in dom (f/^A);
A2: B in dom (f/^A) & A+^ B in dom f by A1,Th8;
then f..(A+^ B) = f.(A+^ B) = (f/^A).B by Def5,Th8;
hence thesis by A2,Def5;
end;
registration
let f be positive Surreal-Sequence;
let A be Ordinal;
cluster f /^ A -> positive;
coherence
proof
let B be Ordinal;
assume
A1: B in dom (f /^ A);
then A+^B in dom f by Th8;
then f..(A+^B) is positive by Def6;
hence thesis by A1,Th36;
end;
end;
registration
let f be decreasing_infinitely Surreal-Sequence;
let A be Ordinal;
cluster f/^A -> decreasing_infinitely;
coherence
proof
let B,C be Ordinal such that
A1: B in C in dom (f/^A);
B in dom (f/^A) by A1,ORDINAL1:10;
then
A2: f..(A+^B) = (f/^A)..B & f..(A+^C) = (f/^A)..C by A1,Th36;
(A+^C) in dom f by A1,Th8;
hence thesis by A2,Def7,A1,ORDINAL2:32;
end;
end;
definition
let S be surreal-membered set;
func Unique_No S -> uniq-surreal-membered set means :Def8:
for x holds
x in it iff ex y st y in S & x = Unique_No y;
existence
proof
consider M be Ordinal such that
A1: for o being object st o in S
ex A being Ordinal st A in M & o in Day A by SURREAL0:47;
set U = {x where x is Element of Day M: ex y being Surreal st
y in S & x= Unique_No y};
now let a be object;
assume a in U;
then ex x be Element of Day M st a=x & ex y being Surreal st
y in S & x= Unique_No y;
hence a is uSurreal;
end;
then reconsider U as uniq-surreal-membered set by SURREALO:def 12;
take U;
let x be Surreal;
thus x in U implies ex y being Surreal st y in S & x = Unique_No y
proof
assume x in U;
then ex a be Element of Day M st x=a & ex y being Surreal st
y in S & a= Unique_No y;
hence thesis;
end;
given y be Surreal such that
A2: y in S & x = Unique_No y;
consider A be Ordinal such that
A3: A in M & y in Day A by A2,A1;
A4: born y c= A by A3,SURREAL0:def 18;
A5: born x = born_eq x by A2,SURREALO:48;
x == y by A2,SURREALO:def 10;
then born_eq x c= born y by SURREALO:def 5;
then born x c= A by A4,A5;
then born x c= M by A3,ORDINAL1:10;
then x in Day born x c= Day M by SURREAL0:35,SURREAL0:def 18;
hence thesis by A2;
end;
uniqueness
proof
let U1,U2 be uniq-surreal-membered set such that
A6: for x being Surreal holds
x in U1 iff ex y being Surreal st y in S & x = Unique_No y
and
A7: for x being Surreal holds
x in U2 iff ex y being Surreal st y in S & x = Unique_No y;
A8: U1 c= U2
proof
let x be object;
assume
A9: x in U1;
then reconsider s=x as Surreal by SURREAL0:def 16;
ex y being Surreal st y in S & s = Unique_No y by A9,A6;
hence thesis by A7;
end;
U2 c= U1
proof
let x be object;
assume A10:x in U2;
then reconsider s=x as Surreal by SURREAL0:def 16;
ex y being Surreal st y in S & s = Unique_No y by A10,A7;
hence thesis by A6;
end;
hence thesis by A8;
end;
end;
definition
let s be Surreal-Sequence;
func Unique_No s -> uSurreal-Sequence means :Def9:
dom it = dom s &
for A st A in dom s holds it.A = Unique_No s..A;
existence
proof
defpred P[object,object] means $2 = Unique_No s..$1;
A1: for e being object st e in dom s ex u being object st P[e,u];
consider IT be Function such that
A2: dom IT = dom s &
for e being object st e in dom s holds P[e,IT.e] from CLASSES1:sch 1(A1);
for o being object st o in rng IT holds o is uSurreal
proof
let o be object such that
A3: o in rng IT;
consider x be object such that
A4: x in dom IT & IT.x = o by A3,FUNCT_1:def 3;
IT.x = Unique_No s..x by A2,A4;
hence thesis by A4;
end;
then rng IT is uniq-surreal-membered;
then reconsider IT as uSurreal-Sequence
by A2,SURREALC:def 10,ORDINAL1:def 7;
take IT;
thus thesis by A2;
end;
uniqueness
proof
let U1,U2 be uSurreal-Sequence such that
A5: dom U1 = dom s &
for O being Ordinal st O in dom s holds U1.O = Unique_No s..O and
A6: dom U2 = dom s &
for O being Ordinal st O in dom s holds U2.O = Unique_No s..O;
for x being object st x in dom s holds U1.x = U2.x
proof
let x be object such that
A7: x in dom s;
U1.x = Unique_No s..x by A5,A7;
hence thesis by A6,A7;
end;
hence thesis by A5,A6,FUNCT_1:2;
end;
end;
theorem Th37:
for s being Surreal-Sequence holds Unique_No rng s = rng Unique_No s
proof
let s be Surreal-Sequence;
set U = Unique_No s;
A1:Unique_No rng s c= rng U
proof
let x be object such that
A2: x in Unique_No rng s;
reconsider a=x as Surreal by A2,SURREAL0:def 16;
consider b be Surreal such that
A3: b in rng s & Unique_No b = a by A2,Def8;
consider c be object such that
A4: c in dom s & s.c = b by A3,FUNCT_1:def 3;
reconsider c as Ordinal by A4;
s..c = s.c by A4,Def5;
then
U.c = a & c in dom U by A3,A4,Def9;
hence thesis by FUNCT_1:def 3;
end;
rng U c= Unique_No rng s
proof
let x be object such that
A5: x in rng U;
consider a be object such that
A6: a in dom U & U.a = x by A5,FUNCT_1:def 3;
reconsider a as Ordinal by A6;
a in dom s by A6,Def9;
then U.a = Unique_No s..a & s..a = s.a & s.a in rng s
by Def9,Def5,FUNCT_1:def 3;
hence thesis by A6,Def8;
end;
hence thesis by A1;
end;
theorem Th38:
Unique_No (S++T) = Unique_No ((Unique_No S)++(Unique_No T))
proof
set US = Unique_No S,UT=Unique_No T;
A1:Unique_No (S++T) c= Unique_No (US++UT)
proof
let u be object;
assume
A2: u in Unique_No (S++T);
then reconsider U=u as uSurreal by SURREALO:def 12;
consider y be Surreal such that
A3: y in S++T & U = Unique_No y by A2,Def8;
consider a,b be Surreal such that
A4: a in S & b in T & y = a+b by A3,SURREALR:def 8;
a == Unique_No a & b == Unique_No b by SURREALO:def 10;
then U == y == (Unique_No a) + (Unique_No b)
by A3,A4,SURREALR:43,SURREALO:def 10;
then U == (Unique_No a) + (Unique_No b) ==
Unique_No ((Unique_No a) + (Unique_No b)) by SURREALO:def 10,4;
then U == Unique_No ((Unique_No a) + (Unique_No b)) by SURREALO:4;
then
A5:U = Unique_No ((Unique_No a) + (Unique_No b)) by SURREALO:50;
Unique_No a in US & Unique_No b in UT by A4,Def8;
then (Unique_No a) + (Unique_No b) in US++UT by SURREALR:def 8;
hence thesis by A5,Def8;
end;
Unique_No (US++UT) c= Unique_No (S++T)
proof
let u be object;
assume
A6: u in Unique_No (US++UT);
then reconsider U=u as uSurreal by SURREALO:def 12;
consider y be Surreal such that
A7: y in US++UT & U = Unique_No y by A6,Def8;
consider Ua,Ub be Surreal such that
A8: Ua in US & Ub in UT & y = Ua+Ub by A7,SURREALR:def 8;
consider a be Surreal such that
A9: a in S & Ua = Unique_No a by A8,Def8;
consider b be Surreal such that
A10: b in T & Ub = Unique_No b by A8,Def8;
a+b in S++T by A9,A10,SURREALR:def 8;
then
A11: Unique_No(a+b) in Unique_No (S++T) by Def8;
a == Ua & b == Ub by A9,A10,SURREALO:def 10;
then Unique_No(a+b) == a+b == Ua+Ub by SURREALR:43,SURREALO:def 10;
then Unique_No(a+b) == y == U by A7,A8,SURREALO:4,def 10;
then Unique_No(a+b)== U by SURREALO:4;
hence thesis by A11,SURREALO:50;
end;
hence thesis by A1;
end;
theorem Th39:
Unique_No S = {} iff S = {}
proof
thus Unique_No S = {} implies S = {}
proof
assume
A1: Unique_No S = {} & S <> {};
then consider a be object such that
A2: a in S by XBOOLE_0:def 1;
reconsider a as Surreal by A2,SURREAL0:def 16;
Unique_No a in Unique_No S by A2,Def8;
hence thesis by A1;
end;
assume S={} & Unique_No S <> {};
then consider x be object such that
A3:x in Unique_No {} by XBOOLE_0:def 1;
reconsider x as Surreal by A3,SURREAL0:def 16;
ex y being Surreal st y in {} & x = Unique_No y by A3,Def8;
hence thesis;
end;
begin :: Well-Ordered Substructures of Surreal Numbers under the Reverse Order
definition
let X be surreal-membered set;
func RevSurrStr X -> strict RelStr means :Def10:
the carrier of it = X &
for a,b being Surreal st a in X & b in X holds
a <= b iff [b,a] in the InternalRel of it;
existence
proof
defpred P[object,object] means
for a,b being Surreal st a=$1 & b=$2 holds b <= a;
consider R be Relation of X such that
A1: for x,y being object
holds [x,y] in R iff x in X & y in X & P[x,y] from RELSET_1:sch 1;
take RS=RelStr(#X,R#);
thus the carrier of RS = X;
let a,b be Surreal such that A2:a in X & b in X;
hereby assume a <= b;
then P[b,a];
hence [b,a] in the InternalRel of RS by A1,A2;
end;
thus thesis by A1;
end;
uniqueness
proof
let R1,R2 be strict RelStr such that
A3: the carrier of R1 = X &
for a,b being Surreal st a in X & b in X holds
a <= b iff [b,a] in the InternalRel of R1
and
A4: the carrier of R2 = X &
for a,b being Surreal st a in X & b in X holds
a <= b iff [b,a] in the InternalRel of R2;
A5: the InternalRel of R1 c= the InternalRel of R2
proof
let x be object;
assume
A6: x in the InternalRel of R1;
then consider a,b be object such that
A7:a in X & b in X & x = [a,b] by A3,ZFMISC_1:def 2;
reconsider a,b as Surreal by A7,SURREAL0:def 16;
b <= a by A3,A7,A6;
hence thesis by A4,A7;
end;
the InternalRel of R2 c= the InternalRel of R1
proof
let x be object;
assume
A8:x in the InternalRel of R2;
then consider a,b be object such that
A9:a in X & b in X & x = [a,b] by A4,ZFMISC_1:def 2;
reconsider a,b as Surreal by A9,SURREAL0:def 16;
b <= a by A4,A9,A8;
hence thesis by A3,A9;
end;
then the InternalRel of R1 = the InternalRel of R2 by A5;
hence thesis by A3,A4;
end;
end;
registration
let X be surreal-membered set;
cluster RevSurrStr X -> reflexive transitive;
coherence
proof
set R = RevSurrStr X,
I = the InternalRel of R;
A1: the carrier of R = X by Def10;
for x being object st x in X holds [x,x] in I
proof
let x be object; assume
A2: x in X; then
reconsider x as Surreal by SURREAL0:def 16;
x <= x;
hence thesis by A2,Def10;
end;
hence R is reflexive by A1,RELAT_2:def 1,ORDERS_2:def 2;
for x,y,z being object st x in X & y in X & z in X &
[x,y] in I & [y,z] in I holds [x,z] in I
proof
let x,y,z be object such that
A3:x in X & y in X & z in X &
[x,y] in I & [y,z] in I;
reconsider x,y,z as Surreal by A3,SURREAL0:def 16;
z<= y<= x by A3,Def10;
then z<= x by SURREALO:9;
hence thesis by A3,Def10;
end;
hence R is transitive by A1,ORDERS_2:def 3,RELAT_2:def 8;
end;
end;
registration
let X be non empty surreal-membered set;
cluster RevSurrStr X -> non empty;
coherence by Def10;
end;
registration
let X be non empty surreal-membered set;
cluster RevSurrStr X -> connected;
coherence
proof
set R = RevSurrStr X,
I = the InternalRel of R;
for x,y being Element of R holds x <= y or y <= x
proof
let x,y be Element of R;
A1: the carrier of R=X by Def10;
then reconsider a=x,b=y as Surreal by SURREAL0:def 16;
a<=b or b <= a;
then [b,a] in I or [a,b] in I by A1,Def10;
hence thesis by ORDERS_2:def 5;
end;
hence thesis by WAYBEL_0:def 29;
end;
end;
definition
let X be surreal-membered set;
attr X is ==_distinct means :Def11:
x1 in X & x2 in X & x1==x2 implies x1=x2;
end;
registration
cluster -> ==_distinct for uniq-surreal-membered set;
coherence
proof
let X be uniq-surreal-membered set;
let a, b be Surreal such that A1:a in X & b in X & a==b;
a is uSurreal & b is uSurreal by A1,SURREALO:def 12;
hence thesis by A1,SURREALO:50;
end;
end;
registration
cluster non empty ==_distinct for surreal-membered set;
existence
proof
take {0_No};
thus thesis;
end;
end;
registration
let S be ==_distinct surreal-membered set;
cluster RevSurrStr S -> antisymmetric;
coherence
proof
set R = RevSurrStr S,
I = the InternalRel of R;
A1: the carrier of R = S by Def10;
for x,y being object st x in S & y in S & [x,y] in I & [y,x] in I
holds x=y
proof
let x,y be object such that
A2: x in S & y in S & [x,y] in I & [y,x] in I;
reconsider x,y as Surreal by A2,SURREAL0:def 16;
x==y by A2,Def10;
hence thesis by A2,Def11;
end;
hence R is antisymmetric by A1,ORDERS_2:def 4,RELAT_2:def 4;
end;
end;
definition
let S be surreal-membered set;
attr S is desc_ordering means :Def12:
ex y being strictly_decreasing Surreal-Sequence st rng y = S;
end;
registration
cluster desc_ordering -> ==_distinct for surreal-membered set;
coherence
proof
let X be surreal-membered set;
assume X is desc_ordering;
then consider s be strictly_decreasing Surreal-Sequence such that
A1: rng s = X;
let sa,sb be Surreal such that
A2: sa in X & sb in X & sa==sb & sa<>sb;
consider a be object such that
A3: a in dom s & s.a = sa by A1,A2,FUNCT_1:def 3;
consider b be object such that
A4: b in dom s & s.b = sb by A1,A2,FUNCT_1:def 3;
reconsider a,b as Ordinal by A3,A4;
a in b or b in a by A2,A3,A4,ORDINAL1:14;
hence thesis by A2,A3,A4,SURREALC:def 11;
end;
end;
registration
let S be ==_distinct surreal-membered set;
cluster -> ==_distinct for Subset of S;
coherence by Def11;
end;
theorem Th40:
for A being Subset of S holds
field ( (the InternalRel of RevSurrStr S) |_2 A) = A
proof
let A be Subset of S;
set R=RevSurrStr S,
I=the InternalRel of R;
A c= field (I |_2 A)
proof
let a be object;
assume
A1:a in A;
then reconsider x=a as Surreal by SURREAL0:def 16;
A2: [x,x] in I by A1,Def10;
[a,a] in [:A,A:] by A1,ZFMISC_1:87;
then [a,a] in I/\[:A,A:] by A2, XBOOLE_0:def 4;
then [a,a] in I |_2 A by WELLORD1:def 6;
hence thesis by RELAT_1:15;
end;
hence thesis by WELLORD1:13;
end;
registration
let S be surreal-membered set;
cluster -> surreal-membered for Subset of RevSurrStr S;
coherence
proof
let A be Subset of RevSurrStr S;
A c= the carrier of RevSurrStr S;
then A c= S by Def10;
hence thesis;
end;
end;
theorem Th41:
field (the InternalRel of RevSurrStr S) = S
proof
set I = the InternalRel of RevSurrStr S,
R=RevSurrStr S,
I=the InternalRel of R;
the carrier of R = S by Def10;
then
A1: field I c= S\/S by RELSET_1:8;
S c= field I
proof
let a be object;
assume
A2: a in S;
then reconsider x=a as Surreal by SURREAL0:def 16;
[x,x] in I by A2,Def10;
hence thesis by RELAT_1:15;
end;
hence thesis by A1;
end;
theorem Th42:
for s being Surreal-Sequence
for X being ==_distinct surreal-membered set st rng s c= X
holds s is Sequence of field the InternalRel of RevSurrStr X
& for t being Sequence of field the InternalRel of RevSurrStr X st
t = s holds s is strictly_decreasing iff t is increasing
proof
let s be Surreal-Sequence;
let X be ==_distinct surreal-membered set such that
A1: rng s c= X;
set R = RevSurrStr X,
I = the InternalRel of R;
field I = X by Th41;
hence s is Sequence of field I by A1,RELAT_1:def 19;
let t be Sequence of field I such that
A2: t=s;
thus s is strictly_decreasing implies t is increasing
proof
assume
A3:s is strictly_decreasing;
let A,B be Ordinal such that A4: A in B in dom t;
A in dom t by A4,ORDINAL1:10;
then
A5:s.A in rng s & s.B in rng s by A2,A4,FUNCT_1:def 3;
A6:s..A = s.A & s..B=s.B by A2,A4,ORDINAL1:10,Def5;
hence t.A <> t.B by A2,A3,A4,SURREALC:def 11,SURREALO:3;
s..B <= s..A by A6,A2,A3,A4,SURREALC:def 11;
hence [t.A,t.B] in I by A2,A5,A1,A6,Def10;
end;
assume
A7:t is increasing;
let A,B be Ordinal such that
A8:A in B in dom s;
let sa,sb be Surreal such that
A9: sa=s.A & sb=s.B & not sb < sa;
A in dom s by A8,ORDINAL1:10;
then
A10: s.A in rng s & s.B in rng s by A8,FUNCT_1:def 3;
sa<>sb & [sa,sb] in I by A7,A2,A8,A9;
then sb==sa by A1,A10,A9, Def10;
hence thesis by A1,A7,A2,A8,A9,A10,Def11;
end;
::$N Characterization of Well-Ordering via Strictly Descending Sequences
theorem Th43:
for S being ==_distinct surreal-membered set
for A being Subset of RevSurrStr S holds
A is desc_ordering iff A is well-ordering
proof
let S be ==_distinct surreal-membered set;
let A be Subset of RevSurrStr S;
set RS = RevSurrStr S, I = the InternalRel of RS;
A1: the carrier of RS=S by Def10;
A2: field I=S by Th41;
A3: field (I|_2 A) =A by A1,Th40;
thus A is desc_ordering implies A is well-ordering
proof
assume A is desc_ordering;
then consider s be strictly_decreasing Surreal-Sequence such that
A4: rng s = A;
reconsider t=s as Sequence of field the InternalRel of RS by A1,A4,Th42;
A5:t is increasing by A1,A4,Th42;
I |_2 A is_reflexive_in A & I |_2 A is_antisymmetric_in A
by WELLORD1:15,18,A3,RELAT_2:def 9,RELAT_2:def 12;
hence thesis by A4,A5,A1,A2,Th24;
end;
assume A is well-ordering;
then consider s be Sequence of field I such that
A6: rng s = A & s is increasing by A1,A2,Th24;
reconsider t=s as Surreal-Sequence by A6,SURREALC:def 9;
t is strictly_decreasing by A6,A1,Th42;
hence thesis by A6;
end;
registration
let s be strictly_decreasing Surreal-Sequence;
cluster rng s -> desc_ordering;
coherence;
end;
begin :: Descending Ordering Subsets of Surreal Numbers
registration
cluster non empty desc_ordering for uniq-surreal-membered set;
existence
proof
reconsider R=rng <%0_No%> as uniq-surreal-membered set;
take R;
thus thesis;
end;
end;
registration
cluster {} -> desc_ordering;
coherence
proof
reconsider X={} as ==_distinct surreal-membered set;
{}(RevSurrStr X) is well-ordering;
hence thesis by Th43;
end;
end;
theorem Th44:
for S being ==_distinct surreal-membered set
for A being Subset of RevSurrStr S st
A is well_founded holds A is well-ordering
proof
let S be ==_distinct surreal-membered set;
set R = RevSurrStr S,
I = the InternalRel of R;
let A be Subset of R such that
A1:A is well_founded;
A2:field I = S by Th41;
A3:the carrier of R=S by Def10;
I is_connected_in S
proof
let x,y be object such that
A4: x in S & y in S & x <>y;
reconsider a=x,b=y as Surreal by A4,SURREAL0:def 16;
a<=b or b <= a;
hence [x,y] in I or [y,x] in I by A4,Def10;
end;
then I is_reflexive_in A & I is_transitive_in A
& I is_antisymmetric_in A & I is_connected_in A
by A3,ORDERS_1:8,9,10,76,A2,RELAT_2:def 9,def 12,def 16;
hence thesis by A1,WELLFND1:def 3,WELLORD1:def 5;
end;
registration
let S be desc_ordering surreal-membered set;
cluster -> desc_ordering for Subset of S;
coherence
proof
let A be Subset of S;
set R=RevSurrStr S;
S = the carrier of R by Def10;
then reconsider RS=S,RA=A as Subset of R;
RS is well-ordering by Th43;
then RA is well-ordering by Th26;
hence thesis by Th43;
end;
end;
registration
let S be ==_distinct surreal-membered set;
cluster finite -> desc_ordering for Subset of S;
coherence
proof
set R = RevSurrStr S,
I = the InternalRel of R;
let A be Subset of S;
reconsider RA=A as Subset of R by Def10;
assume A is finite;
then RA is well-ordering by Th44,Th16;
hence thesis by Th43;
end;
end;
registration
let S be ==_distinct surreal-membered set;
cluster finite desc_ordering for Subset of S;
existence
proof
take IT=the finite Subset of S;
thus thesis;
end;
end;
::$N Union of Descending Orderings
registration
let S be ==_distinct surreal-membered set;
let A,B be desc_ordering Subset of S;
cluster A \/ B -> desc_ordering;
coherence
proof
set R = RevSurrStr S,
I = the InternalRel of R;
reconsider RA=A,RB=B as Subset of R by Def10;
RA is well-ordering & RB is well-ordering by Th43;
then I is_well_founded_in RA & I is_well_founded_in RB by WELLORD1:def 5;
then RA is well_founded & RB is well_founded by WELLFND1:def 3;
then RA\/RB is well-ordering by Th17,Th44;
hence thesis by Th43;
end;
end;
theorem Th45:
for s being Surreal-Sequence holds
s is strictly_decreasing iff Unique_No s is strictly_decreasing
proof
let s be Surreal-Sequence;
set U = Unique_No s;
A1:dom s = dom U by Def9;
thus s is strictly_decreasing implies U is strictly_decreasing
proof
assume
A2: s is strictly_decreasing;
let A,B be Ordinal such that
A3: A in B in dom U;
let sa,sb be Surreal such that
A4: sa=U.A & sb=U.B;
A5: s.A=s..A & s.B=s..B by A3,A1,ORDINAL1:10,Def5;
sa = Unique_No s..A & sb = Unique_No s..B
by A1,A4,A3,ORDINAL1:10,Def9;
then
A6:sa == s..A & sb==s..B by SURREALO:def 10;
then sb < s..A by A5,A1,A2,A3,SURREALC:def 11,SURREALO:9;
hence thesis by A6,SURREALO:9;
end;
assume
A7:U is strictly_decreasing;
let A,B be Ordinal such that
A8:A in B in dom s;
let sa,sb be Surreal such that
A9:sa=s.A & sb=s.B;
A10:U.A=U..A & U.B=U..B by A8,A1,Def5,ORDINAL1:10;
U..A = Unique_No s..A & U..B = Unique_No s..B & sa=s..A & sb=s..B
by A10,A9,A8,ORDINAL1:10,Def9,Def5;
then
A11:U..A == sa & U..B==sb by SURREALO:def 10;
then sb < U..A by A10,A1,A7,A8,SURREALC:def 11,SURREALO:9;
hence thesis by A11,SURREALO:9;
end;
registration
let z be strictly_decreasing Surreal-Sequence;
cluster Unique_No z -> strictly_decreasing;
coherence by Th45;
end;
theorem Th46:
for S being desc_ordering surreal-membered set holds
Unique_No S is desc_ordering
proof
let S be desc_ordering surreal-membered set;
consider y be strictly_decreasing Surreal-Sequence such that
A1: rng y = S by Def12;
rng (Unique_No y) is desc_ordering;
hence Unique_No S is desc_ordering by A1,Th37;
end;
::$N Closure of Descending Orderings under Addition
theorem Th47:
for S,T being desc_ordering surreal-membered set holds
Unique_No (S++T) is desc_ordering
proof
let S,T be desc_ordering surreal-membered set;
per cases;
suppose S={} or T={};
hence thesis by Th39,SURREALR:27;
end;
suppose
A1: S<>{} & T<>{};
set US=Unique_No S,
UT=Unique_No T;
US <>{} by A1,Th39;
then reconsider
U = US\/UT \/ Unique_No (US++UT)
as non empty uniq-surreal-membered set;
set R = RevSurrStr U,
I = the InternalRel of R;
A2: field I = U by Th41;
A3: the carrier of R=U by Def10;
A4: Unique_No (US++UT) = Unique_No (S++T) by Th38;
US c= US\/UT & UT c= US\/UT & US\/UT c= U by XBOOLE_1:7;
then reconsider RA=US,RB=UT,UR=Unique_No (US++UT) as Subset of R
by A3,XBOOLE_1:1,7;
set IU=I|_2 UR;
assume not Unique_No (S++T) is desc_ordering;
then
A5: not UR is well-ordering by A4,Th43;
not UR is well_founded
proof
A6: I is_connected_in UR
proof
let x,y be object such that
A7: x in UR & y in UR & x <>y;
reconsider a=x,b=y as Surreal by A7,SURREAL0:def 16;
a<=b or b <= a;
hence [x,y] in I or [y,x] in I by A3,A7,Def10;
end;
I is_reflexive_in UR & I is_transitive_in UR
& I is_antisymmetric_in UR & I is_connected_in UR
by A3,A6,A2,RELAT_2:def 9,def 12,def 16,ORDERS_1:8,9,10;
hence thesis by WELLFND1:def 3,A5,WELLORD1:def 5;
end;
then consider d be sequence of R such that
A8: rng d c= UR & d is descending by Th12;
A9: dom d = NAT by FUNCT_2:def 1;
rng d is surreal-membered;
then reconsider D=d as surreal-valued Function by SURREALC:def 9;
defpred P[object,object] means
$2 in US & for sa being Surreal st $2 = sa
ex sb being Surreal st sb in UT & D.$1 = Unique_No (sa + sb);
A10: for e being object st e in dom D ex u being object st P[e,u]
proof
let e be object such that
A11: e in dom D;
A12: d.e in rng d & D..e = D.e by Def5,A11,FUNCT_1:def 3;
then consider x be Surreal such that
A13: x in US++UT & D..e = Unique_No x by A8,Def8;
consider a,b be Surreal such that
A14: a in US & b in UT & x=a+b by A13,SURREALR:def 8;
take a;
thus thesis by A12,A13,A14;
end;
consider a be Function such that
A15:dom a = dom D &
for e being object st e in dom D holds P[e,a.e] from CLASSES1:sch 1(A10);
A16:rng a c= RA
proof
let y be object;
assume y in rng a;
then ex x be object st x in dom a & a.x = y by FUNCT_1:def 3;
hence thesis by A15;
end;
then reconsider a as sequence of R by XBOOLE_1:1,A9,A15,FUNCT_2:2;
reconsider Aa=a as surreal-valued Function by A16,SURREALC:def 9;
defpred Q[object,object] means
$2 in UT & for sb being Surreal st $2 = sb holds
D.$1 = Unique_No (Aa..$1 + sb);
A17: for e being object st e in dom D ex u being object st Q[e,u]
proof
let e be object such that
A18: e in dom D;
a.e = Aa..e by A18,A15,Def5;
then consider sb be Surreal such that
A19: sb in UT & D.e = Unique_No (Aa..e + sb) by A18,A15;
take sb;
thus thesis by A19;
end;
consider b be Function such that
A20:dom b = dom D &
for e being object st e in dom D holds Q[e,b.e] from CLASSES1:sch 1(A17);
A21:rng b c= RB
proof
let y be object;
assume y in rng b;
then ex x be object st x in dom b & b.x = y by FUNCT_1:def 3;
hence thesis by A20;
end;
then reconsider b as sequence of R by XBOOLE_1:1,A9,A20,FUNCT_2:2;
reconsider Bb=b as surreal-valued Function by A21,SURREALC:def 9;
RA is desc_ordering by Th46;
then RA is well-ordering by Th43;
then I is_well_founded_in RA by WELLORD1:def 5;
then consider sA be subsequence of a such that
A22: sA is non-descending by A16,Th19,WELLFND1:def 3;
consider NA be increasing sequence of NAT such that
A23: sA = a * NA by VALUED_0:def 17;
reconsider bN = b*NA as subsequence of b;
rng bN c= rng b by RELAT_1:26;
then
A24: rng bN c= RB by A21;
RB is desc_ordering by Th46;
then RB is well-ordering by Th43;
then I is_well_founded_in RB by WELLORD1:def 5;
then consider sB be subsequence of bN such that
A25: sB is non-descending by A24,Th19,WELLFND1:def 3;
consider NB be increasing sequence of NAT such that
A26:sB = bN * NB by VALUED_0:def 17;
reconsider sAN = sA*NB as subsequence of sA;
reconsider dNA = d*NA as subsequence of d;
reconsider dNANB = dNA*NB as subsequence of dNA;
reconsider d1 = dNANB.(0+1),d0 = dNANB.0 as uSurreal by A3,SURREALO:def 12;
dNA is descending by A8,Th13;
then
A27: dNANB is descending by Th13;
then
A28:d1<>d0 & [d1,d0] in I by WELLFND1:def 6;
reconsider sA1 = sAN.(0+1), sA0= sAN.0 as uSurreal by A3,SURREALO:def 12;
sAN is non-descending by A22,Th20;
then [sA0,sA1] in I;
then
A29: sA1 <= sA0 by A3,Def10;
reconsider sB1 = sB.(0+1), sB0= sB.0 as uSurreal by A3,SURREALO:def 12;
[sB0,sB1] in I by A25;
then
A30: sB1 <= sB0 by A3,Def10;
set N0=NA.(NB.0),
N1=NA.(NB.1);
A31: sA0 = sA.(NB.0) by FUNCT_2:15
.= a.N0 by A23,FUNCT_2:15;
A32: sA1 = sA.(NB.1) by FUNCT_2:15
.= a.N1 by A23,FUNCT_2:15;
A33: sB0 = bN.(NB.0) by A26,FUNCT_2:15
.= b.N0 by FUNCT_2:15;
A34: sB1 = bN.(NB.1) by A26,FUNCT_2:15
.= b.N1 by FUNCT_2:15;
A35: d0 = dNA.(NB.0) by FUNCT_2:15
.= d.N0 by FUNCT_2:15;
A36: d1 = dNA.(NB.1) by FUNCT_2:15
.= d.N1 by FUNCT_2:15;
sA1 = Aa..N1 & sA0 = Aa..N0 by A31,A32,A9,A15,Def5;
then d1 = Unique_No (sA1 + sB1) &
d0 = Unique_No (sA0 + sB0) by A33,A34,A35,A36,A9,A20;
then
A37: d1 == sA1 + sB1 <= sA0 + sB0 & d0 == sA0 + sB0
by A30,A29,SURREALO:def 10,SURREALR:43;
then d1 <= sA0 + sB0 by SURREALO:4;
then d1==d0 by A3,Def10,A28,A37,SURREALO:4;
hence thesis by A27,WELLFND1:def 6,SURREALO:50;
end;
end;
theorem Th48:
S c= T implies Unique_No S c= Unique_No T
proof
assume
A1:S c= T;
let x be object;
assume
A2:x in Unique_No S;
then reconsider s=x as uSurreal by SURREALO:def 12;
ex y be Surreal st y in S & s = Unique_No y by A2,Def8;
hence thesis by A1,Def8;
end;
definition
let S be surreal-membered set;
assume A1:S is desc_ordering;
func ord S -> strictly_decreasing Surreal-Sequence means :Def13:
rng it = S;
existence by A1;
uniqueness
proof
let S1,S2 be strictly_decreasing Surreal-Sequence such that
A2: rng S1 = S & rng S2=S;
set R=RevSurrStr S,
I=the InternalRel of R;
reconsider y1=S1,y2=S2 as Sequence of field I by A2,Th42;
A3: field I = S by Th41;
then reconsider YR=S as Subset of field I;
A4: I|_2 YR = I by A3, WELLORD1:23;
A5: I|_2 YR is_reflexive_in YR &
I|_2 YR is_antisymmetric_in YR by A1,A3,A4,RELAT_2:def 9,def 12;
y1 is increasing & y2 is increasing by A2,Th42;
hence thesis by A2,A5,Th25;
end;
end;
registration
cluster strictly_decreasing -> one-to-one for Surreal-Sequence;
coherence
proof
let S be Surreal-Sequence such that
A1: S is strictly_decreasing;
let x1,x2 be object such that
A2: x1 in dom S & x2 in dom S & S.x1=S.x2 & x1<>x2;
reconsider x1,x2 as Ordinal by A2;
A3: S.x1 = S..x1 & S.x2 = S..x2 by A2,Def5;
per cases by A2,ORDINAL1:14;
suppose x1 in x2;
hence thesis by A1,A2,A3,SURREALC:def 11,SURREALO:3;
end;
suppose x2 in x1;
hence thesis by A2,A3,A1,SURREALC:def 11,SURREALO:3;
end;
end;
end;
begin :: Representations for Particular Surreal Numbers
reserve e,e1,e2 for positive Real,
a,b,c for Surreal;
theorem Th49:
for r holds
[the set of all uReal.(r-e1),the set of all uReal.(r+e2)] is Surreal
proof
let r;
set Sl= the set of all uReal.(r-e1),
Sr = the set of all uReal.(r+e2);
now let o be object;
assume o in Sl;
then ex e1 st o = uReal.(r-e1);
hence o is surreal;
end;
then reconsider SL=Sl as surreal-membered set by SURREAL0:def 16;
now let o be object;
assume o in Sr;
then ex e2 st o = uReal.(r+e2);
hence o is surreal;
end;
then reconsider SR=Sr as surreal-membered set by SURREAL0:def 16;
consider M be Ordinal such that
A1: for o being object st o in SL\/SR ex A being Ordinal st A in M & o in Day A
by SURREAL0:47;
Sl << Sr
proof
let x,y be Surreal such that
A2: x in Sl & y in Sr;
consider e1 be positive Real such that
A3: x = uReal.(r-e1) by A2;
consider e2 be positive Real such that
A4: y = uReal.(r+e2) by A2;
r-e1 < r < r+e2 by XREAL_1:29,44;
then r-e1 < r+e2 by XXREAL_0:2;
hence thesis by A3,A4,SURREALN:51;
end;
then [SL,SR] in Day M by A1,SURREAL0:46;
hence thesis;
end;
theorem Th50:
for r holds
[{uReal.(r-e1): r-e1 >0},the set of all uReal.(r+e2)] is Surreal
proof
let r be Real;
set Sl= {uReal.(r-e1): r-e1 >0},
Sr = the set of all uReal.(r+e2);
now let o be object;
assume o in Sl;
then ex e1 st o = uReal.(r-e1) & r-e1 >0;
hence o is surreal;
end;
then reconsider SL=Sl as surreal-membered set by SURREAL0:def 16;
now let o be object;
assume o in Sr;
then ex e2 st o = uReal.(r+e2);
hence o is surreal;
end;
then reconsider SR=Sr as surreal-membered set by SURREAL0:def 16;
consider M be Ordinal such that
A1: for o being object st o in SL\/SR ex A being Ordinal st A in M
& o in Day A by SURREAL0:47;
Sl << Sr
proof
let x,y be Surreal such that
A2: x in Sl & y in Sr;
consider e1 be positive Real such that
A3: x = uReal.(r-e1) & r-e1 >0 by A2;
consider e2 be positive Real such that
A4: y = uReal.(r+e2) by A2;
r-e1 < r < r+e2 by XREAL_1:29,44;
then r-e1 < r+e2 by XXREAL_0:2;
hence thesis by A3,A4,SURREALN:51;
end;
then [SL,SR] in Day M by A1,SURREAL0:46;
hence thesis;
end;
theorem Th51:
for r,z st z > 0_No holds
[the set of all uReal.(r-e1)* z,the set of all uReal.(r+e2)* z] is Surreal
proof
let r be Real, a be Surreal such that
A1:a > 0_No;
set Sl=the set of all uReal.(r-e)* a where e is positive Real;
set Sr = the set of all uReal.(r+e)* a where e is positive Real;
now let o be object;
assume o in Sl;
then ex e being positive Real st o = uReal.(r-e)* a;
hence o is surreal;
end;
then reconsider Sl as surreal-membered set by SURREAL0:def 16;
now let o be object;
assume o in Sr;
then ex e being positive Real st o = uReal.(r+e)* a;
hence o is surreal;
end;
then reconsider Sr as surreal-membered set by SURREAL0:def 16;
consider M be Ordinal such that
A2: for o being object st o in Sl\/Sr ex A being Ordinal st A in M
& o in Day A by SURREAL0:47;
Sl << Sr
proof
let x,y be Surreal such that
A3: x in Sl & y in Sr;
consider e1 be positive Real such that
A4: x = uReal.(r-e1)* a by A3;
consider e2 be positive Real such that
A5: y = uReal.(r+e2)* a by A3;
A6: 0_No + x == 0_No + uReal.r*a - uReal.e1 * a by Th30,A4;
A7: 0_No + y == 0_No + uReal.r*a + uReal.e2 * a by Th30,A5;
- uReal.e1 == uReal.-e1 < uReal.e2 by SURREALN:56,51;
then - uReal.e1 < uReal.e2 by SURREALO:9;
then a * (- uReal.e1) < a * uReal.e2 by A1,SURREALR:70;
then - a * uReal.e1 < a * uReal.e2 by SURREALR:58;
then uReal.r*a+ - a * uReal.e1 < uReal.r*a+ a * uReal.e2 by SURREALR:44;
then uReal.r*a+ - a * uReal.e1 < y by A7,SURREALO:9;
hence x < y by A6,SURREALO:9;
end;
then [Sl,Sr] in Day M by A2,SURREAL0:46;
hence thesis;
end;
theorem Th52:
for s,z,r st z > 0_No holds
[the set of all s + uReal.(r-e1)* z,
the set of all s + uReal.(r+e2)* z] is Surreal
proof
let s, N be Surreal, r be Real such that
A1: N > 0_No;
set Sl=the set of all s + uReal.(r-e)* N where e is positive Real;
set Sr = the set of all s + uReal.(r+e)* N where e is positive Real;
now let o be object;
assume o in Sl;
then ex e being positive Real st o = s + uReal.(r-e)* N;
hence o is surreal;
end;
then reconsider Sl as surreal-membered set by SURREAL0:def 16;
now let o be object;
assume o in Sr;
then ex e being positive Real st o = s + uReal.(r+e)* N;
hence o is surreal;
end;
then reconsider Sr as surreal-membered set by SURREAL0:def 16;
consider M be Ordinal such that
A2: for o being object st o in Sl\/Sr ex A being Ordinal st A in M
& o in Day A by SURREAL0:47;
Sl << Sr
proof
let x,y be Surreal such that
A3: x in Sl & y in Sr;
consider e1 be positive Real such that
A4: x = s + uReal.(r-e1)* N by A3;
consider e2 be positive Real such that
A5: y = s + uReal.(r+e2)* N by A3;
A6: x == s + uReal.r*N - uReal.e1 * N by Th30,A4;
A7: y == s + uReal.r*N + uReal.e2 * N by Th30,A5;
- uReal.e1 == uReal.-e1 < uReal.e2 by SURREALN:56,51;
then - uReal.e1 < uReal.e2 by SURREALO:9;
then N * (- uReal.e1) < N * uReal.e2 by A1,SURREALR:70;
then - N * uReal.e1 < N * uReal.e2 by SURREALR:58;
then s + uReal.r*N+ - N * uReal.e1 < s + uReal.r*N+
N * uReal.e2 by SURREALR:44;
then s + uReal.r*N+ - N * uReal.e1 < y by A7,SURREALO:9;
hence x < y by A6,SURREALO:9;
end;
then [Sl,Sr] in Day M by A2,SURREAL0:46;
hence thesis;
end;
theorem Th53:
L_x << {y} << R_x implies
born Unique_No x c= born y &
(not x == y implies born Unique_No x in born y)
proof
assume
A1: L_x << {y} << R_x;
defpred P[Surreal] means L_x << {$1} << R_x;
A2: ex y be Surreal st P[y] by A1;
A3:for a,b,c be Surreal st a <= b <= c & P[a] & P[c] holds P[b]
by SURREALO:17,18;
consider s be uSurreal such that
A4: P[s] and
A5: for a be uSurreal st P[a] & a <> s holds born s in born a
from SURREALC:sch 1(A2,A3);
A6:Unique_No y == y by SURREALO:def 10;
then
A7:L_x << {Unique_No y} << R_x by A1,SURREALO:17,18;
for z be Surreal st L_x << {z} << R_x holds born s c= born z
proof
let z be Surreal such that
A8: L_x << {z} << R_x;
A9: z == Unique_No z by SURREALO:def 10;
then
A10:L_x << {Unique_No z} << R_x by A8,SURREALO:17,18;
born Unique_No z = born_eq Unique_No z by SURREALO:48;
then
A11:born Unique_No z c= born z by A9,SURREALO:def 5;
per cases;
suppose s == z;
then s == Unique_No z by A9,SURREALO:9;
hence thesis by A11,SURREALO:50;
end;
suppose not s == z;
then born s in born Unique_No z by A10,A5,A9;
hence thesis by A11,ORDINAL1:def 2;
end;
end;
then
A12:s == x == Unique_No x by A4,SURREALO:16,def 10;
then s == Unique_No x by SURREALO:9;
then
A13:s = Unique_No x by SURREALO:50;
A14:born s = born_eq s by SURREALO:48;
per cases;
suppose
A15:x == y;
then s == y by A12,SURREALO:9;
hence thesis by A15,A13,A14,SURREALO:def 5;
end;
suppose
A16: not x == y;
born Unique_No y = born_eq Unique_No y by SURREALO:48;
then
A17:born Unique_No y c= born y by A6,SURREALO:def 5;
y == Unique_No y by SURREALO:def 10;
then not x == Unique_No y by A16,SURREALO:9;
then born s in born Unique_No y by A7,A5,A12;
hence thesis by A13,A17,ORDINAL1:def 2;
end;
end;
theorem Th54:
for s,z,x,r st
x = [the set of all s + uReal.(r-e1)* z,
the set of all s + uReal.(r+e2)* z]
holds x is (s,z,r)_Term &
for u1,u2 being uSurreal st u1 == x & u1 <> u2 &
u2 is (s,z,r)_Term holds born u1 in born u2
proof
let s, N, x be Surreal, r be Real such that
A1:x = [(the set of all s + uReal.(r-e)* N where e is positive Real),
(the set of all s + uReal.(r+e)* N where e is positive Real)];
|. x - (s + uReal.r* N).| infinitely< N
proof
let t be positive Real;
set T = 1/t;
A2: s + uReal.(r+T)* N == s + uReal.r*N + uReal.T * N by Th30;
A3:x in {x} << R_x by TARSKI:def 1,SURREALO:11;
s + uReal.(r+T)* N in R_x by A1;
then x < s + uReal.r* N + uReal.T* N by A3,A2,SURREALO:9;
then
A4: x - (s + uReal.r* N) < uReal.T* N by SURREALR:41;
A5: s + uReal.(r-T)* N == s + uReal.r*N - uReal.T * N by Th30;
A6: x in {x} & L_x << {x} by TARSKI:def 1,SURREALO:11;
s + uReal.(r-T)* N in L_x by A1;
then x > s + uReal.r* N - uReal.T * N by A5,A6,SURREALO:9;
then x - (s + uReal.r* N) > - uReal.T* N = -(uReal.T* N) by SURREALR:42;
then
A7: |. x - (s + uReal.r * N).| < N*uReal.T by A4,SURREALC:52;
A8: 0_No < uReal.t by SURREALN:47,51;
T*t = 1 by XCMPLX_1:87;
then N*uReal.T*uReal.t == N*(uReal.T*uReal.t) == N*1_No
by SURREALR:54,69,SURREALN:57,48;
then
A9: N*uReal.T*uReal.t == N by SURREALO:9;
|. x - (s + uReal.r * N).|*uReal.t < N*uReal.T*uReal.t
by A8,A7,SURREALR:70;
hence thesis by A9,SURREALO:9;
end;
hence x is (s,N,r)_Term by SURREALC:def 14;
let u1,u2 be uSurreal such that
A10: u1 == x & u1 <> u2 & u2 is (s,N,r)_Term;
A11:not u1 == u2 by A10,SURREALO:50;
Unique_No x == x by SURREALO:def 10;
then Unique_No x == u1 by A10,SURREALO:9;
then
A12: Unique_No x = u1 by SURREALO:50;
A13: not x == u2 by A10,A11,SURREALO:9;
L_x << {u2} << R_x
proof
thus L_x << {u2}
proof
let l,r1 be Surreal such that
A14: l in L_x & r1 in {u2};
consider e be positive Real such that
A15: l = s + uReal.(r-e)* N by A1,A14;
set E = e;
r1 is (s,N,r)_Term by A10,A14,TARSKI:def 1;
then |. r1 - (s + uReal.r* N).| infinitely< N by SURREALC:def 14;
then |.r1 - (s + uReal.r* N).| infinitely< N *uReal.E
by SURREALC:13;
then |.r1 - (s + uReal.r* N).| < N *uReal.E by SURREALC:9;
then r1 - (s + uReal.r* N) > - N *uReal.E by SURREALC:52;
then
A16: r1 > (s + uReal.r* N) + - N *uReal.E by SURREALR:42;
s + uReal.(r-E)* N == s + uReal.r*N - uReal.E * N by Th30;
hence l < r1 by A15,A16,SURREALO:9;
end;
let l1,r1 be Surreal such that
A17:l1 in {u2} & r1 in R_x;
consider e be positive Real such that
A18: r1 = s + uReal.(r+e)* N by A1,A17;
set E = e;
l1 is (s,N,r)_Term by A10,A17,TARSKI:def 1;
then |. l1 - (s + uReal.r* N).| infinitely< N by SURREALC:def 14;
then |.l1 - (s + uReal.r* N).| infinitely< N *uReal.E by SURREALC:13;
then |.l1 - (s + uReal.r* N).| < N *uReal.E by SURREALC:9;
then l1 - (s + uReal.r* N) < N *uReal.E by SURREALC:52;
then
A19: l1 < (s + uReal.r* N) + N *uReal.E by SURREALR:41;
s + uReal.(r+E)* N == s + uReal.r*N + (uReal.E) * N by Th30;
hence l1 < r1 by A18,A19,SURREALO:9;
end;
hence born u1 in born u2 by A12,Th53,A13;
end;
theorem Th55:
for r being positive Real,x st
x = [{uReal.(r-e1): r-e1 >0}, the set of all uReal.(r+e2)]
holds x == uReal.r
proof
let r be positive Real, a be Surreal such that
A1: a =[{uReal.(r-e1): r-e1 >0}, the set of all uReal.(r+e2)];
A2: sReal.r == Unique_No sReal.r = uReal.r by SURREALO:def 10,SURREALN:def 7;
L_a << {uReal.r}
proof
let x,y be Surreal such that
A3:x in L_a & y in {uReal.r};
consider e1 be positive Real such that
A4:x = uReal.(r-e1) & r-e1 >0 by A3,A1;
y=uReal.r by A3,TARSKI:def 1;
hence thesis by A4,XREAL_1:44,SURREALN:51;
end;
then
A5: L_a << {sReal.r} by A2,SURREALO:17;
{uReal.r} << R_a
proof
let x,y be Surreal such that
A6: x in {uReal.r} & y in R_a;
consider e1 be positive Real such that
A7: y = uReal.(r+e1) by A6,A1;
x=uReal.r by A6,TARSKI:def 1;
hence thesis by A7,XREAL_1:29,SURREALN:51;
end;
then
A8: {sReal.r} << R_a by A2,SURREALO:18;
A9: sReal.r = [(the set of all uDyadic.( [/ r*(2|^n)-1 \] / (2|^n) )
where n is Nat),
(the set of all uDyadic.( [\ r*(2|^m)+1 /] / (2|^m) ) where m is Nat)]
by SURREALN:def 6;
A10: L_sReal.r << {a}
proof
let x,y be Surreal such that
A11: x in L_sReal.r & y in {a};
consider n be Nat such that
A12: x = uDyadic.( [/ r*(2|^n)-1 \] / (2|^n) ) by A11,A9;
per cases;
suppose
A13: [/ r*(2|^n)-1 \] / (2|^n) > 0;
reconsider R = r - [/ r*(2|^n)-1\] / (2|^n) as positive Real
by XREAL_1:50,SURREALN:41;
x = uReal.(r-R) in L_a << {a}
by A1,A12,A13,SURREALN:46,SURREALO:11;
hence thesis by A11;
end;
suppose [/ r*(2|^n)-1 \] / (2|^n) <= 0;
then x <= uDyadic.0 = uReal.0 <= uReal.(r/2) by A12,SURREALN:24,46,51;
then
A14: x <= uReal.(r/2) by SURREALO:4;
r- r/2=r/2 >0;
then uReal.(r/2) in L_a << {a} by A1,SURREALO:11;
hence thesis by A11,A14,SURREALO:9;
end;
end;
A15: {a} << R_sReal.r
proof
let x,y be Surreal such that
A16: x in {a} & y in R_sReal.r;
consider n be Nat such that
A17: y = uDyadic.( [\ r*(2|^n)+1 /] / (2|^n) ) by A16,A9;
reconsider R = [\ r*(2|^n)+1/] / (2|^n)-r as positive Real
by SURREALN:41,XREAL_1:50;
y = uReal.(r+R) in R_a & {a} << R_a by A1,A17,SURREALN:46,SURREALO:11;
hence thesis by A16;
end;
sReal.r <= a <= sReal.r by A10,A8,A5,A15,SURREAL0:43;
hence thesis by A2,SURREALO:9;
end;
theorem Th56:
for r,x st
x = [the set of all uReal.(r-e1), the set of all uReal.(r+e2)]
holds x == uReal.r
proof
let r be Real, a be Surreal such that
A1: a =[the set of all uReal.(r-e1), the set of all uReal.(r+e2)];
A2: sReal.r == Unique_No sReal.r = uReal.r by SURREALO:def 10,SURREALN:def 7;
L_a << {uReal.r}
proof
let x,y be Surreal such that
A3: x in L_a & y in {uReal.r};
consider e1 be positive Real such that
A4: x = uReal.(r-e1) by A3,A1;
y=uReal.r by A3,TARSKI:def 1;
hence thesis by A4,XREAL_1:44,SURREALN:51;
end;
then
A5: L_a << {sReal.r} by A2,SURREALO:17;
{uReal.r} << R_a
proof
let x,y be Surreal such that
A6: x in {uReal.r} & y in R_a;
consider e1 be positive Real such that
A7: y = uReal.(r+e1) by A6,A1;
x=uReal.r by A6,TARSKI:def 1;
hence thesis by A7,XREAL_1:29,SURREALN:51;
end;
then
A8: {sReal.r} << R_a by A2,SURREALO:18;
A9: sReal.r = [(the set of all uDyadic.( [/ r*(2|^n)-1 \] / (2|^n) )
where n is Nat),
(the set of all uDyadic.( [\ r*(2|^m)+1 /] / (2|^m) ) where m is Nat)]
by SURREALN:def 6;
A10: L_sReal.r << {a}
proof
let x,y be Surreal such that
A11:x in L_sReal.r & y in {a};
consider n be Nat such that
A12:x = uDyadic.( [/ r*(2|^n)-1 \] / (2|^n) ) by A11,A9;
reconsider R = r - [/ r*(2|^n)-1\] / (2|^n) as positive Real
by XREAL_1:50,SURREALN:41;
x = uReal.(r-R) in L_a << {a} by A1,A12,SURREALN:46,SURREALO:11;
hence thesis by A11;
end;
A13: {a} << R_sReal.r
proof
let x,y be Surreal such that
A14:x in {a} & y in R_sReal.r;
consider n be Nat such that
A15:y = uDyadic.( [\ r*(2|^n)+1 /] / (2|^n) ) by A14,A9;
reconsider R = [\ r*(2|^n)+1/] / (2|^n)-r as positive Real
by SURREALN:41,XREAL_1:50;
y = uReal.(r+R) in R_a & {a} << R_a by A1,A15,SURREALN:46,SURREALO:11;
hence thesis by A14;
end;
sReal.r <= a <= sReal.r by A10,A8,A5,A13,SURREAL0:43;
hence thesis by A2,SURREALO:9;
end;
:: Gonshor'86 Lemma 5.2
theorem Th57:
for r,z,x st
x = [the set of all uReal.(r-e1)* No_omega^z,
the set of all uReal.(r+e2)* No_omega^z]
holds uReal.r * No_omega^z == x
proof
let r be Real, a,X be Surreal such that
A1: X = [the set of all uReal.(r-e1)* No_omega^a,
the set of all uReal.(r+e2)* No_omega^a];
reconsider R=[the set of all uReal.(r-e1),
the set of all uReal.(r+e2)] as Surreal by Th49;
A2: R==uReal.r by Th56;
set N=No_omega^a,RN=R*N;
A3: RN = [comp(L_R,R,N,L_N) \/ comp(R_R,R,N,R_N),
comp(L_R,R,N,R_N) \/ comp(R_R,R,N,L_N)] by SURREALR:50;
A4: L_RN << {X}
proof
let x,w be Surreal such that
A5: x in L_RN & w in {X};
per cases by A3,A5,XBOOLE_0:def 3;
suppose x in comp(L_R,R,N,L_N);
then consider a1,b1 be Surreal such that
A6: x = a1*N+R*b1 - a1*b1 & a1 in L_R & b1 in L_N by SURREALR:def 15;
consider e1 such that
A7: a1 = uReal.(r-e1) by A6;
per cases by A6,SURREALC:22;
suppose b1 = 0_No;
then x in L_X << {X} by A1,A6,A7,SURREALO:11;
hence thesis by A5;
end;
suppose ex xL being Surreal, r being positive Real st
xL in L_a & b1 = (No_omega^ xL) * uReal.r;
then consider xL be Surreal, e2 be positive Real such that
A8: xL in L_a & b1 = (No_omega^ xL) * uReal.e2;
set NL=No_omega^ xL,
E2=uReal.e2;
A9: x = a1*N+ (R*(NL * E2) + - uReal.(r-e1)* (NL * E2))
by A6,A7,A8,SURREALR:37;
- uReal.(r-e1) == uReal.-(r-e1) &
- (uReal.(r-e1)* (NL * E2)) = (- uReal.(r-e1)) * (NL * E2)
by SURREALN:56,SURREALR:58;
then R*(NL * E2) == uReal.r *(NL * E2) & -(uReal.(r-e1)* (NL * E2))
== (uReal.-(r-e1)) * (NL * E2)
by Th56,SURREALR:54;
then R*(NL * E2) + - uReal.(r-e1)* (NL * E2)
== uReal.r *(NL * E2) + (uReal.-(r-e1)) * (NL * E2)
== (uReal.r + uReal.-(r-e1)) * (NL * E2)
by SURREALR:43,67;
then
A10: R*(NL * E2) + - uReal.(r-e1)* (NL * E2)
== (uReal.r + uReal.-(r-e1)) * (NL * E2)
by SURREALO:9;
uReal.r + uReal.-(r-e1) == uReal.(r +-(r-e1))
by SURREALN:55;
then (uReal.r + uReal.-(r-e1)) * (NL * E2) == uReal.e1 * (NL * E2)
by SURREALR:54;
then R*(NL * E2) + - uReal.(r-e1)* (NL * E2) == uReal.e1 * (NL * E2)
by A10,SURREALO:9;
then
A11: x == a1*N+ uReal.e1 * (NL * E2) by A9,SURREALR:32;
r-e1 = r-e1/2-e1/2;
then a1 == uReal.(r-e1/2) - uReal.(e1/2) by A7,Th32;
then a1*N == (uReal.(r-e1/2) +- uReal.(e1/2))*N ==
uReal.(r-e1/2)*N +(-uReal.(e1/2))*N by SURREALR:54,67;
then a1*N == uReal.(r-e1/2)*N +(-uReal.(e1/2))*N by SURREALO:9;
then a1*N == uReal.(r-e1/2)*N - uReal.(e1/2)*N by SURREALR:58;
then a1*N+ uReal.e1 * (NL * E2)
== uReal.(r-e1/2)*N - uReal.(e1/2)*N + uReal.e1 * (NL * E2)
by SURREALR:32;
then
A12: x == uReal.(r-e1/2)*N + - uReal.(e1/2)*N + uReal.e1 * (NL * E2)
= uReal.(r-e1/2)*N + (uReal.e1 * (NL * E2) - uReal.(e1/2)*N )
by A11,SURREALR:37,SURREALO:9;
L_a << {a} & a in {a} by SURREALO:11,TARSKI:def 1;
then NL infinitely< N by A8,SURREALC:25;
then NL infinitely< uReal.(e1/2)*N by SURREALC:13;
then NL*E2 infinitely< uReal.(e1/2)*N by SURREALC:13;
then uReal.e1 * (NL * E2) infinitely< uReal.(e1/2)*N by SURREALC:13;
then uReal.e1 * (NL * E2) - uReal.(e1/2)*N < 0_No
by SURREALR:46,SURREALC:9;
then uReal.(r-e1/2)*N + (uReal.e1 * (NL * E2) - uReal.(e1/2)*N) <
uReal.(r-e1/2)*N + 0_No by SURREALR:32;
then
A13: x < uReal.(r-e1/2)*N by A12,SURREALO:9;
uReal.(r-e1/2)*N in L_X << {X} by A1,SURREALO:11;
then uReal.(r-e1/2)*N <= w by A5;
hence thesis by A13,SURREALO:9;
end;
end;
suppose x in comp(R_R,R,N,R_N);
then consider a1,b1 be Surreal such that
A14: x = a1*N+R*b1 - a1*b1 & a1 in R_R & b1 in R_N by SURREALR:def 15;
consider e1 such that
A15: a1 = uReal.(r+e1) by A14;
consider xL be Surreal, e2 be positive Real such that
A16: xL in R_a & b1 = (No_omega^ xL) * uReal.e2 by A14,SURREALC:23;
set NL=No_omega^ xL,
E2=uReal.e2;
A17: x = a1*N+ (R*(NL * E2) + - uReal.(r+e1)* (NL * E2))
by A14,A15,A16,SURREALR:37;
- uReal.(r+e1) == uReal.-(r+e1) &
- (uReal.(r+e1)* (NL * E2)) = (- uReal.(r+e1)) * (NL * E2)
by SURREALN:56,SURREALR:58;
then R*(NL * E2) == uReal.r *(NL * E2) & - (uReal.(r+e1)* (NL * E2))
== (uReal.-(r+e1)) * (NL * E2) by Th56,SURREALR:54;
then R*(NL * E2) + - uReal.(r+e1)* (NL * E2)
== uReal.r *(NL * E2) + (uReal.-(r+e1)) * (NL * E2)
== (uReal.r + uReal.-(r+e1)) * (NL * E2)
by SURREALR:43,67;
then
A18: R*(NL * E2) + - uReal.(r+e1)* (NL * E2)
== (uReal.r + uReal.-(r+e1)) * (NL * E2) by SURREALO:9;
uReal.r + uReal.-(r+e1) == uReal.(r +-(r+e1)) by SURREALN:55;
then (uReal.r + uReal.-(r+e1)) * (NL * E2) == uReal.(-e1) * (NL * E2)
by SURREALR:54;
then R*(NL * E2) + - uReal.(r+e1)* (NL * E2) == uReal.(-e1) * (NL * E2)
by A18,SURREALO:9;
then
A19: x == a1*N+ uReal.(-e1) * (NL * E2)
by A17,SURREALR:32;
uReal.(-e1) * (NL * E2) == (-uReal.(e1)) * (NL * E2)
= -uReal.(e1) * (NL * E2) by SURREALN:56,SURREALR:54,58;
then a1*N+- uReal.(e1) * (NL * E2) == a1*N+ uReal.(-e1) * (NL * E2)
by SURREALR:32;
then
A20: a1*N+- uReal.(e1) * (NL * E2) == x by A19,SURREALO:9;
r-e1+(2*e1) = r+e1;
then a1*N ==(uReal.(r-e1) + uReal.(2*e1))*N ==
uReal.(r-e1)*N + uReal.(2*e1)*N by A15,SURREALN:55,SURREALR:54,67;
then a1*N == uReal.(r-e1)*N + uReal.(2*e1)*N by SURREALO:9;
then a1*N+- uReal.(e1) * (NL * E2)
== uReal.(r-e1)*N + uReal.(2*e1)*N+ - uReal.(e1) * (NL * E2)
by SURREALR:32;
then
A21: x == uReal.(r-e1)*N + uReal.(2*e1)*N+ - uReal.(e1) * (NL * E2)
= uReal.(r-e1)*N + (uReal.(2*e1)*N+ - uReal.(e1) * (NL * E2))
by A20,SURREALR:37,SURREALO:9;
a in {a} << R_a by TARSKI:def 1,SURREALO:11;
then N infinitely< NL by A16,SURREALC:25;
then N infinitely< NL*E2 by SURREALC:13;
then N infinitely< uReal.(e1)*(NL*E2) by SURREALC:13;
then uReal.(2*e1)*N infinitely< uReal.(e1)*(NL*E2) by SURREALC:13;
then uReal.(2*e1)*N - uReal.(e1)*(NL*E2) <0_No by SURREALR:46,SURREALC:9;
then uReal.(r-e1)*N + (uReal.(2*e1)*N+ - uReal.(e1) * (NL * E2))
< uReal.(r-e1)*N +0_No by SURREALR:32;
then
A22: x < uReal.(r-e1)*N by A21,SURREALO:9;
uReal.(r-e1)*N in L_X << {X} by A1,SURREALO:11;
then uReal.(r-e1)*N <= w by A5;
hence thesis by A22,SURREALO:9;
end;
end;
A23: {RN} << R_X
proof
let x,y be Surreal such that
A24:x in {RN} & y in R_X;
consider e such that
A25:y = uReal.(r+e)* N by A1,A24;
A26:N is positive;
r < r+e by XREAL_1:29;
then R < uReal.(r+e) by A2,SURREALO:9,SURREALN:51;
then x= R*N < uReal.(r+e)*N by A24,TARSKI:def 1,A26,SURREALR:70;
hence thesis by A25;
end;
A27:L_X << {RN}
proof
let y,x be Surreal such that
A28: y in L_X & x in {RN};
consider e such that
A29:y = uReal.(r-e)* N by A1,A28;
A30:N is positive;
r+-e < r by XREAL_1:30;
then R > uReal.(r-e) by A2,SURREALO:9,SURREALN:51;
then x= R*N > uReal.(r-e)*N by A28,TARSKI:def 1,A30,SURREALR:70;
hence thesis by A29;
end;
A31: {X} << R_RN
proof
let w,x be Surreal such that
A32: w in {X} & x in R_RN;
per cases by A3,A32,XBOOLE_0:def 3;
suppose x in comp(R_R,R,N,L_N);
then consider a1,b1 be Surreal such that
A33: x = a1*N+R*b1 - a1*b1 & a1 in R_R & b1 in L_N by SURREALR:def 15;
consider e1 such that
A34:a1 = uReal.(r+e1) by A33;
per cases by A33,SURREALC:22;
suppose b1 = 0_No;
then x in R_X & {X}<< R_X by A1,A33,A34,SURREALO:11;
hence thesis by A32;
end;
suppose ex xL being Surreal, r being positive Real st
xL in L_a & b1 = (No_omega^ xL) * uReal.r;
then consider xL be Surreal, e2 be positive Real such that
A35: xL in L_a & b1 = (No_omega^ xL) * uReal.e2;
set NL=No_omega^ xL,
E2=uReal.e2;
A36: x = a1*N+ (R*(NL * E2) + - uReal.(r+e1)* (NL * E2))
by A33,A34,A35,SURREALR:37;
- uReal.(r+e1) == uReal.-(r+e1) &
- (uReal.(r+e1)* (NL * E2)) = (- uReal.(r+e1)) * (NL * E2)
by SURREALN:56,SURREALR:58;
then R*(NL * E2) == uReal.r *(NL * E2) & - (uReal.(r+e1)* (NL * E2))
== (uReal.-(r+e1)) * (NL * E2) by Th56,SURREALR:54;
then R*(NL * E2) + - uReal.(r+e1)* (NL * E2)
== uReal.r *(NL * E2) + (uReal.-(r+e1)) * (NL * E2)
== (uReal.r + uReal.-(r+e1)) * (NL * E2)
by SURREALR:43,67;
then
A37: R*(NL * E2) + - uReal.(r+e1)* (NL * E2)
== (uReal.r + uReal.-(r+e1)) * (NL * E2)
by SURREALO:9;
uReal.r + uReal.-(r+e1) == uReal.(r +-(r+e1)) by SURREALN:55;
then uReal.r + uReal.-(r+e1) == uReal.-e1 == -uReal.e1
by SURREALN:56;
then uReal.r + uReal.-(r+e1) == -uReal.e1 by SURREALO:9;
then (uReal.r + uReal.-(r+e1)) * (NL * E2) == (-uReal.e1) * (NL * E2)
by SURREALR:54;
then R*(NL * E2)+ -uReal.(r+e1)* (NL * E2) == (-uReal.e1) * (NL * E2)
by A37,SURREALO:9;
then
A38: x == a1*N+ (-uReal.e1) * (NL * E2) by A36,SURREALR:32;
r+e1 = r+e1/2+e1/2;
then a1*N == (uReal.(r+e1/2) + uReal.(e1/2))*N
== uReal.(r+e1/2)*N +(uReal.(e1/2))*N
by A34,SURREALN:55,SURREALR:54,67;
then a1*N == uReal.(r+e1/2)*N + uReal.(e1/2)*N by SURREALO:9;
then a1*N+ (-uReal.e1) * (NL * E2)
== uReal.(r+e1/2)*N + uReal.(e1/2)*N + (-uReal.e1) * (NL * E2)
by SURREALR:32;
then
A39: x == uReal.(r+e1/2)*N + uReal.(e1/2)*N + (-uReal.e1) * (NL * E2)
= uReal.(r+e1/2)*N + ((-uReal.e1) * (NL * E2) + uReal.(e1/2)*N )
= uReal.(r+e1/2)*N + (- uReal.e1 * (NL * E2) + uReal.(e1/2)*N )
by A38,SURREALR:37,58,SURREALO:9;
L_a << {a} & a in {a} by SURREALO:11,TARSKI:def 1;
then NL infinitely< N by A35, SURREALC:25;
then NL infinitely< uReal.(e1/2)*N by SURREALC:13;
then NL*E2 infinitely< uReal.(e1/2)*N by SURREALC:13;
then uReal.e1 * (NL * E2) infinitely< uReal.(e1/2)*N by SURREALC:13;
then uReal.(e1/2)*N - uReal.e1 * (NL * E2) > 0_No
by SURREALR:45,SURREALC:9;
then uReal.(r+e1/2)*N + (-uReal.e1 * (NL * E2) + uReal.(e1/2)*N) >
uReal.(r+e1/2)*N + 0_No by SURREALR:32;
then
A40: x > uReal.(r+e1/2)*N by A39,SURREALO:9;
uReal.(r+e1/2)*N in R_X & R_X >> {X} by A1,SURREALO:11;
then uReal.(r+e1/2)*N > w by A32;
then uReal.(r+e1/2)*N >= w by SURREALO:6;
hence thesis by A40,SURREALO:9;
end;
end;
suppose x in comp(L_R,R,N,R_N);
then consider a1,b1 be Surreal such that
A41: x = a1*N+R*b1 - a1*b1 & a1 in L_R & b1 in R_N by SURREALR:def 15;
consider e1 such that
A42: a1 = uReal.(r-e1) by A41;
consider xL be Surreal, e2 be positive Real such that
A43: xL in R_a & b1 = (No_omega^ xL) * uReal.e2 by A41,SURREALC:23;
set NL=No_omega^ xL,
E2=uReal.e2;
A44: x = a1*N+ (R*(NL * E2) + - uReal.(r-e1)* (NL * E2))
by A41,A42,A43,SURREALR:37;
- uReal.(r-e1) == uReal.-(r-e1) &
- (uReal.(r-e1)* (NL * E2)) = (- uReal.(r-e1)) * (NL * E2)
by SURREALN:56,SURREALR:58;
then R*(NL * E2) == uReal.r *(NL * E2) & - (uReal.(r-e1)* (NL * E2))
== (uReal.-(r-e1)) * (NL * E2) by Th56,SURREALR:54;
then R*(NL * E2) + - uReal.(r-e1)* (NL * E2)
== uReal.r *(NL * E2) + (uReal.-(r-e1)) * (NL * E2)
== (uReal.r + uReal.-(r-e1)) * (NL * E2) by SURREALR:43,67;
then
A45: R*(NL * E2) + - uReal.(r-e1)* (NL * E2)
== (uReal.r + uReal.-(r-e1)) * (NL * E2) by SURREALO:9;
uReal.r + uReal.-(r-e1) == uReal.(r +-(r-e1)) by SURREALN:55;
then (uReal.r + uReal.-(r-e1)) * (NL * E2) == uReal.(e1) * (NL * E2)
by SURREALR:54;
then
A46: R*(NL * E2)+ -uReal.(r-e1)* (NL * E2) == uReal.(e1)* (NL * E2)
by A45,SURREALO:9;
A47: a1*N+ uReal.(e1) * (NL * E2) == x by A46,A44,SURREALR:32;
r+e1-(2*e1) = r-e1;
then a1*N ==(uReal.(r+e1) - uReal.(2*e1))*N ==
uReal.(r+e1)*N +(- uReal.(2*e1))*N
by Th32,A42,SURREALR:54,67;
then a1*N == uReal.(r+e1)*N +(- uReal.(2*e1))*N by SURREALO:9;
then a1*N == uReal.(r+e1)*N +- uReal.(2*e1)*N by SURREALR:58;
then a1*N+ uReal.(e1) * (NL * E2)
== uReal.(r+e1)*N + - uReal.(2*e1)*N+ uReal.(e1) * (NL * E2)
by SURREALR:32;
then
A48: x == uReal.(r+e1)*N +- uReal.(2*e1)*N+ uReal.(e1) * (NL * E2)
= uReal.(r+e1)*N + (-uReal.(2*e1)*N+ uReal.(e1) * (NL * E2))
by A47,SURREALR:37,SURREALO:9;
a in {a} << R_a by TARSKI:def 1,SURREALO:11;
then N infinitely< NL by A43,SURREALC:25;
then N infinitely< NL*E2 by SURREALC:13;
then N infinitely< uReal.(e1)*(NL*E2) by SURREALC:13;
then uReal.(2*e1)*N infinitely< uReal.(e1)*(NL*E2) by SURREALC:13;
then 0_No < uReal.(e1)*(NL*E2) - uReal.(2*e1)*N
by SURREALR:45,SURREALC:9;
then uReal.(r+e1)*N + (-uReal.(2*e1)*N+ uReal.(e1) * (NL * E2))
> uReal.(r+e1)*N +0_No by SURREALR:32;
then x > uReal.(r+e1)*N by A48,SURREALO:9;
then
A49: x >= uReal.(r+e1)*N by SURREALO:6;
uReal.(r+e1)*N in R_X & {X} << R_X by A1,SURREALO:11;
hence thesis by A32,A49,SURREALO:9;
end;
end;
A50:X == RN by A23,A4,SURREAL0:43,A27,A31;
RN == uReal.r *N by Th56,SURREALR:54;
hence thesis by A50,SURREALO:9;
end;
begin :: Additive Properties and Laws of Surreal Representations
reserve r,r1,r2,r12,s for Sequence of REAL,
y,y1,y2,y12,z,yz for strictly_decreasing Surreal-Sequence;
theorem Th58:
for y being positive decreasing_infinitely Surreal-Sequence st
A c= dom r /\ dom y holds Partial_Sums(r,y).A = Sum(r|A,y|A)
proof
let y be positive decreasing_infinitely Surreal-Sequence such that
A1: A c= dom r /\ dom y;
A2: Partial_Sums(r,y) |succ A = Partial_Sums(r|A,y|A) by SURREALC:87;
dom r /\ dom y c= dom r & dom r /\ dom y c= dom y by XBOOLE_1:17;
then
A3: A c= dom r & A c= dom y by A1;
dom (r|A) = dom r /\ A & dom (y|A) = dom y /\ A by RELAT_1:61;
then dom (r|A) = A = dom (y|A) by A3,XBOOLE_1:28;
then Sum(r|A,y|A) = Partial_Sums(r|A,y|A).(A/\A) by SURREALC:def 21;
hence thesis by ORDINAL1:6,FUNCT_1:49,A2;
end;
theorem Th59:
for y being positive decreasing_infinitely Surreal-Sequence st
succ A c= dom r/\dom y holds
[the set of all Sum(r|A,y|A) + uReal.(r.A - e1) * y..A,
the set of all Sum(r|A,y|A) + uReal.(r.A + e2) * y..A]
is Surreal
proof
let y be positive decreasing_infinitely Surreal-Sequence such that
A1: succ A c= dom r/\dom y;
A in dom r/\dom y by A1,ORDINAL1:6;
then
A2:A in dom y by XBOOLE_0:def 4;
then y..A = y.A by Def5;
then y..A is positive by A2,SURREALC:def 15;
hence thesis by Th52;
end;
theorem Th60:
for y being positive decreasing_infinitely Surreal-Sequence st
succ A c= dom r/\dom y &
x = [the set of all Sum(r|A,y|A) + uReal.(r.A - e1) * y..A,
the set of all Sum(r|A,y|A) + uReal.(r.A + e2) * y..A]
holds Sum(r|succ A,y|succ A) = Unique_No x
proof
let y be positive decreasing_infinitely Surreal-Sequence such that
A1: succ A c= dom r/\dom y and
A2:x = [(the set of all Sum(r|A,y|A) + uReal.(r.A - e) * y..A
where e is positive Real),
(the set of all Sum(r|A,y|A) + uReal.(r.A + e) * y..A
where e is positive Real)];
set N=y..A,SA=Sum(r|A,y|A),sA=succ A;
A3: succ (dom r/\dom y) = dom Partial_Sums(r,y) by SURREALC:def 20;
A4: Partial_Sums(r,y),y,r simplest_on_position sA
by A3,A1,ORDINAL1:22,SURREALC:def 20;
A5: Partial_Sums(r,y).succ A = Sum(r|sA,y|sA) by A1,Th58;
A6: A in sA by ORDINAL1:6;
then
A7: A c= dom r/\dom y by A1,ORDINAL1:def 2;
A8: SA = Partial_Sums(r,y).A by A6,A1,ORDINAL1:def 2,Th58;
set U = Unique_No x;
A9: x == U by SURREALO:def 10;
A10: x is (SA,N,r.A)_Term by A2,Th54;
then
A11: |. U - (SA + uReal.(r.A)* N) .| infinitely< N
by A9,SURREALC:74,def 14;
A12:A in dom y by A1,A6,XBOOLE_0:def 4;
then
A13: N = y. A by Def5;
A14: U in_meets_terms Partial_Sums(r,y),y,r,sA
proof
let beta be Ordinal,sb,yb be Surreal such that
A15: beta in sA & sb=Partial_Sums(r,y).beta & yb = y.beta;
per cases by A15,ORDINAL1:8;
suppose beta=A;
hence U is (sb,yb,r.beta)_Term by A15,A8,A13,A10,A9,SURREALC:74;
end;
suppose
A16: beta in A;
A17: (Partial_Sums(r,y) |sA).beta = Partial_Sums(r,y).beta by A15,FUNCT_1:49;
A18: Partial_Sums(r,y) |succ A = Partial_Sums(r|A,y|A) by SURREALC:87;
A19: beta in dom y & beta in dom r by A7,A16,XBOOLE_0:def 4;
dom (r|A) = dom r /\ A & dom (y|A) = dom y /\ A by RELAT_1:61;
then beta in dom (r|A) & beta in dom (y|A) by A16,A19,XBOOLE_0:def 4;
then
A20: beta in (dom (r|A))/\(dom (y|A)) by XBOOLE_0:def 4;
A21: (y|A).beta = yb & (r|A).beta = r.beta by A15,A16,FUNCT_1:49;
SA is (sb,yb,r.beta)_Term by A18,A17,A15,A21,A20,SURREALC:92,def 17;
then
A22: |. SA - (sb + uReal.(r.beta)* yb) .| infinitely< yb
by SURREALC:def 14;
|. U - (SA + uReal.(r.A)* N) .| <= N by A11,SURREALC:9;
then
A23: |. U - (SA + uReal.(r.A)* N) .| infinitely< yb
by A16,A12,A13,A15,SURREALC:def 16,SURREALC:11;
N is positive by A13,A12,SURREALC:def 15;
then 0_No <= N;
then |.uReal.(r.A)* N.| infinitely< yb
by A16,A12,A13,A15,SURREALC:def 16,SURREALC:53;
then
A24: |. U - (SA + uReal.(r.A)* N) +uReal.(r.A)* N .| infinitely< yb
by A23,SURREALC:41;
|.U - (SA + uReal.(r.A)* N) +uReal.(r.A)* N .| == |.U - SA.|
proof
A25: U + - (SA + uReal.(r.A)* N) +uReal.(r.A)* N =
U + (- SA + - uReal.(r.A)* N) +uReal.(r.A)* N by SURREALR:40
.= ((U + - SA) + - uReal.(r.A)* N) +uReal.(r.A)* N by SURREALR:37
.= (U + - SA) + (- uReal.(r.A)* N +uReal.(r.A)* N) by SURREALR:37;
- uReal.(r.A)* N +uReal.(r.A)* N = uReal.(r.A)* N -(uReal.(r.A)* N);
then - uReal.(r.A)* N +uReal.(r.A)* N ==0_No by SURREALR:39;
then U + - (SA + uReal.(r.A)* N) +uReal.(r.A)* N == (U + - SA)+0_No
by A25,SURREALR:43;
hence thesis by SURREALC:48;
end;
then |. U - SA .| infinitely< yb by A24,SURREALC:17;
then
A26: |.U - SA + (SA - (sb + uReal.(r.beta)* yb)) .| infinitely< yb
by A22,SURREALC:41;
|.U - (sb + uReal.(r.beta)* yb).| ==
|. U - SA + (SA - (sb + uReal.(r.beta)* yb)).|
proof
A27: U - SA + (SA - (sb + uReal.(r.beta)* yb)) =
U + - SA + SA - (sb + uReal.(r.beta)* yb) by SURREALR:37
.= U + (- SA + SA) + - (sb + uReal.(r.beta)* yb) by SURREALR:37;
- SA + SA = SA-SA;
then - SA + SA ==0_No by SURREALR:39;
then U +(- SA + SA) ==U + 0_No by SURREALR:43;
then U + (- SA + SA) + - (sb + uReal.(r.beta)* yb) ==
U + - (sb + uReal.(r.beta)* yb) by SURREALR:43;
hence thesis by A27,SURREALC:48;
end;
hence U is (sb,yb,r.beta)_Term by A26,SURREALC:17,def 14;
end;
end;
A28: Sum(r|succ A,y|succ A) in_meets_terms Partial_Sums(r,y),y,r,sA
by A4,A5,SURREALC:def 18;
A29: Sum(r|succ A,y|succ A) is (SA,N,r.A)_Term by A13,A28,
ORDINAL1:6,A8,SURREALC:def 17;
A30: for x being uSurreal st x in_meets_terms
Partial_Sums(r,y),y,r,sA & x <> Sum(r|sA,y|sA)
holds born Sum(r|sA,y|sA) in born x by A4,A5,SURREALC:def 18;
Sum(r|sA,y|sA) = Unique_No x
proof
assume
A31: Sum(r|sA,y|sA) <> Unique_No x;
A32: born Sum(r|sA,y|sA) c= born Unique_No x by A14,A30,ORDINAL1:def 2;
Unique_No x==x by SURREALO:def 10;
then born Unique_No x in born Unique_No x by A32,A2,Th54,A31,A29;
hence thesis;
end;
hence thesis;
end;
Lm3:
for y being positive decreasing_infinitely Surreal-Sequence
for A st A c= dom r/\dom y
for Sl,Sr being set st
Sl = {Sum(r|B,y|B) + uReal.(r.B - e1) * y..B
where B is Element of A, e1: B in A} &
Sr = {Sum(r|B,y|B) + uReal.(r.B + e2) * y..B
where B is Element of A,e2: B in A}
holds Sl is surreal-membered &
Sr is surreal-membered & Sl << {Sum(r|A,y|A)} << Sr
proof
let y be positive decreasing_infinitely Surreal-Sequence;
let A be Ordinal such that
A1: A c= dom r/\dom y;
let Sl,Sr be set such that
A2:Sl={Sum(r|B,y|B) + uReal.(r.B - e1) * y..B
where B is Element of A,e1: B in A} &
Sr = {Sum(r|B,y|B) + uReal.(r.B + e2) * y..B
where B is Element of A,e2: B in A};
now let o be object;
assume o in Sl;
then ex B be Element of A, e being positive Real st o =
Sum(r|B,y|B) + uReal.(r.B - e) * y..B & B in A by A2;
hence o is surreal;
end;
hence Sl is surreal-membered;
now let o be object;
assume o in Sr;
then ex B be Element of A,e being positive Real st o =
Sum(r|B,y|B) + uReal.(r.B + e) * y..B & B in A by A2;
hence o is surreal;
end;
hence Sr is surreal-membered;
set SA=Sum(r|A,y|A);
A3: Partial_Sums(r,y).A = SA by A1,Th58;
A in succ (dom r/\dom y) = dom Partial_Sums(r,y)
by A1,ORDINAL1:22,SURREALC:def 20;
then
A4: Partial_Sums(r,y),y,r simplest_on_position A by SURREALC:def 20;
then
A5: (0 = A implies SA = 0_No) & (0 <> A implies
SA in_meets_terms Partial_Sums(r,y),y,r,A &
for x being uSurreal st x in_meets_terms Partial_Sums(r,y),y,r,A & x <> SA
holds born SA in born x) by A3,SURREALC:def 18;
per cases;
suppose
A6: A=0;
A7: Sl={}
proof
assume Sl<>{};
then consider o be object such that
A8: o in Sl by XBOOLE_0:def 1;
ex B be Element of A,e1 st o=Sum(r|B,y|B) + uReal.(r.B - e1) * y..B
& B in A by A8,A2;
hence thesis by A6;
end;
Sr={}
proof
assume Sr<>{};
then consider o be object such that
A9: o in Sr by XBOOLE_0:def 1;
ex B be Element of A, e1 st o=Sum(r|B,y|B) + uReal.(r.B + e1) * y..B
& B in A by A9,A2;
hence thesis by A6;
end;
hence thesis by A7;
end;
suppose
A10:A<>0;
then
A11: SA in_meets_terms Partial_Sums(r,y),y,r,A by A4,A3,SURREALC:def 18;
thus Sl << {SA}
proof
let l,ss be Surreal such that
A12: l in Sl & ss in {SA};
consider B be Element of A,e be positive Real such that
A13: l =Sum(r|B,y|B) + uReal.(r.B - e) * y..B & B in A by A12,A2;
A14: B c= dom r/\dom y & B in dom y by A1,A13,ORDINAL1:def 2,XBOOLE_0:def 4;
A15: Sum(r|B,y|B)=Partial_Sums(r,y).B by Th58,A1,A13,ORDINAL1:def 2;
y..B = y.B by A14,Def5;
then |. SA - (Sum(r|B,y|B) + uReal.(r.B)* y..B).| infinitely< y..B
by A10,A5,A15,SURREALC:def 17,def 14;
then |. SA - (Sum(r|B,y|B) + uReal.(r.B)* y..B).| infinitely<
uReal.(e) * y..B by SURREALC:13;
then |.SA - (Sum(r|B,y|B) + uReal.(r.B) * y..B).| < (uReal.(e) * y..B)
by SURREALC:9;
then - (uReal.(e) * y..B) < SA - (Sum(r|B,y|B) + uReal.(r.B) * y..B)
by SURREALC:52;
then
A16: Sum(r|B,y|B) + uReal.(r.B) * y..B - uReal.(e) * y..B < SA
by SURREALR:42;
Sum(r|B,y|B) + uReal.(r.B - e) * y..B ==
Sum(r|B,y|B) + uReal.(r.B) * y..B - uReal.(e) * y..B by Th30;
then l < SA by A13,A16,SURREALO:9;
hence thesis by A12,TARSKI:def 1;
end;
thus {SA} << Sr
proof
let ss,rr be Surreal such that
A17: ss in {SA} & rr in Sr;
consider B be Element of A,e be positive Real such that
A18: rr =Sum(r|B,y|B) + uReal.(r.B + e) * y..B & B in A by A17,A2;
A19: B c= dom r/\dom y & B in dom y by A1,A18,ORDINAL1:def 2,
XBOOLE_0:def 4;
A20: Sum(r|B,y|B)=Partial_Sums(r,y).B by Th58,A1,A18,ORDINAL1:def 2;
y..B = y.B by A19,Def5;
then |. SA - (Sum(r|B,y|B) + uReal.(r.B)* y..B).| infinitely< y..B
by A11,A18,A20,SURREALC:def 17,def 14;
then |. SA - (Sum(r|B,y|B) + uReal.(r.B)* y..B).| infinitely<
uReal.(e) * y..B by SURREALC:13;
then |.SA - (Sum(r|B,y|B) + uReal.(r.B) * y..B).| < (uReal.(e) * y..B)
by SURREALC:9;
then (uReal.(e) * y..B) > SA - (Sum(r|B,y|B) + uReal.(r.B) * y..B)
by SURREALC:52;
then
A21: Sum(r|B,y|B) + uReal.(r.B) * y..B + uReal.(e) * y..B > SA
by SURREALR:41;
Sum(r|B,y|B) + uReal.(r.B + e) * y..B ==
Sum(r|B,y|B) + uReal.(r.B) * y..B + uReal.(e) * y..B by Th30;
then rr > SA by A18,A21,SURREALO:9;
hence thesis by A17,TARSKI:def 1;
end;
end;
end;
theorem Th61:
for y being positive decreasing_infinitely Surreal-Sequence st
A c= dom r/\dom y
holds
[{Sum(r|B,y|B) + uReal.(r.B - e) * y..B
where B is Element of A,e: B in A},
{Sum(r|B,y|B) + uReal.(r.B + e) * y..B
where B is Element of A,e: B in A}] is Surreal
proof
let y be positive decreasing_infinitely Surreal-Sequence such that
A1: A c= dom r/\dom y;
set Sl={Sum(r|B,y|B) + uReal.(r.B - e1) * y..B
where B is Element of A,e1: B in A};
set Sr = {Sum(r|B,y|B) + uReal.(r.B + e2) * y..B
where B is Element of A,e2: B in A};
A2:Sl={Sum(r|B,y|B) + uReal.(r.B - e1) * y..B
where B is Element of A,e1: B in A};
A3:Sr = {Sum(r|B,y|B) + uReal.(r.B + e2) * y..B
where B is Element of A,e2: B in A};
reconsider Sl,Sr as surreal-membered set by A2,A3,Lm3,A1;
consider M be Ordinal such that
A4: for o being object st o in Sl\/Sr ex A being Ordinal st
A in M & o in Day A by SURREAL0:47;
set SA=Sum(r|A,y|A);
Sl << Sr
proof
let l,r be Surreal such that
A5: l in Sl & r in Sr;
A6: Sl << {SA} << Sr by Lm3,A1,A2,A3;
SA in {SA} by TARSKI:def 1;
then l < SA <= r by A6,A5;
hence thesis by SURREALO:9;
end;
then [Sl,Sr] in Day M by A4,SURREAL0:46;
hence thesis;
end;
:: Gonshor'86 Lemma 5.3
theorem Th62:
for y being positive decreasing_infinitely Surreal-Sequence st
A c= dom r/\dom y & x =
[{Sum(r|B,y|B) + uReal.(r.B - e) * y..B
where B is Element of A,e: B in A},
{Sum(r|B,y|B) + uReal.(r.B + e) * y..B
where B is Element of A,e: B in A}]
holds Sum(r|A,y|A) = Unique_No x
proof
let y be positive decreasing_infinitely Surreal-Sequence such that
A1: A c= dom r/\dom y;
set xL ={Sum(r|B,y|B) + uReal.(r.B - e1) * y..B
where B is Element of A,e1: B in A},
xR={Sum(r|B,y|B) + uReal.(r.B + e2) * y..B
where B is Element of A,e2: B in A};
assume
A2: x = [xL,xR] & Sum(r|A,y|A) <> Unique_No x;
set U=Unique_No x,
SA=Sum(r|A,y|A);
A3: Partial_Sums(r,y).A = SA by A1,Th58;
A in succ (dom r/\dom y) = dom Partial_Sums(r,y)
by A1,ORDINAL1:22,SURREALC:def 20;
then
A4: Partial_Sums(r,y),y,r simplest_on_position A by SURREALC:def 20;
then
A5: (0 = A implies SA = 0_No) & (0 <> A implies
SA in_meets_terms Partial_Sums(r,y),y,r,A &
for x being uSurreal st x in_meets_terms
Partial_Sums(r,y),y,r,A & x <> SA
holds born SA in born x) by A3,SURREALC:def 18;
per cases;
suppose
A6:A=0;
A7: xL={}
proof
assume xL<>{};
then consider o be object such that
A8: o in xL by XBOOLE_0:def 1;
ex B be Element of A st ex e1 st o=Sum(r|B,y|B) +
uReal.(r.B - e1) * y..B & B in A by A8;
hence thesis by A6;
end;
xR={}
proof
assume xR<>{};
then consider o be object such that
A9: o in xR by XBOOLE_0:def 1;
ex B be Element of A st ex e1 st o=Sum(r|B,y|B) +
uReal.(r.B + e1) * y..B & B in A by A9;
hence thesis by A6;
end;
hence thesis by A7,A2,A6,A4,A3,SURREALC:def 18,SURREALO:42;
end;
suppose
A10: A<>0;
A11: U==x by SURREALO:def 10;
L_x << {SA} << R_x by A1,A2,Lm3;
then
A12:born U c= born SA by Th53;
dom r/\dom y c= dom r by XBOOLE_1:17;
then
A13: A c= dom r by A1;
x in_meets_terms Partial_Sums(r,y),y,r,A
proof
let B be Ordinal,sb,yb be Surreal such that
A14: B in A & sb=Partial_Sums(r,y).B & yb = y.B;
|. x - (sb + uReal.(r.B)* yb).| infinitely< yb
proof
let e;
set E=1/e;
B c= dom r/\dom y & B in dom y by A1,A14,ORDINAL1:def 2,XBOOLE_0:def 4;
then
A15: Sum(r|B,y|B)=sb & yb = y..B by A14,Th58,Def5;
A16: sb + uReal.(r.B+E)*yb in R_x by A2,A15,A14;
x in {x} << R_x by TARSKI:def 1,SURREALO:11;
then (sb + uReal.(r.B) * yb) +(yb*uReal.E)==sb + uReal.(r.B+E)*yb > x
by A16,Th30;
then (sb + uReal.(r.B) * yb) +(yb*uReal.E) > x by SURREALO:9;
then
A17: x - (sb + uReal.(r.B) * yb) < (yb*uReal.E)
by SURREALR:41;
A18: sb + uReal.(r.B-E)*yb in L_x by A15,A14,A2;
L_x << {x} & x in {x} by TARSKI:def 1,SURREALO:11;
then (sb + uReal.(r.B) * yb) -(yb*uReal.E)==sb + uReal.(r.B-E)*yb < x
by A18,Th30;
then (sb + uReal.(r.B) * yb) -(yb*uReal.E) < x by SURREALO:9;
then
A19: -(yb*uReal.E) < x - (sb + uReal.(r.B) * yb)
by SURREALR:42;
A20: 0_No < uReal.e by SURREALN:47,51;
E*e = 1 by XCMPLX_1:87;
then yb*uReal.E*uReal.e == yb*(uReal.E*uReal.e) == yb*1_No
by SURREALR:54,69,SURREALN:57,48;
then A21: yb*uReal.E*uReal.e == yb by SURREALO:9;
|. x - (sb + uReal.(r.B) * yb).| < yb*uReal.E by A17,A19,SURREALC:52;
then |. x - (sb + uReal.(r.B) * yb).|*uReal.e < yb*uReal.E*uReal.e
by A20,SURREALR:70;
hence |. x - (sb + uReal.(r.B)* yb).| * uReal.e < yb by A21,SURREALO:9;
end;
hence x is (sb,yb,r.B)_Term by SURREALC:def 14;
end;
then U in_meets_terms Partial_Sums(r,y),y,r,A by A13,A11,SURREALC:82;
then born SA in born SA by A12,A5,A10,A2;
hence thesis;
end;
end;
theorem Th63:
for y being positive decreasing_infinitely Surreal-Sequence st
succ A c= dom r/\dom y &
(for ry being Surreal st
ry = [the set of all uReal.(r.A-e1)* y..A,
the set of all uReal.(r.A+e2)* y..A]
holds ry == uReal.(r.A)* y..A)
holds
Sum(r|succ A,y|succ A) == Sum(r|A,y|A) + uReal.(r.A) * (y..A)
proof
let y be positive decreasing_infinitely Surreal-Sequence such that
A1:succ A c= dom r/\dom y and
A2:for ry being Surreal st
ry = [the set of all uReal.(r.A-e1)* y..A,
the set of all uReal.(r.A+e2)* y..A]
holds ry == uReal.(r.A)* y..A;
set rA=r.A,
yA=y..A;
A3: A in succ A by ORDINAL1:6;
then
A4: A in dom y by A1,XBOOLE_0:def 4;
then
A5:yA = y.A by Def5;
A6: yA is positive by A4,A5,SURREALC:def 15;
A7: 0_No <=yA by A6;
reconsider ry=[the set of all uReal.(rA-e1)* yA,
the set of all uReal.(rA+e2)* yA] as Surreal by A6,Th51;
A8:ry == uReal.(rA)* yA by A2;
reconsider SryA= [the set of all 0_No + Sum(r|A,y|A) + uReal.(rA - e1) * yA,
the set of all 0_No + Sum(r|A,y|A) + uReal.(rA + e2) * yA]
as Surreal by A1,Th59;
reconsider SryA1=[{Sum(r|B,y|B) + uReal.(r.B - e) * y..B
where B is Element of succ A,e: B in succ A},
{Sum(r|B,y|B) + uReal.(r.B + e) * y..B
where B is Element of succ A,e: B in succ A}] as Surreal by A1,Th61;
A9: Sum(r|succ A,y|succ A)=Unique_No SryA1 ==SryA1 by A1,Th62,SURREALO:def 10;
A10: Sum(r|succ A,y|succ A) = Unique_No SryA ==SryA by A1,Th60,SURREALO:def 10;
then A11: SryA == SryA1 by A9,SURREALO:9;
reconsider SryB=
[{Sum(r|B,y|B) + uReal.(r.B - e) * y..B
where B is Element of A,e: B in A},
{Sum(r|B,y|B) + uReal.(r.B + e) * y..B
where B is Element of A,e: B in A}] as Surreal
by A1,A3,ORDINAL1:def 2,Th61;
A12: Sum(r|A,y|A) = Unique_No SryB ==SryB
by A1,A3,ORDINAL1:def 2,Th62,SURREALO:def 10;
A13: L_SryA << {SryB + ry}
proof
let L,R be Surreal such that
A14:L in L_SryA & R in {SryB + ry};
A15:R = SryB + ry by A14,TARSKI:def 1;
consider e such that
A16: L = Sum(r|A,y|A) + uReal.(rA - e) * yA by A14;
A17:L_ry << {ry} & ry in {ry} by SURREALO:11,TARSKI:def 1;
uReal.(rA - e) * yA in L_ry;
hence thesis by A15,A12,A16,A17,SURREALR:44;
end;
A18:{SryB + ry} << R_SryA
proof
let L,R be Surreal such that
A19:L in {SryB + ry} & R in R_SryA;
A20:L = SryB + ry by A19,TARSKI:def 1;
consider e such that
A21: R = Sum(r|A,y|A) + uReal.(rA + e) * yA by A19;
A22:{ry} << R_ry & ry in {ry} by SURREALO:11,TARSKI:def 1;
uReal.(rA + e) * yA in R_ry;
hence thesis by A20,A12,A21,A22,SURREALR:44;
end;
A23:SryB + ry = [(L_SryB ++ {ry})\/({SryB} ++ L_ry),
(R_SryB ++ {ry}) \/({SryB} ++ R_ry)] by SURREALR:28;
A24: L_(SryB + ry) << {SryA}
proof
let L,R be Surreal such that
A25: L in L_(SryB + ry) & R in {SryA};
A26: R == SryA1 by A11,A25,TARSKI:def 1;
per cases by A23,A25,XBOOLE_0:def 3;
suppose L in L_SryB ++ {ry};
then consider L1,L2 be Surreal such that
A27: L1 in L_SryB & L2 in {ry} & L = L1+L2 by SURREALR:def 8;
consider B be Element of A, e such that
A28: L1 = Sum(r|B,y|B) + uReal.(r.B - e) * y..B & B in A by A27;
set yB=y..B,
SB = Sum(r|B,y|B),
E = uReal.(e/2);
e/2+e/2 = e;
then E*yB + E*yB == (E+E)*yB == yB * uReal.e
by SURREALN:55,SURREALR:54,67;
then E*yB + E*yB == yB * uReal.e by SURREALO:9;
then -(E*yB) +- (E*yB) = -(E*yB + E*yB) == -(yB * uReal.e)
by SURREALR:40,10;
then
A29: SB + uReal.(r.B)*yB + - (uReal.e * yB) == SB + uReal.(r.B)*yB +
(-(E*yB) +- (E * yB))
= SB + uReal.(r.B)*yB -(E*yB) +- (E*yB)
by SURREALR:37,43;
L1 == SB + uReal.(r.B)*yB - uReal.e * yB by Th30,A28;
then
A30: L1 == SB + uReal.(r.B)*yB -(E*yB) +- (E*yB) by A29,SURREALO:9;
SB + uReal.(r.B)*yB -(E*yB) == SB + uReal.(r.B-e/2)*yB by Th30;
then SB + uReal.(r.B)*yB -(E*yB) +- (E*yB) ==
SB + uReal.(r.B-e/2)*yB +- (E*yB) by SURREALR:43;
then
A31: L1 == SB + uReal.(r.B-e/2)*yB +- (E*yB) by A30,SURREALO:9;
yB = y.B by A4,A28,ORDINAL1:10,Def5;
then yA infinitely< yB by A28,A4,A5,SURREALC:def 16;
then yA infinitely< E * yB by SURREALC:13;
then (uReal.(rA)) * yA < E * yB by A7,SURREALC:20;
then
A32: ry < E * yB by A8,SURREALO:9;
L1 + ry == SB + uReal.(r.B-e/2)*yB +- (E*yB) +ry =
SB + uReal.(r.B-e/2)*yB +(- (E*yB) +ry) by A31,SURREALR:37,43;
then
A33: L == SB+ uReal.(r.B-e/2)*yB +(ry- (E*yB)) by A27,TARSKI:def 1;
ry - (E*yB) < 0_No by A32,SURREALR:46;
then SB + uReal.(r.B-e/2)*yB +(ry - (E*yB)) <
SB + uReal.(r.B-e/2)*yB +0_No by SURREALR:44;
then
A34: L <= SB + uReal.(r.B-e/2)*yB by A33,SURREALO:9;
A in succ A by ORDINAL1:6;
then B in succ A by A28,ORDINAL1:10;
then SB + uReal.(r.B-e/2)*yB in L_SryA1 << {SryA1} & SryA1 in {SryA1}
by SURREALO:11,TARSKI:def 1;
then L < SryA1 by A34,SURREALO:9;
hence L < R by A26,SURREALO:9;
end;
suppose L in {SryB} ++ L_ry;
then consider L1,L2 be Surreal such that
A35: L1 in {SryB} & L2 in L_ry & L = L1+L2 by SURREALR:def 8;
A36: L1 = SryB by A35,TARSKI:def 1;
consider e2 such that
A37: L2 = uReal.(rA-e2)* yA by A35;
A38: L == Sum(r|A,y|A) + uReal.(rA-e2)* yA by A36,A35,A37,A12,SURREALR:43;
A in succ A by ORDINAL1:6;
then
A39: Sum(r|A,y|A) + uReal.(rA-e2)* yA in L_SryA1;
SryA1 in {SryA1} & L_SryA1 << {SryA1} by SURREALO:11,TARSKI:def 1;
then SryA1 > L by A38,A39,SURREALO:9;
hence L < R by A26,SURREALO:9;
end;
end;
A40: {SryA} << R_(SryB + ry)
proof
let L,R be Surreal such that
A41: L in {SryA} & R in R_(SryB + ry);
A42: L == SryA1 by A11,A41,TARSKI:def 1;
per cases by A23,A41,XBOOLE_0:def 3;
suppose R in R_SryB ++ {ry};
then consider R1,R2 be Surreal such that
A43: R1 in R_SryB & R2 in {ry} & R = R1+R2 by SURREALR:def 8;
A44: R2 = ry by A43,TARSKI:def 1;
consider B be Element of A, e such that
A45: R1 = Sum(r|B,y|B) + uReal.(r.B + e) * y..B & B in A by A43;
set yB=y..B,
SB = Sum(r|B,y|B),
E = uReal.(e/2);
e/2+e/2 = e;
then E*yB + E*yB == (E+E)*yB == yB * uReal.e
by SURREALR:54,67,SURREALN:55;
then (E*yB + E*yB) == (yB * uReal.e) by SURREALO:9;
then
A46: SB + uReal.(r.B)*yB +(uReal.e * yB) == SB+ uReal.(r.B)*yB +
((E*yB) + (E * yB)) = SB + uReal.(r.B)*yB + (E*yB) +(E*yB)
by SURREALR:37,43;
R1 == SB + uReal.(r.B)*yB + uReal.e * yB by Th30,A45;
then
A47: R1 == SB + uReal.(r.B)*yB + (E*yB) + (E*yB) by A46,SURREALO:9;
SB + uReal.(r.B)*yB +(E*yB) == SB + uReal.(r.B+e/2)*yB by Th30;
then SB + uReal.(r.B)*yB + (E*yB) + (E*yB) ==
SB + uReal.(r.B+e/2)*yB + (E*yB) by SURREALR:43;
then
A48: R1 == SB + uReal.(r.B+e/2)*yB + (E*yB) by A47,SURREALO:9;
yB = y.B by Def5,A4,A45,ORDINAL1:10;
then yA infinitely< yB by A45,A4,A5,SURREALC:def 16;
then yA infinitely< E * yB by SURREALC:13;
then
A49: (uReal.(-rA)) * yA < E * yB by A7,SURREALC:20;
A50: (uReal.(-rA))*yA == (- (uReal.rA))*yA = -( (uReal.rA)*yA)
by SURREALN:56,SURREALR:54,58;
- ry == - (uReal.(rA)* yA) by A8,SURREALR:10;
then (uReal.(-rA))*yA == - ry by A50,SURREALO:9;
then
A51: -ry < E * yB by A49,SURREALO:9;
A52: R1 +ry == SB + uReal.(r.B+e/2)*yB + (E*yB) +ry =
SB + uReal.(r.B+e/2)*yB +((E*yB) +ry) by A48,SURREALR:37,43;
ry - - (E*yB) > 0_No by A51,SURREALR:45,10;
then SB + uReal.(r.B+e/2)*yB +(ry + (E*yB)) >
SB + uReal.(r.B+e/2)*yB +0_No by SURREALR:44;
then R > SB + uReal.(r.B+e/2)*yB by A52,A43,A44,SURREALO:9;
then
A53: R >= SB + uReal.(r.B+e/2)*yB by SURREALO:6;
A in succ A by ORDINAL1:6;
then B in succ A by A45,ORDINAL1:10;
then SB + uReal.(r.B+e/2)*yB in R_SryA1 & SryA1 in {SryA1} << R_SryA1
by SURREALO:11,TARSKI:def 1;
then SryA1 < R by A53,SURREALO:9;
hence L < R by A42,SURREALO:9;
end;
suppose R in {SryB} ++ R_ry;
then consider R1,R2 be Surreal such that
A54: R1 in {SryB} & R2 in R_ry & R = R1+R2 by SURREALR:def 8;
A55: R1 = SryB by A54,TARSKI:def 1;
consider e2 such that
A56: R2 = uReal.(rA+e2)* yA by A54;
A57: R == Sum(r|A,y|A) + uReal.(rA+e2)* yA by A55,A54,A56,A12,SURREALR:43;
A in succ A by ORDINAL1:6;
then
A58: Sum(r|A,y|A) + uReal.(rA+e2)* yA
in {Sum(r|B,y|B) + uReal.(r.B + e) * y..B
where B is Element of succ A,e: B in succ A};
SryA1 in {SryA1} << R_SryA1 by SURREALO:11,TARSKI:def 1;
then SryA1 < R by A57,A58,SURREALO:9;
hence L < R by A42,SURREALO:9;
end;
end;
SryA == SryB + ry by A13,A18,A24,A40,SURREAL0:43;
then Sum(r|succ A,y|succ A) == SryB + ry
== Sum(r|A,y|A) + uReal.(rA)* yA by A10,A12,A8,SURREALO:9,SURREALR:43;
hence thesis by SURREALO:9;
end;
theorem Th64:
for y being strictly_decreasing Surreal-Sequence st
succ A c= dom r/\dom y
holds
Sum(r|succ A,No_omega^(y|succ A)) ==
Sum(r|A,No_omega^(y|A)) + uReal.(r.A) * No_omega^(y..A)
proof
let y be strictly_decreasing Surreal-Sequence such that
A1: succ A c= dom r/\dom y;
set N = No_omega^y;
A2: dom N=dom y by SURREALC:def 22;
A in succ A by ORDINAL1:6;
then
A3: A in dom y by A1,XBOOLE_0:def 4;
then N..A = N.A & y.A =y..A by A2,Def5;
then
A4:No_omega^(y..A) = N..A by A2,A3,SURREALC:def 22;
A5: for ry being Surreal st
ry = [the set of all uReal.(r.A-e1)* N..A,
the set of all uReal.(r.A+e2)* N..A]
holds ry == uReal.(r.A)* N..A by A4,Th57;
N| succ A = No_omega^(y|succ A) & N|A = No_omega^(y|A) by SURREALC:88;
hence thesis by A5,A1,A2,Th63,A4;
end;
theorem
for y being positive decreasing_infinitely Surreal-Sequence st
A in dom r/\dom y & r.A = 0
holds
Sum(r|A,y|A) = Sum(r|succ A,y|succ A)
proof
let y be positive decreasing_infinitely Surreal-Sequence such that
A1: A in dom r/\dom y & r.A = 0;
set P=Partial_Sums(r,y),
SsA=Sum(r|succ A,y|succ A),
SA=Sum(r|A,y|A);
A2:succ A in succ (dom r/\dom y) = dom P by A1,ORDINAL3:3,SURREALC:def 20;
A in succ A by ORDINAL1:6;
then
A3:P,y,r simplest_on_position A by A2,ORDINAL1:10,SURREALC:def 20;
A4:P,y,r simplest_on_position succ A by A2,SURREALC:def 20;
A5: P.succ A = SsA by Th58,A1,ORDINAL1:21;
A6:SsA in_meets_terms P,y,r,succ A &
for x being uSurreal st x in_meets_terms P,y,r,succ A & x <> SsA
holds born SsA in born x by A4,A5,SURREALC:def 18;
A7: P.A = SA by Th58,A1,ORDINAL1:def 2;
SA = SsA
proof
assume
A8: SA<>SsA;
SA in_meets_terms P,y,r,succ A
proof
let beta be Ordinal,sb,yb be Surreal such that
A9: beta in succ A & sb=P.beta & yb = y.beta;
per cases by A9, ORDINAL1:8;
suppose
A10: beta =A;
then
A11: |.SA - (SA + uReal.(r.beta)* yb).| == |.0_No.|
by SURREALC:48,A1,SURREALN:47,SURREALR:39;
0_No infinitely< yb
proof
let e;
A in dom y by A1,XBOOLE_0:def 4;
then yb is positive by A9,A10,SURREALC:def 15;
hence thesis;
end;
then |.0_No.| infinitely< yb by SURREALC:def 6;
hence SA is (sb,yb,r.beta)_Term
by A11,SURREALC:11,A9,A10,A7,SURREALC:def 14;
end;
suppose
A12: beta in A;
then SA in_meets_terms P,y,r,A by A7,A3,SURREALC:def 18;
hence thesis by A12,A9,SURREALC:def 17;
end;
end;
then
A13: born SsA in born SA by A4,A5,SURREALC:def 18,A8;
A14: A<>0
proof
assume A=0;
then SA = 0_No by A7,A3,SURREALC:def 18;
hence thesis by A13,SURREAL0:37;
end;
SsA in_meets_terms P,y,r,A
proof
let beta be Ordinal,sb,yb be Surreal such that
A15: beta in A & sb=P.beta & yb = y.beta;
beta in succ A by A15,ORDINAL1:8;
hence SsA is (sb,yb,r.beta)_Term by A15,A6,SURREALC:def 17;
end;
then born SsA in born SsA by A13,A14,A7,A3,SURREALC:def 18;
hence thesis;
end;
hence thesis;
end;
theorem Th66:
for y being positive decreasing_infinitely Surreal-Sequence st rng r c= {0}
holds Sum(r,y) = 0_No
proof
let y be positive decreasing_infinitely Surreal-Sequence such that
A1:rng r c= {0};
defpred P[Ordinal] means $1 c= dom r/\dom y implies Sum(r|$1,y|$1)=0_No;
A2:for A being Ordinal st for C being Ordinal st C in A holds P[C] holds P[A]
proof
let A be Ordinal such that
A3:for C being Ordinal st C in A holds P[C];
assume
A4: A c= dom r/\dom y;
reconsider X= [{Sum(r|B,y|B) + uReal.(r.B - e) * y..B
where B is Element of A,e: B in A},
{Sum(r|B,y|B) + uReal.(r.B + e) * y..B
where B is Element of A,e: B in A}] as Surreal by A4,Th61;
A5: L_X << {0_No}
proof
let x,w be Surreal such that
A6: x in L_X & w in {0_No};
consider B be Element of A,e such that
A7: x = Sum(r|B,y|B) + uReal.(r.B - e) * y..B & B in A by A6;
A8: Sum(r|B,y|B) = 0_No by A3,A4,A7,ORDINAL1:def 2;
B in dom r by A4,A7,XBOOLE_0:def 4;
then r.B in rng r by FUNCT_1:def 3;
then
A9: r.B = 0 by A1,TARSKI:def 1;
A10: B in dom y by A4,A7,XBOOLE_0:def 4;
then y..B = y.B by Def5;
then
A11: y..B is positive by A10,SURREALC:def 15;
0_No =uReal.0 > uReal.(-e) by SURREALN:47,51;
then uReal.(- e) * y..B < 0_No = w by A11,A6,SURREALR:74,TARSKI:def 1;
hence thesis by A9,A7,A8;
end;
{0_No} << R_X
proof
let w,x be Surreal such that
A12: w in {0_No} & x in R_X;
consider B be Element of A,e such that
A13: x = Sum(r|B,y|B) + uReal.(r.B + e) * y..B & B in A by A12;
A14: Sum(r|B,y|B) = 0_No by A3,A4,A13,ORDINAL1:def 2;
B in dom r by A4,A13,XBOOLE_0:def 4;
then r.B in rng r by FUNCT_1:def 3;
then
A15: r.B = 0 by A1,TARSKI:def 1;
A16: B in dom y by A4,A13,XBOOLE_0:def 4;
then y..B = y.B by Def5;
then
A17: y..B is positive by A16,SURREALC:def 15;
0_No =uReal.0 < uReal.(e) by SURREALN:47,51;
then uReal.(e) * y..B > 0_No = w by A17,A12,SURREALR:72,TARSKI:def 1;
hence thesis by A15,A13,A14;
end;
then born Unique_No X c= born 0_No by A5,Th53;
then born Unique_No X c= {} by SURREAL0:37;
then born Unique_No X = {};
then Unique_No X=0_No by SURREAL0:37;
hence thesis by A4,Th62;
end;
A18:for A being Ordinal holds P[A] from ORDINAL1:sch 2(A2);
set A = dom r/\dom y;
Partial_Sums(r,y).A = Sum(r|A,y|A) by Th58;
then Sum(r,y) = Sum(r|A,y|A) by SURREALC:def 21;
hence thesis by A18;
end;
theorem Th67:
for y being positive decreasing_infinitely Surreal-Sequence holds
Sum(r|0,y|0) = 0_No
proof
let y be positive decreasing_infinitely Surreal-Sequence;
A1:{} c= dom r /\ dom y;
then
A2: Sum(r|0,y|0) = Partial_Sums(r,y).0 by Th58;
0 in succ (dom r /\ dom y) =dom Partial_Sums(r,y)
by A1,ORDINAL1:22,SURREALC:def 20;
then Partial_Sums(r,y),y,r simplest_on_position {} by SURREALC:def 20;
hence thesis by A2,SURREALC:def 18;
end;
theorem Th68:
for y being positive decreasing_infinitely Surreal-Sequence st
B in A c= dom r /\ dom y
holds
Sum(r|A,y|A) is (Sum(r|B,y|B),y..B,r.B)_Term
proof
let y be positive decreasing_infinitely Surreal-Sequence;
assume
A1:B in A c= dom r /\ dom y;
then B c= dom r /\ dom y by ORDINAL1:10;
then
A2: Sum(r|A,y|A) = Partial_Sums(r,y).A &
Sum(r|B,y|B) = Partial_Sums(r,y).B by A1,Th58;
A in succ (dom r/\dom y) by A1,ORDINAL1:22;
then A in dom Partial_Sums(r,y) by SURREALC:def 20;
then
A3:Partial_Sums(r,y),y,r simplest_on_position A by SURREALC:def 20;
B in dom y by A1,XBOOLE_0:def 4;
then
A4: y..B = y.B by Def5;
Sum(r|A,y|A) in_meets_terms Partial_Sums(r,y),y,r,A
by A1,A2,A3,SURREALC:def 18;
hence thesis by A1,A2,A4,SURREALC:def 17;
end;
theorem Th69:
for y being positive decreasing_infinitely Surreal-Sequence st
B in A c= dom r /\ dom y
holds Sum(r|B,y|B) + uReal.(r.B - e) * y..B < Sum(r|A,y|A)
< Sum(r|B,y|B) + uReal.(r.B + e) * y..B
proof
let y be positive decreasing_infinitely Surreal-Sequence such that
A1: B in A c= dom r /\ dom y;
reconsider Sr=[{Sum(r|B,y|B) + uReal.(r.B - e) * y..B
where B is Element of A,e: B in A},
{Sum(r|B,y|B) + uReal.(r.B + e) * y..B
where B is Element of A,e: B in A}] as Surreal by A1,Th61;
Unique_No Sr = Sum(r|A,y|A) by A1,Th62;
then
A2: Sr == Sum(r|A,y|A) by SURREALO:def 10;
A3:Sum(r|B,y|B) + uReal.(r.B - e) * y..B in L_Sr &
Sum(r|B,y|B) + uReal.(r.B + e) * y..B in R_Sr by A1;
L_Sr <<{Sr} << R_Sr & Sr in {Sr} by TARSKI:def 1,SURREALO:11;
hence thesis by A2,A3,SURREALO:9;
end;
theorem Th70:
for y being positive decreasing_infinitely Surreal-Sequence st
0 in dom y/\dom r & y..0 infinitely< a
holds
|. Sum(r,y) .| infinitely< a
proof
let y be positive decreasing_infinitely Surreal-Sequence such that
A1: 0 in dom y/\dom r and
A2: y..0 infinitely< a;
set D= dom y/\dom r;
set ry =uReal.(r.0)* y..0;
A3: Sum(r|0,y|0) = 0_No by Th67;
Sum(r|D,y|D) is (Sum(r|0,y|0),y..0,r.0)_Term by A1,Th68;
then |.Sum(r|D,y|D) - (Sum(r|0,y|0)+ ry) .|
infinitely< y..0 by SURREALC:def 14;
then
A4: |.Sum(r|D,y|D) - ry.| infinitely< a by A3,A2,SURREALC:14;
0 in dom y by A1,XBOOLE_0:def 4;
then y..0 is positive by Def6;
then 0_No <= y..0;
then |.ry.| infinitely< a by A2,Th31;
then
A5: |. Sum(r|D,y|D) - ry+ry.| infinitely< a by A4,SURREALC:41;
ry-ry == 0_No by SURREALR:39;
then Sum(r|D,y|D) +- ry+ry
= Sum(r|D,y|D) +(- ry+ry) ==
Sum(r|D,y|D) + 0_No by SURREALR:37,66;
then |.Sum(r|D,y|D) +- ry+ry.| == |.Sum(r|D,y|D).| by SURREALC:48;
then
A6: |.Sum(r|D,y|D).| infinitely< a by A5,SURREALC:11;
Sum(r|D,y|D) = Partial_Sums(r,y).D by Th58;
hence thesis by A6,SURREALC:def 21;
end;
:: Gonshor'86 Lemma 5.5
::$N Decomposition of Selected Surreal Representations into Head and Tail
theorem Th71:
for y being positive decreasing_infinitely Surreal-Sequence st
A c= dom r /\ dom y
holds
Sum(r|A,y|A) + Sum(r/^A,y/^A) == Sum(r,y)
proof
let y be positive decreasing_infinitely Surreal-Sequence such that
A1: A c= dom r /\ dom y;
set rA=r|A, yA=y|A, r1A=r/^A, y1A=y/^A;
A2:dom rA = A = dom yA by A1,XBOOLE_1:18,RELAT_1:62;
reconsider XA=[{Sum(r|B,y|B) + uReal.(r.B - e) * y..B
where B is Element of A,e: B in A},
{Sum(r|B,y|B) + uReal.(r.B + e) * y..B
where B is Element of A,e: B in A}] as Surreal by A1,Th61;
defpred P[Ordinal] means $1 c= dom r1A /\ dom y1A implies
Sum(r|A,y|A) + Sum(r1A|$1,y1A|$1) == Sum(r| (A+^$1),y| (A+^$1));
A3: Sum(rA,yA) = Unique_No XA == XA by A1,Th62,SURREALO:def 10;
A4:for D being Ordinal st for C being Ordinal st C in D holds P[C] holds P[D]
proof
let D be Ordinal such that
A5: for C being Ordinal st C in D holds P[C];
set AD=A+^D;
assume
A6: D c= dom r1A /\ dom y1A;
then
A7: D c= dom r1A & D c= dom y1A by XBOOLE_1:18;
D c= dom r -^ A & D c= dom y -^ A by Def1,A7;
then
A8: A+^D c= A+^(dom r -^ A) =dom r &
A+^D c= A+^(dom y -^ A) =dom y by A1,XBOOLE_1:18,Th3,ORDINAL3:18;
per cases;
suppose D=0;
then AD=A & Sum(r1A|D,y1A|D)=0_No by ORDINAL2:27,Th67;
hence thesis;
end;
suppose
A9: D <>0;
{} c= D;
then
A10: 0 in D by ORDINAL1:11,A9,XBOOLE_0:def 8;
then A+^0 in dom r & A+^0 in dom y by A7,Th8;
then
A11: A in dom y by ORDINAL2:27;
reconsider XB=[{Sum(r1A|B,y1A|B) + uReal.(r1A.B - e) * y1A..B
where B is Element of D,e: B in D},
{Sum(r1A|B,y1A|B) + uReal.(r1A.B + e) * y1A..B
where B is Element of D,e: B in D}] as Surreal by A6,Th61;
A12: y..A is positive by A11,Def6;
A13: y..A >=0_No by A12,SURREALO:6;
A14: Sum(r1A|D,y1A|D) = Unique_No XB ==XB by A6,Th62,SURREALO:def 10;
A15: AD c= dom r /\ dom y by A8,XBOOLE_1:19;
reconsider XD=[{Sum(r|B,y|B) + uReal.(r.B - e) * y..B
where B is Element of AD,e: B in AD},
{Sum(r|B,y|B) + uReal.(r.B + e) * y..B
where B is Element of AD,e: B in AD}] as Surreal by A15,Th61;
A16: Sum(r|AD,y|AD) = Unique_No XD == XD by A15,Th62,SURREALO:def 10;
A17: XA + XB = [(L_XA ++ {XB})\/({XA} ++ L_XB), (R_XA ++ {XB})
\/({XA} ++ R_XB)] by SURREALR:28;
A-^A=0 by ORDINAL3:54;
then
A18: y1A..0 =y..A by Th35,A11;
A19: L_(XA + XB) << {XD}
proof
let b,a be Surreal such that
A20: b in L_(XA + XB) & a in {XD};
per cases by A17,A20,XBOOLE_0:def 3;
suppose b in L_XA ++ {XB};
then consider b1,b2 be Surreal such that
A21: b1 in L_XA & b2 in {XB} & b = b1+b2 by SURREALR:def 8;
consider B be Element of A,e such that
A22: b1 = Sum(r|B,y|B) + uReal.(r.B - e) * y..B & B in A by A21;
r.B - e = r.B -e/2 -e/2;
then
A23: b1 == Sum(r|B,y|B)+ uReal.(r.B -e/2) * y..B- uReal.(e/2)* y..B
by A22,Th30;
A24: y..A infinitely< y..B by A22,A11,Def7;
Sum(r1A|D,y1A|D) is (Sum(r1A|0,y1A|0),y1A..0,r1A.0)_Term
by A6,A10,Th68;
then
A25: |. Sum(r1A|D,y1A|D) - (Sum(r1A|0,y1A|0)
+ uReal.(r1A.0)* y1A..0).| infinitely< y1A..0 by SURREALC:def 14;
Sum(r1A|0,y1A|0) = 0_No by Th67;
then
A26: |. Sum(r1A|D,y1A|D) +- (uReal.(r1A.0)* y..A).| infinitely< y..B
by A25,A18,A24,SURREALC:14;
|.(uReal.(r1A.0)* y..A).| infinitely< y..B by A13,Th31,A22,A11,Def7;
then
A27: |.Sum(r1A|D,y1A|D) +- (uReal.(r1A.0)* y..A) + (uReal.(r1A.0)* y..A).|
infinitely< y..B by A26,SURREALC:41;
(uReal.(r1A.0)* y..A) - (uReal.(r1A.0)* y..A) == 0_No
by SURREALR:39;
then Sum(r1A|D,y1A|D) +-(uReal.(r1A.0)* y..A) + (uReal.(r1A.0)* y..A)
= Sum(r1A|D,y1A|D) +(- (uReal.(r1A.0)* y..A) + (uReal.(r1A.0)* y..A))
== Sum(r1A|D,y1A|D) +0_No
by SURREALR:32,37;
then Sum(r1A|D,y1A|D) +-(uReal.(r1A.0)* y..A) +(uReal.(r1A.0)* y..A)
==XB by A14,SURREALO:9;
then |.XB.| infinitely< y..B by A27,SURREALC:17,48;
then |.XB.| infinitely< uReal.(e/2)* y..B by SURREALC:13;
then XB <= |.XB.| < uReal.(e/2)* y..B by SURREALC:9,34;
then XB < uReal.(e/2)* y..B by SURREALO:9;
then - XB > -( uReal.(e/2)* y..B) by SURREALR:10;
then Sum(r|B,y|B) + uReal.(r.B -e/2) * y..B + - XB >
Sum(r|B,y|B) + uReal.(r.B - e/2) * y..B +- uReal.(e/2)* y..B
by SURREALR:32;
then Sum(r|B,y|B) + uReal.(r.B -e/2) * y..B - XB > b1
by A23,SURREALO:9;
then Sum(r|B,y|B) + uReal.(r.B -e/2) * y..B > b1 + XB = b
by A21,TARSKI:def 1,SURREALR:42;
then
A28: Sum(r|B,y|B) + uReal.(r.B -e/2) * y..B >= b by SURREALO:6;
A c= A+^D by ORDINAL3:24;
then Sum(r|B,y|B) + uReal.(r.B - e/2) * y..B in
L_XD <<{XD} by A22,SURREALO:11;
hence thesis by A20,A28,SURREALO:9;
end;
suppose b in {XA} ++ L_XB;
then consider b1,b2 be Surreal such that
A29: b1 in {XA} & b2 in L_XB & b = b1+b2 by SURREALR:def 8;
consider B be Element of D,e such that
A30: b2 =Sum(r1A|B,y1A|B) + uReal.(r1A.B - e) * y1A..B & B in D by A29;
set AB=A+^B;
Sum(r|A,y|A) + Sum(r1A|B,y1A|B) == Sum(r|AB,y|AB)
by A30,A6,A5,ORDINAL1:def 2;
then Sum(r|AB,y|AB) + uReal.(r1A.B - e) * y1A..B
== Sum(r|A,y|A) + Sum(r1A|B,y1A|B) + uReal.(r1A.B - e) * y1A..B
= Sum(r|A,y|A) + (Sum(r1A|B,y1A|B) + uReal.(r1A.B - e) * y1A..B)
== XA + (Sum(r1A|B,y1A|B) + uReal.(r1A.B - e) * y1A..B)
by A3,SURREALR:43,SURREALR:37;
then
A31: Sum(r|AB,y|AB) + uReal.(r1A.B - e) * y1A..B == XA +b2 =b
by A30,A29,SURREALO:9,TARSKI:def 1;
A32: AB in AD by A30,ORDINAL3:17;
B in dom r1A & B in dom y1A by A30,A6,XBOOLE_0:def 4;
then AB in dom y & r1A.B = r.AB & y1A..B = y1A.B = y.AB
by Def5,Th8;
then r1A.B = r.AB & y1A..B = y..AB by Def5;
then Sum(r|AB,y|AB)+ uReal.(r1A.B - e)* y1A..B in L_XD & L_XD << {XD}
by A32,SURREALO:11;
hence thesis by A20,A31,SURREALO:9;
end;
end;
A33: {XD} << R_(XA + XB)
proof
let a,b be Surreal such that
A34: a in {XD} & b in R_(XA + XB);
per cases by XBOOLE_0:def 3,A17,A34;
suppose b in R_XA ++ {XB};
then consider b1,b2 be Surreal such that
A35: b1 in R_XA & b2 in {XB} & b = b1+b2 by SURREALR:def 8;
consider B be Element of A,e such that
A36: b1 = Sum(r|B,y|B) + uReal.(r.B + e) * y..B & B in A by A35;
r.B + e = r.B +e/2 +e/2;
then
A37: b1 == Sum(r|B,y|B) + uReal.(r.B +e/2) * y..B + uReal.(e/2)* y..B
by A36,Th30;
A38: y..A infinitely< y..B by A36,A11,Def7;
Sum(r1A|D,y1A|D) is (Sum(r1A|0,y1A|0),y1A..0,r1A.0)_Term
by A6,A10,Th68;
then
A39: |. Sum(r1A|D,y1A|D) - (Sum(r1A|0,y1A|0)
+ uReal.(r1A.0)* y1A..0).| infinitely< y1A..0 by SURREALC:def 14;
Sum(r1A|0,y1A|0) = 0_No by Th67;
then
A40: |. Sum(r1A|D,y1A|D) +- (uReal.(r1A.0)* y..A).| infinitely< y..B
by A39,A18,A38,SURREALC:14;
|.(uReal.(r1A.0)* y..A).| infinitely< y..B
by A13,Th31,A36,A11,Def7;
then
A41: |.Sum(r1A|D,y1A|D) +- (uReal.(r1A.0)* y..A) + (uReal.(r1A.0)* y..A).|
infinitely< y..B by A40,SURREALC:41;
(uReal.(r1A.0)* y..A) - (uReal.(r1A.0)* y..A) == 0_No
by SURREALR:39;
then
Sum(r1A|D,y1A|D) +- (uReal.(r1A.0)* y..A) + (uReal.(r1A.0)* y..A)
= Sum(r1A|D,y1A|D) +(- (uReal.(r1A.0)* y..A) + (uReal.(r1A.0)* y..A))
== Sum(r1A|D,y1A|D) +0_No
by SURREALR:32,37;
then Sum(r1A|D,y1A|D)+-(uReal.(r1A.0)* y..A) + (uReal.(r1A.0)* y..A)
==XB by A14,SURREALO:9;
then |.XB.| infinitely< y..B by A41,SURREALC:17,48;
then |.XB.| infinitely< uReal.(e/2)* y..B by SURREALC:13;
then - XB <= |.XB.| < uReal.(e/2)* y..B by Lm2,SURREALC:9;
then - XB < uReal.(e/2)* y..B by SURREALO:9;
then Sum(r|B,y|B) + uReal.(r.B +e/2) * y..B + - XB <
Sum(r|B,y|B) + uReal.(r.B + e/2) * y..B + uReal.(e/2)* y..B
by SURREALR:32;
then Sum(r|B,y|B) + uReal.(r.B +e/2) * y..B + - XB < b1
by A37,SURREALO:9;
then Sum(r|B,y|B) + uReal.(r.B +e/2) * y..B < b1 - -XB = b
by A35,TARSKI:def 1,SURREALR:42;
then
A42: Sum(r|B,y|B) + uReal.(r.B +e/2) * y..B <= b;
A c= A+^D by ORDINAL3:24;
then Sum(r|B,y|B) + uReal.(r.B + e/2) * y..B in R_XD
& XD in {XD} << R_XD by A36,TARSKI:def 1,SURREALO:11;
hence thesis by A34,A42,SURREALO:9;
end;
suppose b in {XA} ++ R_XB;
then consider b1,b2 be Surreal such that
A43: b1 in {XA} & b2 in R_XB & b = b1+b2 by SURREALR:def 8;
consider B be Element of D,e such that
A44: b2 =Sum(r1A|B,y1A|B) + uReal.(r1A.B + e) * y1A..B & B in D by A43;
set AB=A+^B;
Sum(r|A,y|A) + Sum(r1A|B,y1A|B) == Sum(r|AB,y|AB)
by A44,A6,A5,ORDINAL1:def 2;
then Sum(r|AB,y|AB) + uReal.(r1A.B + e) * y1A..B
== Sum(r|A,y|A) + Sum(r1A|B,y1A|B) + uReal.(r1A.B + e) * y1A..B
= Sum(r|A,y|A) + (Sum(r1A|B,y1A|B) + uReal.(r1A.B + e) * y1A..B)
== XA + (Sum(r1A|B,y1A|B) + uReal.(r1A.B + e) * y1A..B)
by A3,SURREALR:43,SURREALR:37;
then
A45: Sum(r|AB,y|AB) + uReal.(r1A.B + e) * y1A..B == XA +b2 =b by
A44,A43,SURREALO:9,TARSKI:def 1;
A46: AB in AD by A44,ORDINAL3:17;
B in dom r1A & B in dom y1A by A44,A6,XBOOLE_0:def 4;
then AB in dom y & r1A.B = r.AB & y1A..B = y1A.B = y.AB
by Def5,Th8;
then r1A.B = r.AB & y1A..B = y..AB by Def5;
then Sum(r|AB,y|AB) + uReal.(r1A.B + e) * y1A..B in R_XD &
{XD} << R_XD by A46,SURREALO:11;
hence thesis by A34,A45,SURREALO:9;
end;
end;
A47: L_XD << {XA + XB}
proof
let a,b be Surreal such that
A48: a in L_XD & b in {XA + XB};
consider B be Element of AD , e such that
A49: a = Sum(r|B,y|B) + uReal.(r.B - e) * y..B & B in A+^D by A48;
r.B - e = r.B -e/2 -e/2;
then
A50: a == Sum(r|B,y|B) + uReal.(r.B -e/2) * y..B - uReal.(e/2)* y..B
by A49,Th30;
per cases by ORDINAL1:16;
suppose
A51: A c= B;
then
A52: B = A +^(B-^A) by ORDINAL3:def 5;
set BA=B-^A;
A53: B-^A in AD-^A = D by A49,A51,ORDINAL3:52,53;
Sum(r|A,y|A) + Sum(r1A|BA,y1A|BA) == Sum(r|B,y|B)
by A53,A5,A52,A6,ORDINAL1:def 2;
then a==(Sum(r|A,y|A) + Sum(r1A|BA,y1A|BA)) + uReal.(r.B - e) * y..B
= Sum(r|A,y|A) + (Sum(r1A|BA,y1A|BA) + uReal.(r.B - e) * y..B)
== XA + (Sum(r1A|BA,y1A|BA) + uReal.(r.B - e) * y..B)
by A3,A49,SURREALR:32,37;
then
A54: a == XA + (Sum(r1A|BA,y1A|BA) + uReal.(r.B - e) * y..B)
by SURREALO:9;
r.B = r1A.BA & y..B = y1A..BA by A51,A52,A8,A49,Th35,Th8;
then Sum(r1A|BA,y1A|BA) + uReal.(r.B - e) * y..B in L_XB << {XB} &
XB in {XB} by A53,SURREALO:11,TARSKI:def 1;
then XA + (Sum(r1A|BA,y1A|BA) + uReal.(r.B - e) * y..B) < XA+XB
by SURREALR:32;
then a < XA+XB by A54,SURREALO:9;
hence thesis by A48,TARSKI:def 1;
end;
suppose
A55: B in A;
A56: y..A infinitely< y..B by A55,A11,Def7;
Sum(r1A|D,y1A|D) is (Sum(r1A|0,y1A|0),y1A..0,r1A.0)_Term
by A6,A10,Th68;
then
A57: |. Sum(r1A|D,y1A|D) - (Sum(r1A|0,y1A|0)
+ uReal.(r1A.0)* y1A..0).| infinitely< y1A..0 by SURREALC:def 14;
Sum(r1A|0,y1A|0) = 0_No by Th67;
then
A58: |. Sum(r1A|D,y1A|D) +- (uReal.(r1A.0)* y..A).| infinitely< y..B
by A57,A18,A56,SURREALC:14;
|.(uReal.(r1A.0)* y..A).| infinitely< y..B
by A13,Th31,A55,A11,Def7;
then
A59: |.Sum(r1A|D,y1A|D) +- (uReal.(r1A.0)* y..A) + (uReal.(r1A.0)* y..A).|
infinitely< y..B by A58,SURREALC:41;
(uReal.(r1A.0)* y..A) - (uReal.(r1A.0)* y..A) == 0_No
by SURREALR:39;
then
Sum(r1A|D,y1A|D) +- (uReal.(r1A.0)* y..A) + (uReal.(r1A.0)* y..A)
= Sum(r1A|D,y1A|D) +(- (uReal.(r1A.0)* y..A) + (uReal.(r1A.0)* y..A))
== Sum(r1A|D,y1A|D) +0_No
by SURREALR:32,37;
then Sum(r1A|D,y1A|D)+-(uReal.(r1A.0)* y..A)+(uReal.(r1A.0)* y..A)
==XB by A14,SURREALO:9;
then |.XB.| infinitely< y..B by A59,SURREALC:48,17;
then |.XB.| infinitely< uReal.(e/2)* y..B by SURREALC:13;
then -XB <= |.XB.| < uReal.(e/2)* y..B by Lm2,SURREALC:9;
then -XB < uReal.(e/2)* y..B by SURREALO:9;
then - - XB > - (uReal.(e/2)* y..B) by SURREALR:10;
then Sum(r|B,y|B) + uReal.(r.B -e/2) * y..B +XB >
Sum(r|B,y|B) + uReal.(r.B - e/2) * y..B +- uReal.(e/2)* y..B
by SURREALR:32;
then
A60: Sum(r|B,y|B) + uReal.(r.B -e/2) * y..B +XB > a by A50,SURREALO:9;
Sum(r|B,y|B) + uReal.(r.B - e/2) * y..B in
L_XA << {XA} & XA in {XA} by A55,TARSKI:def 1,SURREALO:11;
then Sum(r|B,y|B) + uReal.(r.B - e/2) * y..B+XB <= XA+XB
by SURREALR:32;
then a < XA+XB by A60,SURREALO:9;
hence thesis by A48,TARSKI:def 1;
end;
end;
A61: {XA + XB} << R_XD
proof
let b,a be Surreal such that
A62: b in {XA + XB} & a in R_XD;
consider B be Element of AD, e such that
A63: a = Sum(r|B,y|B) + uReal.(r.B + e) * y..B & B in AD by A62;
r.B + e = r.B +e/2 +e/2;
then
A64: a == Sum(r|B,y|B) + uReal.(r.B +e/2) * y..B + uReal.(e/2)* y..B
by A63,Th30;
per cases by ORDINAL1:16;
suppose
A65: A c= B;
then
A66: B = A +^(B-^A) by ORDINAL3:def 5;
set BA=B-^A;
A67: B-^A in AD-^A = D by A63,A65,ORDINAL3:52,53;
Sum(r|A,y|A) + Sum(r1A|BA,y1A|BA) == Sum(r|B,y|B)
by A5,A66,A67,A6,ORDINAL1:def 2;
then a == (Sum(r|A,y|A) + Sum(r1A|BA,y1A|BA))+ uReal.(r.B + e)* y..B
= Sum(r|A,y|A) + (Sum(r1A|BA,y1A|BA) + uReal.(r.B + e) * y..B)
== XA + (Sum(r1A|BA,y1A|BA) + uReal.(r.B + e) * y..B)
by A3,A63,SURREALR:32,37;
then
A68: a == XA + (Sum(r1A|BA,y1A|BA) +uReal.(r.B + e)* y..B)by SURREALO:9;
r.B = r1A.BA & y..B = y1A..BA
by A65,A66,A8,Th35,Th8,A63;
then Sum(r1A|BA,y1A|BA) + uReal.(r.B + e) * y..B in R_XB &
XB in {XB} << R_XB by A67,SURREALO:11,TARSKI:def 1;
then XA + (Sum(r1A|BA,y1A|BA) + uReal.(r.B + e) * y..B) > XA+XB
by SURREALR:32;
then a > XA+XB by A68,SURREALO:9;
hence thesis by A62,TARSKI:def 1;
end;
suppose
A69: B in A;
A70: y..A infinitely< y..B by A69,A11,Def7;
Sum(r1A|D,y1A|D) is (Sum(r1A|0,y1A|0),y1A..0,r1A.0)_Term
by A6,A10,Th68;
then
A71: |. Sum(r1A|D,y1A|D) - (Sum(r1A|0,y1A|0)
+ uReal.(r1A.0)* y1A..0).| infinitely< y1A..0
by SURREALC:def 14;
Sum(r1A|0,y1A|0) = 0_No by Th67;
then
A72: |. Sum(r1A|D,y1A|D) +- (uReal.(r1A.0)* y..A).| infinitely< y..B
by A71,A18,A70,SURREALC:14;
|.(uReal.(r1A.0)* y..A).| infinitely< y..B
by A13,Th31,A69,A11,Def7;
then
A73: |.Sum(r1A|D,y1A|D) +- (uReal.(r1A.0)* y..A) + (uReal.(r1A.0)* y..A).|
infinitely< y..B by A72,SURREALC:41;
(uReal.(r1A.0)* y..A) - (uReal.(r1A.0)* y..A) == 0_No by SURREALR:39;
then
Sum(r1A|D,y1A|D) +- (uReal.(r1A.0)* y..A) + (uReal.(r1A.0)* y..A)
= Sum(r1A|D,y1A|D) +(- (uReal.(r1A.0)* y..A) + (uReal.(r1A.0)* y..A))
== Sum(r1A|D,y1A|D) +0_No by SURREALR:32,37;
then Sum(r1A|D,y1A|D)+-(uReal.(r1A.0)* y..A) + (uReal.(r1A.0)* y..A)
==XB by A14,SURREALO:9;
then |.XB.| infinitely< y..B by A73,SURREALC:17,48;
then |.XB.| infinitely< uReal.(e/2)* y..B by SURREALC:13;
then XB <= |.XB.| < uReal.(e/2)* y..B by SURREALC:9,34;
then XB < uReal.(e/2)* y..B by SURREALO:9;
then Sum(r|B,y|B) + uReal.(r.B +e/2) * y..B +XB <
Sum(r|B,y|B) + uReal.(r.B + e/2) * y..B + uReal.(e/2)* y..B
by SURREALR:32;
then
A74: Sum(r|B,y|B) + uReal.(r.B +e/2) * y..B +XB < a by A64, SURREALO:9;
Sum(r|B,y|B) + uReal.(r.B + e/2)* y..B in R_XA & XA in {XA} << R_XA
by A69,TARSKI:def 1,SURREALO:11;
then Sum(r|B,y|B) + uReal.(r.B + e/2) * y..B+XB > XA+XB
by SURREALR:32;
then Sum(r|B,y|B) + uReal.(r.B + e/2) * y..B+XB >= XA+XB
by SURREALO:6;
then a > XA+XB by A74,SURREALO:9;
hence thesis by A62,TARSKI:def 1;
end;
end;
XA + XB == XD by A33,A47,A61,A19,SURREAL0:43;
then Sum(rA,yA) + Sum(r1A|D,y1A|D) == XA + XB == Sum(r|AD,y|AD)
by A16,A3,A14,SURREALO:9,SURREALR:43;
hence thesis by SURREALO:9;
end;
end;
set D = dom r1A /\ dom y1A;
A75:for A being Ordinal holds P[A] from ORDINAL1:sch 2(A4);
A76: Sum (r1A,y1A)= Partial_Sums(r1A,y1A).D by SURREALC:def 21
.= Sum(r1A|D,y1A|D) by Th58;
r = rA ^r1A & y = yA^y1A by Def1;
then
A77:dom r = A+^(dom r1A) & dom y = A+^(dom y1A) by A2,ORDINAL4:def 1;
A78:A+^D = dom r/\dom y
proof
per cases by ORDINAL3:13;
suppose
A79: dom r/\dom y = dom r;
then (A+^(dom r1A)) c= (A+^(dom y1A)) by A77,XBOOLE_1:17;
hence thesis by A79,A77,ORDINAL3:23,XBOOLE_1:28;
end;
suppose
A80: dom r/\dom y = dom y;
then (A+^(dom y1A)) c= (A+^(dom r1A)) by A77,XBOOLE_1:17;
hence thesis by A80,A77,ORDINAL3:23,XBOOLE_1:28;
end;
end;
then Sum (r,y)= Partial_Sums(r,y).(A+^D) by SURREALC:def 21
.= Sum(r| (A+^D),y| (A+^D)) by A78,Th58;
hence thesis by A75,A76;
end;
theorem Th72:
for y being positive decreasing_infinitely Surreal-Sequence st
A c= B c= dom r /\ dom y & for C st A c= C in B holds r.C = 0
holds Sum(r|B,y|B) = Sum(r|A,y|A)
proof
let y be positive decreasing_infinitely Surreal-Sequence such that
A1: A c= B c= dom r /\ dom y and
A2: for C being Ordinal st A c= C in B holds r.C = 0;
reconsider rB=r|B as Sequence of REAL;
set yB=y|B,
rBA = rB/^A,
yBA=yB/^A,
D = dom rBA/\dom yBA;
A3:rB|A = r|A & yB|A = y|A by A1,RELAT_1:74;
A4:dom rB = B & dom yB = B by A1,XBOOLE_1:18,RELAT_1:62;
then A c= dom rB /\ dom yB by A1;
then
A5:Sum(rB|A,yB|A) + Sum(rB/^A,yB/^A) == Sum(rB,yB) by Th71;
A6:Sum(rBA,yBA) = Partial_Sums(rBA,yBA).D = Sum(rBA|D,yBA|D)
by SURREALC:def 21,Th58;
rng (rBA|D) c= {0}
proof
let b be object;
assume b in rng (rBA|D);
then consider a be object such that
A7: a in dom (rBA|D) & (rBA|D).a=b by FUNCT_1:def 3;
A8: a in D & a in dom rBA & rBA.a = b by A7,FUNCT_1:47,RELAT_1:57;
reconsider a as Ordinal by A7;
A9: rBA.a = rB.(A+^a) by Th8;
A c= A+^a in B by Th8,A4,A8,ORDINAL3:24;
then rB.(A+^a)= r.(A+^a) = 0 by A2,FUNCT_1:49;
hence thesis by A8,A9,TARSKI:def 1;
end;
then Sum(rBA|D,yBA|D)=0_No by Th66;
hence thesis by A3,A5,A6,SURREALO:50;
end;
::Gonshor'86 Lemma5.4
::$N Invariance of Surreal Sums under Zero Coefficient Extension
theorem Th73:
for r,rE being Sequence of REAL
for y,yE being positive decreasing_infinitely Surreal-Sequence
st dom r = dom y & dom rE = dom yE & rng y c= rng yE &
(for A,B st
A in dom y & B in dom yE & y.A = yE.B holds r.A = rE.B) &
(for A st A in dom yE & not yE.A in rng y holds rE.A = 0)
holds
Sum(r,y) = Sum(rE,yE)
proof
let r,rE be Sequence of REAL;
let y,yE be positive decreasing_infinitely Surreal-Sequence such that
A1: dom r = dom y & dom rE = dom yE & rng y c= rng yE and
A2: for A,B being Ordinal st
A in dom y & B in dom yE & y.A = yE.B holds r.A = rE.B and
A3: for A being Ordinal st A in dom yE & not yE.A in rng y holds rE.A = 0;
per cases;
suppose
A4: dom r = {};
then dom r/\dom y ={};
then Sum(r,y) = Partial_Sums(r,y).{} = Sum(r|{},y|{})
by SURREALC:def 21,Th58;
then
A5: Sum(r,y) = 0_No by Th67;
rng rE c= {0}
proof
let b be object;
assume b in rng rE;
then consider o be object such that
A6: o in dom rE & rE.o = b by FUNCT_1:def 3;
reconsider o as Ordinal by A6;
rng y ={} by A1,A4,RELAT_1:42;
then rE.o =0 by A1,A6,A3;
hence thesis by A6,TARSKI:def 1;
end;
hence thesis by A5,Th66;
end;
suppose
A7: dom r <>{};
defpred M[object,object] means y.$1 = yE.$2 & $2 in dom yE;
A8: for e being object st e in dom y ex u being object st M[e,u]
proof
let e be object such that
A9: e in dom y;
y.e in rng y by A9,FUNCT_1:def 3;
then consider z be object such that
A10: z in dom yE & yE.z = y.e by A1,FUNCT_1:def 3;
take z;
thus thesis by A10;
end;
consider m be Function such that
A11:dom m = dom y and
A12:for e being object st e in dom y holds M[e,m.e] from CLASSES1:sch 1(A8);
A13: rng m c= dom yE
proof
let b be object;
assume b in rng m;
then ex a be object st a in dom m & m.a =b by FUNCT_1:def 3;
hence thesis by A11,A12;
end;
0 c= dom r;
then 0 in dom r by ORDINAL1:11,A7,XBOOLE_0: def 8;
then M[0,m.0] by A12,A1;
then reconsider m0=m.0 as Ordinal;
A14: for A,B being Ordinal st (A in dom y or B in dom yE) & y.A = yE.B
holds A in dom y & B in dom yE & B=m.A
proof
let A,B be Ordinal such that
A15: (A in dom y or B in dom yE) & y.A = yE.B;
thus
A16: A in dom y & B in dom yE
proof
per cases by A15;
suppose A in dom y;
then y.A =y..A by Def5;
hence thesis by A15,FUNCT_1:def 2;
end;
suppose B in dom yE;
then yE.B =yE..B by Def5;
hence thesis by A15,FUNCT_1:def 2;
end;
end;
y.A = yE.(m.A) & (m.A) in dom yE by A12,A16;
hence thesis by A15,A16,FUNCT_1:def 4;
end;
A17: for A,B being Ordinal st A in dom y & B in dom y holds
A in B iff m.A in m.B
proof
let A,B be Ordinal such that
A18: A in dom y & B in dom y;
A19: M[A,m.A] & M[B,m.B] by A18,A12;
A20: y..A = y.A & y..B = y.B by A18,Def5;
thus A in B implies m.A in m.B
proof
assume
A21: A in B & not m.A in m.B;
then
A22: y..B < y..A by A18,Def7,SURREALC:9;
then
A23: m.B <> m.A by A19,A20,SURREALO:3;
A24: m.B in m.A by A19,A23,A21,ORDINAL1:16;
y..A < y..B by SURREALC:9,A19,A20,A24,SURREALC:def 16;
hence thesis by A22,SURREALO:6;
end;
assume
A25: m.A in m.B & not A in B;
then
A26: yE..(m.B) < yE..(m.A) by A19,Def7,SURREALC:9;
A27: yE..(m.B) = y.B & yE..(m.A) = y.A by A19,Def5;
A28: B <> A by A25;
B in A by A25,ORDINAL1:16,A28;
then y..A < y..B by A18,A20,SURREALC:def 16,SURREALC:9;
hence thesis by A20,A27,A26,SURREALO:6;
end;
A29: for B,mB being Ordinal st B in dom y & mB=m.B holds
sup (m.:B) c= mB &
Sum(rE|mB,yE|mB) = Sum(rE|sup (m.:B),yE|sup (m.:B))
proof
let B,mB be Ordinal such that
A30: B in dom y & mB=m.B;
A31: m.B in dom yE by A30,A12;
set S=sup (m.:B);
for A being Ordinal st A in m.:B holds A in mB
proof
let A be Ordinal such that
A32: A in m.:B;
ex x be object st x in dom m & x in B & A = m.x by A32,FUNCT_1:def 6;
hence thesis by A30,A17,A11;
end;
then
A33: S c= mB by ORDINAL2:20;
A34: mB c= dom yE/\dom rE by A1,A30,A12,ORDINAL1:def 2;
for C being Ordinal st S c= C in mB holds rE.C = 0
proof
let C be Ordinal such that
A35: S c= C in mB and
A36: rE.C<>0;
C in dom yE by A30,A31,A35,ORDINAL1:10;
then yE.C in rng y by A3,A36;
then consider a be object such that
A37: a in dom y & yE.C=y.a by FUNCT_1:def 3;
reconsider a as Ordinal by A37;
A38: C = m.a by A14,A37;
then a in B by A17,A37,A30,A35;
then m.a in m.:B by A11,A37,FUNCT_1:def 6;
then C in S by A38,ORDINAL2:19;
then C in C by A35;
hence thesis;
end;
hence thesis by A33,A34,Th72;
end;
defpred P[Ordinal] means $1 c= dom y implies Sum(r|$1,y|$1) =
Sum(rE|sup (m.:$1),yE|sup (m.:$1));
A39:for A being Ordinal st for C being Ordinal st C in A holds
P[C] holds P[A]
proof
let A be Ordinal such that
A40: for C being Ordinal st C in A holds P[C];
set SAL={Sum(r|B,y|B) + uReal.(r.B - e) * y..B
where B is Element of A,e: B in A},
SAR={Sum(r|B,y|B) + uReal.(r.B + e) * y..B
where B is Element of A,e: B in A};
assume
A41: A c= dom y;
then
A42: A c= dom r /\ dom y by A1;
then reconsider SA= [SAL,SAR] as Surreal by Th61;
A43: Sum(r|A,y|A) = Unique_No SA == SA by A42,Th62,SURREALO:def 10;
set MA =sup (m.:A);
set SML={Sum(rE|B,yE|B) + uReal.(rE.B - e) * yE..B
where B is Element of MA,e: B in MA},
SMR={Sum(rE|B,yE|B) + uReal.(rE.B + e) * yE..B
where B is Element of MA,e: B in MA};
A44: MA c= dom yE
proof
m.:A c= rng m by RELAT_1:111;
then for C being Ordinal st C in m.:A holds C in dom yE by A13;
hence thesis by ORDINAL2:20;
end;
then
A45: MA c= dom rE /\ dom yE by A1;
then reconsider SMA= [SML,SMR] as Surreal by Th61;
A46: Sum(rE|MA,yE|MA) = Unique_No SMA == SMA by A45,Th62,SURREALO:def 10;
A47: for x being Surreal st x in SAL
ex a being Surreal st a in SML & x <= a
proof
let x be Surreal;
assume x in SAL;
then consider B be Element of A,e such that
A48: x = Sum(r|B,y|B) + uReal.(r.B - e) * y..B & B in A;
M[B,m.B] by A41,A48,A12;
then reconsider mB=m.B as Ordinal;
A50: Sum(r|B,y|B) = Sum(rE|sup (m.:B),yE|sup (m.:B)) =
Sum(rE|mB,yE|mB) by A40,A48,A41,ORDINAL1:def 2,A29;
A51: mB in dom yE by A41,A48,A12;
y..B=y.B = yE.mB =yE..mB by A41,A48,A12,Def5;
then
A52: x = Sum(rE|mB,yE|mB) + uReal.(rE.mB - e) * yE..mB
by A48,A50,A2,A51,A41;
mB in m.:A by A48,A41,A11,FUNCT_1:def 6;
then mB in MA by ORDINAL2:19;
then x in SML by A52;
hence thesis;
end;
for x being Surreal st x in SMR ex a being Surreal st a in SAR & a <= x
proof
let x be Surreal;assume x in SMR;
then consider B be Element of MA,e such that
A53: x = Sum(rE|B,yE|B) + uReal.(rE.B + e) * yE..B & B in MA;
set X = {C where C is Element of m.:A : B c= C in m.:A}, I = inf X;
I in X
proof
consider c be Ordinal such that
A54: c in m.:A & B c= c by A53,ORDINAL2:21;
c in X by A54;
hence thesis by ORDINAL2:17;
end;
then consider C be Element of m.:A such that
A55: I = C & B c= C in m.:A;
reconsider C as Ordinal by A55;
consider D be object such that
A56: D in dom m & D in A & m.D = C by A55,FUNCT_1:def 6;
reconsider D as Ordinal by A56;
A57: M[D,C] by A56,A12,A11;
A58: Sum(r|D,y|D) = Sum(rE|sup (m.:D),yE|sup (m.:D)) = Sum(rE|C,yE|C)
by A40,A56,A11,ORDINAL1:def 2,A29;
A59: y..D=y.D = yE.C =yE..C by A56,A11,A12,Def5;
A60: r.D = rE.C by A2,A57,A56,A11;
per cases;
suppose B=C;
then x in SAR by A53,A56,A59,A58,A60;
hence thesis;
end;
suppose
A61: B <> C;
then
A62: B in C by A55,ORDINAL1:11,XBOOLE_0:def 8;
then
A63: y..D infinitely< yE..B by A59,A57,Def7;
A64: rE.B = 0
proof
assume rE.B <> 0;
then yE.B in rng y by A44,A53,A3;
then consider E be object such that
A65: E in dom y & y.E= yE.B by FUNCT_1:def 3;
reconsider E as Ordinal by A65;
A66: m.E = B by A14,A65;
then E in D by A62,A56,A65,A11,A17;
then E in A by A56,ORDINAL1:10;
then m.E in m.:A by A65,A11,FUNCT_1:def 6;
then B in X by A66;
hence contradiction by A61,A55,ORDINAL2:14;
end;
C c= dom rE /\ dom yE by A1,A56,A12,A11,ORDINAL1:def 2;
then Sum(rE|C,yE|C) is (Sum(rE|B,yE|B),yE..B,rE.B)_Term by A62,Th68;
then |. Sum(r|D,y|D) - (Sum(rE|B,yE|B) + 0_No* yE..B).|
infinitely< yE..B
by A64,SURREALN:47,A58,SURREALC:def 14;
then |. Sum(r|D,y|D) - Sum(rE|B,yE|B).| infinitely<
uReal. (e/2) * yE..B by SURREALC:13;
then Sum(r|D,y|D) - Sum(rE|B,yE|B) <=
|.Sum(r|D,y|D) - Sum(rE|B,yE|B).| < uReal. (e/2) * yE..B
by SURREALC:9,34;
then
A68: Sum(r|D,y|D) - Sum(rE|B,yE|B) <= uReal. (e/2) * yE..B
by SURREALO:9;
y..D is positive by Def6,A56,A11;
then
A69: 0_No <= y..D;
y..D infinitely< uReal. (e/2) * yE..B by SURREALC:13,A63;
then uReal.(r.D + e) * y..D < uReal. (e/2) * yE..B
by A69,SURREALC:20;
then uReal.(r.D + e) * y..D + Sum(r|D,y|D) - Sum(rE|B,yE|B) =
uReal.(r.D + e) * y..D + (Sum(r|D,y|D) +- Sum(rE|B,yE|B))
< uReal. (e/2) * yE..B + uReal. (e/2) * yE..B by A68,SURREALR:37,44;
then uReal.(r.D + e) * y..D + Sum(r|D,y|D) <
uReal. (e/2) * yE..B + uReal. (e/2) * yE..B + Sum(rE|B,yE|B)=
uReal. (e/2) * yE..B + (uReal. (e/2) * yE..B + Sum(rE|B,yE|B))
== Sum(rE|B,yE|B) + uReal. (e/2+e/2) * yE..B
by Th30,SURREALR:37,41;
then
A70: Sum(r|D,y|D)+ uReal.(r.D+e) * y..D <= x
by A53,A64,SURREALO:9;
Sum(r|D,y|D)+ uReal.(r.D + e) * y..D in SAR by A56;
hence thesis by A70;
end;
end;
then
A71: SA <= SMA by A47,SURREAL0:44;
A72: for x being Surreal st x in SAR ex a being Surreal st a in SMR & a <= x
proof
let x be Surreal;
assume x in SAR;
then consider B be Element of A,e such that
A73: x = Sum(r|B,y|B) + uReal.(r.B + e) * y..B & B in A;
A74: M[B,m.B] by A41,A73,A12;
then reconsider mB=m.B as Ordinal;
A75: Sum(r|B,y|B) = Sum(rE|sup (m.:B),yE|sup (m.:B)) =
Sum(rE|mB,yE|mB) by A40,A73,A41,ORDINAL1:def 2,A29;
y..B=y.B = yE.mB =yE..mB by A41,A73,A12,Def5;
then
A76: x = Sum(rE|mB,yE|mB) + uReal.(rE.mB + e) * yE..mB
by A73,A75,A2,A74,A41;
mB in m.:A by A73,A41,A11,FUNCT_1:def 6;
then mB in MA by ORDINAL2:19;
then x in SMR by A76;
hence thesis;
end;
for x being Surreal st x in SML ex a being Surreal st a in SAL & x <= a
proof
let x be Surreal;assume x in SML;
then consider B be Element of MA,e such that
A77: x = Sum(rE|B,yE|B) + uReal.(rE.B - e) * yE..B & B in MA;
set X = {C where C is Element of m.:A : B c= C in m.:A}, I = inf X;
I in X
proof
consider c be Ordinal such that
A78: c in m.:A & B c= c by A77,ORDINAL2:21;
c in X by A78;
hence thesis by ORDINAL2:17;
end;
then consider C be Element of m.:A such that
A79: I = C & B c= C in m.:A;
reconsider C as Ordinal by A79;
consider D be object such that
A80: D in dom m & D in A & m.D = C by A79,FUNCT_1:def 6;
reconsider D as Ordinal by A80;
A81: M[D,C] by A80,A11,A12;
A82: Sum(r|D,y|D) = Sum(rE|sup (m.:D),yE|sup (m.:D)) = Sum(rE|C,yE|C)
by A40,A80,A11,ORDINAL1:def 2,A29;
A83: y..D=y.D = yE.C =yE..C by A80,A11,A12,Def5;
A84: r.D = rE.C by A2,A80,A11,A81;
per cases;
suppose B=C;
then x in SAL by A77,A80,A83,A82,A84;
hence thesis;
end;
suppose
A85: B <> C;
then
A86: B in C by A79,ORDINAL1:11,XBOOLE_0:def 8;
then
A87: y..D infinitely< yE..B by A83,A81,Def7;
A88: rE.B = 0
proof
assume rE.B <> 0;
then yE.B in rng y by A44,A77,A3;
then consider E be object such that
A89: E in dom y & y.E= yE.B by FUNCT_1:def 3;
reconsider E as Ordinal by A89;
A90: m.E = B by A14,A89;
then E in D by A80,A86,A89,A11,A17;
then E in A by A80,ORDINAL1:10;
then m.E in m.:A by A89,A11,FUNCT_1:def 6;
then B in X by A90;
hence contradiction by A85,A79,ORDINAL2:14;
end;
C c= dom rE /\ dom yE by A1,A80,A11,A12,ORDINAL1:def 2;
then Sum(rE|C,yE|C) is (Sum(rE|B,yE|B),yE..B,rE.B)_Term by A86,Th68;
then |. Sum(r|D,y|D) - (Sum(rE|B,yE|B) + 0_No* yE..B).|
infinitely< yE..B by A88,A82,SURREALC:def 14,SURREALN:47;
then |. Sum(r|D,y|D) - Sum(rE|B,yE|B).| infinitely<
uReal. (e/2) * yE..B by SURREALC:13;
then -(Sum(r|D,y|D) - Sum(rE|B,yE|B)) <=
|.Sum(r|D,y|D) - Sum(rE|B,yE|B).| < uReal. (e/2) * yE..B
by Lm2,SURREALC:9;
then -(Sum(r|D,y|D) - Sum(rE|B,yE|B)) <= - - uReal. (e/2) * yE..B
by SURREALO:9;
then (Sum(r|D,y|D) - Sum(rE|B,yE|B)) >= - uReal. ( - - e/2) * yE..B
== uReal. ( - e/2) * yE..B by Th33,SURREALR:10;
then
A91: Sum(r|D,y|D) - Sum(rE|B,yE|B) >= uReal. (-e/2) * yE..B
by SURREALO:9;
y..D is positive by Def6,A80,A11;
then
A92: 0_No <= y..D;
y..D infinitely< uReal. (e/2) * yE..B by SURREALC:13,A87;
then - uReal.(- -(r.D - e)) * y..D == uReal.(-(r.D - e)) * y..D
< uReal. (e/2) * yE..B by Th33,A92,SURREALC:20;
then - uReal.(r.D - e) * y..D < uReal. (e/2) * yE..B ==
- uReal. (- e/2) * yE..B by Th33,SURREALO:9;
then - uReal.(r.D - e) * y..D < - uReal. (- e/2) * yE..B
by SURREALO:9;
then uReal.(r.D - e) * y..D > uReal. (-e/2) * yE..B
by SURREALR:10;
then uReal.(r.D - e) * y..D + Sum(r|D,y|D) - Sum(rE|B,yE|B) =
uReal.(r.D - e) * y..D + (Sum(r|D,y|D) +- Sum(rE|B,yE|B))
> uReal. (-e/2) * yE..B + uReal. (-e/2) * yE..B
by A91,SURREALR:37,44;
then uReal.(r.D - e) * y..D + Sum(r|D,y|D) >
uReal. (-e/2) * yE..B + uReal. (-e/2) * yE..B + Sum(rE|B,yE|B)
= uReal. (-e/2) * yE..B + (uReal. (-e/2) * yE..B + Sum(rE|B,yE|B))
== Sum(rE|B,yE|B) + uReal. (-e/2+-e/2) * yE..B
by Th30,SURREALR:37,42;
then uReal.(r.D - e) * y..D + Sum(r|D,y|D) >
Sum(rE|B,yE|B) + uReal. (-e) * yE..B by SURREALO:9;
then
A93: Sum(r|D,y|D)+ uReal.(r.D-e) * y..D >= x
by A77,A88,SURREALO:6;
Sum(r|D,y|D)+ uReal.(r.D - e) * y..D in SAL by A80;
hence thesis by A93;
end;
end;
then
A94: SMA <= SA by A72,SURREAL0:44;
SMA == Sum(r|A,y|A) by A71,A94,A43,SURREALO:9;
then Sum(rE|MA,yE|MA) == Sum(r|A,y|A) by A46,SURREALO:9;
hence thesis by SURREALO:50;
end;
set S=sup (m.:dom y);
for A being Ordinal holds P[A] from ORDINAL1:sch 2(A39);
then
A95:Sum(r|dom y,y|dom y) = Sum(rE|S,yE|S);
A96: m.:dom y = rng m by A11,RELAT_1:113;
then for A be Ordinal st A in m.:dom y holds A in dom yE by A13;
then
A97:S c= dom yE by ORDINAL2:20;
A98:dom yE c= dom yE/\dom rE by A1;
for C being Ordinal st S c= C in dom yE holds rE.C = 0
proof
let C be Ordinal such that
A99: S c= C in dom yE;
assume rE.C <> 0;
then yE.C in rng y by A3,A99;
then consider a be object such that
A100: a in dom y & y.a =yE.C by FUNCT_1:def 3;
reconsider a as Ordinal by A100;
m.a = C by A100,A14;
then C in rng m by A100,A11,FUNCT_1:def 3;
then C in S by A96,ORDINAL2:19;
then C in C by A99;
hence thesis;
end;
then Sum(rE|S,yE|S) = Sum(rE|dom yE,yE|dom yE) by A98,A97,Th72;
hence thesis by A1,A95;
end;
end;
::$N The Additive Law for Compatible Selected Surreal Series
theorem Th74:
for y being positive decreasing_infinitely Surreal-Sequence
for r,s being Sequence of REAL st dom r = dom s & A c= dom r/\dom y
holds
Sum((r + s) |A,y|A) == Sum(r|A,y|A) + Sum(s|A,y|A)
proof
let y be positive decreasing_infinitely Surreal-Sequence;
defpred P[Ordinal] means
for r,s being Sequence of REAL st dom r = dom s & $1 c= dom r/\dom y holds
Sum((r + s) |$1,y|$1) == Sum(r|$1,y|$1) + Sum(s|$1,y|$1);
A1:for A being Ordinal st for C being Ordinal st C in A holds P[C] holds P[A]
proof
let A be Ordinal such that
A2: for C being Ordinal st C in A holds P[C];
A3: for r,s being Sequence of REAL st dom r = dom s
for B being Ordinal,e st B in A c= dom r/\dom y
holds
Sum((r + s) |A,y|A) < Sum(r|A,y|A) +
(Sum(s|B,y|B) + uReal.(s.B + e) * y..B) &
Sum(r|A,y|A) +
(Sum(s|B,y|B) + uReal.(s.B - e) * y..B) < Sum((r + s) |A,y|A)
proof
let r,s be Sequence of REAL such that
A4: dom r = dom s;
let B be Ordinal,e such that
A5: B in A c= dom r/\dom y;
set rs=r+s;
A6: dom rs = dom r/\dom s by VALUED_1:def 1;
reconsider Srs=[{Sum(rs|B,y|B) + uReal.(rs.B - e) * y..B
where B is Element of A,e: B in A},
{Sum(rs|B,y|B) + uReal.(rs.B + e) * y..B
where B is Element of A,e: B in A}] as Surreal by A4,A5,A6,Th61;
reconsider Sr=[{Sum(r|B,y|B) + uReal.(r.B - e) * y..B
where B is Element of A,e: B in A},
{Sum(r|B,y|B) + uReal.(r.B + e) * y..B
where B is Element of A,e: B in A}] as Surreal by A5,Th61;
Unique_No Srs = Sum(rs|A,y|A) & Unique_No Sr = Sum(r|A,y|A)
by A4,A5,A6,Th62;
then
A7: Srs == Sum(rs|A,y|A) & Sr == Sum(r|A,y|A) by SURREALO:def 10;
A8: Sum(rs|B,y|B) == Sum(r|B,y|B) + Sum(s|B,y|B) by A2,A4,A5,ORDINAL1:def 2;
set e2=e/2;
B in dom rs by A4,A5,A6,XBOOLE_0:def 4;
then r.B +s.B = rs.B by VALUED_1:def 1;
then
A9: (r.B - e2) + (s.B + e) = rs.B+e2 & (r.B + e2) +(s.B - e) = rs.B-e2;
Sum(r|B,y|B) + uReal.(r.B - e2) * y..B + Sum(s|B,y|B)
< Sum(r|A,y|A) + Sum(s|B,y|B)
< Sum(r|B,y|B) + uReal.(r.B + e2) * y..B + Sum(s|B,y|B)
by SURREALR:44,Th69,A5;
then Sum(rs|B,y|B) + uReal.(r.B - e2) * y..B <=
Sum(r|B,y|B)+ Sum(s|B,y|B) + uReal.(r.B - e2) * y..B
< Sum(r|A,y|A) + Sum(s|B,y|B)
< Sum(r|B,y|B)+ Sum(s|B,y|B) + uReal.(r.B + e2) * y..B
<=Sum(rs|B,y|B) + uReal.(r.B + e2) * y..B
by A8,SURREALR:32,37;
then
A10: Sum(rs|B,y|B) + uReal.(r.B - e2) * y..B
< Sum(r|A,y|A) + Sum(s|B,y|B)
< Sum(rs|B,y|B) + uReal.(r.B + e2) * y..B
by SURREALO:9;
then Sum(rs|B,y|B) + uReal.(r.B - e2) * y..B +uReal.(s.B + e) * y..B
< Sum(r|A,y|A) + Sum(s|B,y|B) +uReal.(s.B + e) * y..B
by SURREALR:32;
then Sum(rs|B,y|B) + uReal.((rs.B + e2)) * y..B
== Sum(rs|B,y|B) + uReal.(r.B - e2) * y..B +uReal.(s.B + e) * y..B
< Sum(r|A,y|A) + (Sum(s|B,y|B) +uReal.(s.B + e) * y..B)
by A9,SURREALR:37,Th30;
then
A11: Sum(rs|B,y|B) + uReal.((rs.B + e2)) * y..B
< Sum(r|A,y|A) + (Sum(s|B,y|B) +uReal.(s.B + e) * y..B)
by SURREALO:9;
Sum(rs|B,y|B) + uReal.(r.B + e2) * y..B +uReal.(s.B - e) * y..B
> Sum(r|A,y|A) + Sum(s|B,y|B) +uReal.(s.B - e) * y..B by A10,SURREALR:32;
then Sum(rs|B,y|B) + uReal.(rs.B-e2) * y..B
== Sum(rs|B,y|B) + uReal.(r.B + e2) * y..B +uReal.(s.B - e) * y..B
> Sum(r|A,y|A) + (Sum(s|B,y|B) +uReal.(s.B - e) * y..B)
by SURREALR:37,A9,Th30;
then
A12: Sum(rs|B,y|B) + uReal.(rs.B-e2) * y..B
> Sum(r|A,y|A) + (Sum(s|B,y|B) +uReal.(s.B - e) * y..B) by SURREALO:9;
A13: Sum(rs|B,y|B) + uReal.(rs.B + e2) * y..B in R_Srs &Srs in {Srs} << R_Srs
by TARSKI:def 1,A5,SURREALO:11;
then Sum(rs|B,y|B) + uReal.((rs.B + e2)) * y..B > Sum(rs |A,y|A)
by A7,SURREALO:9;
then Sum(rs|B,y|B) + uReal.((rs.B + e2)) * y..B >= Sum(rs |A,y|A)
by SURREALO:6;
hence Sum((r + s) |A,y|A) <
Sum(r|A,y|A) + (Sum(s|B,y|B) + uReal.(s.B + e) * y..B)
by A11,SURREALO:4;
Sum(rs|B,y|B) + uReal.(rs.B - e2) * y..B in L_Srs << {Srs}
by A5,SURREALO:11;
then Sum(rs|B,y|B) + uReal.((rs.B - e2)) * y..B <= Sum(rs |A,y|A)
by A7,A13,SURREALO:9;
hence Sum((r + s) |A,y|A) >
Sum(r|A,y|A) + (Sum(s|B,y|B) + uReal.(s.B - e) * y..B) by A12,SURREALO:4;
end;
let r,s be Sequence of REAL such that
A14: dom r = dom s & A c= dom r/\dom y;
set rs=r+s;
A15:dom rs = dom r/\dom s by VALUED_1:def 1;
reconsider Sr=[{Sum(r|B,y|B) + uReal.(r.B - e) * y..B
where B is Element of A,e: B in A},
{Sum(r|B,y|B) + uReal.(r.B + e) * y..B
where B is Element of A,e: B in A}] as Surreal by A14,Th61;
reconsider Ss=[{Sum(s|B,y|B) + uReal.(s.B - e) * y..B
where B is Element of A,e: B in A},
{Sum(s|B,y|B) + uReal.(s.B + e) * y..B
where B is Element of A,e: B in A}] as Surreal
by A14,Th61;
reconsider Srs=[{Sum(rs|B,y|B) + uReal.(rs.B - e) * y..B
where B is Element of A,e: B in A},
{Sum(rs|B,y|B) + uReal.(rs.B + e) * y..B
where B is Element of A,e: B in A}] as Surreal by A14,A15,Th61;
Unique_No Sr = Sum(r|A,y|A) & Unique_No Ss = Sum(s|A,y|A) &
Unique_No Srs = Sum(rs|A,y|A) by A14,A15,Th62;
then
A16: Sr == Sum(r|A,y|A) & Ss == Sum(s|A,y|A) & Srs == Sum(rs|A,y|A)
by SURREALO:def 10;
A17: Sr+Ss = [(L_Sr ++ {Ss})\/({Sr} ++ L_Ss), (R_Sr ++ {Ss}) \/({Sr} ++ R_Ss)]
by SURREALR:28;
A18:L_(Sr+Ss) << {Srs}
proof
let x,yy be Surreal such that
A19: x in L_(Sr+Ss) & yy in {Srs};
per cases by A17,A19,XBOOLE_0:def 3;
suppose x in L_Sr ++ {Ss};
then consider a,b be Surreal such that
A20: a in L_Sr & b in {Ss} & a+b = x by SURREALR:def 8;
consider B be Element of A,e such that
A21: a = Sum(r|B,y|B) + uReal.(r.B - e) * y..B & B in A by A20;
A22: Ss+a == Sum(s|A,y|A) +a < Srs by A16,A21,A14,A3,SURREALO:4,SURREALR:43;
b=Ss & yy=Srs by A19,A20,TARSKI:def 1;
hence thesis by A20,A22,SURREALO:4;
end;
suppose x in {Sr} ++ L_Ss;
then consider a,b be Surreal such that
A23: a in {Sr} & b in L_Ss & a+b = x by SURREALR:def 8;
consider B be Element of A,e such that
A24: b = Sum(s|B,y|B) + uReal.(s.B - e) * y..B & B in A by A23;
A25: Sr + b == Sum(r|A,y|A) + b < Srs
by A14,A24,A3,A16,SURREALO:4,SURREALR:43;
a=Sr & yy=Srs by A19,A23,TARSKI:def 1;
hence thesis by A23,A25,SURREALO:4;
end;
end;
{Sr+Ss} << R_Srs
proof
let x,yy be Surreal such that
A26: x in {Sr+Ss} & yy in R_Srs;
consider B be Element of A,e such that
A27: yy=Sum(rs|B,y|B) + uReal.(rs.B + e) * y..B & B in A by A26;
set e2=e/2;
Sum(r|A,y|A) < Sum(r|B,y|B) + uReal.(r.B + e2) * y..B &
Sum(s|A,y|A) <= Sum(s|B,y|B) + uReal.(s.B + e2) * y..B
by Th69,A14,A27;
then
A28: Sum(r|A,y|A) + Sum(s|A,y|A) < Sum(r|B,y|B) + uReal.(r.B + e2) * y..B
+ (Sum(s|B,y|B) + uReal.(s.B + e2) * y..B) by SURREALR:44;
Sum(r|A,y|A) + Sum(s|A,y|A) == Sr+Ss by A16,SURREALR:43;
then
A29: Sum(r|A,y|A) + Sum(s|A,y|A) == x by A26,TARSKI:def 1;
A30: Sum(r|B,y|B) + uReal.(r.B + e2) * y..B
+ (Sum(s|B,y|B) + uReal.(s.B + e2) * y..B)=
Sum(r|B,y|B) + (uReal.(r.B + e2) * y..B
+ (Sum(s|B,y|B) + uReal.(s.B + e2) * y..B)) by SURREALR:37
.= Sum(r|B,y|B) + ((uReal.(r.B + e2) * y..B +uReal.(s.B + e2) * y..B)
+ Sum(s|B,y|B)) by SURREALR:37
.= Sum(r|B,y|B) + Sum(s|B,y|B)
+ (uReal.(r.B + e2) * y..B +uReal.(s.B + e2) * y..B) by SURREALR:37;
B in dom rs by A14,A15,A27,XBOOLE_0:def 4;
then r.B +s.B = rs.B by VALUED_1:def 1;
then
A31: (r.B + e2) +(s.B + e2) = rs.B+e;
Sum(rs |B,y|B)==Sum(r|B,y|B) + Sum(s|B,y|B) by A2,A27,A14,ORDINAL1:def 2;
then Sum(r|B,y|B) + uReal.(r.B + e2) * y..B
+ (Sum(s|B,y|B) + uReal.(s.B + e2) * y..B) <=
Sum(rs |B,y|B) + (uReal.(r.B + e2) * y..B +uReal.(s.B + e2) * y..B)
by A30,SURREALR:43;
then Sum(r|A,y|A) + Sum(s|A,y|A) <
Sum(rs |B,y|B) + (uReal.(r.B + e2) * y..B +uReal.(s.B + e2) * y..B)
by A28,SURREALO:4;
then x <
Sum(rs |B,y|B) + (uReal.(r.B + e2) * y..B +uReal.(s.B + e2) * y..B)
= Sum(rs |B,y|B) + uReal.(r.B + e2) * y..B +uReal.(s.B + e2) * y..B
== yy
by A31,Th30,A29,SURREALO:4,SURREALR:37,A27;
hence thesis by SURREALO:4;
end;
then
A32:Sr+Ss <= Srs by A18,SURREAL0:43;
A33: {Srs} << R_(Sr+Ss)
proof
let yy,x be Surreal such that
A34: yy in {Srs} & x in R_(Sr+Ss);
per cases by A17,A34,XBOOLE_0:def 3;
suppose x in R_Sr ++ {Ss};
then consider a,b be Surreal such that
A35: a in R_Sr & b in {Ss} & a+b = x by SURREALR:def 8;
consider B be Element of A,e such that
A36: a = Sum(r|B,y|B) + uReal.(r.B + e) * y..B & B in A by A35;
A37: Ss + a == Sum(s|A,y|A) + a
> Srs by A16,A36,A14,A3,SURREALO:4,SURREALR:43;
b=Ss & yy=Srs by A34,A35,TARSKI:def 1;
hence thesis by A35,A37,SURREALO:4;
end;
suppose x in {Sr} ++ R_Ss;
then consider a,b be Surreal such that
A38: a in {Sr} & b in R_Ss & a+b = x by SURREALR:def 8;
consider B be Element of A,e such that
A39: b = Sum(s|B,y|B) + uReal.(s.B + e) * y..B & B in A by A38;
A40: Sr + b == Sum(r|A,y|A) + b
> Srs by A14,A39,A3,A16,SURREALO:4,SURREALR:43;
a=Sr & yy=Srs by A34,A38,TARSKI:def 1;
hence thesis by A38,A40,SURREALO:4;
end;
end;
L_Srs << {Sr+Ss}
proof
let yy,x be Surreal such that
A41: yy in L_Srs & x in {Sr+Ss};
consider B be Element of A,e such that
A42: yy=Sum(rs|B,y|B) + uReal.(rs.B - e) * y..B & B in A by A41;
set e2=e/2;
Sum(r|A,y|A) > Sum(r|B,y|B) + uReal.(r.B - e2) * y..B &
Sum(s|A,y|A) > Sum(s|B,y|B) + uReal.(s.B - e2) * y..B
by Th69,A14,A42;
then Sum(r|A,y|A) > Sum(r|B,y|B) + uReal.(r.B - e2) * y..B &
Sum(s|A,y|A) >= Sum(s|B,y|B) + uReal.(s.B - e2) * y..B
by SURREALO:6;
then
A43: Sum(r|A,y|A) + Sum(s|A,y|A) >
Sum(r|B,y|B) + uReal.(r.B - e2) * y..B
+ (Sum(s|B,y|B) + uReal.(s.B - e2) * y..B) by SURREALR:44;
Sum(r|A,y|A) + Sum(s|A,y|A) == Sr+Ss by A16,SURREALR:43;
then
A44: Sum(r|A,y|A) + Sum(s|A,y|A) == x by A41,TARSKI:def 1;
A45: Sum(r|B,y|B) + uReal.(r.B - e2) * y..B
+ (Sum(s|B,y|B) + uReal.(s.B - e2) * y..B)=
Sum(r|B,y|B) + (uReal.(r.B - e2) * y..B
+ (Sum(s|B,y|B) + uReal.(s.B - e2) * y..B)) by SURREALR:37
.= Sum(r|B,y|B) + ((uReal.(r.B - e2) * y..B +uReal.(s.B - e2) * y..B)
+ Sum(s|B,y|B)) by SURREALR:37
.= Sum(r|B,y|B) + Sum(s|B,y|B)
+ (uReal.(r.B - e2) * y..B +uReal.(s.B - e2) * y..B) by SURREALR:37;
B in dom rs by A14,A15,A42,XBOOLE_0:def 4;
then r.B +s.B = rs.B by VALUED_1:def 1;
then
A46: (r.B - e2) +(s.B - e2) = rs.B-e;
Sum(rs |B,y|B) == Sum(r|B,y|B) + Sum(s|B,y|B)
by A2,A42,A14,ORDINAL1:def 2;
then Sum(r|B,y|B) + uReal.(r.B - e2) * y..B
+ (Sum(s|B,y|B) + uReal.(s.B - e2) * y..B) >=
Sum(rs |B,y|B) + (uReal.(r.B - e2) * y..B +uReal.(s.B - e2) * y..B)
by A45,SURREALR:43;
then Sum(r|A,y|A) + Sum(s|A,y|A) >
Sum(rs |B,y|B) + (uReal.(r.B - e2) * y..B +uReal.(s.B - e2) * y..B)
by A43,SURREALO:4;
then x >
Sum(rs |B,y|B) + (uReal.(r.B - e2) * y..B +uReal.(s.B - e2) * y..B)
= Sum(rs |B,y|B) + uReal.(r.B - e2) * y..B +uReal.(s.B - e2) * y..B
== yy by A46,Th30,A44,SURREALO:4,SURREALR:37,A42;
hence thesis by SURREALO:4;
end;
then
A47:Sr+Ss >= Srs by A33,SURREAL0:43;
Sum(r|A,y|A) + Sum(s|A,y|A) == Sr+Ss by A16,SURREALR:43;
then Sum(r|A,y|A) + Sum(s|A,y|A) == Srs by A32,A47,SURREALO:4;
hence thesis by A16,SURREALO:4;
end;
for A being Ordinal holds P[A] from ORDINAL1:sch 2(A1);
hence thesis;
end;
theorem Th75:
for y being positive decreasing_infinitely Surreal-Sequence
for r being Sequence of REAL st A c= dom r/\dom y holds
Sum((-r) |A,y|A) == - Sum(r|A,y|A)
proof
let y be positive decreasing_infinitely Surreal-Sequence;
let r be Sequence of REAL;
set mr=-r;
defpred P[Ordinal] means $1 c= dom r/\dom y
implies Sum(mr |$1,y|$1) == - Sum(r|$1,y|$1);
A1:for A being Ordinal st for C being Ordinal st C in A holds P[C] holds P[A]
proof
let A be Ordinal such that
A2: for C being Ordinal st C in A holds P[C];
assume
A3: A c= dom r/\dom y;
A4: dom mr=dom r by VALUED_1:8;
reconsider Sr=[{Sum(r|B,y|B) + uReal.(r.B - e) * y..B
where B is Element of A,e: B in A},
{Sum(r|B,y|B) + uReal.(r.B + e) * y..B
where B is Element of A,e: B in A}] as Surreal by A3,Th61;
reconsider Smr=[{Sum(mr|B,y|B) + uReal.(mr.B - e) * y..B
where B is Element of A,e: B in A},
{Sum(mr|B,y|B) + uReal.(mr.B + e) * y..B
where B is Element of A,e: B in A}] as Surreal by A3,A4,Th61;
Unique_No Sr = Sum(r|A,y|A) & Unique_No Smr = Sum(mr|A,y|A)
by A3,A4,Th62;
then
A5: Sr == Sum(r|A,y|A) & Smr == Sum(mr|A,y|A) by SURREALO:def 10;
A6: -Sr = [-- R_Sr, -- L_Sr ] by SURREALR:7;
A7: L_(-Sr) << {Smr}
proof
let x,yy be Surreal such that A8:x in L_(-Sr) & yy in {Smr};
consider mx be Surreal such that
A9: mx in R_Sr & x = -mx by A6,A8,SURREALR:def 4;
consider B be Element of A,e such that
A10: mx = Sum(r|B,y|B) + uReal.(r.B + e) * y..B & B in A by A9;
A11: Sum(mr|B,y|B) == - Sum(r|B,y|B) by A2,A10,A3,ORDINAL1:def 2;
A12: -(r.B) = mr.B by VALUED_1:8;
-(r.B + e) = mr.B-e by A12;
then (- uReal.(r.B + e)) * y..B == uReal.(mr.B - e) * y..B
by SURREALN:56,SURREALR:54;
then - Sum(r|B,y|B) + - (uReal.(r.B + e) * y..B)
= - Sum(r|B,y|B) + (- uReal.(r.B + e)) * y..B
== Sum(mr|B,y|B) + uReal.(mr.B - e) * y..B
by A11,SURREALR:43,58;
then
A13: x == Sum(mr|B,y|B) + uReal.(mr.B - e) * y..B
by A10,A9,SURREALR:40;
Sum(mr|B,y|B) + uReal.(mr.B - e) * y..B < Sum(mr|A,y|A)
by A3,A4,A10,Th69;
then x < Sum(mr|A,y|A) by A13,SURREALO:9;
then x < Smr by A5,SURREALO:9;
hence thesis by A8,TARSKI:def 1;
end;
A14: {Smr} << R_-Sr
proof
let yy,x be Surreal such that
A15: yy in {Smr} & x in R_(-Sr);
consider mx be Surreal such that
A16: mx in L_Sr & x = -mx by A6,A15,SURREALR:def 4;
consider B be Element of A,e such that
A17: mx = Sum(r|B,y|B) + uReal.(r.B - e) * y..B & B in A by A16;
A18: Sum(mr|B,y|B) == - Sum(r|B,y|B) by A3,A17,A2,ORDINAL1:def 2;
A19: -(r.B) = mr.B by VALUED_1:8;
-(r.B - e) = mr.B+e by A19;
then (- uReal.(r.B - e)) * y..B == uReal.(mr.B + e) * y..B
by SURREALR:54,SURREALN:56;
then - Sum(r|B,y|B) + - (uReal.(r.B - e) * y..B)
= - Sum(r|B,y|B) + (- uReal.(r.B - e)) * y..B
== Sum(mr|B,y|B) + uReal.(mr.B + e) * y..B
by A18,SURREALR:43,58;
then
A20: x == Sum(mr|B,y|B) + uReal.(mr.B + e) * y..B
by A17,A16,SURREALR:40;
Sum(mr|B,y|B) + uReal.(mr.B + e) * y..B > Sum(mr|A,y|A)
by A3,A4,A17,Th69;
then x > Sum(mr|A,y|A) by A20,SURREALO:9;
then x > Smr by A5,SURREALO:9;
hence thesis by A15,TARSKI:def 1;
end;
A21: {-Sr} << R_Smr
proof
let yy,x be Surreal such that
A22: yy in {-Sr} & x in R_(Smr);
consider B be Element of A,e such that
A23: x = Sum(mr|B,y|B) + uReal.(mr.B + e) * y..B & B in A by A22;
A24: Sum(mr|B,y|B) == - Sum(r|B,y|B) by A2,A23,A3,ORDINAL1:def 2;
-(r.B) = mr.B by VALUED_1:8;
then -(r.B - e) = mr.B+e;
then (- uReal.(r.B - e)) * y..B == uReal.(mr.B + e) * y..B
by SURREALR:54,SURREALN:56;
then x == - Sum(r|B,y|B) + (- uReal.(r.B - e)) * y..B
by A23,A24,SURREALR:43;
then x == - Sum(r|B,y|B) + (- (uReal.(r.B - e) * y..B))
by SURREALR:58;
then
A25: x == - (Sum(r|B,y|B) + uReal.(r.B - e) * y..B)
by SURREALR:40;
Sum(r|B,y|B) + uReal.(r.B - e) * y..B < Sum(r|A,y|A) by A3,A23,Th69;
then Sum(r|B,y|B) + uReal.(r.B - e) * y..B < Sr by A5,SURREALO:9;
then -(Sum(r|B,y|B) + uReal.(r.B - e) * y..B) > -Sr by SURREALR:10;
then x > -Sr by A25,SURREALO:9;
hence thesis by A22,TARSKI:def 1;
end;
L_Smr << {-Sr}
proof
let x,yy be Surreal such that
A26: x in L_(Smr) & yy in {-Sr};
consider B be Element of A,e such that
A27: x = Sum(mr|B,y|B) + uReal.(mr.B - e) * y..B & B in A by A26;
A28: Sum(mr|B,y|B) == - Sum(r|B,y|B) by A2,A3,A27,ORDINAL1:def 2;
-(r.B) = mr.B by VALUED_1:8;
then -(r.B + e) = mr.B-e;
then (-uReal.(r.B + e)) * y..B == uReal.(mr.B - e) * y..B
by SURREALR:54,SURREALN:56;
then x == - Sum(r|B,y|B) + (- uReal.(r.B + e)) * y..B
by A27,A28,SURREALR:43;
then x == - Sum(r|B,y|B) + (- (uReal.(r.B + e) * y..B)) by SURREALR:58;
then
A29: x == - (Sum(r|B,y|B) + uReal.(r.B + e) * y..B) by SURREALR:40;
Sum(r|B,y|B) + uReal.(r.B + e) * y..B > Sum(r|A,y|A) by A3,A27,Th69;
then Sum(r|B,y|B) + uReal.(r.B + e) * y..B > Sr by A5,SURREALO:9;
then -(Sum(r|B,y|B) + uReal.(r.B + e) * y..B) < -Sr by SURREALR:10;
then x < -Sr by A29,SURREALO:9;
hence thesis by A26,TARSKI:def 1;
end;
then -Sr == Smr by A7,A14,A21,SURREAL0:43;
then
A30:-Sr == Sum(mr|A,y|A) by A5,SURREALO:9;
-Sum(r|A,y|A) == -Sr by SURREALR:10,A5;
hence thesis by A30,SURREALO:9;
end;
for A being Ordinal holds P[A] from ORDINAL1:sch 2(A1);
hence thesis;
end;
definition
let r be Sequence of REAL;
let y be one-to-one Sequence, yE be Sequence;
func r-extended_by(y,yE) -> Sequence of REAL means :Def14:
dom it = dom yE &
(for A,B st
A in dom y & B in dom yE & y.A = yE.B holds r.A = it.B) &
(for A st A in dom yE & not yE.A in rng y holds it.A = 0);
existence
proof
defpred P[object,object] means $2 is real &
(for A being Ordinal st
A in dom y & y.A = yE.$1 holds r.A = $2) &
(for A being Ordinal st not yE.$1 in rng y holds $2 = 0);
A1: for e being object st e in dom yE ex u being object st P[e,u]
proof
let e be object such that
A2: e in dom yE;
reconsider E=e as Ordinal by A2;
per cases;
suppose
A3: not yE.E in rng y;
take 0;
thus thesis by A3,FUNCT_1:def 3;
end;
suppose
A4: yE.E in rng y;
then consider A be object such that
A5: A in dom y & y.A = yE.E by FUNCT_1:def 3;
reconsider A as Ordinal by A5;
take rA=r.A;
thus thesis by A4,A5,FUNCT_1:def 4;
end;
end;
consider f be Function such that
A6: dom f = dom yE and
A7: for e being object st e in dom yE holds P[e,f.e] from CLASSES1:sch 1(A1);
rng f c= REAL
proof
let b be object;
assume b in rng f;
then consider a be object such that
A8: a in dom f & f.a=b by FUNCT_1:def 3;
f.a is real by A6,A7,A8;
hence thesis by A8,XREAL_0:def 1;
end;
then reconsider f as Sequence of REAL by A6,ORDINAL1:def 7,RELAT_1:def 19;
take f;
thus thesis by A6,A7;
end;
uniqueness
proof
let it1,it2 be Sequence of REAL such that
A9: dom it1 = dom yE and
A10: for A,B being Ordinal st
A in dom y & B in dom yE & y.A = yE.B holds r.A = it1.B and
A11: for A being Ordinal st A in dom yE & not yE.A in rng y holds
it1.A = 0 and
A12: dom it2 = dom yE and
A13: for A,B being Ordinal st
A in dom y & B in dom yE & y.A = yE.B holds r.A = it2.B and
A14: for A being Ordinal st A in dom yE & not yE.A in rng y holds it2.A = 0;
for x being object st x in dom it1 holds it1.x=it2.x
proof
let x be object such that
A15: x in dom it1;
reconsider A=x as Ordinal by A15;
per cases;
suppose yE.A in rng y;
then consider B be object such that
A16: B in dom y & y.B=yE.A by FUNCT_1:def 3;
reconsider B as Ordinal by A16;
it1.A = r.B by A9,A10,A15,A16;
hence thesis by A9,A13,A15,A16;
end;
suppose
A17: not yE.A in rng y;
then it1.A=0 by A9,A11,A15;
hence thesis by A9,A14,A15,A17;
end;
end;
hence thesis by A9,A12,FUNCT_1:2;
end;
end;
theorem Th76:
for y,yE being strictly_decreasing Surreal-Sequence st
rng(y|dom r) c= rng yE & rng yE is ==_distinct
holds
Sum(r,No_omega^ y) = Sum(r-extended_by(y|dom r,yE),No_omega^ yE)
proof
let y,yE be strictly_decreasing Surreal-Sequence such that
A1: rng(y|dom r) c= rng yE & rng yE is ==_distinct;
set D = dom y/\dom r,
Ny = No_omega^ y,
NyE = No_omega^ yE,
rE = r-extended_by(y|dom r,yE);
A2: dom Ny = dom y by SURREALC:def 22;
dom (r|D) = dom r /\ D & dom (Ny|D) = dom Ny /\ D by RELAT_1:61;
then
A3:dom (r|D) = D = dom (Ny|D) by A2,XBOOLE_1:17,28;
A4:y|dom r = y|D by RELAT_1:157;
A5:rng (Ny|D) c= rng NyE
proof
let b be object;
assume b in rng (Ny|D);
then consider a be object such that
A6: a in dom (Ny|D) & (Ny|D).a = b by FUNCT_1:def 3;
reconsider a as Ordinal by A6;
A7: Ny|D = No_omega^ (y|D) by SURREALC:88;
then
A8: a in dom (y|D) = dom No_omega^ (y|D) by A6,SURREALC:def 22;
then
A9: (y|D).a = (y|D)..a by Def5;
then
A10:b = No_omega^ ((y|D)..a) by A6,A7,SURREALC:def 22;
(y|D)..a in rng(y|dom r) by A8,A9,A4,FUNCT_1:def 3;
then consider c be object such that
A11: c in dom yE & yE.c = (y|D)..a by A1,FUNCT_1:def 3;
A12:c in dom NyE by A11,SURREALC:def 22;
then NyE.c = b by A11,A10,SURREALC:def 22;
hence thesis by A12,FUNCT_1:def 3;
end;
dom rE = dom yE by Def14;
then
A13: dom rE = dom NyE by SURREALC:def 22;
A14: for A,B being Ordinal st
A in dom (Ny|D) & B in dom NyE & (Ny|D).A = NyE.B
holds (r|D).A = rE.B
proof
let A,B be Ordinal such that
A15: A in dom (Ny|D) & B in dom NyE & (Ny|D).A = NyE.B;
A16: A in dom Ny & A in D by A15,RELAT_1:57;
then
A17: A in dom y by SURREALC:def 22;
then
A18:A in dom (y|D) by A16,RELAT_1:57;
then
A19: (y|D).A = (y|D)..A by Def5;
A20: dom No_omega^ (y|D) = dom (y|D) by SURREALC:def 22;
(Ny|D).A = (No_omega^ (y|D)) .A by SURREALC:88;
then
A21:(Ny|D).A = No_omega^ ((y|D)..A)
by A17,A19,A20,SURREALC:def 22,A16,RELAT_1:57;
A22:B in dom yE = dom NyE by A15,SURREALC:def 22;
then
A23:yE.B = yE..B by Def5;
then No_omega^ ((y|D)..A) == No_omega^ ((yE)..B)
by A15,A21,SURREALC:def 22;
then not No_omega^ ((y|D)..A) infinitely< No_omega^ ((yE)..B)
& not No_omega^ ((yE)..B)infinitely< No_omega^ ((y|D)..A)
by SURREALC:9;
then
A24:(y|D)..A == (yE)..B by SURREALC:25;
A25:(yE)..B in rng yE by A22,A23,FUNCT_1:def 3;
(y|D)..A in rng (y|D) by A19,A18,FUNCT_1:def 3;
then y.A = (y|D).A = yE.B by A24,A25,A1,A4,A19,A23,A16,FUNCT_1:49;
then rE.B = r.A by A22,A4,A18,Def14;
hence thesis by A16,FUNCT_1:49;
end;
for A being Ordinal st A in dom NyE & not NyE.A in rng (Ny|D)
holds rE.A = 0
proof
let A be Ordinal such that
A26: A in dom NyE & not NyE.A in rng (Ny|D);
not yE.A in rng (y|dom r)
proof
assume yE.A in rng (y|dom r);
then consider B be object such that
A27: B in dom (y|D) & (y|D).B =yE.A by A4,FUNCT_1:def 3;
reconsider B as Ordinal by A27;
A28: B in dom No_omega^ (y|D) by A27,SURREALC:def 22;
A29: Ny|D = No_omega^ (y|D) by SURREALC:88;
NyE.A = No_omega^ ((y|D)..B) =
(Ny|D).B by A26,A27,Def5,A29,A28,SURREALC:def 22;
hence thesis by A26,A29,A28,FUNCT_1:def 3;
end;
then A in dom yE & not yE.A in rng (y|dom r) by A26,SURREALC:def 22;
hence thesis by Def14;
end;
then
A30:Sum(r|D,Ny|D) = Sum(rE,NyE) by A3,A5,A13,A14,Th73;
Partial_Sums(r,Ny).D = Sum(r|D,Ny|D) by A2,Th58;
hence thesis by A30,A2,SURREALC:def 21;
end;
begin :: Product Construction for Selected Surreal Series
definition
let A,B be Ordinal;
let r,s be Sequence of REAL;
func Product(r,s,A,B) -> Function of [:A,B:],REAL means :Def15:
for a,b being Ordinal st a in A & b in B
holds it.(a,b) = r.a * s.b;
existence
proof
deffunc F(object,object) = r.$1 * s.$2;
consider f be Function such that
A1:dom f = [:A,B:] and
A2:for x,y being object st x in A & y in B holds f.(x,y) = F(x,y)
from FUNCT_3:sch 2;
rng f c= REAL
proof
let b be object;
assume b in rng f;
then consider a be object such that
A3: a in dom f & f.a =b by FUNCT_1:def 3;
consider c,d be object such that
A4: c in A & d in B & a = [c,d] by A1,A3,ZFMISC_1:def 2;
f.a = f.(c,d) by A4,BINOP_1:def 1;
then f.a = F(c,d) by A2,A4;
hence thesis by A3,XREAL_0:def 1;
end;
then reconsider f as Function of [:A,B:],REAL by A1,FUNCT_2:2;
take f;
thus thesis by A2;
end;
uniqueness
proof
let F1,F2 be Function of [:A,B:],REAL such that
A5: for a,b being Ordinal st a in A & b in B
holds F1.(a,b) = r.a * s.b and
A6: for a,b being Ordinal st a in A & b in B
holds F2.(a,b) = r.a * s.b;
A7: dom F1 = [:A,B:] = dom F2 by FUNCT_2:def 1;
for x,y being object st x in A & y in B holds F1.(x,y) = F2.(x,y)
proof
let x,y be object such that
A8: x in A & y in B;
F1.(x,y) = r.x * s.y by A5,A8;
hence thesis by A8,A6;
end;
hence thesis by A7,FUNCT_3:6;
end;
end;
definition
let A,B be Ordinal;
let y,z be strictly_decreasing Surreal-Sequence such that
A1:dom y c= A & dom z c= B;
let s be Surreal;
func (y,z,A,B) += s -> Element of Fin [:A,B:] means :Def16:
for a,b being Ordinal holds
[a,b] in it iff a in dom y & b in dom z & y..a + z..b == s;
existence
proof
set IT={[a,b] where a is Element of A, b is Element of B:
a in dom y & b in dom z & y..a + z..b == s};
A2: IT c= [:A,B:]
proof
let ab be object;
assume ab in IT;
then consider a be Element of A, b be Element of B such that
A3: ab=[a,b] & a in dom y & b in dom z & y..a + z..b == s;
thus thesis by A1,A3,ZFMISC_1:def 2;
end;
then reconsider IT as Relation;
dom IT c= dom y
proof
let d be object;
assume d in dom IT;
then consider e be object such that
A4: [d,e] in IT by XTUPLE_0:def 12;
consider a be Element of A, b be Element of B such that
A5: [d,e]=[a,b] & a in dom y & b in dom z & y..a + z..b == s by A4;
thus thesis by A5,XTUPLE_0:1;
end;
then consider ss be Ordinal-Sequence such that
A6: ss is increasing & rng ss = dom IT by Th27;
IT is Function-like
proof
let x,y1,y2 be object such that
A7: [x,y1] in IT & [x,y2] in IT;
consider a1 be Element of A, b1 be Element of B such that
A8: [x,y1]=[a1,b1] & a1 in dom y & b1 in dom z &
y..a1 + z..b1 == s by A7;
consider a2 be Element of A, b2 be Element of B such that
A9: [x,y2]=[a2,b2] & a2 in dom y & b2 in dom z &
y..a2 + z..b2 == s by A7;
A10: a1=x=a2 & b1=y1 & b2=y2 by A8,A9,XTUPLE_0:1;
then y..a1 + z..b1 == y..a1 + z..b2 by A8,A9,SURREALO:4;
then
A11: z..b1 == y..a1 + z..b2 - y..a1 by SURREALR:41,42;
A12: y..a1 - y..a1 == 0_No by SURREALR:39;
y..a1 + z..b2 +- y..a1 =
y..a1 - y..a1+ z..b2 by SURREALR:37;
then y..a1 + z..b2 +- y..a1 == 0_No + z..b2 by A12,SURREALR:43;
then
A13: z..b1 == z..b2 by A11,SURREALO:4;
A14: rng z is ==_distinct;
z.b1 = z..b1 & z.b2=z..b2 & z.b1 in rng z & z.b2 in rng z
by A8,A9,Def5,FUNCT_1:def 3;
hence thesis by A10,A8,A9,A13,A14,FUNCT_1:def 4;
end;
then reconsider IT as Function;
A15: dom (IT*ss) = dom ss by A6,RELAT_1:27;
then reconsider ITs=IT*ss as Sequence by ORDINAL1:def 7;
A16:rng IT c= dom z
proof
let d be object;
assume d in rng IT;
then consider e be object such that
A17: [e,d] in IT by XTUPLE_0:def 13;
consider a be Element of A, b be Element of B such that
A18: [e,d]=[a,b] & a in dom y & b in dom z & y..a + z..b == s by A17;
thus thesis by A18,XTUPLE_0:1;
end;
rng ITs c= rng IT by RELAT_1:26;
then rng ITs c= dom z by A16;
then reconsider ITs as Ordinal-Sequence by ORDINAL2:def 4;
for a,b be Ordinal st a in b & b in dom ITs holds ITs.b in ITs.a
proof
let a,b be Ordinal such that
A19: a in b & b in dom ITs;
a in dom ITs by A19,ORDINAL1:10;
then
A20: ITs.a = IT.(ss.a) & a in dom ss & ss.a in dom IT by FUNCT_1:12,11;
A21: ITs.b = IT.(ss.b) & b in dom ss & ss.b in dom IT by A19,FUNCT_1:12,11;
[ss.a,ITs.a] in IT by A20,FUNCT_1:def 2;
then consider a1 be Element of A, b1 be Element of B such that
A22: [ss.a,ITs.a] =[a1,b1] & a1 in dom y & b1 in dom z &
y..a1 + z..b1 == s;
[ss.b,ITs.b] in IT by A21,FUNCT_1:def 2;
then consider a2 be Element of A, b2 be Element of B such that
A23: [ss.b,ITs.b] =[a2,b2] & a2 in dom y & b2 in dom z &
y..a2 + z..b2 == s;
A24: ss.a = a1 & ITs.a=b1 & ss.b = a2 & ITs.b=b2
by A22,A23,XTUPLE_0:1;
y..a1=y.a1 & y..a2 = y.a2 by A22,A23,Def5;
then y..a2 < y..a1 by A6,A19,A21,ORDINAL2:def 12,A24,A23,SURREALC:def 11;
then y..a2 + z..b1 < y..a1 + z..b1 by SURREALR:44;
then y..a2 + z..b1 < s by A22,SURREALO:4;
then y..a2 + z..b1 < y..a2 + z..b2 by A23,SURREALO:4;
then
A25: z..b1 < y..a2 + z..b2 - y..a2 by SURREALR:42;
A26: z..b1=z.b1 & z..b2 = z.b2 by A22,A23,Def5;
A27: y..a2 - y..a2 == 0_No by SURREALR:39;
y..a2 + z..b2 +- y..a2 =y..a2 - y..a2+ z..b2 by SURREALR:37;
then
A28: y..a2 + z..b2 +- y..a2 == 0_No + z..b2 by A27,SURREALR:43;
then
A29: z..b1 < z..b2 by A25,SURREALO:4;
not z..b2 < z..b1 by A29,SURREALO:6;
then not b1 in b2 by A26,A23,SURREALC:def 11;
then b2 c< b1 by A28,A25,ORDINAL1:16;
hence thesis by A24,ORDINAL1:11;
end;
then ITs is decreasing by ORDINAL5:def 1;
then IT is finite by A6,A15,FINSET_1:8,10;
then reconsider I=IT as Element of Fin [:A,B:] by A2,FINSUB_1:def 5;
take I;
let a,b be Ordinal;
hereby assume [a,b] in I;
then consider a1 be Element of A, b1 be Element of B such that
A30: [a,b]=[a1,b1] & a1 in dom y & b1 in dom z & y..a1 + z..b1 == s;
a=a1 & b=b1 by A30,XTUPLE_0:1;
hence a in dom y & b in dom z & y..a + z..b == s by A30;
end;
thus thesis by A1;
end;
uniqueness
proof
let F1,F2 be Element of Fin [:A,B:] such that
A31:for a,b being Ordinal holds
[a,b] in F1 iff a in dom y & b in dom z & y..a + z..b == s and
A32:for a,b being Ordinal holds
[a,b] in F2 iff a in dom y & b in dom z & y..a + z..b == s;
A33: F1 c= F2
proof
let x be object;
A34: F1 c= [:A,B:] by FINSUB_1:def 5;
assume
A35: x in F1;
then consider a,b be object such that
A36: a in A & b in B & x=[a,b] by A34,ZFMISC_1:def 2;
reconsider a,b as Ordinal by A36;
y..a + z..b == s & a in dom y & b in dom z by A31,A35,A36;
hence thesis by A32,A36;
end;
F2 c= F1
proof
let x be object;
A37: F2 c= [:A,B:] by FINSUB_1:def 5;
assume
A38: x in F2;
then consider a,b be object such that
A39: a in A & b in B & x=[a,b] by A37,ZFMISC_1:def 2;
reconsider a,b as Ordinal by A39;
y..a + z..b == s & a in dom y & b in dom z by A32,A38,A39;
hence thesis by A31,A39;
end;
hence thesis by A33;
end;
end;
theorem Th77:
dom y c= A & dom z c= B & a==b implies (y,z,A,B) += a c= (y,z,A,B) += b
proof
assume that
A1: dom y c= A & dom z c= B and
A2: a==b;
let x be object;
A3: (y,z,A,B) += a c= [:A,B:] by FINSUB_1:def 5;
assume
A4:x in (y,z,A,B) += a;
then consider i,j be object such that
A5: i in A & j in B & x=[i,j] by A3,ZFMISC_1:def 2;
reconsider i,j as Ordinal by A5;
A6:i in dom y & j in dom z & y..i + z..j == a by A4,A1,A5,Def16;
then y..i + z..j == b by A2,SURREALO:4;
hence thesis by A1,A5,A6,Def16;
end;
theorem Th78:
for c st dom y c= A & dom z c= B &
for a st a==c holds not a in rng y ++ rng z
holds (y,z,A,B) += c = {}
proof
let c such that
A1: dom y c= A & dom z c= B and
A2:for a being Surreal st a==c holds not a in rng y ++ rng z;
assume (y,z,A,B) += c <> {};
then consider x be object such that
A3: x in (y,z,A,B) += c by XBOOLE_0:def 1;
(y,z,A,B) += c c= [:A,B:] by FINSUB_1:def 5;
then consider i,j be object such that
A4: i in A & j in B & x=[i,j] by A3,ZFMISC_1:def 2;
reconsider i,j as Ordinal by A4;
A5:i in dom y & j in dom z & y..i + z..j == c by A3,A1,A4,Def16;
y.i =y..i & z.j = z..j by A5,Def5;
then y..i in rng y & z..j in rng z by A5,FUNCT_1:def 3;
then y..i + z..j in rng y ++ rng z by SURREALR:def 8;
hence contradiction by A5,A2;
end;
Lm4:for x,y being Surreal
for a,b,c,d,e being Real holds
uReal.(a-b) * (x + uReal.(c + d) * y)
+ uReal.b * (x + uReal.(c - e) * y) ==
uReal.a *x + uReal.(a*c -b*e+d*(a-b))* y
proof
let x,y be Surreal, a,b,c,d,e be Real;
A1:uReal.(a-b) * (x + uReal.(c + d) * y) ==
uReal.(a-b) * x + uReal.(a-b) * (uReal.(c + d) * y) by SURREALR:67;
uReal.(a-b) * (uReal.(c + d) * y) ==
(uReal.(a-b) * uReal.(c + d)) * y ==
uReal.((a-b)*(c + d)) * y by SURREALN:57,SURREALR:54,69;
then uReal.(a-b) * (uReal.(c + d) * y) ==
uReal.((a-b)*(c + d)) * y by SURREALO:9;
then uReal.(a-b) * x + uReal.(a-b) * (uReal.(c + d) * y) ==
uReal.(a-b) * x + uReal.((a-b)*(c + d)) * y by SURREALR:43;
then
A2:uReal.(a-b) * (x + uReal.(c + d) * y) ==
uReal.(a-b) * x + uReal.((a-b)*(c + d)) * y by A1,SURREALO:9;
A3:uReal.b * (x + uReal.(c - e) * y) ==
uReal.b * x + uReal.b *(uReal.(c - e) * y) by SURREALR:67;
uReal.b *(uReal.(c - e) * y) ==
(uReal.b *uReal.(c - e)) * y ==
uReal.(b*(c - e))*y by SURREALN:57,SURREALR:54,69;
then uReal.b *(uReal.(c - e) * y) ==
uReal.(b*(c - e))*y by SURREALO:9;
then uReal.b * x + uReal.b *(uReal.(c - e) * y) ==
uReal.b * x + uReal.(b*(c - e)) * y by SURREALR:43;
then uReal.b * (x + uReal.(c - e) * y) ==
uReal.b * x + uReal.(b*(c - e)) * y by A3,SURREALO:9;
then
A4: uReal.(a-b) * (x + uReal.(c + d) * y)
+ uReal.b * (x + uReal.(c - e) * y) ==
uReal.(a-b) * x + uReal.((a-b)*(c + d)) * y
+(uReal.b * x + uReal.(b*(c - e)) * y) by A2,SURREALR:43;
A5:uReal.(a-b) * x + uReal.((a-b)*(c + d)) * y +uReal.b * x
== uReal.((a-b)+b) * x + uReal.((a-b)*(c + d)) * y by Th30;
uReal.(a-b) * x + uReal.((a-b)*(c + d)) * y
+(uReal.b * x + uReal.(b*(c - e)) * y) =
(uReal.(a-b) * x + uReal.((a-b)*(c + d)) * y
+uReal.b * x) + uReal.(b*(c - e)) * y by SURREALR:37;
then uReal.(a-b) * x + uReal.((a-b)*(c + d)) * y
+(uReal.b * x + uReal.(b*(c - e)) * y) ==
uReal.a * x + uReal.((a-b)*(c + d)) * y + uReal.(b*(c - e)) * y
== uReal.a * x + uReal.((a-b)*(c + d)+b*(c - e)) * y
by Th30,A5,SURREALR:43;
then uReal.(a-b) * x + uReal.((a-b)*(c + d)) * y
+(uReal.b * x + uReal.(b*(c - e)) * y) ==
uReal.a * x + uReal.((a-b)*(c + d)+b*(c - e)) * y by SURREALO:4;
hence thesis by A4,SURREALO:4;
end;
Lm5: for y being positive decreasing_infinitely Surreal-Sequence
for x being positive Real
for A st A c= dom r/\dom y holds
Sum((x(#)r) |A,y|A) == uReal.x * Sum(r|A,y|A)
proof
let y be positive decreasing_infinitely Surreal-Sequence;
:: let r be Sequence of REAL;
let x be positive Real;
reconsider X=[{uReal.(x-e1):x-e1>0},
the set of all uReal.(x+e2)] as Surreal by Th50;
A1:X== uReal.x by Th55;
set xr=x(#)r;
defpred P[Ordinal] means $1 c= dom r/\dom y implies
Sum(xr |$1,y|$1) == uReal.x * Sum(r|$1,y|$1);
A2:for A being Ordinal st for C being Ordinal st C in A holds P[C] holds P[A]
proof
let A be Ordinal such that
A3: for C being Ordinal st C in A holds P[C];
assume
A4: A c= dom r/\dom y;
A5: dom xr=dom r by VALUED_1:def 5;
reconsider Sr=[{Sum(r|B,y|B) + uReal.(r.B - e) * y..B
where B is Element of A,e: B in A},
{Sum(r|B,y|B) + uReal.(r.B + e) * y..B
where B is Element of A,e: B in A}] as Surreal by A4,Th61;
reconsider Sxr=[{Sum(xr|B,y|B) + uReal.(xr.B - e) * y..B
where B is Element of A,e: B in A},
{Sum(xr|B,y|B) + uReal.(xr.B + e) * y..B
where B is Element of A,e: B in A}] as Surreal by A4,A5,Th61;
A6: Unique_No Sr = Sum(r|A,y|A) & Unique_No Sxr = Sum(xr|A,y|A) by A4,A5,Th62;
then
A7: Sr == Sum(r|A,y|A) & Sxr == Sum(xr|A,y|A) by SURREALO:def 10;
A8: X*Sr = [comp(L_X,X,Sr,L_Sr) \/ comp(R_X,X,Sr,R_Sr),
comp(L_X,X,Sr,R_Sr) \/ comp(R_X,X,Sr,L_Sr)] by SURREALR:50;
A9:L_(X*Sr) << {Sxr}
proof
let xx,yy be Surreal such that
A10: xx in L_(X*Sr) & yy in {Sxr};
per cases by A10,A8,XBOOLE_0:def 3;
suppose xx in comp(L_X,X,Sr,L_Sr);
then consider x1,y1 be Surreal such that
A11: xx = x1*Sr + X*y1 - x1*y1 & x1 in L_X & y1 in L_Sr by SURREALR:def 15;
consider e1 such that
A12: x1 = uReal.(x-e1) & x-e1 >0 by A11;
reconsider xe1=x-e1 as positive Real by A12;
consider B be Element of A,e2 such that
A13: y1 = Sum(r|B,y|B) + uReal.(r.B - e2) * y..B & B in A by A11;
set SB=Sum(r|B,y|B);
A14: xx = x1*Sr + (X*y1 +- x1*y1) by A11,SURREALR:37
.= x1*Sr + (X*y1 +(- x1)*y1) by SURREALR:58;
X+-(x1) == uReal.x -x1 == uReal.(x -(x-e1))
by A12,Th32,A1,SURREALR:43;
then X+-(x1)==uReal.(e1) by SURREALO:4;
then X*y1 +(- x1)*y1 == (X+-(x1)) *y1 == uReal.(e1) * y1
by SURREALR:54,67;
then X*y1 +(- x1)*y1 == uReal.(e1) * y1 by SURREALO:4;
then
A15: xx == x1*Sr + uReal.(e1) * y1 by A14,SURREALR:43;
set e3= e1*e2/2/xe1;
A16: uReal.xe1 is positive;
Sr in {Sr} << R_Sr & SB + uReal.(r.B + e3) * y..B in R_Sr
by A13,TARSKI:def 1,SURREALO:11;
then Sr < SB + uReal.(r.B + e3) * y..B;
then x1* Sr < uReal.xe1 * (SB + uReal.(r.B + e3) * y..B)
by A16,A12,SURREALR:70;
then x1*Sr + uReal.(e1) * y1
< uReal.xe1 * (SB + uReal.(r.B + e3) * y..B)
+ uReal.e1 * y1 by SURREALR:44;
then
A17: xx < uReal.xe1 * (SB + uReal.(r.B + e3) * y..B)
+ uReal.e1 * (SB + uReal.(r.B - e2) * y..B)
by A13,A15,SURREALO:4;
A18: e1*e2 - e3*xe1 = e1*e2 - e1*e2/2 by XCMPLX_1:87
.= e1*e2/2;
A19: x*(r.B) = xr.B by VALUED_1:6;
uReal.xe1 * (SB + uReal.(r.B + e3) * y..B)
+ uReal.e1 * (SB + uReal.(r.B - e2) * y..B)==
uReal.x * SB + uReal.(x*(r.B) -e1*e2+e3*xe1)*y..B by Lm4;
then
A20: xx < uReal.x * SB + uReal.(x*(r.B) -e1*e2+e3*xe1)*y..B
by A17,SURREALO:4;
B c= dom r/\dom y by A4,A13,ORDINAL1:5;
then uReal.x * SB == Sum(xr|B,y|B) by A3,A13;
then uReal.x * SB + uReal.(x*(r.B) -e1*e2+e3*xe1)*y..B
== Sum(xr|B,y|B) + uReal.(xr.B - e1*e2/2)*y..B
by A18,A19,SURREALR:43;
then xx <= Sum(xr|B,y|B) + uReal.(xr.B - e1*e2/2)*y..B
in L_Sxr << {Sxr} by A13,A20,SURREALO:4,11;
hence thesis by A10,SURREALO:4;
end;
suppose xx in comp(R_X,X,Sr,R_Sr);
then consider x1,y1 be Surreal such that
A21: xx = x1*Sr + X*y1 - x1*y1 & x1 in R_X & y1 in R_Sr by SURREALR:def 15;
consider e1 such that
A22: x1 = uReal.(x+e1) by A21;
reconsider xe1=x+e1 as positive Real;
consider B be Element of A,e2 such that
A23: y1 = Sum(r|B,y|B) + uReal.(r.B + e2) * y..B & B in A by A21;
set SB=Sum(r|B,y|B);
A24: xx = x1*Sr + (X*y1 +- x1*y1) by A21,SURREALR:37
.= x1*Sr + (X*y1 +(- x1)*y1) by SURREALR:58;
X+-(x1) == uReal.x -x1 == uReal.(x -(x+e1)) by A22,Th32,A1,SURREALR:43;
then X+-(x1)==uReal.(-e1) by SURREALO:4;
then X*y1 +(- x1)*y1 == (X+-(x1)) *y1 == uReal.(-e1) * y1
by SURREALR:54,67;
then X*y1 +(- x1)*y1 == uReal.(-e1) * y1 by SURREALO:4;
then
A25: xx == x1*Sr + uReal.(-e1) * y1 by A24,SURREALR:43;
set e3= e1*e2/2/xe1;
A26: uReal.xe1 is positive;
Sr in {Sr} << R_Sr & SB + uReal.(r.B + e3) * y..B in R_Sr
by A23,TARSKI:def 1,SURREALO:11;
then Sr < SB + uReal.(r.B + e3) * y..B;
then x1* Sr < uReal.xe1 * (SB + uReal.(r.B + e3) * y..B)
by A26,A22,SURREALR:70;
then x1*Sr + uReal.(-e1) * y1
< uReal.xe1 * (SB + uReal.(r.B + e3) * y..B)
+ uReal.(-e1) * y1 by SURREALR:44;
then
A27: xx < uReal.xe1 * (SB + uReal.(r.B + e3) * y..B)
+ uReal.(-e1) * (SB + uReal.(r.B + e2) * y..B)
by A23,A25,SURREALO:4;
A28: e1*e2 - e3*xe1 = e1*e2 - e1*e2/2 by XCMPLX_1:87
.= e1*e2/2;
A29: x*(r.B) = xr.B by VALUED_1:6;
uReal.(x- -e1) * (SB + uReal.(r.B + e3) * y..B)
+ uReal.(-e1) * (SB + uReal.(r.B - - e2) * y..B)==
uReal.x * SB + uReal.(x*(r.B) -(-e1)*(-e2)+e3*xe1)*y..B by Lm4;
then
A30: xx < uReal.x * SB + uReal.(x*(r.B) -e1*e2+e3*xe1)*y..B
by A27,SURREALO:4;
B c= dom r/\dom y by A4,A23,ORDINAL1:5;
then uReal.x * SB == Sum(xr|B,y|B) by A3,A23;
then uReal.x * SB + uReal.(x*(r.B) -e1*e2+e3*xe1)*y..B
== Sum(xr|B,y|B) + uReal.(xr.B - e1*e2/2)*y..B by A29,A28,SURREALR:43;
then xx <= Sum(xr|B,y|B) + uReal.(xr.B - e1*e2/2)*y..B
in L_Sxr << {Sxr} by A23,A30,SURREALO:4,11;
hence thesis by A10,SURREALO:4;
end;
end;
A31:L_Sxr << {X*Sr}
proof
let xx,yy be Surreal such that
A32: xx in L_Sxr & yy in {X*Sr};
consider B be Element of A,e such that
A33: xx= Sum(xr|B,y|B) + uReal.(xr.B - e) * y..B & B in A by A32;
set SB=Sum(r|B,y|B);
Sum(xr|B,y|B) == uReal.x * SB == X*SB
by A33,Th55,A3,SURREALR:54,A4,ORDINAL1:def 2;
then
A34: Sum(xr|B,y|B) == X*SB by SURREALO:4;
uReal.x is positive;
then
A35: 0_No < X by A1,SURREALO:4;
SB + uReal.(r.B - e/x) * y..B < Sr by A4,A33,Th69,A7,SURREALO:4;
then
A36: X*(SB + uReal.(r.B - e/x) * y..B) < X*Sr by A35,SURREALR:70;
xr.B = x * r.B & x * (e/x) = e by VALUED_1:6,XCMPLX_1:87;
then x *(r.B - e/x) = xr.B -e;
then
A37: (uReal.x) * uReal.(r.B - e/x) * y..B == uReal.( xr.B -e) * y..B
by SURREALR:54,SURREALN:57;
X*(uReal.(r.B - e/x) * y..B) == (uReal.x) * (uReal.(r.B - e/x) * y..B)
== (uReal.x) * uReal.(r.B - e/x) * y..B
by Th55,SURREALR:54,69;
then X*(uReal.(r.B - e/x) * y..B)
== (uReal.x) * uReal.(r.B - e/x) * y..B by SURREALO:4;
then
A38: X*(uReal.(r.B - e/x) * y..B) == uReal.( xr.B -e) * y..B
by A37,SURREALO:4;
X*(SB + uReal.(r.B - e/x) * y..B)
== X*SB + X*(uReal.(r.B - e/x) * y..B)
== xx by A33,A34,A38,SURREALR:67,SURREALR:43;
then X*(SB + uReal.(r.B - e/x) * y..B) == xx by SURREALO:4;
then X*Sr > xx by A36,SURREALO:4;
hence thesis by A32,TARSKI:def 1;
end;
A39: {Sxr} << R_(X*Sr)
proof
let yy,xx be Surreal such that
A40: yy in {Sxr} & xx in R_(X*Sr);
per cases by A40,A8,XBOOLE_0:def 3;
suppose xx in comp(L_X,X,Sr,R_Sr);
then consider x1,y1 be Surreal such that
A41: xx = x1*Sr + X*y1 - x1*y1 & x1 in L_X & y1 in R_Sr
by SURREALR:def 15;
consider e1 such that
A42: x1 = uReal.(x-e1) & x-e1 >0 by A41;
reconsider xe1=x-e1 as positive Real by A42;
consider B be Element of A,e2 such that
A43: y1 = Sum(r|B,y|B) + uReal.(r.B + e2) * y..B & B in A by A41;
set SB=Sum(r|B,y|B);
A44: xx = x1*Sr + (X*y1 +- x1*y1) by A41,SURREALR:37
.= x1*Sr + (X*y1 +(- x1)*y1) by SURREALR:58;
X+-(x1) == uReal.x -x1 == uReal.(x -(x-e1))
by A42,Th32,A1,SURREALR:43;
then X+-(x1)==uReal.(e1) by SURREALO:4;
then X*y1 +(- x1)*y1 == (X+-(x1)) *y1 == uReal.(e1) * y1
by SURREALR:54,67;
then X*y1 +(- x1)*y1 == uReal.(e1) * y1 by SURREALO:4;
then
A45: xx == x1*Sr + uReal.(e1) * y1 by A44,SURREALR:43;
set e3= e1*e2/2/xe1;
A46: uReal.xe1 is positive;
Sr in {Sr} & L_Sr << {Sr} & SB + uReal.(r.B - e3) * y..B in L_Sr
by A43,TARSKI:def 1,SURREALO:11;
then Sr > SB + uReal.(r.B - e3) * y..B;
then x1* Sr > uReal.xe1 * (SB + uReal.(r.B - e3) * y..B)
by A46,A42,SURREALR:70;
then x1*Sr + uReal.(e1) * y1
> uReal.xe1 * (SB + uReal.(r.B - e3) * y..B)
+ uReal.e1 * y1 by SURREALR:44;
then
A47: xx > uReal.xe1 * (SB + uReal.(r.B - e3) * y..B)
+ uReal.e1 * (SB + uReal.(r.B + e2) * y..B) by A43,A45,SURREALO:4;
A48: e1*e2 - e3*xe1 = e1*e2 - e1*e2/2 by XCMPLX_1:87
.= e1*e2/2;
A49: x*(r.B) = xr.B by VALUED_1:6;
uReal.xe1 * (SB + uReal.(r.B + - e3) * y..B)
+ uReal.e1 * (SB + uReal.(r.B - - e2) * y..B)==
uReal.x * SB + uReal.(x*(r.B) -e1*(-e2)+(-e3)*xe1)*y..B by Lm4;
then
A50: xx > uReal.x * SB + uReal.(x*(r.B) +e1*e2 - e3*xe1)*y..B
by A47,SURREALO:4;
B c= dom r/\dom y by A4,A43,ORDINAL1:5;
then uReal.x * SB == Sum(xr|B,y|B) by A3,A43;
then uReal.x * SB + uReal.(x*(r.B) +e1*e2-e3*xe1)*y..B
== Sum(xr|B,y|B) + uReal.(xr.B + e1*e2/2)*y..B
by A48,A49,SURREALR:43;
then
A51: xx > Sum(xr|B,y|B) + uReal.(xr.B + e1*e2/2)*y..B in R_Sxr
& {Sxr} << R_Sxr by A43,A50,SURREALO:4,11;
then Sum(xr|B,y|B) + uReal.(xr.B + e1*e2/2)*y..B > yy by A40;
then Sum(xr|B,y|B) + uReal.(xr.B + e1*e2/2)*y..B >= yy
by SURREALO:6;
hence thesis by A51,SURREALO:4;
end;
suppose xx in comp(R_X,X,Sr,L_Sr);
then consider x1,y1 be Surreal such that
A52: xx = x1*Sr + X*y1 - x1*y1 & x1 in R_X & y1 in L_Sr
by SURREALR:def 15;
consider e1 such that
A53: x1 = uReal.(x+e1) by A52;
reconsider xe1=x+e1 as positive Real;
consider B be Element of A,e2 such that
A54: y1 = Sum(r|B,y|B) + uReal.(r.B - e2) * y..B & B in A by A52;
set SB=Sum(r|B,y|B);
A55: xx = x1*Sr + (X*y1 +- x1*y1) by A52,SURREALR:37
.= x1*Sr + (X*y1 +(- x1)*y1) by SURREALR:58;
X+-(x1) == uReal.x -x1 == uReal.(x -(x+e1))
by A53,Th32,A1,SURREALR:43;
then X+-(x1)==uReal.(-e1) by SURREALO:4;
then X*y1 +(- x1)*y1 == (X+-(x1)) *y1 == uReal.(-e1) * y1
by SURREALR:54,67;
then X*y1 +(- x1)*y1 == uReal.(-e1) * y1 by SURREALO:4;
then
A56: xx == x1*Sr + uReal.(-e1) * y1 by A55,SURREALR:43;
set e3= e1*e2/2/xe1;
A57: uReal.xe1 is positive;
Sr in {Sr} & SB + uReal.(r.B - e3) * y..B in L_Sr << {Sr}
by A54,TARSKI:def 1,SURREALO:11;
then Sr > SB + uReal.(r.B - e3) * y..B;
then x1* Sr > uReal.xe1 * (SB + uReal.(r.B - e3) * y..B)
by A57,A53,SURREALR:70;
then x1*Sr + uReal.(-e1) * y1
> uReal.xe1 * (SB + uReal.(r.B - e3) * y..B)
+ uReal.(-e1) * y1 by SURREALR:44;
then
A58: xx > uReal.xe1 * (SB + uReal.(r.B - e3) * y..B)
+ uReal.(-e1) * (SB + uReal.(r.B - e2) * y..B)
by A54,A56,SURREALO:4;
A59: e1*e2 - e3*xe1 = e1*e2 - e1*e2/2 by XCMPLX_1:87
.= e1*e2/2;
A60: x*(r.B) = xr.B by VALUED_1:6;
uReal.(x- -e1) * (SB + uReal.(r.B + - e3) * y..B)
+ uReal.(-e1) * (SB + uReal.(r.B - e2) * y..B)==
uReal.x * SB + uReal.(x*(r.B) -(-e1)*e2+(-e3)*xe1)*y..B by Lm4;
then
A61: xx > uReal.x * SB + uReal.(x*(r.B) +e1*e2-e3*xe1)*y..B
by A58,SURREALO:4;
B c= dom r/\dom y by A4,A54,ORDINAL1:5;
then uReal.x * SB == Sum(xr|B,y|B) by A3,A54;
then uReal.x * SB + uReal.(x*(r.B) +e1*e2-e3*xe1)*y..B
== Sum(xr|B,y|B) + uReal.(xr.B + e1*e2/2)*y..B by A59,A60,SURREALR:43;
then
A62: xx > Sum(xr|B,y|B) + uReal.(xr.B + e1*e2/2)*y..B in R_Sxr
by A54,A61,SURREALO:4;
{Sxr} << R_Sxr by SURREALO:11;
then Sum(xr|B,y|B) + uReal.(xr.B + e1*e2/2)*y..B > yy by A62,A40;
then Sum(xr|B,y|B) + uReal.(xr.B + e1*e2/2)*y..B >= yy by SURREALO:6;
hence thesis by A62,SURREALO:4;
end;
end;
{X*Sr} << R_Sxr
proof
let yy,xx be Surreal such that
A63: yy in {X*Sr} & xx in R_Sxr;
consider B be Element of A,e such that
A64: xx= Sum(xr|B,y|B) + uReal.(xr.B + e) * y..B & B in A by A63;
set SB=Sum(r|B,y|B);
Sum(xr|B,y|B) == uReal.x * SB == X*SB
by A4,A64,ORDINAL1:def 2,Th55,A3,SURREALR:54;
then
A65: Sum(xr|B,y|B) == X*SB by SURREALO:4;
uReal.x is positive;
then
A66: 0_No < X by A1,SURREALO:4;
SB + uReal.(r.B + e/x) * y..B > Sr by A4,A64,Th69,A7,SURREALO:4;
then
A67: X*(SB + uReal.(r.B + e/x) * y..B) > X*Sr by A66,SURREALR:70;
xr.B = x * r.B & x * (e/x) = e by VALUED_1:6,XCMPLX_1:87;
then x *(r.B + e/x) = xr.B +e;
then
A68: (uReal.x) * uReal.(r.B + e/x) * y..B == uReal.( xr.B +e) * y..B
by SURREALR:54,SURREALN:57;
X*(uReal.(r.B + e/x) * y..B) == (uReal.x) * (uReal.(r.B + e/x) * y..B)
== (uReal.x) * uReal.(r.B + e/x) * y..B
by Th55,SURREALR:54,69;
then X*(uReal.(r.B + e/x) * y..B)
== (uReal.x) * uReal.(r.B + e/x) * y..B by SURREALO:4;
then
A69: X*(uReal.(r.B + e/x) * y..B) == uReal.( xr.B +e) * y..B
by A68,SURREALO:4;
X*(SB + uReal.(r.B + e/x) * y..B)
== X*SB + X*(uReal.(r.B + e/x) * y..B)
== xx by A64,A65,A69,SURREALR:67,SURREALR:43;
then X*(SB + uReal.(r.B + e/x) * y..B) == xx by SURREALO:4;
then X*Sr < xx by A67,SURREALO:4;
hence thesis by A63,TARSKI:def 1;
end;
then
A70:X*Sr == Sxr by A9,A31,A39,SURREAL0:43;
X*Sr == X*Sum(r|A,y|A) == uReal.x * Sum(r|A,y|A)
by Th55,A6,SURREALO:def 10,SURREALR:54;
then X*Sr == uReal.x * Sum(r|A,y|A) by SURREALO:4;
then uReal.x * Sum(r|A,y|A) == Sxr by A70,SURREALO:4;
hence thesis by A7,SURREALO:4;
end;
for A being Ordinal holds P[A] from ORDINAL1:sch 2(A2);
hence thesis;
end;
theorem Th79:
for y being positive decreasing_infinitely Surreal-Sequence
for x being Real st A c= dom r/\dom y
holds Sum((x(#)r) |A,y|A) == uReal.x * Sum(r|A,y|A)
proof
let y be positive decreasing_infinitely Surreal-Sequence;
let x be Real such that
A1: A c= dom r/\dom y;
per cases;
suppose x >0;
hence thesis by A1,Lm5;
end;
suppose
A2: x=0;
rng ((x(#)r) |A) c= {0}
proof
let y be object;
assume y in rng ((x(#)r) |A);
then consider a be object such that
A3: a in dom ((x(#)r) |A) & ((x(#)r) |A).a=y by FUNCT_1:def 3;
y = (x(#)r).a = x * (r.a) by A3,FUNCT_1:47,VALUED_1:6;
hence thesis by A2,TARSKI:def 1;
end;
hence thesis by A2,Th66,SURREALN:47;
end;
suppose x <0;
then reconsider mx=-x as positive Real;
A4: dom (mx(#)r)=dom r by VALUED_1:def 5;
-(mx(#)r) = (-1) (#) (mx(#)r) by VALUED_1:def 6
.= ((-1)*mx) (#)r by VALUED_2:16;
then
A5: - Sum((mx(#)r) |A,y|A) == Sum((x(#)r) |A,y|A) by A4,A1,Th75;
Sum((mx(#)r) |A,y|A) == uReal.mx * Sum(r|A,y|A) by A1,Lm5;
then
A6: - Sum((mx(#)r) |A,y|A) == - (uReal.mx * Sum(r|A,y|A))
= (- uReal.mx) * Sum(r|A,y|A) by SURREALR:10,58;
(- uReal.mx) * Sum(r|A,y|A) == uReal.(-mx) * Sum(r|A,y|A)
by SURREALN:56,SURREALR:54;
then - Sum((mx(#)r) |A,y|A) == uReal.(-mx) * Sum(r|A,y|A) by A6,SURREALO:4;
hence thesis by A5,SURREALO:4;
end;
end;
definition
let s be Surreal-Sequence;
let a be Surreal;
func s+a -> Surreal-Sequence means :Def17:
dom it = dom s &
for A st A in dom s holds it.A = s..A +a;
existence
proof
defpred P[object,object] means $2 = s..$1 +a;
A1: for e being object st e in dom s ex u being object st P[e,u];
consider IT be Function such that
A2: dom IT = dom s &
for e being object st e in dom s holds P[e,IT.e] from CLASSES1:sch 1(A1);
for o being object st o in rng IT holds o is Surreal
proof
let o be object such that
A3: o in rng IT;
consider x be object such that
A4: x in dom IT & IT.x = o by A3,FUNCT_1:def 3;
IT.x = s..x +a by A2,A4;
hence thesis by A4;
end;
then rng IT is surreal-membered;
then reconsider IT as Surreal-Sequence
by A2,SURREALC:def 9,ORDINAL1:def 7;
take IT;
thus thesis by A2;
end;
uniqueness
proof
let s1,s2 be Surreal-Sequence such that
A5: dom s1 = dom s &
for O being Ordinal st O in dom s holds s1.O = s..O +a
and
A6: dom s2 = dom s &
for O being Ordinal st O in dom s holds s2.O = s..O+a;
for x being object st x in dom s holds s1.x = s2.x
proof
let x be object such that
A7: x in dom s;
s1.x = s..x +a by A5,A7;
hence thesis by A6,A7;
end;
hence thesis by A5,A6,FUNCT_1:2;
end;
end;
registration
let s be strictly_decreasing Surreal-Sequence;
let a be Surreal;
cluster s+a -> strictly_decreasing;
coherence
proof
let A,B be Ordinal such that
A1: A in B in dom (s+a);
let sa,sb be Surreal such that
A2: sa=(s+a).A & sb=(s+a).B;
A3:dom s = dom (s+a) & A in dom (s+a) by A1,Def17,ORDINAL1:10;
then s..A = s.A & s..B = s.B by A1,Def5;
then sa= s..A +a > s..B +a
by A1,A3,SURREALC:def 11,SURREALR:44,A2,Def17;
hence thesis by A1,A2,A3,Def17;
end;
end;
theorem
for s being Surreal-Sequence holds s|A+x = (s+x) |A
proof
let s be Surreal-Sequence;
dom (s+x) = dom s by Def17;
then
A1:dom ((s+x) |A) = dom s /\A by RELAT_1:61;
A2:dom s /\A = dom (s|A) = dom (s|A+x) by Def17,RELAT_1:61;
for z being object st z in dom s /\A holds (s|A+x).z = ((s+x) |A).z
proof
let z be object;
assume
A3: z in dom s /\A;
A4: ((s+x) |A).z = (s+x).z by A1,A3,FUNCT_1:47;
z in dom s by A3,XBOOLE_0:def 4;
then
A5: s.z =s..z & (s+x).z =s..z +x by Def5,Def17;
(s|A)..z = (s|A).z = s.z by A2,A3,Def5,FUNCT_1:47;
hence thesis by A3,A4,A5,A2,Def17;
end;
hence thesis by A1,A2,FUNCT_1:2;
end;
theorem Th81:
rng (y+a) = rng y ++{a}
proof
A1:dom (y+a) = dom y by Def17;
A2:rng (y+a) c= rng y ++{a}
proof
let u be object such that
A3: u in rng (y+a);
consider x be object such that
A4: x in dom (y+a) & (y+a).x = u by A3,FUNCT_1:def 3;
A5: (y+a).x = y..x + a by A4,A1,Def17;
A6: y..x = y.x in rng y by Def5,A4,A1,FUNCT_1:def 3;
a in {a} by TARSKI:def 1;
hence thesis by A4,A5,A6,SURREALR:def 8;
end;
rng y ++{a} c= rng (y+a)
proof
let ya be object such that
A7: ya in rng y ++{a};
consider i,j be Surreal such that
A8: i in rng y & j in {a} & ya = i+j by A7,SURREALR:def 8;
consider x be object such that
A9: x in dom y & y.x = i by A8,FUNCT_1:def 3;
j=a & i = y..x by Def5,A8,A9,TARSKI:def 1;
then (y+a).x = i + j by A9,Def17;
hence thesis by FUNCT_1:def 3,A1,A9,A8;
end;
hence thesis by A2;
end;
theorem Th82:
for s being Surreal-Sequence st A in dom s holds
(No_omega^ a) * (No_omega^ s)..A == (No_omega^ (s+a))..A
proof
let s be Surreal-Sequence such that
A1: A in dom s;
A2:dom (No_omega^ s) = dom s by SURREALC:def 22;
s.A = s..A by A1,Def5;
then
A3:No_omega^ (s..A) = (No_omega^ s).A by A1,A2,SURREALC:def 22;
A4: dom (No_omega^ (s+a)) = dom (s+a) by SURREALC:def 22;
A5:dom s = dom (s+a) by Def17;
then (s+a)..A=(s+a).A = s..A +a by A1,Def17,Def5;
then (No_omega^ (s+a))..A = (No_omega^ (s+a)).A = No_omega^ (s..A +a)
by A1,A5,A4,Def5,SURREALC:def 22;
then (No_omega^ (s+a))..A == (No_omega^ (s..A)) * (No_omega^ a)
by SURREALC:27;
hence thesis by A1,A2,A3,Def5;
end;
Lm6: for a,b,c being Surreal,r,t being Real st a*b == c
holds
(a * uReal.r) * (b* uReal.t) == c * uReal.(r*t)
proof
let a,b,c be Surreal,r,t be Real such that
A1:a*b == c;
set R=uReal.r,T=uReal.t,RT=uReal.(r*t);
(a * R)*T == a * (R*T) == a * RT by SURREALN:57,SURREALR:54,69;
then (a * R)*T == a * RT by SURREALO:9;
then (R * a)*(T* b) ==(R*a)*T* b == a * RT *b by SURREALR:54,69;
then (R * a)*(T* b) == a * RT *b == RT *(a*b) by SURREALR:69,SURREALO:9;
then (R*a)*(T* b) == RT *(a*b) == RT *c by A1,SURREALR:54,SURREALO:9;
hence thesis by SURREALO:9;
end;
::Gonshor'86 Lemma 5.6
theorem Th83:
for y being strictly_decreasing Surreal-Sequence st
A c= dom r/\dom y
holds
Sum(r |A,(No_omega^ (y+a)) |A ) == No_omega^ a * Sum(r|A,(No_omega^ y) | A)
proof
let y be strictly_decreasing Surreal-Sequence;
set Ny = No_omega^ y,ya=y+a,Nya = No_omega^ ya, Na = No_omega^ a;
defpred P[Ordinal] means $1 c= dom r/\dom y
implies Sum(r |$1,Nya|$1 ) == Na * Sum(r|$1,Ny| $1);
A1:for A being Ordinal st for C being Ordinal st C in A holds P[C] holds P[A]
proof
let A be Ordinal such that
A2: for C being Ordinal st C in A holds P[C];
assume
A3: A c= dom r/\dom y;
dom ya = dom y by Def17;
then
A4: dom Nya = dom y = dom Ny by SURREALC:def 22;
reconsider
Sr=[{Sum(r|B,Ny|B) + uReal.(r.B - e) * Ny..B
where B is Element of A,e: B in A},
{Sum(r|B,Ny|B) + uReal.(r.B + e) * Ny..B
where B is Element of A,e: B in A}] as Surreal by A3,A4,Th61;
reconsider
Sra=[{Sum(r|B,Nya|B) + uReal.(r.B - e) * Nya..B
where B is Element of A,e: B in A},
{Sum(r|B,Nya|B) + uReal.(r.B + e) * Nya..B
where B is Element of A,e: B in A}] as Surreal by A3,A4,Th61;
A5: Unique_No Sr = Sum(r|A,Ny|A) & Unique_No Sra = Sum(r|A,Nya|A)
by A3,A4,Th62;
then
A6: Sr == Sum(r|A,Ny|A) & Sra == Sum(r|A,Nya|A)
by SURREALO:def 10;
A7: Na * Sr = [comp(L_Na,Na,Sr,L_Sr) \/ comp(R_Na,Na,Sr,R_Sr),
comp(L_Na,Na,Sr,R_Sr) \/ comp(R_Na,Na,Sr,L_Sr)] by SURREALR:50;
A8: L_(Na * Sr) << {Sra}
proof
let xx,yy be Surreal such that
A9: xx in L_(Na * Sr) & yy in {Sra};
per cases by A7,A9,XBOOLE_0:def 3;
suppose xx in comp(L_Na,Na,Sr,L_Sr);
then consider x1,y1 be Surreal such that
A10: xx = x1*Sr + Na*y1 - x1*y1 & x1 in L_Na & y1 in L_Sr
by SURREALR:def 15;
consider B be Element of A,e such that
A11: y1 = Sum(r|B,Ny|B) + uReal.(r.B - e) * Ny..B & B in A by A10;
A12: Sum(r |B,Nya|B ) == Na * Sum(r|B,Ny| B)
by A2,A11,A3,ORDINAL1:def 2;
A13: B in dom y by A11,A3,XBOOLE_0:def 4;
then y..B = y.B by Def5;
then
A14: Ny..B = Ny.B = No_omega^ (y..B) by Def5,A13,A4,SURREALC:def 22;
A15: Na * Ny..B == Nya..B by Th82,A13;
A16: Na*y1 == Na * Sum(r|B,Ny|B) + Na * (uReal.(r.B - e) * Ny..B)
by A11,SURREALR:67;
Na * (uReal.(r.B - e) * Ny..B) == uReal.(r.B - e) * (Na*Ny..B)
== uReal.(r.B - e) * (Nya..B) by Th82,A13,SURREALR:54,69;
then Na * (uReal.(r.B - e) * Ny..B)
== uReal.(r.B - e) * (Nya..B) by SURREALO:4;
then Na * Sum(r|B,Ny|B) + Na * (uReal.(r.B - e) * Ny..B) ==
Sum(r |B,Nya|B ) + uReal.(r.B - e) * (Nya..B) by A12,SURREALR:43;
then
A17: Na*y1 == Sum(r |B,Nya|B ) + uReal.(r.B - e) * (Nya..B)
by A16,SURREALO:4;
per cases;
suppose x1 = 0_No;
then xx < Sum(r |A,Nya|A ) by A3,A4,A11,Th69,A10,A17,SURREALO:4;
then xx < Sra by A6,SURREALO:4;
hence thesis by A9,TARSKI:def 1;
end;
suppose x1 <> 0_No;
then consider xL be Surreal, e2 such that
A18: xL in L_a & x1 = (No_omega^ xL) * uReal.e2 by A10,SURREALC:22;
Sum(r|A,Ny|A) is (Sum(r|B,Ny|B),Ny..B,r.B)_Term
by A3,A4,A11,Th68;
then
A19: |. Sum(r|A,Ny|A) - ( Sum(r|B,Ny|B) + uReal.(r.B)* Ny..B) .|
infinitely< Ny..B by SURREALC:def 14;
y1 == Sum(r|B,Ny|B) + uReal.(r.B) * Ny..B - uReal.e * Ny..B
by A11,Th30;
then y1 + uReal.e * Ny..B == Sum(r|B,Ny|B) + uReal.(r.B) * Ny..B
by SURREALR:41,42;
then -(y1 + uReal.e * Ny..B)
== -(Sum(r|B,Ny|B) + uReal.(r.B) * Ny..B) by SURREALR:65;
then Sum(r|A,Ny|A) +- ( Sum(r|B,Ny|B) + uReal.(r.B)* Ny..B)
== Sr + -(y1 + uReal.e * Ny..B) by A6,SURREALR:66;
then |.Sr + -(y1 + uReal.e * Ny..B).| infinitely< Ny..B
by A19,SURREALC:17,48;
then |.Sr + -(y1 + uReal.e * Ny..B).| infinitely<
uReal.e* Ny..B by SURREALC:13;
then Sr + -(y1 + uReal.e * Ny..B) <=
|.Sr + -(y1 + uReal.e * Ny..B).| < uReal.e * Ny..B
by SURREALC:9,34;
then
A20: Sr + -(y1 + uReal.e * Ny..B) < uReal.e * Ny..B by SURREALO:9;
Sr + -(y1 + uReal.e * Ny..B) =
Sr + (- y1 + - uReal.e * Ny..B) by SURREALR:40
.= Sr + - y1 - uReal.e * Ny..B by SURREALR:37;
then Sr + - y1 < 0_No + uReal.e * Ny..B + uReal.e * Ny..B
== 0_No + uReal.(e+e) * Ny..B by A20,SURREALR:41,Lm1;
then
A21: Sr- y1 < uReal.(e+e) * Ny..B by SURREALO:9;
a in {a} & L_a << {a} by SURREALO:11,TARSKI:def 1;
then No_omega^ xL infinitely< Na by A18,SURREALC:25;
then x1 infinitely< Na by A18,SURREALC:13;
then x1 infinitely< uReal.(1/4) * Na by SURREALC:13;
then
A22: x1 < uReal.(1/4)* Na by SURREALC:9;
A23: uReal.(e+e) * Ny..B is positive by A14;
x1 is positive by A18;
then x1*(Sr- y1) <= (uReal.(e+e) * Ny..B)*x1 <
(uReal.(e+e) * Ny..B)*(uReal.(1/4)* Na) by A21,A23,A22,SURREALR:70;
then
A24: x1*(Sr- y1) < (uReal.(e+e) * Ny..B)*(uReal.(1/4)* Na)
by SURREALO:4;
(e+e)*(1/4) =e/2;
then (uReal.(e+e)* Ny..B)*(uReal.(1/4)* Na)
== uReal.(e/2)*Nya..B by A15,Lm6;
then x1*Sr + x1*(-y1) == x1*(Sr+- y1) < uReal.(e/2)*Nya..B
by A24,SURREALO:4,SURREALR:67;
then
A25: x1*Sr + x1*(-y1) < uReal.(e/2)*Nya..B by SURREALO:4;
xx = Na*y1 + (x1*Sr + - x1*y1) by A10,SURREALR:37
.= Na*y1 + (x1*Sr + x1*(-y1)) by SURREALR:58;
then xx
< Sum(r |B,Nya|B ) + uReal.(r.B - e) * (Nya..B) + uReal.(e/2)*Nya..B
== Sum(r |B,Nya|B ) + uReal.(r.B - e +e/2) * (Nya..B)
by A17,A25,SURREALR:44,Th30;
then xx <= Sum(r |B,Nya|B) + uReal.(r.B - e/2) * (Nya..B)
by SURREALO:4;
then xx < Sum(r |A,Nya|A ) by A3,A4,A11,Th69,SURREALO:4;
then xx < Sra by A6,SURREALO:4;
hence thesis by A9,TARSKI:def 1;
end;
end;
suppose xx in comp(R_Na,Na,Sr,R_Sr);
then consider x1,y1 be Surreal such that
A26: xx = x1*Sr + Na*y1 - x1*y1 & x1 in R_Na & y1 in R_Sr
by SURREALR:def 15;
consider B be Element of A,e such that
A27: y1 = Sum(r|B,Ny|B) + uReal.(r.B + e) * Ny..B & B in A by A26;
A28: Sum(r |B,Nya|B ) == Na * Sum(r|B,Ny| B)
by A2,A27,A3,ORDINAL1:def 2;
A29: B in dom y by A27,A3,XBOOLE_0:def 4;
then y..B = y.B by Def5;
then
A30: Ny..B = Ny.B = No_omega^ (y..B)
by Def5,A29,A4,SURREALC:def 22;
A31: Na*y1 == Na * Sum(r|B,Ny|B) + Na * (uReal.(r.B + e) * Ny..B)
by A27,SURREALR:67;
Na * (uReal.(r.B + e) * Ny..B) == uReal.(r.B + e) * (Na*Ny..B)
== uReal.(r.B + e) * (Nya..B) by Th82,A29,SURREALR:54,69;
then Na * (uReal.(r.B + e) * Ny..B)
== uReal.(r.B + e) * (Nya..B) by SURREALO:4;
then Na * Sum(r|B,Ny|B) + Na * (uReal.(r.B + e) * Ny..B) ==
Sum(r |B,Nya|B ) + uReal.(r.B + e) * (Nya..B) by A28,SURREALR:43;
then
A32: Na*y1 == Sum(r |B,Nya|B) + uReal.(r.B + e) * (Nya..B)
by A31,SURREALO:4;
consider xR be Surreal, e2 such that
A33: xR in R_a & x1 = (No_omega^ xR) * uReal.e2
by A26,SURREALC:23;
Sum(r|A,Ny|A) is (Sum(r|B,Ny|B),Ny..B,r.B)_Term
by A3,A4,A27,Th68;
then
A34: |. Sum(r|A,Ny|A) - ( Sum(r|B,Ny|B) + uReal.(r.B)* Ny..B) .|
infinitely< Ny..B by SURREALC:def 14;
y1 == Sum(r|B,Ny|B) + uReal.(r.B) * Ny..B + uReal.e * Ny..B
by A27,Th30;
then y1 - uReal.e * Ny..B == Sum(r|B,Ny|B) + uReal.(r.B) * Ny..B
by SURREALR:41,42;
then -(y1 - uReal.e * Ny..B)== -(Sum(r|B,Ny|B) + uReal.(r.B) * Ny..B)
by SURREALR:65;
then Sum(r|A,Ny|A) +- ( Sum(r|B,Ny|B) + uReal.(r.B)* Ny..B)
== Sr + -(y1 - uReal.e * Ny..B) by A6,SURREALR:66;
then |.Sr + -(y1 - uReal.e * Ny..B).| infinitely< Ny..B
by A34,SURREALC:17,48;
then |.Sr + -(y1 - uReal.e * Ny..B).| infinitely< uReal.(e/2)* Ny..B
by SURREALC:13;
then (Sr + -(y1 - uReal.e * Ny..B))
<= |.Sr + -(y1 - uReal.e * Ny..B).|
< uReal.(e/2)* Ny..B by SURREALC:9,34;
then
A35: (Sr + -(y1 - uReal.e * Ny..B)) < uReal.(e/2)* Ny..B
by SURREALO:4;
Sr + -(y1 - uReal.e * Ny..B) = Sr + (- y1 + - - uReal.e * Ny..B)
by SURREALR:40
.= Sr + - y1 + uReal.e * Ny..B by SURREALR:37;
then 0_No + (uReal.(e/2-e)* Ny..B) ==
0_No + (uReal.(e/2) * Ny..B) - uReal.e * Ny..B
> Sr + - y1 by A35,SURREALR:42,Th30;
then
A36: (uReal.(-e/2) * Ny..B) > Sr + - y1 by SURREALO:9;
A37: Ny..B is positive by A30;
uReal.(-2*e) < uReal.0 =0_No by SURREALN:47,51;
then
A38: 0_No > (uReal.(-2*e) * Ny..B) by A37,SURREALR:74;
A39: x1 is positive by A33;
a in {a}<<R_a by SURREALO:11,TARSKI:def 1;
then Na infinitely< No_omega^ xR by A33,SURREALC:25;
then Na infinitely< x1 by A33,SURREALC:13;
then Na infinitely< uReal.(1/4) * x1 by SURREALC:13;
then Na < uReal.(1/4) * x1 by SURREALC:9;
then Na * (uReal.(-2*e)* Ny..B) >
(uReal.(-2*e)* Ny..B) *(uReal.(1/4) *x1)
== uReal.((-2*e)*(1/4)) * (Ny..B *x1)
by A38,SURREALR:71,Lm6;
then Na * (uReal.(-2*e) * Ny..B) >
uReal.(-e/2) * (Ny..B *x1) == (uReal.(-e/2)* Ny..B) *x1
by SURREALO:9,SURREALR:69;
then Na * (uReal.(-2*e) * Ny..B) >
(uReal.(-e/2) * Ny..B) * x1 by SURREALO:4;
then
A40: Na * (uReal.(-2*e) * Ny..B) >=
(uReal.(-e/2) * Ny..B) *x1 by SURREALO:6;
(uReal.(-e/2) * Ny..B) *x1 > (Sr + - y1) *x1
by A36,A39,SURREALR:70;
then
A41: Na * (uReal.(-2*e) * Ny..B) > (Sr + - y1) *x1 by A40,SURREALO:9;
Na * (uReal.(-2*e) * Ny..B)
== uReal.(-2*e) * (Na*Ny..B) == uReal.(-2*e)* Nya..B
by SURREALR:54,69,Th82,A29;
then Na * (uReal.(-2*e) * Ny..B) == uReal.(-2*e)* Nya..B
by SURREALO:9;
then
A42: (Sr + - y1) *x1 < uReal.(-2*e)* Nya..B by A41,SURREALO:9;
x1*Sr + x1*(-y1) == x1*(Sr+- y1) by SURREALR:67;
then
A43: x1*Sr + x1*(-y1) < uReal.(-2*e)*Nya..B
by SURREALO:4,A42;
xx = Na*y1 + (x1*Sr + - x1*y1) by A26,SURREALR:37
.= Na*y1 + (x1*Sr + x1*(-y1)) by SURREALR:58;
then xx
< Sum(r |B,Nya|B ) + uReal.(r.B + e) * (Nya..B) + uReal.(-2*e)*Nya..B
== Sum(r |B,Nya|B ) + uReal.(r.B + e +-2* e) * (Nya..B)
by A32,A43,SURREALR:44,Th30;
then
A44: xx <= Sum(r |B,Nya|B ) + uReal.(r.B +e+- 2*e) * (Nya..B)
by SURREALO:4;
Sum(r |B,Nya|B ) + uReal.(r.B - e) * (Nya..B) < Sum(r |A,Nya|A )
by A3,A4,A27,Th69;
then xx < Sum(r |A,Nya|A ) by A44,SURREALO:4;
then xx < Sra by A6,SURREALO:4;
hence thesis by A9,TARSKI:def 1;
end;
end;
A45: {Sra} << R_(Na*Sr)
proof
let yy,xx be Surreal such that
A46: yy in {Sra} & xx in R_(Na * Sr);
per cases by A7,A46,XBOOLE_0:def 3;
suppose xx in comp(L_Na,Na,Sr,R_Sr);
then consider x1,y1 be Surreal such that
A47: xx = x1*Sr + Na*y1 - x1*y1 & x1 in L_Na & y1 in R_Sr
by SURREALR:def 15;
consider B be Element of A,e such that
A48: y1 = Sum(r|B,Ny|B) + uReal.(r.B + e) * Ny..B & B in A by A47;
A49: Sum(r |B,Nya|B ) == Na * Sum(r|B,Ny| B)
by A3,A48,ORDINAL1:def 2,A2;
A50: B in dom y by A48,A3,XBOOLE_0:def 4;
then y..B = y.B by Def5;
then
A51: Ny..B = Ny.B = No_omega^ (y..B) by Def5,A50,A4,SURREALC:def 22;
A52: Na * Ny..B == Nya..B by Th82,A50;
A53: Na*y1 == Na * Sum(r|B,Ny|B) + Na * (uReal.(r.B + e) * Ny..B)
by A48,SURREALR:67;
Na * (uReal.(r.B + e) * Ny..B) == uReal.(r.B + e) * (Na*Ny..B)
== uReal.(r.B + e) * (Nya..B) by Th82,A50,SURREALR:54,69;
then Na * (uReal.(r.B + e) * Ny..B)
== uReal.(r.B + e) * (Nya..B) by SURREALO:4;
then Na * Sum(r|B,Ny|B) + Na * (uReal.(r.B + e) * Ny..B) ==
Sum(r |B,Nya|B ) + uReal.(r.B + e) * (Nya..B) by A49,SURREALR:43;
then
A54: Na*y1 == Sum(r |B,Nya|B ) + uReal.(r.B + e) * (Nya..B)
by A53,SURREALO:4;
per cases;
suppose x1 = 0_No;
then xx > Sum(r |A,Nya|A ) by A3,A4,A48,Th69,A54,A47,SURREALO:4;
then xx > Sra by A6,SURREALO:4;
hence thesis by A46,TARSKI:def 1;
end;
suppose x1 <> 0_No;
then consider xL be Surreal, e2 such that
A55: xL in L_a & x1 = (No_omega^ xL) * uReal.e2 by A47,SURREALC:22;
Sum(r|A,Ny|A) is (Sum(r|B,Ny|B),Ny..B,r.B)_Term
by A3,A4,A48,Th68;
then
A56: |. Sum(r|A,Ny|A) - ( Sum(r|B,Ny|B) + uReal.(r.B)* Ny..B) .|
infinitely< Ny..B by SURREALC:def 14;
y1 == Sum(r|B,Ny|B) + uReal.(r.B) * Ny..B + uReal.e * Ny..B
by A48,Th30;
then y1 - uReal.e * Ny..B == Sum(r|B,Ny|B) + uReal.(r.B) * Ny..B
by SURREALR:41,42;
then -(y1 - uReal.e * Ny..B)
== -(Sum(r|B,Ny|B) + uReal.(r.B) * Ny..B)
by SURREALR:65;
then Sum(r|A,Ny|A) +- ( Sum(r|B,Ny|B) + uReal.(r.B)* Ny..B)
== Sr + -(y1 - uReal.e * Ny..B) by A6,SURREALR:66;
then |.Sr + -(y1 - uReal.e * Ny..B).| infinitely< Ny..B
by A56,SURREALC:17,48;
then |.Sr + -(y1 - uReal.e * Ny..B).| infinitely< uReal.e* Ny..B
by SURREALC:13;
then |.Sr + -(y1 - uReal.e * Ny..B).| < uReal.e *Ny..B
by SURREALC:9;
then
A57: (Sr + -(y1 - uReal.e * Ny..B)) > -(uReal.e* Ny..B) by SURREALC:52;
Sr + -(y1 - uReal.e * Ny..B) =
Sr + (- y1 + - - uReal.e * Ny..B) by SURREALR:40
.= Sr + - y1 + uReal.e * Ny..B by SURREALR:37;
then
A58: - (uReal.e * Ny..B) - uReal.e * Ny..B
< Sr + - y1 by A57,SURREALR:41;
0_No + uReal.e * Ny..B +uReal.e * Ny..B ==
0_No + uReal.(e+e) * Ny..B by Th30;
then - (uReal.e * Ny..B) + - uReal.e * Ny..B =
- (uReal.e * Ny..B +uReal.e * Ny..B) ==
- (uReal.(e+e) * Ny..B) by SURREALR:40,SURREALR:10;
then
A59: - (uReal.(e+e) * Ny..B) < Sr + - y1 by A58,SURREALO:9;
a in {a} & L_a << {a} by SURREALO:11,TARSKI:def 1;
then No_omega^ xL infinitely< Na by A55,SURREALC:25;
then x1 infinitely< Na by A55,SURREALC:13;
then x1 infinitely< uReal.(1/4)* Na by SURREALC:13;
then
A60: x1 < uReal.(1/4)* Na by SURREALC:9;
uReal.(e+e) * Ny..B is positive by A51;
then
A61: - (uReal.(e+e) * Ny..B) < -0_No by SURREALR:10;
x1 is positive by A55;
then
A62: x1*(Sr- y1) > (- (uReal.(e+e) * Ny..B))*x1
> (-(uReal.(e+e) * Ny..B))*(uReal.(1/4)* Na)
by A61,A60,A59,SURREALR:70,71;
then x1*(Sr- y1) >= (- (uReal.(e+e) * Ny..B))*x1
by SURREALO:6;
then
A63: x1*(Sr- y1) > (-(uReal.(e+e) * Ny..B))*(uReal.(1/4)* Na)
= -( (uReal.(e+e) * Ny..B)*(uReal.(1/4)* Na))
by A62,SURREALO:4,SURREALR:58;
(e+e)*(1/4) = e/2;
then (uReal.(e+e)* Ny..B)*(uReal.(1/4)* Na)
== uReal.(e/2)*Nya..B
by A52,Lm6;
then - ((uReal.(e+e)* Ny..B)*(uReal.(1/4)* Na))
== -(uReal.(e/2)*Nya..B) by SURREALR:10;
then x1*Sr + x1*(-y1) == x1*(Sr+- y1) > - uReal.(e/2)*Nya..B
by SURREALR:67,A63,SURREALO:4;
then
A64: x1*Sr + x1*(-y1) > - uReal.(e/2)*Nya..B by SURREALO:4;
xx = Na*y1 + (x1*Sr + - x1*y1) by A47,SURREALR:37
.= Na*y1 + (x1*Sr + x1*(-y1)) by SURREALR:58;
then xx
> Sum(r|B,Nya|B) + uReal.(r.B + e) * (Nya..B)-uReal.(e/2)*Nya..B
== Sum(r|B,Nya|B) + uReal.(r.B + e - e/2) * (Nya..B)
by A54,A64,SURREALR:44,Th30;
then xx > Sum(r |B,Nya|B ) + uReal.(r.B + e/2) * (Nya..B)
by SURREALO:4;
then xx >= Sum(r |B,Nya|B ) + uReal.(r.B + e/2) * (Nya..B)
by SURREALO:6;
then xx > Sum(r |A,Nya|A ) by A3,A4,A48,Th69,SURREALO:4;
then xx > Sra by A6,SURREALO:4;
hence thesis by A46,TARSKI:def 1;
end;
end;
suppose xx in comp(R_Na,Na,Sr,L_Sr);
then consider x1,y1 be Surreal such that
A65: xx = x1*Sr + Na*y1 - x1*y1 & x1 in R_Na & y1 in L_Sr
by SURREALR:def 15;
consider B be Element of A,e such that
A66: y1 = Sum(r|B,Ny|B) + uReal.(r.B - e) * Ny..B & B in A by A65;
A67: Sum(r |B,Nya|B ) == Na * Sum(r|B,Ny| B) by A2,A66,A3,ORDINAL1:def 2;
A68: B in dom y by A66,A3,XBOOLE_0:def 4;
then y..B = y.B by Def5;
then
A69: Ny..B = Ny.B = No_omega^ (y..B) by Def5,A68,A4,SURREALC:def 22;
A70: Na * Ny..B == Nya..B by Th82,A68;
A71: Na*y1 == Na * Sum(r|B,Ny|B) + Na * (uReal.(r.B - e) * Ny..B)
by A66,SURREALR:67;
Na * (uReal.(r.B - e) * Ny..B) == uReal.(r.B - e) * (Na*Ny..B)
== uReal.(r.B - e) * (Nya..B) by Th82,A68,SURREALR:54,69;
then Na * (uReal.(r.B - e) * Ny..B)
== uReal.(r.B - e) * (Nya..B) by SURREALO:4;
then Na * Sum(r|B,Ny|B) + Na * (uReal.(r.B - e) * Ny..B) ==
Sum(r |B,Nya|B ) + uReal.(r.B - e) * (Nya..B) by A67,SURREALR:43;
then A72: Na*y1 == Sum(r |B,Nya|B ) + uReal.(r.B - e) * (Nya..B)
by A71,SURREALO:4;
consider xR be Surreal, e2 such that
A73: xR in R_a & x1 = (No_omega^ xR) * uReal.e2 by A65,SURREALC:23;
Sum(r|A,Ny|A) is (Sum(r|B,Ny|B),Ny..B,r.B)_Term
by A3,A4,A66,Th68;
then
A74: |. Sum(r|A,Ny|A) - ( Sum(r|B,Ny|B) + uReal.(r.B)* Ny..B) .|
infinitely< Ny..B by SURREALC:def 14;
y1 == Sum(r|B,Ny|B) + uReal.(r.B) * Ny..B - uReal.e * Ny..B
by A66,Th30;
then y1 + uReal.e * Ny..B == Sum(r|B,Ny|B) + uReal.(r.B) * Ny..B
by SURREALR:41,42;
then -(y1 + uReal.e * Ny..B) == -(Sum(r|B,Ny|B)+ uReal.(r.B)* Ny..B)
by SURREALR:65;
then Sum(r|A,Ny|A) +- ( Sum(r|B,Ny|B) + uReal.(r.B)* Ny..B)
== Sr + -(y1 + uReal.e * Ny..B) by A6,SURREALR:66;
then |.Sr + -(y1 + uReal.e * Ny..B).| infinitely< Ny..B
by A74,SURREALC:17,48;
then |.Sr + -(y1 + uReal.e * Ny..B).| infinitely< uReal.(e/2)* Ny..B
by SURREALC:13;
then
A75: |.Sr + -(y1 + uReal.e * Ny..B).|
< uReal.(e/2) * Ny..B by SURREALC:9;
Sr + -(y1 + uReal.e * Ny..B) =
Sr + (- y1 + - uReal.e * Ny..B) by SURREALR:40
.= Sr + - y1 + - uReal.e * Ny..B by SURREALR:37;
then Sr + - y1 - uReal.e * Ny..B > - uReal.(e/2) * Ny..B
by A75,SURREALC:52;
then 0_No + (uReal.(e-e/2) * Ny..B) ==
0_No+ uReal.e * Ny..B - (uReal.(e/2) * Ny..B)
< Sr + - y1 by SURREALR:42,Th30; then
A76: (uReal.(e/2) * Ny..B) < Sr + - y1 by SURREALO:9;
A77: Ny..B is positive by A69;
uReal.(e/2) > uReal.0 =0_No by SURREALN:47,51;
then
A78: 0_No < (uReal.(e/2) * Ny..B) by A77,SURREALR:72;
A79: x1 is positive by A73;
uReal.0 = 0_No=uReal.0 < uReal.(1/4) by SURREALN:47,51;
then
A80: 0_No < uReal.(1/4) *x1 by A79,SURREALR:72;
a in {a}<<R_a by SURREALO:11,TARSKI:def 1;
then Na infinitely< No_omega^ xR by A73,SURREALC:25;
then Na infinitely< x1 by A73,SURREALC:13;
then Na infinitely< uReal.(1/4) * x1 by SURREALC:13;
then Na < uReal.(1/4) * x1 by SURREALC:9;
then Na * (uReal.(e/2) * Ny..B) <=
(uReal.(e/2) * Ny..B) * (uReal.(1/4) * x1)
< (Sr + - y1) * (uReal.(1/4) *x1) by A78,A76,A80,SURREALR:70;
then
A81: Na * (uReal.(e/2) * Ny..B) < (Sr + - y1) *(uReal.(1/4) *x1)
by SURREALO:9;
uReal.0 =0_No=uReal.0 < uReal.4 by SURREALN:47,51;
then
A82: Na * (uReal.(e/2) * Ny..B) * uReal.4
< (Sr + - y1) * (uReal.(1/4) *x1) * uReal.4 by A81,SURREALR:70;
(Sr + - y1) * (uReal.(1/4) * x1) * uReal.4
== (uReal.(1/4) * x1)*((Sr + - y1) * uReal.4)
== uReal.(1/4*4) * (x1*(Sr + - y1))
by SURREALR:69,Lm6;
then (Sr + - y1) *(uReal.(1/4) * x1) * uReal.4
== uReal.1 *(x1*(Sr + - y1)) = x1 * (Sr + - y1)
by SURREALO:9,SURREALN:48;
then
A83: Na * (uReal.(e/2) * Ny..B) * uReal.4 < x1*(Sr + - y1)
by A82,SURREALO:9;
Na * (uReal.(e/2) * Ny..B) * uReal.4 ==
(uReal.(e/2) * Ny..B)*(Na * uReal.4)==
uReal.(e/2*4) * Nya..B by A70,SURREALR:69,Lm6;
then Na * (uReal.(e/2)* Ny..B) * uReal.4 ==
uReal.(2*e) * Nya..B by SURREALO:9;
then
A84: (uReal.(2*e) * Nya..B) < (Sr + - y1)*x1
by A83,SURREALO:9;
x1*Sr + x1*(-y1) == x1*(Sr+- y1) by SURREALR:67;
then
A85: x1*Sr + x1*(-y1) > uReal.(2*e)*Nya..B
by A84,SURREALO:4;
xx = Na*y1 + (x1*Sr + - x1*y1) by A65,SURREALR:37
.= Na*y1 + (x1*Sr + x1*(-y1)) by SURREALR:58;
then xx
> Sum(r |B,Nya|B ) + uReal.(r.B - e) * (Nya..B) + uReal.(2*e)*Nya..B
== Sum(r |B,Nya|B ) + uReal.(r.B - e +2* e) * (Nya..B)
by A72,A85,SURREALR:44,Th30;
then xx > Sum(r |B,Nya|B ) + uReal.(r.B -e+2*e) * (Nya..B)
by SURREALO:4;
then
A86: xx >= Sum(r |B,Nya|B ) + uReal.(r.B +e) * (Nya..B) by SURREALO:6;
Sum(r |B,Nya|B ) + uReal.(r.B + e) * (Nya..B) > Sum(r |A,Nya|A )
by A3,A4,A66,Th69;
then xx > Sum(r |A,Nya|A ) by A86,SURREALO:4;
then xx > Sra by A6,SURREALO:4;
hence thesis by A46,TARSKI:def 1;
end;
end;
A87: L_Sra << {Na*Sr}
proof
let xx,yy be Surreal such that
A88: xx in L_Sra & yy in {Na*Sr};
consider B be Element of A,e such that
A89: xx = Sum(r|B,Nya|B) + uReal.(r.B - e) * Nya..B & B in A by A88;
A90: Sum(r |B,Nya|B ) == Na * Sum(r|B,Ny| B) by A3,A2,A89,ORDINAL1:def 2;
A91: B in dom y by A89,A3,XBOOLE_0:def 4;
A92: 0_No < Na by SURREALI:def 8;
Sum(r|B,Ny|B) + uReal.(r.B - e) * Ny..B < Sr
by A6,SURREALO:9,A3,A4,A89,Th69;
then
A93: (Sum(r|B,Ny|B) + uReal.(r.B - e) * Ny..B)*Na < Sr * Na
by A92,SURREALR:70;
(uReal.(r.B - e) * Ny..B)*Na == uReal.(r.B - e) * (Ny..B*Na)
== uReal.(r.B - e) * Nya..B by Th82,A91,SURREALR:54,69;
then (uReal.(r.B - e) * Ny..B)*Na == uReal.(r.B - e) * Nya..B
by SURREALO:4;
then (Sum(r|B,Ny|B) + uReal.(r.B - e) * Ny..B)*Na ==
Sum(r|B,Ny|B)*Na + (uReal.(r.B - e) * Ny..B)*Na
== xx by A89,A90,SURREALR:66,67;
then (Sum(r|B,Ny|B) + uReal.(r.B - e) * Ny..B)*Na == xx by SURREALO:4;
then xx < Sr * Na by A93,SURREALO:4;
hence thesis by A88,TARSKI:def 1;
end;
{Na*Sr} << R_Sra
proof
let yy,xx be Surreal such that
A94: yy in {Na*Sr} & xx in R_Sra;
consider B be Element of A,e such that
A95: xx = Sum(r|B,Nya|B) + uReal.(r.B + e) * Nya..B & B in A by A94;
A96: Sum(r|B,Nya|B) == Na * Sum(r|B,Ny| B) by A2,A3,A95,ORDINAL1:def 2;
A97: B in dom y by A95,A3,XBOOLE_0:def 4;
A98: 0_No < Na by SURREALI:def 8;
Sum(r|B,Ny|B) + uReal.(r.B + e) * Ny..B > Sr
by A3,A4,A95,Th69,A6,SURREALO:9;
then
A99: (Sum(r|B,Ny|B) + uReal.(r.B + e) * Ny..B)*Na > Sr * Na
by A98,SURREALR:70;
(uReal.(r.B + e) * Ny..B)*Na == uReal.(r.B + e) * (Ny..B*Na)
== uReal.(r.B + e) * Nya..B by Th82,A97,SURREALR:54,69;
then (uReal.(r.B + e) * Ny..B)*Na == uReal.(r.B + e) * Nya..B
by SURREALO:4;
then (Sum(r|B,Ny|B) + uReal.(r.B + e) * Ny..B)*Na ==
Sum(r|B,Ny|B)*Na + (uReal.(r.B + e) * Ny..B)*Na
== xx by A95,A96,SURREALR:66,67;
then (Sum(r|B,Ny|B) + uReal.(r.B + e) * Ny..B)*Na == xx by SURREALO:4;
then xx > Sr * Na by A99,SURREALO:4;
hence thesis by A94,TARSKI:def 1;
end;
then Sra == Na*Sr == Na * Sum(r|A,Ny|A)
by A5,A8,A45,A87,SURREAL0:43,SURREALO:def 10,SURREALR:54;
then Sra == Na * Sum(r|A,Ny|A) by SURREALO:4;
hence thesis by A6,SURREALO:4;
end;
for A being Ordinal holds P[A] from ORDINAL1:sch 2(A1);
hence thesis;
end;
reserve S,T for non empty Ordinal;
definition
let S,T be non empty Ordinal;
let y,z be strictly_decreasing Surreal-Sequence;
let r,s be Sequence of REAL;
let a be Surreal;
func Partial_Sums(y,z,r,s,a,S,T) -> Real equals
addreal $$ ( (y,z,S,T) += a, Product(r,s,S,T));
coherence;
end;
theorem Th84:
dom y c= S & dom z c= T implies
Partial_Sums(y,z,r,s,a,S,T) = Partial_Sums(z,y,s,r,a,T,S)
proof
assume
A1: dom y c= S & dom z c= T;
set S1 = (y,z,S,T) += a,S2=(z,y,T,S) += a;
set AD1 = Product(r,s,S,T), AD2=Product(s,r,T,S);
defpred P[object,object] means
for i,j being object st $1=[i,j] holds $2=[j,i];
A2:S1 c= [:S,T:] & S2 c= [:T,S:] by FINSUB_1:def 5;
A3:for e being object st e in S1 ex u being object st P[e,u]
proof
let e be object;
assume e in S1;
then consider i,j be object such that
A4: i in S & j in T & e = [i,j] by A2,ZFMISC_1:def 2;
take [j,i];
let i1,j1 be object;
assume e=[i1,j1];
then i1=i & j1=j by A4,XTUPLE_0:1;
hence thesis;
end;
consider TR be Function such that
A5: dom TR = S1 & for e being object st e in S1 holds P[e,TR.e]
from CLASSES1:sch 1(A3);
A6: rng TR c= S2
proof
let f be object;
assume f in rng TR;
then consider e be object such that
A7: e in dom TR & TR.e =f by FUNCT_1:def 3;
consider i,j be object such that
A8: i in S & j in T & e = [i,j] by A7,A5,A2,ZFMISC_1:def 2;
reconsider i,j as Ordinal by A8;
i in dom y & j in dom z & y..i + z..j == a by A8,A1,A7,A5,Def16;
then [j,i] in S2 by A1,Def16;
hence thesis by A5,A7,A8;
end;
S2 c= rng TR
proof
let f be object;
assume
A9: f in S2;
then consider i,j be object such that
A10: i in T & j in S & f = [i,j] by A2,ZFMISC_1:def 2;
reconsider i,j as Ordinal by A10;
i in dom z & j in dom y & z..i + y..j == a by A10,A1,A9,Def16;
then
A11: [j,i] in S1 by A1,Def16;
TR. [j,i] = f by A10,A5,A11;
hence thesis by A11,A5,FUNCT_1:def 3;
end;
then
A12: rng TR = S2 by A6;
A13: TR is one-to-one
proof
let x1,x2 be object such that
A14: x1 in dom TR & x2 in dom TR & TR.x1=TR.x2;
consider i1,j1 be object such that
A15: i1 in S & j1 in T & x1 = [i1,j1] by A14,A5,A2,ZFMISC_1:def 2;
consider i2,j2 be object such that
A16: i2 in S & j2 in T & x2 = [i2,j2] by A14,A5,A2,ZFMISC_1:def 2;
TR.x1 = [j1,i1] & TR.x2 = [j2,i2] by A5,A14,A15,A16;
then j1=j2 & i1=i2 by A14,XTUPLE_0:1;
hence thesis by A15,A16;
end;
dom AD2 = [:T,S:] by FUNCT_2:def 1;
then
A17: dom (AD2*TR) = dom TR by A2,A12,RELAT_1:27;
dom AD1 = [:S,T:] by FUNCT_2:def 1;
then
A18: dom (AD1|S1) = S1 by A2,RELAT_1:62;
for e being object st e in S1 holds (AD1|S1).e = (AD2*TR).e
proof
let e be object;
assume
A19:e in S1;
then consider i,j be object such that
A20: i in S & j in T & e = [i,j] by A2,ZFMISC_1:def 2;
reconsider i,j as Ordinal by A20;
A21: AD1.e = AD1.(i,j) = r.i * s.j by Def15,A20,BINOP_1:def 1;
TR.e = [j,i] by A5,A19,A20;
then (AD2*TR).e = AD2.[j,i] by FUNCT_1:12,A17,A5,A19
.= AD2.(j,i) by BINOP_1:def 1
.= s.j * r.i by Def15,A20;
hence thesis by A19,FUNCT_1:49,A21;
end;
then AD1|S1 = AD2*TR by A5,A17,A18,FUNCT_1:2;
hence thesis by A5,A13,A12,SETWOP_2:5;
end;
theorem Th85:
for r12 being Sequence of REAL st
r1^r2 = r12 & dom y c= dom r1 & dom y c= S & dom z c= T
holds Partial_Sums(y,z,r1,s,a,S,T) = Partial_Sums(y,z,r12,s,a,S,T)
proof
let r12 be Sequence of REAL such that
A1: r1^r2 = r12 & dom y c= dom r1 & dom y c= S & dom z c= T;
set S1 = (y,z,S,T) += a;
set AD1 = Product(r1,s,S,T),AD12 = Product(r12,s,S,T);
A2: S1 c= [:S,T:] by FINSUB_1:def 5;
dom AD12 = [:S,T:] & dom AD1 = [:S,T:] by FUNCT_2:def 1;
then
A3: dom (AD12|S1)=S1 = dom (AD1|S1) by A2,RELAT_1:62;
for x being object st x in S1 holds (AD12|S1).x = (AD1|S1).x
proof
let x be object such that
A4: x in S1;
consider i,j be object such that
A5: i in S & j in T & x = [i,j] by A2,A4,ZFMISC_1:def 2;
reconsider i,j as Ordinal by A5;
A6: i in dom y & j in dom z & y..i + z..j == a by A5,A1,A4,Def16;
(AD12|S1).x = AD12.x = AD12.(i,j) by A4,A5,FUNCT_1:49,BINOP_1:def 1;
then
A7: (AD12|S1).x = r12.i * s.j by A5,Def15;
(AD1|S1).x = AD1.x = AD1.(i,j) by A4,A5,FUNCT_1:49,BINOP_1:def 1;
then (AD1|S1).x = r1.i * s.j by A5,Def15;
hence thesis by A7,A1,A6,ORDINAL4:def 1;
end;
then AD12|S1 = AD1|S1 by A3,FUNCT_1:2;
hence thesis by SETWOP_2:7;
end;
theorem Th86:
y1^y2 = y12 & r1^r2 = r12 & dom y12 c= S & dom z c= T &
dom y1 = dom r1 & dom y2 c= dom r2
implies
Partial_Sums(y12,z,r12,s,a,S,T)
=
Partial_Sums(y1,z,r1,s,a,S,T) + Partial_Sums(y2,z,r2,s,a,S,T)
proof
assume that
A1: y1^y2 = y12 & r1^r2 = r12 & dom y12 c= S & dom z c= T and
A2: dom y1 = dom r1 & dom y2 c= dom r2;
set S1 = (y1,z,S,T) += a,
S2=(y2,z,S,T) += a,
S12=(y12,z,S,T) += a;
set AD1 = Product(r1,s,S,T),
AD2 = Product(r2,s,S,T),
AD12 = Product(r12,s,S,T);
A3: dom y1 c= (dom y1)+^(dom y2)=dom y12 &
dom y2 c= (dom y1)+^(dom y2) by A1,ORDINAL3:24,ORDINAL4:def 1;
then
A4:dom y1 c= S & dom y2 c= S by A1;
then
A5: Partial_Sums(y1,z,r1,s,a,S,T) =Partial_Sums(y1,z,r12,s,a,S,T)
by Th85,A1,A2;
set SS= S12\S1;
A6: S1 c= [:S,T:] by FINSUB_1:def 5;
A7: S1\/ SS= S12\/S1 by XBOOLE_1:39;
S1 c= S12
proof
let x be object such that
A8: x in S1;
consider i,j be object such that
A9: i in S & j in T & x = [i,j] by A6,A8,ZFMISC_1:def 2;
reconsider i,j as Ordinal by A9;
A10: i in dom y1 & j in dom z & y1..i + z..j == a by A4,A9,A1,A8,Def16;
y1..i = y1.i = y12.i=y12..i by A10,A3,Def5,A1,ORDINAL4:def 1;
hence thesis by A9,A10,A3,A1,Def16;
end;
then
A11: S1\/SS = S12 by A7,XBOOLE_1:12;
A12: SS misses S1 by XBOOLE_1:79;
A13: SS c= [:S,T:] & S2 c= [:S,T:] by FINSUB_1:def 5;
defpred P[object,object] means
for i,j being Ordinal st $1=[i,j] holds $2=[i-^(dom y1),j];
A14:for e being object st e in SS ex u being object st P[e,u]
proof
let e be object;assume e in SS;
then consider i,j be object such that
A15: i in S & j in T & e = [i,j] by A13,ZFMISC_1:def 2;
reconsider i,j as Ordinal by A15;
take [i-^(dom y1),j];
let i1,j1 be Ordinal;
assume e=[i1,j1];
then i1=i & j1=j by A15,XTUPLE_0:1;
hence thesis;
end;
consider TR be Function such that
A16:dom TR = SS & for e being object st e in SS holds P[e,TR.e]
from CLASSES1:sch 1(A14);
A17: for i,j being Ordinal holds
[i,j] in SS iff dom y1 c= i & [i-^(dom y1),j] in S2
proof
let i,j be Ordinal;
set D=i-^(dom y1);
thus [i,j] in SS implies dom y1 c= i & [D,j] in S2
proof
assume [i,j] in SS;
then
A18: [i,j] in S12 & not [i,j] in S1 by XBOOLE_0:def 5;
then
A19: i in dom y12 & j in dom z & y12..i + z..j == a by A1,Def16;
then
A20: y12..i = y12.i by Def5;
A21: not i in dom y1
proof
assume
A22: i in dom y1;
then y1..i = y1.i = y12.i by ORDINAL4:def 1, A1,Def5;
hence thesis by A18,A19,A20,A22,A1,A4,Def16;
end;
hence dom y1 c= i by ORDINAL1:16;
A23: (dom y1)+^D = i by A21,ORDINAL1:16,Th3;
(dom y1)+^D in (dom y1)+^(dom y2) & not (dom y1)+^D in (dom y1)+^D
by A21,ORDINAL1:16,Th3,A3,A19;
then not (dom y1)+^(dom y2) c= (dom y1)+^D;
then
A24: D in dom y2 by ORDINAL1:16,ORDINAL2:33;
then y2.D = y2..D & y12.i = y2.D by A1,Def5,A23,ORDINAL4:def 1;
hence thesis by A24,A19,A20,A1,A4,Def16;
end;
assume
A25: dom y1 c= i & [D,j] in S2;
then
A26:D in dom y2 & j in dom z & y2..D + z..j == a by A1,A4,Def16;
A27:(dom y1)+^D = i by Th3,A25;
then
A28: y2.D = y2..D & y12.i = y2.D by A1,Def5,A26,ORDINAL4:def 1;
A29:i in dom y12 by A3,A27,A26,ORDINAL2:32;
y12.i = y12..i by A3,A27,A26,ORDINAL2:32,Def5;
then
A30:[i,j] in S12 by A26,A28,A29,A1,Def16;
not [i,j] in S1
proof
assume [i,j] in S1;
then i in dom y1 by A1,A4,Def16;
then i in i by A25;
hence thesis;
end;
hence thesis by A30,XBOOLE_0:def 5;
end;
A31: rng TR c= S2
proof
let f be object;
assume f in rng TR;
then consider e be object such that
A32: e in dom TR & TR.e =f by FUNCT_1:def 3;
consider i,j be object such that
A33: i in S & j in T & e = [i,j] by A32,A16,A13,ZFMISC_1:def 2;
reconsider i,j as Ordinal by A33;
TR.[i,j] = [i-^(dom y1),j] in S2 by A16,A32,A33,A17;
hence thesis by A32,A33;
end;
S2 c= rng TR
proof
let f be object;
assume
A34: f in S2;
then consider i,j be object such that
A35: i in S & j in T & f = [i,j] by A13,ZFMISC_1:def 2;
reconsider i,j as Ordinal by A35;
set D=(dom y1) +^i;
A36:dom y1 c= D by ORDINAL3:24;
A37: D-^ (dom y1) = i by ORDINAL3:52;
A38: [D,j] in SS by ORDINAL3:24,A37,A17,A34,A35;
TR.[D,j] = f by A35,A37,A16,A36,A17,A34;
hence thesis by A38,A16,FUNCT_1:def 3;
end;
then
A39: rng TR = S2 by A31;
A40: TR is one-to-one
proof
let x1,x2 be object such that
A41: x1 in dom TR & x2 in dom TR & TR.x1=TR.x2;
consider i1,j1 be object such that
A42: i1 in S & j1 in T & x1 = [i1,j1] by A41,A16,A13,ZFMISC_1:def 2;
consider i2,j2 be object such that
A43: i2 in S & j2 in T & x2 = [i2,j2] by A41,A16,A13,ZFMISC_1:def 2;
reconsider i1,i2,j1,j2 as Ordinal by A42,A43;
A44: TR.x1 = [i1-^(dom y1),j1] & TR.x2 = [i2-^(dom y1),j2] by A16,A41,A42,A43;
then j1=j2 & i1-^(dom y1)=i2-^(dom y1) by A41,XTUPLE_0:1;
then i1 = dom y1 +^(i2-^(dom y1))=i2 by A17,A42,A43,A16,A41,Th3;
hence thesis by A42,A43,A44,A41,XTUPLE_0:1;
end;
dom AD2 = [:S,T:] by FUNCT_2:def 1;
then
A45: dom (AD2*TR) = dom TR by A13,A39,RELAT_1:27;
dom AD12 = [:S,T:] by FUNCT_2:def 1;
then
A46: dom (AD12|SS) = SS by A13,RELAT_1:62;
for e being object st e in SS holds (AD12|SS).e = (AD2*TR).e
proof
let e be object;
assume
A47:e in SS;
then consider i,j be object such that
A48: i in S & j in T & e = [i,j] by A13,ZFMISC_1:def 2;
reconsider i,j as Ordinal by A48;
A49: AD12.e = AD12.(i,j) = r12.i * s.j by Def15,A48,BINOP_1:def 1;
A50: TR.e = [i-^(dom y1),j] in S2 & dom y1 c= i by A16,A47,A48,A17;
then
A51:i-^(dom y1) in S by A13,ZFMISC_1:87;
i-^(dom y1) in dom y2 by A50,A1,A4,Def16;
then
A52:r2.(i-^(dom y1)) = r12.((dom y1)+^((i-^(dom y1))))
by A1,A2,ORDINAL4:def 1
.= r12.i by A47,A48,A17,Th3;
(AD2*TR).e = AD2.[i-^(dom y1),j] by A50,FUNCT_1:12,A45,A16,A47
.= AD2.(i-^(dom y1),j) by BINOP_1:def 1
.= r2.(i-^(dom y1)) * s.j by A51,Def15,A48;
hence thesis by A47,FUNCT_1:49,A49,A52;
end;
then AD12|SS = AD2*TR by A16,A45,A46,FUNCT_1:2;
then addreal $$ (SS,AD12) = addreal $$ (S2,AD2) by A16,A40,A39,SETWOP_2:5;
hence Partial_Sums(y12,z,r12,s,a,S,T)
= addreal.(addreal $$ ( S1, AD12),addreal $$ (S2,AD2))
by A11,A12,SETWOP_2:4
.= Partial_Sums(y1,z,r1,s,a,S,T)+ Partial_Sums(y2,z,r2,s,a,S,T)
by A5,BINOP_2:def 9;
end;
registration
let s be Surreal;
cluster <%s%> -> strictly_decreasing;
coherence
proof
set S=<%s%>;
let a,b be Ordinal such that A1: a in b in dom S;
dom S={0} by CARD_1:49,AFINSQ_1:33;
hence thesis by A1,TARSKI:def 1;
end;
end;
theorem Th87:
dom y c= S & dom z c= T & a==b implies
Partial_Sums(y,z,r,s,a,S,T) = Partial_Sums(y,z,r,s,b,S,T)
proof
assume dom y c= S & dom z c= T & a==b;
then (y,z,S,T) += a = (y,z,S,T) += b by Th77;
hence thesis;
end;
theorem Th88:
for c st dom y c= S & dom z c= T &
for a st a==c holds not a in rng y ++ rng z
holds Partial_Sums(y,z,r,s,c,S,T) = 0
proof
let c;
assume dom y c= S & dom z c= T &
for a being Surreal st a==c holds not a in rng y ++ rng z;
then (y,z,S,T) += c = {}.[:S,T:] by Th78;
hence thesis by SETWISEO:31,BINOP_2:2;
end;
theorem Th89:
for r being Real st dom z c= T & A in dom z & a == c+z..A
holds Partial_Sums(<%c%>,z,<%r%>,s,a,S,T) = r * s.A
proof
let r be Real such that
A1: dom z c= T and
A2:A in dom z and
A3:a == c +z..A;
set Y=<%c%>;
A4:dom Y = Segm 1 by AFINSQ_1:33;
A5: 1=succ {} c= S by ORDINAL3:8,ORDINAL1:21;
A6: 0 in succ {} by ORDINAL1:6;
then Y..0 = Y.0 = c by A4,Def5;
then
A7:[0,A] in (<%c%>,z,S,T) += a by A3,A1,A2,A4,A5,A6,Def16;
reconsider OO=[0,A] as Element of [:S,T:] by A1,A2,A5,A6,ZFMISC_1:87;
(<%c%>,z,S,T) += a c= {[0,A]}
proof
A8: (Y,z,S,T) += a c= [:S,T:] by FINSUB_1:def 5;
let a1 be object;
assume
A9:a1 in (Y,z,S,T) += a;
then consider i,j be object such that
A10: i in S & j in T & a1=[i,j] by A8,ZFMISC_1:def 2;
reconsider i,j as Ordinal by A10;
A11:i in dom Y & j in dom z & Y..i + z..j == a by A1,A4,A5,A9,A10,Def16;
A12: i ={} by A11,A4,A5,ORDINAL1:8;
then Y..i = Y.i = c by A11,Def5;
then c + z..j == c + z..A by A3,A11,SURREALO:4;
then
A13:z..j == z..A by SURREALR:44;
z..j = z.j in rng z & z..A = z.A in rng z by A2,A11,Def5,FUNCT_1:def 3;
then j=A by A2,A11,A13,Def11,FUNCT_1:def 4;
hence thesis by A10,A12,TARSKI:def 1;
end;
then (<%c%>,z,S,T) += a = {. OO .} by A7,ZFMISC_1:33;
hence Partial_Sums(<%c%>,z,<%r%>,s,a,S,T) = Product(<%r%>,s,S,T).OO
by SETWISEO:17
.= Product(<%r%>,s,S,T).(0,A) by BINOP_1:def 1
.= <%r%>.0 * s.A by Def15,A1,A2,A5,A6
.= r * s.A;
end;
begin :: Compatibility of Series Products with Conway Normal Form
definition
let S,T be non empty Ordinal;
let y,z,yz be strictly_decreasing Surreal-Sequence;
let r,s be Sequence of REAL;
func Sum(y,z,yz,r,s,S,T) -> Sequence of REAL means :Def19:
dom it = dom yz &
for A st A in dom yz holds it.A = Partial_Sums(y,z,r,s,yz..A,S,T);
existence
proof
defpred P[object,object] means $2 = Partial_Sums(y,z,r,s,yz..$1,S,T);
A1: for e being object st e in dom yz ex u being object st P[e,u];
consider IT be Function such that
A2: dom IT = dom yz &
for e being object st e in dom yz holds P[e,IT.e]
from CLASSES1:sch 1(A1);
rng IT c= REAL
proof
let o be object such that
A3: o in rng IT;
consider x be object such that
A4: x in dom IT & IT.x = o by A3,FUNCT_1:def 3;
IT.x = Partial_Sums(y,z,r,s,yz..x,S,T) by A2,A4;
hence thesis by A4;
end;
then reconsider IT as Sequence of REAL
by A2,ORDINAL1:def 7,RELAT_1:def 19;
take IT;
thus thesis by A2;
end;
uniqueness
proof
let U1,U2 be Sequence of REAL such that
A5: dom U1 = dom yz & for O being Ordinal st O in dom yz holds
U1.O = Partial_Sums(y,z,r,s,yz..O,S,T)
and
A6: dom U2 = dom yz & for O being Ordinal st O in dom yz holds
U2.O = Partial_Sums(y,z,r,s,yz..O,S,T);
for x being object st x in dom yz holds U1.x = U2.x
proof
let x be object such that
A7: x in dom yz;
U2.x = Partial_Sums(y,z,r,s,yz..x,S,T) by A6,A7;
hence thesis by A5,A7;
end;
hence thesis by A5,A6,FUNCT_1:2;
end;
end;
registration
let f be strictly_decreasing Surreal-Sequence;
let A be Ordinal;
cluster f/^A -> strictly_decreasing;
coherence
proof
let B,C be Ordinal such that
A1: B in C in dom (f/^A);
let sb,sc be Surreal such that
A2: sb = (f/^A).B & sc = (f/^A).C;
B in dom (f/^A) by A1,ORDINAL1:10; then
A3: f..(A+^B) = (f/^A)..B=sb & f..(A+^C) = (f/^A)..C = sc by A1,Th36,A2,Def5;
A4: (A+^B) in (A+^C) by A1,ORDINAL2:32;
A5: (A+^C) in dom f by A1,Th8;
then f..(A+^B) = f.(A+^B) & f..(A+^C) = f.(A+^C)
by A4,ORDINAL1:10,Def5;
hence thesis by A3,A1,ORDINAL2:32,A5,SURREALC:def 11;
end;
end;
theorem Th90:
dom y c= S & dom z c= T implies
Sum(y,z,yz,r,s,S,T) = Sum(z,y,yz,s,r,T,S)
proof
assume
A1: dom y c= S & dom z c= T;
A2: dom Sum(y,z,yz,r,s,S,T) = dom yz = dom Sum(z,y,yz,s,r,T,S)
by Def19;
for a being object st a in dom yz holds
Sum(y,z,yz,r,s,S,T).a = Sum(z,y,yz,s,r,T,S).a
proof
let a be object such that
A3: a in dom yz;
thus Sum(y,z,yz,r,s,S,T).a = Partial_Sums(y,z,r,s,yz..a,S,T) by A3,Def19
.= Partial_Sums(z,y,s,r,yz..a,T,S) by A1,Th84
.= Sum(z,y,yz,s,r,T,S).a by A3,Def19;
end;
hence thesis by A2,FUNCT_1:2;
end;
theorem Th91:
y = {} & dom z c= T implies rng Sum(y,z,yz,r,s,S,T) c= {0}
proof
assume that
A1: y={} and
A2: dom z c= T;
set P=Sum(y,z,yz,r,s,S,T);
let o be object;
assume o in rng P;
then consider i be object such that
A3: i in dom P & P.i=o by FUNCT_1:def 3;
reconsider i as Ordinal by A3;
dom P = dom yz by Def19;
then
A4: P.i = Partial_Sums(y,z,r,s,yz..i,S,T) by A3,Def19;
A5: dom y c= S by A1;
rng y ={} by A1;
then for a being Surreal st a==yz..i holds not a in rng y ++ rng z
by SURREALR:27;
then o=0 by A3,A4,A5,A2,Th88;
hence thesis by TARSKI:def 1;
end;
theorem Th92:
for A,Y,Z being Ordinal st
dom y c= S & dom z c= T & A in dom yz & yz..A > y..Y + z..Z
holds
Sum(y/^Y,z/^Z,yz,r,s,S,T).A = 0
proof
let A,Y,Z be Ordinal such that
A1: dom y c= S & dom z c= T and
A2:A in dom yz & yz..A > y..Y + z..Z;
set yY=y/^Y,zZ=z/^Z;
A3:Sum(yY,zZ,yz,r,s,S,T).A = Partial_Sums(yY,zZ,r,s,yz..A,S,T) by A2,Def19;
(yY,zZ,S,T) += yz..A={}.[:S,T:]
proof
assume (yY,zZ,S,T) += yz..A <> {}.[:S,T:];
then consider ij be object such that
A4: ij in (yY,zZ,S,T) += yz..A by XBOOLE_0:def 1;
(yY,zZ,S,T) += yz..A c= [:S,T:] by FINSUB_1:def 5;
then consider i,j be object such that
A5: i in S & j in T & [i,j] = ij by A4,ZFMISC_1:def 2;
reconsider i,j as Ordinal by A5;
dom yY c= dom y & dom zZ c= dom z by Th6;
then dom yY c= S & dom zZ c= T by A1;
then
A6: i in dom yY & j in dom zZ & yY..i + zZ..j == yz..A by A4,A5,Def16;
then
A7: yY..i = yY.i & zZ..j = zZ.j by Def5;
A8: yY.i = y.(Y+^i) & (Y+^i) in dom y &
zZ.j = z.(Z+^j) & (Z+^j) in dom z by A6,Th8;
then
A9: y.(Y+^i) = y..(Y+^i) & z.(Z+^j)= z..(Z+^j) by Def5;
A10: y..Y >= y..(Y+^i)
proof
per cases;
suppose i=0;
then Y+^i = Y by ORDINAL2:27;
hence thesis by SURREALO:3;
end;
suppose i <> 0;
then
A11: Y= Y+^0 in Y+^i by ORDINAL3:8,ORDINAL2:27,32;
then y..Y = y.Y by Def5,A8,ORDINAL1:10;
then y..(Y+^i) < y..Y by A11,A8,A9,SURREALC:def 11;
hence thesis by SURREALO:6;
end;
end;
A12: z..Z >= z..(Z+^j)
proof
per cases;
suppose j=0;
then Z+^j = Z by ORDINAL2:27;
hence thesis by SURREALO:3;
end;
suppose j <>0;
then
A13: Z= Z+^0 in Z+^j by ORDINAL3:8,ORDINAL2:27,32;
then z..Z = z.Z by Def5,A8,ORDINAL1:10;
then z..(Z+^j) < z..Z by A13,A8,A9,SURREALC:def 11;
hence thesis by SURREALO:6;
end;
end;
y..Y+ z..Z >= yY..i + zZ..j by A8,A7,A9,A10,A12,SURREALR:43;
hence thesis by A2,A6,SURREALO:4;
end;
hence thesis by A3,BINOP_2:2,SETWISEO:31;
end;
theorem Th93:
for A st A c= dom r/\dom y1 & dom y1 = dom y2 &
for B st B in A holds y1..B==y2..B
holds
Sum(r|A,(No_omega^ y1) |A ) = Sum(r|A,(No_omega^ y2) | A)
proof
let O be Ordinal such that
A1:O c= dom r/\dom y1 and
A2:dom y1 = dom y2 and
A3: for X being Ordinal st X in O holds y1..X==y2..X;
set N1=No_omega^ y1,N2=No_omega^ y2;
defpred P[Ordinal] means $1 c= O implies
Sum(r|$1,N1|$1) = Sum(r|$1,N2 |$1);
A4:dom N1 = dom y1 & dom N2 = dom y2 by SURREALC:def 22;
A5: for B being Ordinal st B in O holds N1..B == N2..B
proof
let B be Ordinal such that
A6: B in O;
A7: B in dom y1 by A1,A6,XBOOLE_0:def 4;
then y1.B = y1..B & y2.B = y2..B by A2,Def5;
then
A8: N1.B = No_omega^ (y1..B) & N2.B = No_omega^ (y2..B)
by A2,A4,A7,SURREALC:def 22;
A9: y1..B == y2..B by A6,A3;
N1.B=N1..B & N2.B =N2..B by A2,A7,A4,Def5;
hence thesis by A8,A9,SURREALC:24;
end;
A10:for A being Ordinal st for C being Ordinal st C in A holds P[C] holds P[A]
proof
let A be Ordinal such that
A11:for C being Ordinal st C in A holds P[C];
assume
A12: A c= O;
then
A13: A c= dom r/\dom y1 by A1;
reconsider X1= [{Sum(r|B,N1|B) + uReal.(r.B - e) * N1..B
where B is Element of A,e: B in A},
{Sum(r|B,N1|B) + uReal.(r.B + e) * N1..B
where B is Element of A,e: B in A}] as Surreal by A13,A4,Th61;
reconsider X2= [{Sum(r|B,N2|B) + uReal.(r.B - e) * N2..B
where B is Element of A,e: B in A},
{Sum(r|B,N2|B) + uReal.(r.B + e) * N2..B
where B is Element of A,e: B in A}] as Surreal by A13,A2,A4,Th61;
A14: L_X1 <==> L_X2
proof
thus L_X1 <=_ L_X2
proof
let x be Surreal;
assume x in L_X1;
then consider B be Element of A,e such that
A15: x = Sum(r|B,N1|B) + uReal.(r.B - e) * N1..B & B in A;
B c= O by A12,A15,ORDINAL1:10;
then
A16: Sum(r|B,N1|B) = Sum(r|B,N2|B) by A11,A15;
uReal.(r.B - e) * N1..B==uReal.(r.B - e) * N2..B
by A12,A15,A5,SURREALR:54;
then x == Sum(r|B,N2|B) + uReal.(r.B - e) * N2..B in L_X2
by A15,A16,SURREALR:66;
hence thesis;
end;
let x be Surreal;
assume x in L_X2;
then consider B be Element of A,e such that
A17: x = Sum(r|B,N2|B) + uReal.(r.B - e) * N2..B & B in A;
B c= O by A12,A17,ORDINAL1:10;
then
A18: Sum(r|B,N1|B) = Sum(r|B,N2|B) by A11,A17;
uReal.(r.B - e) * N1..B==uReal.(r.B - e) * N2..B
by A12,A17,A5,SURREALR:54;
then x == Sum(r|B,N1|B) + uReal.(r.B - e) * N1..B in L_X1
by A17,A18,SURREALR:66;
hence thesis;
end;
A19:R_X1 <==> R_X2
proof
thus R_X1 <=_ R_X2
proof
let x be Surreal;
assume x in R_X1;
then consider B be Element of A,e such that
A20: x = Sum(r|B,N1|B) + uReal.(r.B + e) * N1..B & B in A;
B c= O by A12,A20,ORDINAL1:10;
then
A21: Sum(r|B,N1|B) = Sum(r|B,N2|B) by A11,A20;
uReal.(r.B + e) * N1..B == uReal.(r.B + e) * N2..B
by A12,A20,A5,SURREALR:54;
then x == Sum(r|B,N2|B) + uReal.(r.B + e) * N2..B in R_X2
by A20,A21,SURREALR:66;
hence thesis;
end;
let x be Surreal;
assume x in R_X2;
then consider B be Element of A,e such that
A22: x = Sum(r|B,N2|B) + uReal.(r.B + e) * N2..B & B in A;
B c= O by A12,A22,ORDINAL1:10;
then
A23: Sum(r|B,N1|B) = Sum(r|B,N2|B) by A11,A22;
uReal.(r.B + e) * N1..B==uReal.(r.B + e) * N2..B
by A12,A22,A5,SURREALR:54;
then x == Sum(r|B,N1|B) + uReal.(r.B + e) * N1..B in R_X1
by A22,A23,SURREALR:66;
hence thesis;
end;
A24:X1==X2 by A14,A19,SURREALO:29;
A25:Sum(r|A,N1 |A ) = Unique_No X1 ==X1 by Th62,A13,A4,SURREALO:def 10;
A26: Sum(r|A,N2 |A ) = Unique_No X2 ==X2 by A2,Th62,A13,A4,SURREALO:def 10;
X2 == Sum(r|A,N1 |A ) by A24,A25,SURREALO:4;
then Sum(r|A,N2 |A ) == Sum(r|A,N1 |A ) by A26,SURREALO:4;
hence thesis by SURREALO:50;
end;
for A being Ordinal holds P[A] from ORDINAL1:sch 2(A10);
hence thesis;
end;
theorem Th94:
A c= dom r/\dom y implies
Sum(r|A,(No_omega^ y) | A) = Sum(r|A,(No_omega^ Unique_No y) |A)
proof
assume
A1: A c= dom r/\dom y;
set Uy = Unique_No y;
A2: dom y = dom Uy by Def9;
for O being Ordinal st O in A holds y..O==Uy..O
proof
let O be Ordinal such that
A3: O in A;
A4: O in dom y by A3,A1,XBOOLE_0:def 4;
Uy..O = Uy.O by A2,A4,Def5
.= Unique_No y..O by A4,Def9;
hence thesis by SURREALO:def 10;
end;
hence thesis by A1,A2,Th93;
end;
theorem Th95:
for yz being strictly_decreasing uSurreal-Sequence,r being Real st
dom s = dom z c= T & Unique_No ({a}++rng z) c= rng yz
holds
Sum (Sum(<%a%>,z,yz,<%r%>,s,S,T), No_omega^ yz) ==
uReal.r * No_omega^a *Sum(s, No_omega^ z)
proof
let yz be strictly_decreasing uSurreal-Sequence,r be Real such that
A1: dom s = dom z c= T and
A2: Unique_No ({a}++rng z) c= rng yz;
set D=dom s;
A3: dom (No_omega^ (z+a)) = dom (z+a) =dom z by Def17,SURREALC:def 22;
A4: dom (No_omega^ z) = dom z by SURREALC:def 22;
A5: D = dom s/\dom z by A1;
then
A6: Sum(s|D, (No_omega^ (z+a)) |D) ==
No_omega^ a * Sum(s|D,(No_omega^ z) | D) by Th83;
set U = Unique_No (z+a);
A7: dom U = dom (z+a) by Def9;
rng (z+a) = rng z ++{a} by Th81;
then
A8: rng U = Unique_No (rng z ++{a}) by Th37;
then
A9:rng (U|D) c= rng yz by A2;
set eS = s-extended_by(U,yz),
rS= r(#)eS,Y=<%a%>,R=<%r%>,
P =Sum(Y,z,yz,R,s,S,T);
A10:dom eS = dom yz & dom P = dom yz & dom rS = dom eS
by Def14,Def19,VALUED_1:def 5;
A11: dom (No_omega^ yz) = dom yz by SURREALC:def 22;
then
A12: dom eS = dom eS /\ dom (No_omega^ yz) by A10;
A13:dom (No_omega^ U) = dom U by SURREALC:def 22;
for o being object st o in dom yz holds rS.o = P.o
proof
let o be object such that
A14:o in dom yz;
reconsider O=o as Ordinal by A14;
A15: P.O = Partial_Sums(Y,z,R,s,yz..O,S,T) by Def19,A14;
A16: yz..O = yz.O by A14,Def5;
per cases;
suppose yz.O in rng U;
then consider d be object such that
A17: d in dom U & U.d = yz.O by FUNCT_1:def 3;
reconsider d as Ordinal by A17;
A18: s.d = eS.O by A14,A17,Def14;
A19: d in dom z by Def17,A7,A17;
A20: yz..O = Unique_No ((z+a)..d) == (z+a)..d
by SURREALO:def 10,A16,A7,A17,Def9;
(z+a)..d = (z+a).d = z..d+a by A3,A7,A17,Def17,Def5;
then P.O = r * s.d by A1,A19,A20,Th89,A15;
hence thesis by A18,VALUED_1:6;
end;
suppose
A21: not yz.O in rng U;
then
A22: eS.O=0 & r * eS.O = rS.O by VALUED_1:6,A14,Def14;
A23: 1=succ {} c= S by ORDINAL3:8,ORDINAL1:21;
A24: dom Y c= S & dom z c= T by A1,AFINSQ_1:33,A23;
for b being Surreal st b== yz..O holds not b in rng Y ++ rng z
proof
let b be Surreal such that
A25: b== yz..O & b in rng Y ++ rng z;
Unique_No b == b by SURREALO:def 10;
then
A26: yz..O == Unique_No b by A25,SURREALO:4;
yz.O in rng yz by A14,FUNCT_1:def 3;
then yz..O is uSurreal by A16,SURREALO:def 12;
then
A27: yz..O = Unique_No b by A26,SURREALO:50;
b in {a}++rng z by A25,AFINSQ_1:33;
hence thesis by A8,A27,A21,A16,Def8;
end;
hence thesis by A22,A15,A24,Th88;
end;
end;
then
A28: rS = Sum(<%a%>,z,yz,<%r%>,s,S,T) by A10,FUNCT_1:2;
A29: Sum(eS,No_omega^ yz) =
Sum(s|D, (No_omega^ U) |D) by A13,A1,A3,A7,A9,Th76
.= Sum(s|D, (No_omega^ (z+a)) |D) by Th94,A5,A3
.= Sum(s, No_omega^ (z+a)) by A1,A3;
A30: Sum(rS |dom eS,(No_omega^ yz) |dom eS)
== uReal.r * Sum(eS|dom eS,(No_omega^ yz) | dom eS) by A12,Th79;
uReal.r * Sum(s, No_omega^ (z+a)) ==
uReal.r * (No_omega^ a * Sum(s,No_omega^ z))==
uReal.r * No_omega^ a * Sum(s,No_omega^ z)
by A6,A1,A4,A3,SURREALR:54,69;
then uReal.r * Sum(s, No_omega^ (z+a)) ==
uReal.r * No_omega^ a * Sum(s,No_omega^ z) by SURREALO:4;
hence thesis by A28,A30,A10,A11,A29,SURREALO:4;
end;
theorem Th96:
for yz being strictly_decreasing uSurreal-Sequence,s being Real st
dom r = dom y c= S & Unique_No (rng y++{a}) c= rng yz
holds
Sum (Sum(y,<%a%>,yz,r,<%s%>,S,T), No_omega^ yz) ==
uReal.s * No_omega^a *Sum(r, No_omega^ y)
proof
let yz be strictly_decreasing uSurreal-Sequence,s be Real such that
A1: dom r = dom y c= S & Unique_No (rng y++{a}) c= rng yz;
A2: dom <%a%> = Segm 1 by AFINSQ_1:33;
A3: 1=succ {} c= T by ORDINAL3:8,ORDINAL1:21;
uReal.s * No_omega^a *Sum(r, No_omega^ y)
== Sum (Sum(<%a%>,y,yz,<%s%>,r,T,S), No_omega^ yz)
= Sum (Sum(y,<%a%>,yz,r,<%s%>,S,T), No_omega^ yz) by Th95,A1,A2,A3,Th90;
hence thesis;
end;
theorem
y={} & dom z c= T implies
Sum (Sum(y,z,yz,r,s,S,T), No_omega^ yz) = 0_No
proof
assume y={} & dom z c= T;
then rng Sum(y,z,yz,r,s,S,T) c= {0} by Th91;
hence Sum (Sum(y,z,yz,r,s,S,T), No_omega^ yz) = 0_No by Th66;
end;
theorem Th98:
dom y c= S & dom z c= T & dom y c= dom r & A c= dom y implies
Sum(y|A,z,yz,r|A,s,S,T) + Sum(y/^A,z,yz,r/^A,s,S,T)=
Sum(y,z,yz,r,s,S,T)
proof
assume that
A1:dom y c= S & dom z c= T and
A2: dom y c= dom r and
A3: A c= dom y;
set P1 = Sum(y|A,z,yz,r|A,s,S,T),
P2= Sum(y/^A,z,yz,r/^A,s,S,T),
P12= Sum(y,z,yz,r,s,S,T);
A4:dom P1 = dom yz = dom P2 & dom yz = dom P12 by Def19;
then dom yz = dom P1/\dom P2;
then
A5:dom (P1+P2) = dom yz by VALUED_1:def 1;
for a being object st a in dom yz holds P12.a = (P1+P2).a
proof
let a be object such that
A6:a in dom yz;
A7:y = (y|A) ^ (y/^A) by Def1;
A8:r = (r|A) ^ (r/^A) by Def1;
A c= dom r by A2,A3;
then
A9: dom (y|A) = A & dom (r|A) = A by A3,RELAT_1:62;
A10:dom (y/^A) = (dom y) -^ A & dom (r/^A) = (dom r) -^ A by Def1;
thus
P12.a = Partial_Sums(y,z,r,s,yz..a,S,T) by A6,Def19
.= Partial_Sums(y|A,z,r|A,s,yz..a,S,T)
+ Partial_Sums(y/^A,z,r/^A,s,yz..a,S,T)
by A1,A7,A8,A9,A10,A2,ORDINAL3:59,Th86
.= P1.a + Partial_Sums(y/^A,z,r/^A,s,yz..a,S,T)by A6,Def19
.= P1.a + P2.a by A6,Def19
.=(P1+P2).a by A6,A5,VALUED_1:def 1;
end;
hence thesis by A4,A5,FUNCT_1:2;
end;
theorem Th99:
dom y c= S & dom z c= T & dom y c= dom r & A c= dom y implies
Sum (Sum(y,z,yz,r,s,S,T), No_omega^ yz) ==
Sum(Sum(y|A,z,yz,r|A,s,S,T), No_omega^ yz) +
Sum(Sum(y/^A,z,yz,r/^A,s,S,T), No_omega^ yz)
proof
assume that
A1:dom y c= S & dom z c= T and
A2: dom y c= dom r and
A3: A c= dom y;
set P1 = Sum(y|A,z,yz,r|A,s,S,T),
P2= Sum(y/^A,z,yz,r/^A,s,S,T),
P12= Sum(y,z,yz,r,s,S,T),
N=No_omega^ yz;
A4:dom P1 = dom yz = dom P2 & dom yz = dom P12 by Def19;
A5:dom N = dom yz by SURREALC:def 22;
A6: P1+P2=P12 by A1,A2,A3,Th98;
dom yz = dom P1/\dom N by A4,A5;
then Sum((P1 + P2) |dom yz,N|dom yz) ==
Sum(P1 |dom yz,N|dom yz) + Sum(P2 |dom yz,N|dom yz) by Th74,A4;
hence thesis by A4,A5,A6;
end;
theorem Th100:
dom y c= S & dom z c= T & dom z c= dom s & A c= dom z
implies
Sum (Sum(y,z,yz,r,s,S,T), No_omega^ yz) ==
Sum(Sum(y,z|A,yz,r,s|A,S,T), No_omega^ yz) +
Sum(Sum(y,z/^A,yz,r,s/^A,S,T), No_omega^ yz)
proof
assume that
A1:dom y c= S & dom z c= T and
A2: dom z c= dom s and
A3: A c= dom z;
A4: Sum (Sum(z,y,yz,s,r,T,S), No_omega^ yz) ==
Sum(Sum(z|A,y,yz,s|A,r,T,S), No_omega^ yz) +
Sum(Sum(z/^A,y,yz,s/^A,r,T,S), No_omega^ yz) by Th99,A1,A2,A3;
A5:Sum(z,y,yz,s,r,T,S) = Sum(y,z,yz,r,s,S,T) by A1,Th90;
dom (z|A) c= dom z by RELAT_1:60;
then dom (z|A) c= T by A1;
then
A6:Sum(z|A,y,yz,s|A,r,T,S) = Sum(y,z|A,yz,r,s|A,S,T) by A1,Th90;
0 c= A;
then dom (z/^A) = (dom z)-^ A c= (dom z)-^ 0 =dom z by Def1,ORDINAL3:56,58;
then dom (z/^A) c= T by A1;
hence thesis by A4,A5,A6,A1,Th90;
end;
theorem
for r being Real holds
Sum(<%r%>, No_omega^ <%a%>) == uReal.r * No_omega^a
proof
let r be Real;
set R=<%r%>,
Y=<%a%>,
N=No_omega^ Y;
No_omega^(Y|0) = N|0 by SURREALC:88;
then
A1:Sum(R|0,No_omega^(Y|0)) = 0_No by Th67;
A2:dom R=1 =dom Y & dom Y = dom N by SURREALC:def 22,AFINSQ_1:def 4;
then succ 0 c= dom R/\dom Y;
then
A3: Sum(R|succ 0,No_omega^(Y|succ 0)) ==
Sum(R|0,No_omega^(Y|0)) + uReal.(R.0) * No_omega^(Y..0) by Th64;
0 in succ 0 by ORDINAL1:6;
then Y..0 = Y.0 by Def5,A2;
hence thesis by A3,A1,A2;
end;
theorem Th102:
succ A c= dom r/\dom y
implies
Sum(r|A,( No_omega^ y) |A) + uReal.(r.A - e) * (No_omega^y)..A
== Sum(r|succ A,(No_omega^ y) |succ A) + uReal.(-e) * No_omega^(y..A)
&
Sum(r|A,( No_omega^ y) |A) + uReal.(r.A + e) * (No_omega^y)..A
== Sum(r|succ A,(No_omega^ y) |succ A) + uReal.(e) * No_omega^(y..A)
proof
assume
A1:succ A c= dom r/\dom y;
set Ny=No_omega^ y;
set SA=Sum(r|A,Ny |A),SsA=Sum(r|succ A,Ny |succ A);
A2: Ny |A = No_omega^ (y|A) & Ny |succ A = No_omega^ (y|succ A)
by SURREALC:88;
A in dom r/\dom y by A1,ORDINAL1:6;
then
A3: A in dom y = dom Ny by XBOOLE_0:def 4,SURREALC:def 22;
then y..A = y.A & Ny.A = Ny..A by Def5;
then
A4: Ny..A = No_omega^ (y..A) by A3,SURREALC:def 22;
A5:SsA == SA + uReal.(r.A) * Ny..A by A1,A2,A4,Th64;
A6: - uReal.(- - e) * Ny..A == uReal.(-e) * Ny..A by Th33;
SA + uReal.(r.A - e) * Ny..A ==
SA + uReal.(r.A) * Ny..A - uReal.e * Ny..A =
SA + uReal.(r.A) * Ny..A + - uReal.e * Ny..A == SsA +uReal.(-e) * Ny..A
by Th30,A5,A6,SURREALR:66;
hence SA + uReal.(r.A - e) * Ny..A
== SsA +uReal.(-e) * No_omega^(y..A) by A4,SURREALO:4;
SA + uReal.(r.A + e) * Ny..A ==
SA + uReal.(r.A) * Ny..A + uReal.e * Ny..A
== SsA +uReal.(e) * Ny..A by Th30,A5,SURREALR:66;
hence thesis by A4,SURREALO:4;
end;
theorem Th103:
for x,x0,y,y0,s,t being Surreal holds
x*(y0+s) + (x0+t)*y - (x0+t)*(y0+s) ==
(x*y0+x0*y-x0*y0) + ((x-x0) *s + (y-y0) *t) - t*s
proof
let x,x0,y,y0,s,t be Surreal;
A1: x0*(-y0 + -s) == x0 *(-y0) + x0*(-s) &
t * (-y0 + -s) == t*(-y0) + t*(-s) by SURREALR:67;
-(y0+s) = -y0 +-s by SURREALR:40;
then - (x0+t)*(y0+s) = (x0+t)*(-(y0+s)) ==
x0*(-y0 + -s)+ t * (-y0 + -s) ==
(x0 *(-y0) + x0*(-s)) + (t*(-y0) + t*(-s)) by A1,SURREALR:58,66,67;
then
A2: - (x0+t)*(y0+s) ==
(x0 *(-y0) + x0*(-s)) + (t*(-y0) + t*(-s))
= x0 *(-y0) + ((x0*(-s)) + (t*(-y0) + t*(-s)))by SURREALO:4,SURREALR:37;
x*(y0+s) == x*y0 + x*s & (x0+t)*y == x0*y + t*y by SURREALR:67;
then
A3: x*(y0+s) + (x0+t)*y == (x*y0 + x*s) + (x0*y + t*y) by SURREALR:66;
x*s + (x0*y + t*y) = x*s +t*y + x0*y by SURREALR:37;
then (x*y0 + x*s) + (x0*y + t*y) = x*y0 + (x0*y + (x*s +t*y)) by SURREALR:37
.= (x*y0 + x0*y) + (x*s +t*y) by SURREALR:37;
then
A4: x*(y0+s) + (x0+t)*y +- (x0+t)*(y0+s) ==
(x*y0 + x0*y) + (x*s +t*y) + (x0 *(-y0) + ((x0*(-s)) + (t*(-y0) + t*(-s))))
by A2,A3,SURREALR:66;
set X= x*y0+x0*y-x0*y0, XY=(x-x0) *s + (y-y0) *t;
x0 *(-y0) = -x0 *y0 by SURREALR:58;
then
A5:(x*y0 + x0*y) + (x*s +t*y) + x0 *(-y0) =
X + (x*s +t*y) by SURREALR:37;
t*y + t*(-y0) == t*(y+-y0) by SURREALR:67;
then
A6: t*y + (t*(-y0) + t*(-s)) = t*y + t*(-y0) + t*(-s)
== t*(y-y0) + t*(-s) by SURREALR:37,66;
A7: x*s + (-x0)*s == (x+-x0)*s by SURREALR:67;
x0*(-s) = -x0*s = (-x0)*s by SURREALR:58;
then (x*s +t*y) + x0*(-s) =
x*s + (-x0)*s + t*y == (x+-x0)*s + t*y by A7,SURREALR:37,66;
then (x*s +t*y) + (x0*(-s) + (t*(-y0) + t*(-s)))
= (x*s +t*y) + x0*(-s) + (t*(-y0) + t*(-s))
== (x+-x0)*s + t*y + (t*(-y0) + t*(-s))
= (x+-x0)*s + (t*y + (t*(-y0) + t*(-s)))
== (x+-x0)*s + (t*(y-y0) + t*(-s))
= XY + t*(-s) by A6,SURREALR:37,66;
then (x*s +t*y) + (x0*(-s) + (t*(-y0) + t*(-s)))
== XY + t*(-s) by SURREALO:4;
then
A8: X + ((x*s +t*y) + ((x0*(-s)) + (t*(-y0) + t*(-s))))
== X+ (XY + t*(-s)) by SURREALR:66;
t*(-s) = -t*s by SURREALR:58;
then
A9: X+ (XY + t*(-s)) = X+ XY + - t*s by SURREALR:37;
(x*y0 + x0*y) + (x*s +t*y) + (x0 *(-y0) + ((x0*(-s)) + (t*(-y0) + t*(-s))))
= (X + (x*s +t*y)) + ((x0*(-s)) + (t*(-y0) + t*(-s)))
by A5,SURREALR:37
.= X + ((x*s +t*y) + ((x0*(-s)) + (t*(-y0) + t*(-s))))
by SURREALR:37;
hence thesis by A4,A8,A9,SURREALO:4;
end;
Lm7: for r being Sequence of REAL
for y being strictly_decreasing Surreal-Sequence
for a being Surreal, e being positive Real
for A,B being Ordinal st succ B c= A c= dom r/\dom y
holds
|.(Sum(r|A,No_omega^ y|A) - Sum(r|succ B,No_omega^ y|succ B))
* ((uReal.e)* No_omega^ a).| infinitely< No_omega^ (y..B+a)
proof
let r be Sequence of REAL;
let y be strictly_decreasing Surreal-Sequence;
let a be Surreal,e be positive Real;
let A,B be Ordinal such that A1:succ B c= A c= dom r/\dom y;
let P be positive Real;
set p=1/(P*e),
Ny=No_omega^ y,
Na = No_omega^ a,
NA = (uReal.e) * Na,
sB=succ B,
S=Sum(r|A,Ny|A) - Sum(r|sB,Ny|sB);
A2: dom Ny = dom y by SURREALC:def 22;
A3: sB c= dom r/\dom y by A1;
A4: Ny|A = No_omega^(y|A) &
Ny|B = No_omega^(y|B) & Ny|sB = No_omega^(y|sB) by SURREALC:88;
B in succ B by ORDINAL1:6;
then B in dom r/\dom y by A1;
then
A5: B in dom y = dom Ny by XBOOLE_0:def 4,SURREALC:def 22;
then y..B = y.B & Ny.B = Ny..B by Def5;
then
A6: Ny..B = No_omega^ (y..B) by A5,SURREALC:def 22;
then - Sum(r|sB,Ny|sB) == -(Sum(r|B,Ny|B) + uReal.(r.B) * Ny..B)
by A3,A4,Th64,SURREALR:65;
then Sum(r|A,Ny|A) +- ( Sum(r|B,Ny|B) + uReal.(r.B)* Ny..B)
== Sum(r|A,Ny|A) +- Sum(r|sB,Ny|sB) by SURREALR:66;
then
A7: |.Sum(r|A,Ny|A) - ( Sum(r|B,Ny|B) + uReal.(r.B)* Ny..B).|
== |.S.| by SURREALC:48;
Sum(r|A,Ny|A) is (Sum(r|B,Ny|B),Ny..B,r.B)_Term by A1,A2,ORDINAL1:21,Th68;
then |.S.| infinitely< Ny..B by A7,SURREALC:17,SURREALC:def 14;
then |.S.| infinitely< uReal.p * Ny..B by SURREALC:13;
then |.S.| < uReal.p * Ny..B by SURREALC:9;
then
A8: -(uReal.p * Ny..B) < S < uReal.p * Ny..B by SURREALC:52;
0_No < NA by SURREALI:def 8;
then
A9: (-(uReal.p * Ny..B))*NA < S*NA < uReal.p * Ny..B*NA by A8,SURREALR:70;
A10: 0_No < uReal.P by SURREALI:def 8;
Ny..B * Na == No_omega^(y..B+a) by A6,SURREALC:27;
then
A11: uReal.p * Ny..B*NA ==
uReal.(p*e) * No_omega^(y..B+a) by Lm6;
then
A12:S*NA < uReal.(p*e) * No_omega^(y..B+a) by A9,SURREALO:4;
(-(uReal.p * Ny..B))*NA = - ((uReal.p * Ny..B)*NA) by SURREALR:58;
then (-(uReal.p * Ny..B))*NA == - (uReal.(p*e) * No_omega^(y..B+a))
by A11,SURREALR:65;
then - (uReal.(p*e) * No_omega^(y..B+a)) < S*NA by A9,SURREALO:4;
then |.S*NA.| < uReal.(p*e) * No_omega^(y..B+a) by A12,SURREALC:52;
then
A13: uReal.P * |.S*NA.| < uReal.P * (uReal.(p*e) * No_omega^(y..B+a))
by SURREALR:70,A10;
A14:p*(P*e) =1 by XCMPLX_1:87;
No_omega^(y..B+a) *1_No = No_omega^(y..B+a);
then (1_No *uReal.P) * (uReal.(p*e) * No_omega^(y..B+a))
== uReal.(P*(p*e)) * No_omega^(y..B+a) by Lm6;
hence thesis by A4,A13,A14,SURREALN:48,SURREALO:4;
end;
theorem Th104:
for e being Real st succ B c= A c= dom r/\dom y holds
|.(Sum(r|A,No_omega^ y|A) - Sum(r|succ B,No_omega^ y|succ B))
* ((uReal.e)* No_omega^ a).| infinitely< No_omega^ (y..B+a)
proof
let e be Real such that
A1:succ B c= A c= dom r/\dom y;
set SB=Sum(r|succ B,No_omega^ y|succ B),
SA=Sum(r|A,No_omega^ y|A),
NA=No_omega^ a,
NB=No_omega^ (y..B+a);
per cases;
suppose e >0;
hence thesis by A1,Lm7;
end;
suppose e < 0;
then
A2: |.(SA-SB)*((uReal.(-e))* NA).| infinitely< NB by A1,Lm7;
(uReal.(-e))* NA == (-uReal.(e))* NA =
- (uReal.(e)* NA) by SURREALN:56,SURREALR:54,58;
then (SA-SB)*((uReal.(-e))* NA) == (SA-SB)*(-(uReal.(e)* NA))
= - ((SA-SB)*((uReal.(e)* NA))) by SURREALR:54,58;
then |.(SA-SB)*((uReal.(-e))* NA).|==
|.(SA-SB)*(-(uReal.(e)* NA)).| ==
|.(SA-SB)*((uReal.(e)* NA)).| by SURREALC:48,40;
hence thesis by A2,SURREALC:11,SURREALO:4;
end;
suppose
A3:e = 0;
0_No infinitely< NB
proof
let e;
NB is positive;
hence thesis;
end;
hence thesis by A3,SURREALN:47,SURREALC:def 6;
end;
end;
theorem Th105:
Partial_Sums(y,z,-r,s,a,S,T) = - Partial_Sums(y,z,r,s,a,S,T)
proof
set S1 = (y,z,S,T) += a,AD = Product(r,s,S,T),mAD = Product(-r,s,S,T),
ST=[:S,T:], F =addreal;
defpred P[set] means
for X being Element of Fin ST st X=$1 holds
addreal $$ ( X, mAD) = - addreal $$ ( X, AD);
A1:P[{}.ST]
proof
let X be Element of Fin ST;
assume X={}.ST;
then F $$ ( X, mAD) = the_unity_wrt F &
F$$ ( X, AD) = the_unity_wrt F by SETWISEO:31;
hence thesis by BINOP_2:2;
end;
A2: for B9 being (Element of Fin ST), b being Element of ST holds P[B9] &
not b in B9 implies P[B9 \/ {b}]
proof
let B9 be (Element of Fin ST), b be Element of ST such that
A3:P[B9] & not b in B9;
let X be Element of Fin ST such that
A4: X=B9 \/ {b};
A5: F $$(X, mAD) = F.(F $$ (B9,mAD),mAD.b) by A3,A4,SETWOP_2:2
.= F $$ (B9,mAD) + mAD.b by BINOP_2:def 9;
A6: F $$(X, AD) = F.(F $$ (B9,AD),AD.b) by A3,A4,SETWOP_2:2
.= F $$ (B9,AD) + AD.b by BINOP_2:def 9;
A7:F $$(B9, mAD) = -F $$(B9, AD) by A3;
consider i,j be object such that
A8: i in S & j in T & b=[i,j] by ZFMISC_1:def 2;
reconsider i,j as Ordinal by A8;
A9: (-r).i = -(r.i) by VALUED_1:8;
mAD.b = mAD.(i,j) by A8,BINOP_1:def 1
.= (-r).i * s.j by A8,Def15
.= - (r.i * s.j) by A9
.= - AD.(i,j) by A8,Def15
.= - AD.b by A8,BINOP_1:def 1;
hence thesis by A5,A6,A7;
end;
for B being Element of Fin ST holds P[B] from SETWISEO:sch 2(A1,A2);
hence thesis;
end;
Lm8: for A,B being non empty Ordinal
for y,z,yz being strictly_decreasing Surreal-Sequence
for r,s being Sequence of REAL holds
Sum(y,z,yz,-r,s,A,B) = - Sum(y,z,yz,r,s,A,B)
proof
let A,B be non empty Ordinal;
let y,z,yz be strictly_decreasing Surreal-Sequence;
let r,s be Sequence of REAL;
set MP = Sum(y,z,yz,-r,s,A,B),
P= Sum(y,z,yz,r,s,A,B),
mP=-P;
A2:dom P = dom yz = dom MP & dom mP = dom P by Def19,VALUED_1:8;
for a being object st a in dom yz holds
MP.a = mP.a
proof
let a be object such that
A3: a in dom yz;
A4: mP.a = -(P.a) by VALUED_1:8;
MP.a = Partial_Sums(y,z,-r,s,yz..a,A,B) &
P.a = Partial_Sums(y,z,r,s,yz..a,A,B) by A3,Def19;
hence thesis by A4,Th105;
end;
hence thesis by A2,FUNCT_1:2;
end;
theorem
dom y c= S & dom z c= T implies
Sum(y,z,yz,-r,s,S,T) = - Sum(y,z,yz,r,s,S,T) &
Sum(y,z,yz,r,-s,S,T) = - Sum(y,z,yz,r,s,S,T)
proof
assume
A1:dom y c= S & dom z c= T;
thus Sum(y,z,yz,-r,s,S,T) = - Sum(y,z,yz,r,s,S,T) by Lm8;
Sum(y,z,yz,r,-s,S,T) = Sum(z,y,yz,-s,r,T,S) by A1,Th90
.= - Sum(z,y,yz,s,r,T,S) by Lm8;
hence thesis by A1,Th90;
end;
theorem Th107:
dom y c= S & dom z c= T & dom y c= dom r & dom z c= dom s &
A c= dom y & B c= dom z
implies
Sum (Sum(y,z,yz,r,s,S,T), No_omega^ yz)
- Sum(Sum(y/^A,z/^B,yz,r/^A,s/^B,S,T), No_omega^ yz)
== Sum(Sum(y|A,z,yz,r|A,s,S,T), No_omega^ yz) +
Sum(Sum(y,z|B,yz,r,s|B,S,T), No_omega^ yz)
- Sum(Sum(y|A,z|B,yz,r|A,s|B,S,T), No_omega^ yz)
proof
assume that
A1: dom y c= S & dom z c= T and
A2: dom y c= dom r & dom z c= dom s and
A3: A c= dom y & B c= dom z;
set Nyz = No_omega^ yz;
set Syz = Sum (Sum(y,z,yz,r,s,S,T), Nyz),
SyYz= Sum(Sum(y|A,z,yz,r|A,s,S,T), Nyz),
SyzZ= Sum(Sum(y,z|B,yz,r,s|B,S,T), Nyz),
SyYzZ= Sum(Sum(y|A,z|B,yz,r|A,s|B,S,T),Nyz),
SYZ=Sum(Sum(y/^A,z/^B,yz,r/^A,s/^B,S,T), Nyz);
A4: Syz == SyYz + Sum(Sum(y/^A,z,yz,r/^A,s,S,T), Nyz) by A1,A2,A3,Th99;
dom (z|B) c= dom z by RELAT_1:60;
then dom (z|B) c= T by A1;
then SyzZ == SyYzZ + Sum(Sum(y/^A,z|B,yz,r/^A,s|B,S,T),Nyz)
by A1,A2,A3,Th99;
then SyzZ - SyYzZ == Sum(Sum(y/^A,z|B,yz,r/^A,s|B,S,T),Nyz)
by SURREALR:41,42;
then
A5:Sum(Sum(y/^A,z|B,yz,r/^A,s|B,S,T), Nyz) + SYZ == (SyzZ - SyYzZ) + SYZ
by SURREALR:66;
dom (y/^A) c= dom y by Th6;
then dom (y/^A) c= S by A1;
then Sum(Sum(y/^A,z,yz,r/^A,s,S,T), Nyz)
== Sum(Sum(y/^A,z|B,yz,r/^A,s|B,S,T), Nyz) + SYZ
by A1,A2,A3,Th100;
then
A6: Sum(Sum(y/^A,z,yz,r/^A,s,S,T), Nyz) ==
(SyzZ - SyYzZ) + SYZ by A5,SURREALO:4;
SyYz + Sum(Sum(y/^A,z,yz,r/^A,s,S,T), Nyz)
== SyYz + ((SyzZ - SyYzZ) + SYZ) by A6,SURREALR:66;
then Syz == SyYz + ((SyzZ - SyYzZ) + SYZ)
= SyYz + (SyzZ +- SyYzZ) + SYZ
= SyYz + SyzZ +- SyYzZ + SYZ by A4,SURREALO:4,SURREALR:37;
hence thesis by SURREALR:41,42;
end;
theorem Th108:
dom y c= S & dom z c= T & Unique_No (rng y++rng z) c= rng yz &
A in dom y & B in dom z & y..A + z..B < a
implies
|.Sum(Sum(y/^A,z/^B,yz,r,s,S,T), No_omega^ yz).|
infinitely< No_omega^ a
proof
assume that
A1: dom y c= S & dom z c= T & Unique_No (rng y++rng z) c= rng yz and
A2:A in dom y & B in dom z and
A3: y..A + z..B < a;
set yY=y/^A,zZ=z/^B,P=Sum(yY,zZ,yz,r,s,S,T),Nyz = No_omega^ yz;
y.A = y..A & z.B = z..B by A2,Def5;
then y..A in rng y & z..B in rng z by A2,FUNCT_1:def 3;
then y..A + z..B in rng y++rng z by SURREALR:def 8;
then Unique_No (y..A + z..B) in Unique_No (rng y++rng z) by Def8;
then consider O be object such that
A4:O in dom yz & yz.O = Unique_No (y.. A+ z..B) by A1,FUNCT_1:def 3;
reconsider O as Ordinal by A4;
A5: yz.O = yz..O by A4,Def5;
A6:dom P = dom yz =dom Nyz by Def19,SURREALC:def 22;
O c= dom P /\ dom Nyz by A6,A4,ORDINAL1:def 2;
then
A7: Sum(P,Nyz) == Sum(P|O,Nyz|O) + Sum(P/^O,Nyz/^O) by Th71;
A8: yz..O == y..A + z..B by A4,A5,SURREALO:def 10;
then
A9: yz..O < a by A3,SURREALO:4;
rng(P|O) c= {0}
proof
let c be object such that
A10:c in rng (P|O);
consider d be object such that
A11:d in dom (P|O) & (P|O).d = c by A10,FUNCT_1:def 3;
reconsider d as Ordinal by A11;
A12:d in O & d in dom P by A11,RELAT_1:57;
A13: (P|O).d = P.d by A11,FUNCT_1:47;
yz..d = yz.d by A6,A12,Def5;
then yz..d > y..A + z..B by A8,SURREALO:4,A12,A5,A4,SURREALC:def 11;
then P.d = 0 by A1,A6,A12,Th92;
hence thesis by A11,A13,TARSKI:def 1;
end;
then Sum(P|O,Nyz|O) = 0_No by Th66;
then
A14: Sum(P,Nyz) = Sum(P/^O,Nyz/^O) by A7,SURREALO:50;
A15: dom (P/^O) = (dom P)-^O & dom (Nyz/^O) = (dom Nyz)-^O by Def1;
A16:0=O-^O in (dom yz)-^O by A4,ORDINAL3:53,54;
then
A17:0 in dom (P/^O)/\ dom (Nyz/^O) by A6,A15;
(Nyz/^O)..0 = (Nyz/^O).0 by A16,A15,A6,Def5
.= Nyz.(O+^0) by Th8
.= Nyz.O by ORDINAL2:27
.= No_omega^ (yz..O) by A4,Def5,A6,SURREALC:def 22;
hence thesis by A14,A17,Th70,A9,SURREALC:25;
end;
theorem Th109:
for yz,yzE being strictly_decreasing uSurreal-Sequence st
dom y c= S & dom z c= T &
Unique_No (rng y++rng z) c= rng yz c= rng yzE
holds
Sum (Sum(y,z,yz,r,s,S,T), No_omega^ yz) =
Sum (Sum(y,z,yzE,r,s,S,T), No_omega^ yzE)
proof
let yz,yzE be strictly_decreasing uSurreal-Sequence such that
A1: dom y c= S & dom z c= T and
A2: Unique_No (rng y++rng z) c= rng yz c= rng yzE;
set P=Sum(y,z,yz,r,s,S,T),
PE=Sum(y,z,yzE,r,s,S,T);
set N=No_omega^ yz,
NE=No_omega^ yzE;
A3: dom P = dom yz = dom N & dom PE = dom yzE = dom NE
by Def19,SURREALC:def 22;
A4: rng N c= rng NE
proof
let b be object;
assume b in rng N;
then consider a be object such that
A5:a in dom N & N.a =b by FUNCT_1:def 3;
yz.a =yz..a by A3,A5,Def5;
then
A6: N.a = No_omega^ (yz..a) by A5,SURREALC:def 22;
yz.a in rng yz by A3,A5,FUNCT_1:def 3;
then consider c be object such that
A7:c in dom yzE & yzE.c = yz.a by A2,FUNCT_1:def 3;
NE.c = b by A6,A3,A5,Def5,A7,SURREALC:def 22;
hence thesis by A3,A7,FUNCT_1:def 3;
end;
A8: for C,D being Ordinal st
C in dom N & D in dom NE & N.C = NE.D holds P.C = PE.D
proof
let C,D be Ordinal such that
A9:C in dom N & D in dom NE & N.C = NE.D;
yz.C=yz..C & yzE.D=yzE..D by A3,A9,Def5;
then
A10: N.C = No_omega^ (yz..C) &
NE.D = No_omega^ (yzE..D) by A9,SURREALC:def 22;
A11: yz..C == yzE..D
proof
assume not yz..C == yzE..D;
then No_omega^ (yz..C) infinitely< No_omega^ (yzE..D) or
No_omega^ (yzE..D) infinitely< No_omega^ (yz..C)
by SURREALC:25;
hence thesis by A9,A10,SURREALO:3,SURREALC:9;
end;
thus P.C = Partial_Sums(y,z,r,s,yz..C,S,T) by A3,A9,Def19
.= Partial_Sums(y,z,r,s,yzE..D,S,T) by A1,A11,Th87
.=PE.D by A3,A9,Def19;
end;
for C being Ordinal st C in dom NE & not NE.C in rng N holds PE.C = 0
proof
let C be Ordinal such that
A12: C in dom NE & not NE.C in rng N;
for a being Surreal st a==yzE..C holds not a in rng y ++ rng z
proof
let a be Surreal such that
A13: a==yzE..C & a in rng y ++ rng z;
Unique_No a in Unique_No (rng y++rng z) by A13,Def8;
then consider b be object such that
A14: b in dom yz & yz.b = Unique_No a by A2,FUNCT_1:def 3;
A15: N.b = No_omega^ (Unique_No a) by A14,A3,SURREALC:def 22;
A16: yzE..C= yzE.C by A12,A3,Def5;
then
A17: NE.C = No_omega^ (yzE..C) by A12,SURREALC:def 22;
Unique_No a == a by SURREALO:def 10;
then
A18: Unique_No a ==yzE..C by A13,SURREALO:4;
yzE..C in rng yzE by A16,A12,A3,FUNCT_1:def 3;
then yzE..C is uSurreal by SURREALO:def 12;
then Unique_No a =yzE..C by A18,SURREALO:50;
hence thesis by A12,A14,A3,A15,A17,FUNCT_1:def 3;
end;
then Partial_Sums(y,z,r,s,yzE..C,S,T) = 0 by A1,Th88;
hence thesis by A12,A3,Def19;
end;
hence thesis by A3,A8,A4,Th73;
end;
::$N Correctness of the Product for Selected Representations
::Gonshor'86 Theorem 5.6
theorem
for yz being strictly_decreasing uSurreal-Sequence st
dom y c= S & dom z c= T & Unique_No (rng y++rng z) c= rng yz &
dom y = dom r & dom z = dom s
holds Sum(r,No_omega^ y) * Sum(s,No_omega^z)==
Sum (Sum(y,z,yz,r,s,S,T), No_omega^ yz)
proof
let yz be strictly_decreasing uSurreal-Sequence such that
A1: dom y c= S & dom z c= T & Unique_No (rng y++rng z) c= rng yz and
A2:dom y = dom r & dom z = dom s;
set Ny = No_omega^ y,
Nz = No_omega^ z,
Nyz = No_omega^ yz;
defpred P[Ordinal] means for Y,Z being Ordinal st
Y c= dom y & Z c= dom z & Y(+)Z = $1
holds
Sum(r|Y,Ny|Y) * Sum(s|Z,Nz|Z)==
Sum (Sum(y|Y,z|Z,yz,r|Y,s|Z,S,T), Nyz);
A3:for O being Ordinal st for C being Ordinal st C in O holds P[C] holds P[O]
proof
let O be Ordinal such that
A4: for C being Ordinal st C in O holds P[C];
let Y,Z be Ordinal such that
A5: Y c= dom y & Z c= dom z & Y(+)Z = O;
reconsider rY=r|Y,sZ=s|Z as Sequence of REAL;
set yY = y|Y,
zZ = z|Z;
set P = Sum(yY,zZ,yz,rY,sZ,S,T);
set NyY = Ny|Y,
NzZ = Nz|Z;
A6: dom yY = Y = dom rY & dom zZ = Z =dom sZ by A5,A2,RELAT_1:62;
per cases;
suppose
A7: Y is limit_ordinal & Z is limit_ordinal;
set Uyz = ord Unique_No (rng yY++rng zZ);
Unique_No (rng yY++rng zZ) is desc_ordering by Th47;
then
A8: rng Uyz = Unique_No (rng yY++rng zZ) by Def13;
then reconsider Uyz as strictly_decreasing uSurreal-Sequence
by SURREALC:def 10;
set NUyz = No_omega^ Uyz,
PU=Sum(yY,zZ,Uyz,rY,sZ,S,T);
dom Ny = dom y & dom Nz = dom z by SURREALC:def 22;
then
A9: Y c= dom r/\dom Ny & Z c= dom s/\dom Nz by A5,A2;
reconsider SuY =[{Sum(r|B,Ny|B) + uReal.(r.B - e) * Ny..B
where B is Element of Y,e: B in Y},
{Sum(r|B,Ny|B) + uReal.(r.B + e) * Ny..B
where B is Element of Y,e: B in Y}] as Surreal by A9,Th61;
Unique_No SuY = Sum(r|Y,Ny|Y) by A9,Th62;
then
A10: SuY == Sum(r|Y,Ny|Y) by SURREALO:def 10;
reconsider SuZ = [{Sum(s|B,Nz|B) + uReal.(s.B - e) * Nz..B
where B is Element of Z,e: B in Z},
{Sum(s|B,Nz|B) + uReal.(s.B + e) * Nz..B
where B is Element of Z,e: B in Z}] as Surreal by A9,Th61;
Unique_No SuZ = Sum(s|Z,Nz|Z) by A9,Th62;
then
A11: SuZ == Sum(s|Z,Nz|Z) by SURREALO:def 10;
rng yY++rng zZ c= rng y++rng z by Th34;
then Unique_No(rng yY++rng zZ) c= Unique_No(rng y++rng z) by Th48;
then
A12: Unique_No (rng yY++rng zZ) c= rng yz by A1;
dom yY c= S & dom zZ c= T by A5,A1,A6;
then
A13: Sum (P, Nyz) = Sum (PU, NUyz) by A12,Th109,A8;
A14: for Y1,Z1 being Ordinal st Y1 in Y & Z1 in Z
for ey,ez being Real
for y1,z1 being Surreal st
y1 == Sum(r|succ Y1,Ny |succ Y1) + uReal.ey * No_omega^(y..Y1) &
z1 == Sum(s|succ Z1,Nz |succ Z1) + uReal.ez * No_omega^(z..Z1)
for O1 being Ordinal st O1 in dom Uyz & Uyz..O1 == (y..Y1)+(z..Z1)
holds
ex T being Surreal st |.T.| infinitely< No_omega^ ((y..Y1)+(z..Z1)) &
SuY*z1 + y1*SuZ - z1*y1 ==
Sum(PU|succ O1,NUyz|succ O1 ) + T -
uReal.(ey*ez)* No_omega^(y..Y1 + z..Z1)
proof
let Y1,Z1 be Ordinal such that
A15: Y1 in Y & Z1 in Z;
set suY = succ Y1,
suZ = succ Z1,
NY = No_omega^(y..Y1),
NZ = No_omega^(z..Z1);
let ey,ez be Real;
set Ry = uReal.ey,
Rz = uReal.ez;
set Sy = Sum(r|suY,Ny |suY),
Sz = Sum(s|suZ,Nz |suZ);
let y1,z1 be Surreal such that
A16: y1 == Sy + Ry * NY &
z1 == Sz + Rz * NZ;
let O1 be Ordinal such that
A17: O1 in dom Uyz & Uyz..O1 == (y..Y1)+(z..Z1);
set OPC=SuY*z1 + y1*SuZ - z1*y1;
SuY*z1 == SuY*(Sz + Rz * NZ) & y1*SuZ == (Sy + Ry * NY) * SuZ
by A16,SURREALR:54;
then SuY*z1 + y1*SuZ ==
SuY*(Sz + Rz * NZ) + (Sy + Ry * NY) * SuZ &
z1*y1 == (Sy + Ry * NY)*(Sz + Rz * NZ)
by A16,SURREALR:66,Th29;
then
A18: OPC == SuY*(Sz + Rz * NZ) + (Sy + Ry * NY) * SuZ -
(Sy + Ry * NY)*(Sz + Rz * NZ) by Th28;
SuY*(Sz + Rz * NZ) + (Sy + Ry * NY) * SuZ -
(Sy + Ry * NY)*(Sz + Rz * NZ)
== (SuY*Sz +Sy*SuZ - Sy*Sz)
+ ((SuY-Sy)*(Rz * NZ) + (SuZ-Sz) * (Ry * NY))
- (Rz * NZ) * (Ry * NY) by Th103;
then
A19: OPC == (SuY*Sz +Sy*SuZ - Sy*Sz)
+ ((SuY-Sy)*(Rz * NZ) + (SuZ-Sz) * (Ry * NY))
- (Rz * NZ) * (Ry * NY) by A18,SURREALO:4;
A20: suY in Y by A7,A15,ORDINAL1:28;
A21: suY c= Y by A7,A15,ORDINAL1:28,ORDINAL1:def 2;
then
A22: suY c= dom y by A5;
A23: suZ in Z by A7,A15,ORDINAL1:28;
A24: suZ c= Z by ORDINAL1:def 2,A7,A15,ORDINAL1:28;
then
A25: suZ c= dom z by A5;
A26: y|suY = yY |suY & r|suY = rY|suY & z|suZ = zZ |suZ & s|suZ = sZ|suZ
by A21,A24,RELAT_1:74;
A27: No_omega^y |Y = Ny|Y & No_omega^y |suY =Ny|suY by SURREALC:88;
A28: No_omega^z |Z = Nz|Z & No_omega^z |suZ =Nz|suZ by SURREALC:88;
set Pyz = Sum(yY /^ suY,zZ /^ suZ,yz,rY /^ suY,sZ /^ suZ,S,T);
A29: SuY*Sz +Sy*SuZ - Sy*Sz == Sum (P, Nyz) - Sum (Pyz, Nyz)
proof
suY (+) Z in Y(+)Z by A20,ORDINAL7:94;
then Sy * SuZ == Sy * Sum(s|Z,Nz|Z) ==
Sum (Sum(y|suY,zZ,yz,r|suY,sZ,S,T), Nyz) by A4,A5,A22,A11,Th29;
then
A30: Sy * SuZ == Sum (Sum(y|suY,zZ,yz,r|suY,sZ,S,T), Nyz)by SURREALO:4;
A31: Y (+) suZ in O by A23,A5,ORDINAL7:94;
then SuY * Sz == Sum(r|Y,Ny|Y) * Sz ==
Sum (Sum(yY,z|suZ,yz,rY,s|suZ,S,T), Nyz) by A4,A5,A25,A10,Th29;
then
A32: SuY * Sz == Sum (Sum(yY,z|suZ,yz,rY,s|suZ,S,T), Nyz) by SURREALO:4;
suY (+) suZ in Y (+) suZ by A20,ORDINAL7:94;
then
A33: Sy * Sz == Sum (Sum(y|suY,z|suZ,yz,r|suY,s|suZ,S,T), Nyz)
by A4,A22,A25,A31,ORDINAL1:10;
SuY*Sz +Sy*SuZ ==
Sum (Sum(y|suY,zZ,yz,r|suY,sZ,S,T), Nyz)+
Sum (Sum(yY,z|suZ,yz,rY,s|suZ,S,T), Nyz) by A30,A32,SURREALR:66;
then
A34: SuY*Sz +Sy*SuZ - Sy*Sz ==
Sum (Sum(yY|suY,zZ,yz,rY|suY,sZ,S,T), Nyz)+
Sum (Sum(yY,zZ|suZ,yz,rY,sZ|suZ,S,T), Nyz)
- Sum (Sum(yY|suY,zZ|suZ,yz,rY|suY,sZ|suZ,S,T), Nyz)
by A26,A33,Th28;
A35: dom yY c= S & dom zZ c= T by A6,A5,A1;
Sum (Sum(yY|suY,zZ,yz,rY|suY,sZ,S,T), Nyz)
+ Sum (Sum(yY,zZ|suZ,yz,rY,sZ|suZ,S,T), Nyz)
- Sum (Sum(yY|suY,zZ|suZ,yz,rY|suY,sZ|suZ,S,T), Nyz)
== Sum (P,Nyz) - Sum (Pyz, Nyz) by A35,A21,A24,A6,Th107;
hence thesis by A34,SURREALO:4;
end;
A36: y..Y1 = y.Y1 & z..Z1 = z.Z1 by A5,A15,Def5;
A37: |.((SuY-Sy)*(Rz * NZ) + (SuZ-Sz) * (Ry * NY)).|
infinitely< No_omega^ (y..Y1+z..Z1)
proof
suY c= Y c= dom r/\dom y
by A7,A15,ORDINAL1:28,ORDINAL1:def 2,A5,A2;
then
A38: |.(Sum(rY,Ny|Y) - Sy )
* (Rz* NZ).| infinitely< No_omega^ (y..Y1+z..Z1) by Th104,A27;
Sum(rY,Ny|Y) - Sy == SuY -Sy by A10,Th28;
then (Sum(rY,Ny|Y) - Sy ) * (Rz* NZ) == (SuY -Sy)*(Rz* NZ) by Th29;
then
A39: |.(SuY - Sy ) * (Rz* NZ).| infinitely< No_omega^ (y..Y1+z..Z1)
by A38,SURREALC:17,48;
suZ c= Z c= dom s/\dom z by ORDINAL1:def 2,A7,A15,ORDINAL1:28,A5,A2;
then
A40: |.(Sum(sZ,Nz|Z) - Sz ) * (Ry* NY).| infinitely<
No_omega^ (y..Y1+z..Z1) by Th104,A28;
Sum(sZ,Nz|Z) - Sz == SuZ - Sz by A11,Th28;
then (Sum(sZ,Nz|Z) - Sz ) * (Ry* NY) == (SuZ - Sz)*(Ry* NY) by Th29;
then |.(SuZ - Sz ) * (Ry* NY).| infinitely< No_omega^ (y..Y1+z..Z1)
by A40,SURREALC:17,48;
hence thesis by A39,SURREALC:41;
end;
A41: yY..suY = yY.suY = y.suY = y..suY & zZ..suZ = zZ.suZ = z.suZ = z..suZ
by A5,A6,A20,A23,Def5,FUNCT_1:47;
then yY..suY < y..Y1 & zZ..suZ <= z..Z1
by ORDINAL1:6,A5,A20,A23,A36,SURREALC:def 11;
then
A42: yY..suY + zZ..suZ < (y..Y1)+(z..Z1) by SURREALR:44;
A43: dom yY c= S & dom zZ c= T by A5,A1,A6;
A44: |. Sum(Pyz, Nyz).|
infinitely< No_omega^ (y..Y1+z..Z1) by A43,A12,A20,A23,A6,A42,Th108;
set sO1=succ O1;
A45: dom PU = dom Uyz & dom NUyz = dom Uyz by Def19,SURREALC:def 22;
then sO1 c= dom PU/\dom NUyz by A17,ORDINAL1:21;
then
A46: Sum(PU, NUyz) == Sum(PU|sO1, NUyz|sO1) +
Sum(PU/^sO1, NUyz/^sO1) by Th71;
take APR = Sum(PU/^sO1, NUyz/^sO1) +- Sum (Pyz, Nyz)
+ ((SuY-Sy)*(Rz * NZ) + (SuZ-Sz) * (Ry * NY));
A47: sO1 in dom Uyz
proof
yY..suY in rng yY & zZ..suZ in rng zZ
by A20,A23,A6,A41,FUNCT_1:def 3;
then yY..suY + zZ..suZ in rng yY ++ rng zZ by SURREALR:def 8;
then Unique_No (yY..suY + zZ..suZ) in rng Uyz by A8,Def8;
then consider d be object such that
A48: d in dom Uyz & Uyz.d = Unique_No (yY..suY + zZ..suZ)
by FUNCT_1:def 3;
reconsider d as Ordinal by A48;
A49: Uyz.d = Uyz..d by A48,Def5;
A50: Uyz..O1 = Uyz.O1 by A17,Def5;
Unique_No (yY..suY + zZ..suZ) == yY..suY + zZ..suZ
by SURREALO:def 10;
then
A51: Uyz..d == yY..suY + zZ..suZ by A48,Def5;
then Uyz..d < (y..Y1)+(z..Z1) by A42,SURREALO:4;
then Uyz..d <= Uyz..O1 by A17,SURREALO:4;
then not d in O1 by A17,A49,A50,SURREALC:def 11;
then O1 c< d by A51,A17,ORDINAL1:16,A42,SURREALO:4;
then sO1 c= d by ORDINAL1:11,21;
hence thesis by A48,ORDINAL1:12;
end;
A52: O1 in sO1 by ORDINAL1:6;
A53: Uyz..sO1 = Uyz.sO1 & Uyz..O1 = Uyz.O1 by A17,A47,Def5;
A54: 0=sO1-^sO1 in (dom PU)-^sO1 by A47,A45,ORDINAL3:53,54;
A55: dom (PU/^sO1) = (dom PU)-^sO1 & dom (NUyz/^sO1) = (dom NUyz)-^sO1
by Def1;
then
A56: 0 in dom (PU/^sO1)/\ dom(NUyz/^sO1) by A45,A54;
A57: Uyz..sO1 < (y..Y1)+(z..Z1)
by A17,A53,A47,A52,SURREALC:def 11,SURREALO:4;
sO1+^0 = sO1 by ORDINAL2:27;
then
A58: (NUyz/^sO1)..0 = (NUyz/^sO1).0 = NUyz.sO1 by A47,A45,A55,Def5,Th8;
Uyz.sO1 = Uyz..sO1 by A47,Def5;
then (NUyz/^sO1)..0 = No_omega^(Uyz..sO1)
by A58,A45,A47,SURREALC:def 22;
then |.Sum(PU/^sO1, NUyz/^sO1).| infinitely<
No_omega^ ((y..Y1)+(z..Z1))
by A56,A57, Th70,SURREALC:25;
then |.Sum(PU/^sO1, NUyz/^sO1) - Sum (Pyz, Nyz).|
infinitely< No_omega^ ((y..Y1)+(z..Z1)) by A44,SURREALC:43;
hence |.APR.| infinitely< No_omega^ ((y..Y1)+(z..Z1))
by A37,SURREALC:41;
Sum (P, Nyz) - Sum (Pyz, Nyz)==
Sum(PU|sO1, NUyz|sO1) + Sum(PU/^sO1, NUyz/^sO1) - Sum (Pyz, Nyz)
by A13,A46,SURREALR:66;
then SuY*Sz +Sy*SuZ - Sy*Sz == Sum(PU|sO1, NUyz|sO1)
+ Sum(PU/^sO1, NUyz/^sO1) +- Sum (Pyz, Nyz) = Sum(PU|sO1, NUyz|sO1)
+ (Sum(PU/^sO1, NUyz/^sO1) +- Sum (Pyz, Nyz))
by A29,SURREALO:4,SURREALR:37;
then
A59: (SuY*Sz +Sy*SuZ - Sy*Sz) + ((SuY-Sy)*(Rz * NZ) + (SuZ-Sz) * (Ry * NY))
== Sum(PU|sO1, NUyz|sO1) + (Sum(PU/^sO1, NUyz/^sO1) +- Sum (Pyz, Nyz))
+ ((SuY-Sy)*(Rz * NZ) + (SuZ-Sz) * (Ry * NY))
= Sum(PU|sO1, NUyz|sO1) + APR by SURREALR:66,37;
NZ*NY == No_omega^(y..Y1 + z..Z1) by SURREALC:27;
then (Rz * NZ) * (Ry * NY) == uReal.(ey*ez)* No_omega^(y..Y1 + z..Z1)
by Lm6;
then (SuY*Sz +Sy*SuZ - Sy*Sz)
+ ((SuY-Sy)*(Rz * NZ) + (SuZ-Sz) * (Ry * NY))
- (Rz * NZ) * (Ry * NY)
== Sum(PU|sO1, NUyz|sO1) + APR-uReal.(ey*ez)* No_omega^(y..Y1 + z..Z1)
by A59,Th28;
hence thesis by A19,SURREALO:4;
end;
set D = dom Uyz;
A60: dom NUyz = dom Uyz = dom PU by Def19,SURREALC:def 22;
then
A61: D c= (dom PU)/\(dom NUyz);
reconsider SUP =[{Sum(PU|B,NUyz|B) + uReal.(PU.B - e) * NUyz..B
where B is Element of D,e: B in D},
{Sum(PU|B,NUyz|B) + uReal.(PU.B + e) * NUyz..B
where B is Element of D,e: B in D}] as Surreal by A61,Th61;
Unique_No SUP = Sum(PU|D,NUyz|D) by A61,Th62;
then
A62: SUP == Sum(PU|D,NUyz|D) by SURREALO:def 10;
A63: SuY*SuZ = [comp(L_SuY,SuY,SuZ,L_SuZ) \/ comp(R_SuY,SuY,SuZ,R_SuZ),
comp(L_SuY,SuY,SuZ,R_SuZ) \/ comp(R_SuY,SuY,SuZ,L_SuZ)]
by SURREALR:50;
A64: for Y1,Z1 being Ordinal st Y1 in Y & Z1 in Z
ex O1 being Ordinal st O1 in dom Uyz & Uyz..O1 == (y..Y1)+(z..Z1)
proof
let Y1,Z1 be Ordinal such that
A65: Y1 in Y & Z1 in Z;
A66: y..Y1 = y.Y1 = yY.Y1 & z..Z1 = z.Z1 = zZ.Z1
by A65,A6,Def5,A5,FUNCT_1:47;
y..Y1 in rng yY & z..Z1 in rng zZ by A65,A6,A66,FUNCT_1:def 3;
then y..Y1 + z..Z1 in rng yY ++ rng zZ by SURREALR:def 8;
then Unique_No (y..Y1 + z..Z1) in rng Uyz by A8,Def8;
then consider d be object such that
A67: d in dom Uyz & Uyz.d = Unique_No (y..Y1 + z..Z1) by FUNCT_1:def 3;
reconsider d as Ordinal by A67;
take d;
Unique_No (y..Y1 + z..Z1) == y..Y1 + z..Z1 by SURREALO:def 10;
hence thesis by A67,Def5;
end;
A68: for ll being Surreal st ll in L_(SuY*SuZ)
ex rr being Surreal st rr in L_SUP & ll <= rr
proof
let ll be Surreal such that
A69: ll in L_(SuY*SuZ);
per cases by A63,A69,XBOOLE_0:def 3;
suppose ll in comp(L_SuY,SuY,SuZ,L_SuZ);
then consider a1,b1 be Surreal such that
A70: ll = a1*SuZ + SuY*b1 - a1*b1 & a1 in L_SuY & b1 in L_SuZ
by SURREALR:def 15;
consider Y1 be Element of Y,ey be positive Real such that
A71: a1 = Sum(r|Y1,Ny|Y1) + uReal.(r.Y1 - ey) * Ny..Y1 & Y1 in Y by A70;
consider Z1 be Element of Z,ez be positive Real such that
A72: b1 = Sum(s|Z1,Nz|Z1) + uReal.(s.Z1 - ez) * Nz..Z1 & Z1 in Z by A70;
set E = ey*ez;
succ Y1 c= dom r/\dom y by A5,A2,A71,ORDINAL1:21;
then
A73: a1 == Sum(r|succ Y1,Ny|succ Y1) + uReal.(- ey) * No_omega^(y..Y1)
by A71,Th102;
succ Z1 c= dom s/\dom z by A5,A2,A72,ORDINAL1:21;
then
A74: b1 == Sum(s|succ Z1,Nz|succ Z1) + uReal.(- ez) * No_omega^(z..Z1)
by A72,Th102;
consider O1 be Ordinal such that
A75: O1 in dom Uyz & Uyz..O1 == (y..Y1)+(z..Z1) by A71,A72,A64;
set sO1=succ O1;
take rr=Sum(PU|O1,NUyz|O1 ) + uReal.(PU.O1 - E/2) * NUyz..O1;
thus rr in L_SUP by A75;
set SS=Sum(PU|sO1,NUyz|sO1 ),
NN=No_omega^ ((y..Y1)+(z..Z1));
consider T be Surreal such that
A76: |.T.| infinitely< NN and
A77: SuY*b1 + a1*SuZ - b1*a1 == SS + T - uReal.((-ey)*(-ez))* NN
by A71,A72,A73,A74,A75,A14;
|.T.| infinitely< uReal.(E/2) * NN by A76,SURREALC:13;
then T <= |.T.| < uReal.(E/2) * NN by SURREALC:9,34;
then T < uReal.(E/2) * NN by SURREALO:4;
then SS+T < SS + uReal.(E/2) * NN by SURREALR:44;
then SS + T + - uReal.E* NN < SS + uReal.(E/2) * NN - uReal.E* NN
== SS + uReal.(E/2-E)*NN by Th30,SURREALR:44;
then SS + T + - uReal.E* NN < SS + uReal.(-E/2)*NN by SURREALO:4;
then
A78: ll < SS + uReal.(-E/2)*NN by A70,A77,SURREALO:4;
NN == No_omega^(Uyz..O1) by A75,SURREALC:24;
then uReal.(-E/2)*NN == uReal.(-E/2) * No_omega^(Uyz..O1)
by SURREALR:54;
then SS + uReal.(-E/2)*NN == SS + uReal.(-E/2)*No_omega^(Uyz..O1)
by SURREALR:66;
then
A79: ll < SS + uReal.(-E/2)*No_omega^(Uyz..O1) by A78,SURREALO:4;
sO1 c= dom PU/\dom Uyz by A60,A75,ORDINAL1:21;
then SS + uReal.(-E/2) * No_omega^(Uyz..O1) == rr by Th102;
hence thesis by A79,SURREALO:4;
end;
suppose ll in comp(R_SuY,SuY,SuZ,R_SuZ);
then consider a1,b1 be Surreal such that
A80: ll = a1*SuZ + SuY*b1 - a1*b1 & a1 in R_SuY & b1 in R_SuZ
by SURREALR:def 15;
consider Y1 be Element of Y,ey be positive Real such that
A81: a1 = Sum(r|Y1,Ny|Y1) + uReal.(r.Y1 + ey) * Ny..Y1 & Y1 in Y by A80;
consider Z1 be Element of Z,ez be positive Real such that
A82: b1 = Sum(s|Z1,Nz|Z1) + uReal.(s.Z1 + ez) * Nz..Z1 & Z1 in Z by A80;
set E = ey*ez;
succ Y1 c= dom r/\dom y by A5,A2,A81,ORDINAL1:21;
then
A83: a1 == Sum(r|succ Y1,Ny|succ Y1) + uReal.ey * No_omega^(y..Y1)
by A81,Th102;
succ Z1 c= dom s/\dom z by A5,A2,A82,ORDINAL1:21;
then
A84: b1 == Sum(s|succ Z1,Nz|succ Z1) + uReal.ez * No_omega^(z..Z1)
by A82,Th102;
consider O1 be Ordinal such that
A85: O1 in dom Uyz & Uyz..O1 == (y..Y1)+(z..Z1) by A81,A82,A64;
set sO1=succ O1;
take rr=Sum(PU|O1,NUyz|O1 ) + uReal.(PU.O1 - E/2) * NUyz..O1;
thus rr in L_SUP by A85;
set SS=Sum(PU|sO1,NUyz|sO1 ),
NN=No_omega^ ((y..Y1)+(z..Z1));
consider T be Surreal such that
A86: |.T.| infinitely< NN and
A87: SuY*b1 + a1*SuZ - b1*a1 == SS + T - uReal.(ey*ez)* NN
by A81,A82,A83,A84,A85,A14;
|.T.| infinitely< uReal.(E/2) * NN by A86,SURREALC:13;
then T <= |.T.| < uReal.(E/2) * NN by SURREALC:9,34;
then T < uReal.(E/2) * NN by SURREALO:4;
then SS+T < SS + uReal.(E/2) * NN by SURREALR:44;
then SS + T + - uReal.E* NN < SS + uReal.(E/2) * NN - uReal.E* NN
== SS + uReal.(E/2-E)*NN by Th30,SURREALR:44;
then SS + T + - uReal.E* NN < SS + uReal.(-E/2)*NN by SURREALO:4;
then
A88: ll < SS + uReal.(-E/2)*NN by A80,A87,SURREALO:4;
NN == No_omega^(Uyz..O1) by A85,SURREALC:24;
then uReal.(-E/2)*NN == uReal.(-E/2) * No_omega^(Uyz..O1)
by SURREALR:54;
then SS + uReal.(-E/2)*NN == SS + uReal.(-E/2)*No_omega^(Uyz..O1)
by SURREALR:66;
then
A89: ll < SS + uReal.(-E/2)*No_omega^(Uyz..O1) by A88,SURREALO:4;
sO1 c= dom PU/\dom Uyz by A60,A85,ORDINAL1:21;
then SS + uReal.(-E/2) * No_omega^(Uyz..O1) == rr by Th102;
hence thesis by A89,SURREALO:4;
end;
end;
A90: for O1 being Ordinal st O1 in dom Uyz
ex Y1,Z1 being Ordinal st Y1 in Y & Z1 in Z &
Uyz..O1 == (y..Y1)+(z..Z1)
proof
let O1 be Ordinal such that
A91: O1 in dom Uyz;
Uyz.O1 = Uyz..O1 by A91,Def5;
then Uyz..O1 in Unique_No (rng yY ++ rng zZ) by A8,A91,FUNCT_1:def 3;
then consider d be Surreal such that
A92: d in rng yY ++ rng zZ & Unique_No d = Uyz..O1 by Def8;
consider i,j be Surreal such that
A93: i in rng yY & j in rng zZ & d = i+j by A92,SURREALR:def 8;
consider Y1 be object such that
A94: Y1 in dom yY & yY.Y1=i by A93,FUNCT_1:def 3;
consider Z1 be object such that
A95: Z1 in dom zZ & zZ.Z1=j by A93,FUNCT_1:def 3;
reconsider Y1,Z1 as Ordinal by A94,A95;
take Y1,Z1;
thus Y1 in Y & Z1 in Z by A94,A95,A5,RELAT_1:62;
y..Y1 = y.Y1 = yY.Y1 & z..Z1 = z.Z1 = zZ.Z1
by A94,A95,Def5,A5,A6,FUNCT_1:47;
hence thesis by A92,A93,A94,A95,SURREALO:def 10;
end;
A96: for ll being Surreal st ll in R_SUP
ex rr being Surreal st rr in R_(SuY*SuZ) & rr <= ll
proof
let ll be Surreal such that
A97: ll in R_SUP;
consider O1 be Element of D,e such that
A98: ll=Sum(PU|O1,NUyz|O1) + uReal.(PU.O1 + e) * NUyz..O1 & O1 in D by A97;
consider Y1,Z1 be Ordinal such that
A99: Y1 in Y and
A100: Z1 in Z and
A101: Uyz..O1 == (y..Y1)+(z..Z1) by A90,A98;
set ey = e,
ez = 1/2,
E=ey*ez;
set a1 = Sum(r|Y1,Ny|Y1) + uReal.(r.Y1 - ey) * Ny..Y1;
set b1 = Sum(s|Z1,Nz|Z1) + uReal.(s.Z1 + ez) * Nz..Z1;
succ Y1 c= dom r/\dom y by A5,A2,A99,ORDINAL1:21;
then
A102: a1 == Sum(r|succ Y1,Ny|succ Y1) + uReal.(- ey) * No_omega^(y..Y1)
by Th102;
succ Z1 c= dom s/\dom z by A5,A2,A100,ORDINAL1:21;
then
A103: b1 == Sum(s|succ Z1,Nz|succ Z1) + uReal.(ez) * No_omega^(z..Z1)
by Th102;
take rr=SuY*b1 + a1*SuZ - b1*a1;
set sO1=succ O1;
set SS=Sum(PU|sO1,NUyz|sO1 ),
NN=No_omega^ ((y..Y1)+(z..Z1));
consider T be Surreal such that
A104: |.T.| infinitely< NN and
A105: rr == SS + T - uReal.((-ey)*ez)* NN by A98,A99,A100,A102,A103,A101,A14;
sO1 c= dom PU/\dom Uyz by A60,A98,ORDINAL1:21;
then
A106: SS + uReal.e * No_omega^(Uyz..O1) == ll by Th102,A98;
b1 in R_SuZ & a1 in L_SuY by A99,A100;
then rr in comp(L_SuY,SuY,SuZ,R_SuZ) by SURREALR:def 15;
hence rr in R_(SuY*SuZ) by A63,XBOOLE_0:def 3;
|.T.| infinitely< uReal.(e/2) * NN by A104,SURREALC:13;
then T <= |.T.| < uReal.(e/2) * NN by SURREALC:9,34;
then T < uReal.(e/2) * NN by SURREALO:4;
then SS+T < SS + uReal.(e/2) * NN by SURREALR:44;
then SS + T + - uReal.(-E)* NN < SS + uReal.(e/2) * NN - uReal.(-E)* NN
== SS + uReal.(e/2- - E)*NN by Th30,SURREALR:44;
then SS + T + - uReal.(-E)* NN < SS + uReal.e*NN by SURREALO:4;
then
A107: rr < SS + uReal.e*NN by A105,SURREALO:4;
NN == No_omega^(Uyz..O1) by A101,SURREALC:24;
then uReal.e*NN == uReal.e * No_omega^(Uyz..O1) by SURREALR:54;
then SS + uReal.e*NN == SS + uReal.e*No_omega^(Uyz..O1)
by SURREALR:66;
then rr < SS + uReal.e*No_omega^(Uyz..O1) by A107,SURREALO:4;
hence rr <= ll by A106,SURREALO:4;
end;
A108: for ll being Surreal st ll in R_(SuY*SuZ)
ex rr being Surreal st rr in R_SUP & rr<= ll
proof
let ll be Surreal such that
A109: ll in R_(SuY*SuZ);
per cases by A63,A109,XBOOLE_0:def 3;
suppose ll in comp(L_SuY,SuY,SuZ,R_SuZ);
then consider a1,b1 be Surreal such that
A110: ll = a1*SuZ + SuY*b1 - a1*b1 & a1 in L_SuY & b1 in R_SuZ
by SURREALR:def 15;
consider Y1 be Element of Y,ey be positive Real such that
A111: a1 = Sum(r|Y1,Ny|Y1) + uReal.(r.Y1 - ey) * Ny..Y1 & Y1 in Y by A110;
consider Z1 be Element of Z,ez be positive Real such that
A112: b1 = Sum(s|Z1,Nz|Z1) + uReal.(s.Z1 + ez) * Nz..Z1 & Z1 in Z by A110;
set E = ey*ez;
succ Y1 c= dom r/\dom y by A5,A2,A111,ORDINAL1:21;
then
A113: a1 == Sum(r|succ Y1,Ny|succ Y1) + uReal.(- ey) * No_omega^(y..Y1)
by A111,Th102;
succ Z1 c= dom s/\dom z by A5,A2,A112,ORDINAL1:21;
then
A114: b1 == Sum(s|succ Z1,Nz|succ Z1) + uReal.(ez) * No_omega^(z..Z1)
by A112,Th102;
consider O1 be Ordinal such that
A115: O1 in dom Uyz & Uyz..O1 == (y..Y1)+(z..Z1) by A111,A112,A64;
set sO1=succ O1;
take rr=Sum(PU|O1,NUyz|O1) + uReal.(PU.O1 + E/2) * NUyz..O1;
thus rr in R_SUP by A115;
set SS=Sum(PU|sO1,NUyz|sO1),
NN=No_omega^ ((y..Y1)+(z..Z1));
consider T be Surreal such that
A116: |.T.| infinitely< NN and
A117: SuY*b1 + a1*SuZ - b1*a1 == SS + T - uReal.((-ey)*ez)* NN
by A111,A112,A113,A114,A115,A14;
A118: - uReal.(-E)* NN == uReal.(E)* NN by Th33;
|.T.| infinitely< uReal.(E/2) * NN by A116,SURREALC:13;
then |.T.| < uReal.(E/2) * NN by SURREALC:9;
then T > - uReal.(E/2) * NN by SURREALC:52;
then SS+T > SS - uReal.(E/2) * NN by SURREALR:44;
then
A119: SS + T + - uReal.(-E)* NN > SS - uReal.(E/2) * NN + uReal.E* NN
by SURREALR:44,A118;
SS +- uReal.(E/2) * NN + uReal.E* NN
= SS + uReal.E* NN - uReal.(E/2) * NN by SURREALR:37;
then SS +- uReal.(E/2) * NN + uReal.E* NN
== SS + uReal.(E - E/2)*NN by Th30;
then SS + T + - uReal.(-E)* NN > SS + uReal.(E/2)*NN
by A119,SURREALO:4;
then
A120: ll > SS + uReal.(E/2)*NN by A110,A117,SURREALO:4;
NN == No_omega^(Uyz..O1) by A115,SURREALC:24;
then uReal.(E/2)*NN == uReal.(E/2) * No_omega^(Uyz..O1)
by SURREALR:54;
then SS + uReal.(E/2)*NN == SS + uReal.(E/2)*No_omega^(Uyz..O1)
by SURREALR:66;
then A121: ll > SS + uReal.(E/2)*No_omega^(Uyz..O1)
by A120,SURREALO:4;
sO1 c= dom PU/\dom Uyz by A60,A115,ORDINAL1:21;
then SS + uReal.(E/2) * No_omega^(Uyz..O1) == rr by Th102;
hence thesis by A121,SURREALO:4;
end;
suppose ll in comp(R_SuY,SuY,SuZ,L_SuZ);
then consider a1,b1 be Surreal such that
A122: ll = a1*SuZ + SuY*b1 - a1*b1 & a1 in R_SuY & b1 in L_SuZ
by SURREALR:def 15;
consider Y1 be Element of Y,ey be positive Real such that
A123: a1 = Sum(r|Y1,Ny|Y1) + uReal.(r.Y1 + ey) * Ny..Y1 & Y1 in Y by A122;
consider Z1 be Element of Z,ez be positive Real such that
A124: b1 = Sum(s|Z1,Nz|Z1) + uReal.(s.Z1 - ez) * Nz..Z1 & Z1 in Z by A122;
set E = ey*ez;
succ Y1 c= dom r/\dom y by A5,A2,A123,ORDINAL1:21;
then
A125: a1 == Sum(r|succ Y1,Ny|succ Y1) + uReal.(ey) * No_omega^(y..Y1)
by A123,Th102;
succ Z1 c= dom s/\dom z by A5,A2,A124,ORDINAL1:21;
then
A126: b1 == Sum(s|succ Z1,Nz|succ Z1) + uReal.(-ez) * No_omega^(z..Z1)
by A124,Th102;
consider O1 be Ordinal such that
A127: O1 in dom Uyz & Uyz..O1 == (y..Y1)+(z..Z1) by A123,A124,A64;
set sO1=succ O1;
take rr=Sum(PU|O1,NUyz|O1) + uReal.(PU.O1 + E/2) * NUyz..O1;
thus rr in R_SUP by A127;
set SS=Sum(PU|sO1,NUyz|sO1 ),
NN=No_omega^ ((y..Y1)+(z..Z1));
consider T be Surreal such that
A128: |.T.| infinitely< NN and
A129: SuY*b1 + a1*SuZ - b1*a1 == SS + T - uReal.(ey*(-ez))* NN
by A123,A124,A125,A126,A127,A14;
A130: - uReal.(-E)* NN == uReal.(E)* NN by Th33;
|.T.| infinitely< uReal.(E/2) * NN by A128,SURREALC:13;
then |.T.| < uReal.(E/2) * NN by SURREALC:9;
then T > - uReal.(E/2) * NN by SURREALC:52;
then SS+T > SS - uReal.(E/2) * NN by SURREALR:44;
then
A131: SS + T + - uReal.(-E)* NN > SS - uReal.(E/2) * NN + uReal.E* NN
by SURREALR:44,A130;
SS +- uReal.(E/2) * NN + uReal.E* NN
= SS + uReal.E* NN - uReal.(E/2) * NN by SURREALR:37;
then SS +- uReal.(E/2) * NN + uReal.E* NN ==
SS + uReal.(E - E/2)*NN by Th30;
then SS + T + - uReal.(-E)* NN > SS + uReal.(E/2)*NN
by A131,SURREALO:4;
then
A132: ll > SS + uReal.(E/2)*NN by A122,A129,SURREALO:4;
NN == No_omega^(Uyz..O1) by A127,SURREALC:24;
then uReal.(E/2)*NN == uReal.(E/2) * No_omega^(Uyz..O1)
by SURREALR:54;
then SS + uReal.(E/2)*NN == SS + uReal.(E/2)*No_omega^(Uyz..O1)
by SURREALR:66;
then
A133: ll > SS + uReal.(E/2)*No_omega^(Uyz..O1) by A132,SURREALO:4;
sO1 c= dom PU/\dom Uyz by A60,A127,ORDINAL1:21;
then SS + uReal.(E/2) * No_omega^(Uyz..O1) == rr by Th102;
hence thesis by A133,SURREALO:4;
end;
end;
A134: for ll being Surreal st ll in L_SUP ex rr being Surreal st
rr in L_(SuY*SuZ) & ll <= rr
proof
let ll be Surreal such that
A135: ll in L_SUP;
consider O1 be Element of D,e such that
A136: ll= Sum(PU|O1,NUyz|O1) + uReal.(PU.O1 - e) * NUyz..O1 & O1 in D
by A135;
consider Y1,Z1 be Ordinal such that
A137: Y1 in Y and
A138: Z1 in Z and
A139: Uyz..O1 == (y..Y1)+(z..Z1) by A90,A136;
set ey = e,
ez = 1/2,
E = ey*ez,
a1 = Sum(r|Y1,Ny|Y1) + uReal.(r.Y1 - ey) * Ny..Y1,
b1 = Sum(s|Z1,Nz|Z1) + uReal.(s.Z1 - ez) * Nz..Z1;
succ Y1 c= dom r/\dom y by A5,A2,A137,ORDINAL1:21;
then
A140: a1 == Sum(r|succ Y1,Ny|succ Y1) + uReal.(- ey) * No_omega^(y..Y1)
by Th102;
succ Z1 c= dom s/\dom z by A5,A2,A138,ORDINAL1:21;
then
A141: b1 == Sum(s|succ Z1,Nz|succ Z1) + uReal.(-ez) * No_omega^(z..Z1)
by Th102;
take rr=SuY*b1 + a1*SuZ - b1*a1;
set sO1=succ O1;
set SS=Sum(PU|sO1,NUyz|sO1 ),
NN=No_omega^ ((y..Y1)+(z..Z1));
consider T be Surreal such that
A142: |.T.| infinitely< NN and
A143: rr == SS + T - uReal.((-ey)*(-ez))* NN
by A136,A137,A138,A140,A141,A139,A14;
sO1 c= dom PU/\dom Uyz by A60,A136,ORDINAL1:21;
then
A144: SS + uReal.(-e) * No_omega^(Uyz..O1) == ll by Th102,A136;
b1 in L_SuZ & a1 in L_SuY by A137,A138;
then rr in comp(L_SuY,SuY,SuZ,L_SuZ) by SURREALR:def 15;
hence rr in L_(SuY*SuZ) by A63,XBOOLE_0:def 3;
A145: - uReal.(- - E)* NN == uReal.(-E)* NN by Th33;
|.T.| infinitely< uReal.(e/2) * NN by A142,SURREALC:13;
then |.T.| < uReal.(e/2) * NN by SURREALC:9;
then T > - uReal.(e/2) * NN by SURREALC:52;
then SS+T > SS + - uReal.(e/2) * NN by SURREALR:44;
then
A146: SS + T + - uReal.E* NN > SS - uReal.(e/2) * NN + uReal.(-E)* NN
by SURREALR:44,A145;
SS +- uReal.(e/2) * NN + uReal.(-E)* NN
= SS + uReal.(-E)* NN - uReal.(e/2) * NN by SURREALR:37;
then SS +- uReal.(e/2) * NN + uReal.(-E)* NN ==
SS + uReal.(-E - e/2)*NN by Th30;
then SS + T + - uReal.E* NN > SS + uReal.(-e)*NN by A146,SURREALO:4;
then
A147: rr > SS + uReal.(-e)*NN by A143,SURREALO:4;
NN == No_omega^(Uyz..O1) by A139,SURREALC:24;
then uReal.(-e)*NN == uReal.(-e) * No_omega^(Uyz..O1)
by SURREALR:54;
then SS + uReal.(-e)*NN == SS + uReal.(-e)*No_omega^(Uyz..O1)
by SURREALR:66;
then rr > SS + uReal.(-e)*No_omega^(Uyz..O1) by A147,SURREALO:4;
then rr > ll by A144,SURREALO:4;
hence rr >= ll by SURREALO:6;
end;
SUP = [L_SUP,R_SUP] & SuY*SuZ = [L_(SuY*SuZ), R_(SuY*SuZ)];
then SuY*SuZ == SUP by A68,A96,A108,A134,SURREAL0:44;
then
A148: SuY*SuZ == Sum (P, Nyz) by A60,A13,A62,SURREALO:4;
Sum(r|Y,Ny|Y) * Sum(s|Z,Nz|Z) == SuY*SuZ by Th29,A10,A11;
hence thesis by A148,SURREALO:4;
end;
suppose not Y is limit_ordinal;
then consider Y1 be Ordinal such that
A149: Y = succ Y1 by ORDINAL1:29;
A150: No_omega^ zZ = Nz|Z & Ny|Y = No_omega^ yY & Ny|Y1 = No_omega^ (y|Y1)
by SURREALC:88;
Y1 c= Y by A149,ORDINAL3:1; then
A156: Y1 c= dom y by A5;
A152: rY|Y1 = r|Y1 & yY|Y1 = y|Y1 by A149,ORDINAL3:1,RELAT_1:74;
A153: Y c= dom r/\dom y by A5,A2;
A154: Y c= S by A1,A5;
A155: dom zZ c= T by A5,A6,A1;
A157: Y1 in dom y by A5,A149,ORDINAL1:6;
then
A158: y.Y1=y..Y1 by Def5;
A159: rY/^Y1 = <%r.Y1%> & yY/^Y1 = <%y..Y1%> by A158,A5,A149,A2,Th9;
y.Y1 in rng y by A157,FUNCT_1:def 3;
then
A160:{y..Y1} c= rng y by A158,ZFMISC_1:31;
{y..Y1}++rng zZ c= rng y ++ rng z by A160,Th34;
then Unique_No ({y..Y1}++rng zZ) c= Unique_No (rng y ++ rng z) by Th48;
then
A161: Unique_No ({y..Y1}++rng zZ) c= rng yz by A1;
Y1 (+)Z in O by A5,A149,ORDINAL1:6,ORDINAL7:94;
then
A162:Sum(r|Y1,Ny|Y1) * Sum(sZ,Nz|Z)==
Sum (Sum(y|Y1,zZ,yz,r|Y1,sZ,S,T), Nyz) by A4,A5,A156;
A163: Sum(Sum(<%y..Y1%>,zZ,yz,<%r.Y1%>,sZ,S,T), Nyz)
== uReal.(r.Y1) * No_omega^ (y..Y1) *Sum(sZ, No_omega^ zZ)
by A161,A6,A155,Th95;
Sum (Sum(yY|Y1,zZ,yz,rY|Y1,sZ,S,T), Nyz) +
Sum(Sum(yY /^ Y1,zZ,yz,rY/^Y1,sZ,S,T), Nyz)
== Sum(r|Y1,Ny|Y1) * Sum(sZ,Nz|Z) +
uReal.(r.Y1) * No_omega^ (y..Y1) *Sum(sZ, Nz|Z)
== (Sum(r|Y1,Ny|Y1) + uReal.(r.Y1) * No_omega^ (y..Y1)) * Sum(sZ, Nz|Z)
by A162,A163,A152,A159,A150,SURREALR:66,SURREALR:67;
then Sum (Sum(yY|Y1,zZ,yz,rY|Y1,sZ,S,T), Nyz) +
Sum(Sum(yY /^ Y1,zZ,yz,rY/^Y1,sZ,S,T), Nyz)
== (Sum(r|Y1,Ny|Y1) + uReal.(r.Y1) * No_omega^ (y..Y1)) * Sum(sZ, Nz|Z)
== Sum(r|Y,Ny|Y) * Sum(sZ, Nz|Z)
by SURREALO:4,SURREALR:54,A153,A150,A149,Th64;
then
A164: Sum (Sum(yY|Y1,zZ,yz,rY|Y1,sZ,S,T), Nyz) +
Sum(Sum(yY /^ Y1,zZ,yz,rY/^Y1,sZ,S,T), Nyz)
== Sum(r|Y,Ny|Y) * Sum(sZ, Nz|Z) by SURREALO:4;
Sum (Sum(yY,zZ,yz,rY,s|Z,S,T), Nyz) ==
Sum(Sum(yY|Y1,zZ,yz,rY|Y1,sZ,S,T), Nyz) +
Sum(Sum(yY /^ Y1,zZ,yz,rY/^Y1,sZ,S,T), Nyz)
by A149,ORDINAL3:1,A154,A155,A6,Th99;
hence thesis by A164,SURREALO:4;
end;
suppose not Z is limit_ordinal;
then consider Z1 be Ordinal such that
A165: Z = succ Z1 by ORDINAL1:29;
A166: No_omega^ zZ = Nz|Z &
Ny|Y = No_omega^ yY & Nz|Z1 = No_omega^ (z|Z1) by SURREALC:88;
A167: Z1 c= Z by A165,ORDINAL3:1;
A168: sZ|Z1 = s|Z1 & zZ|Z1 = z|Z1 by A165,ORDINAL3:1,RELAT_1:74;
A169: Z c= dom s/\dom z by A5,A2;
A170: Z c= T by A1,A5;
A171: dom yY c= S by A6,A5,A1;
A172: Z1 c= dom z by A167,A5;
A173: Z1 in dom z by A5,A165,ORDINAL1:6;
then
A174: z.Z1=z..Z1 by Def5;
A175: sZ/^Z1 = <%s.Z1%> & zZ/^Z1 = <%z..Z1%> by A174,A5,A165,A2,Th9;
z.Z1 in rng z by A173,FUNCT_1:def 3;
then
A176:{z..Z1} c= rng z by A174,ZFMISC_1:31;
{z..Z1}++rng yY c= rng y ++ rng z by A176,Th34;
then Unique_No ({z..Z1}++rng yY) c= Unique_No (rng y ++ rng z) by Th48;
then
A177: Unique_No ({z..Z1}++rng yY) c= rng yz by A1;
Y (+)Z1 in O by A5,A165,ORDINAL1:6,ORDINAL7:94;
then
A178: Sum(rY,Ny|Y) * Sum(s|Z1,Nz|Z1) ==
Sum (Sum(yY,z|Z1,yz,rY,s|Z1,S,T), Nyz) by A4,A5,A172;
A179: Sum(Sum(yY,<%z..Z1%>,yz,rY,<%s.Z1%>,S,T), Nyz)
== uReal.(s.Z1) * No_omega^ (z..Z1) *Sum(rY, No_omega^ yY)
by A177,A6,A171,Th96;
Sum (Sum(yY,z|Z1,yz,rY,s|Z1,S,T), Nyz)+
Sum(Sum(yY,zZ/^Z1,yz,rY,sZ/^Z1,S,T), Nyz)
== Sum(rY,Ny|Y) * Sum(s|Z1,Nz|Z1) +
uReal.(s.Z1) * No_omega^ (z..Z1) *Sum(rY, No_omega^ yY)
== (Sum(s|Z1,Nz|Z1) + uReal.(s.Z1) * No_omega^ (z..Z1)) * Sum(rY,Ny|Y)
by A178,A179,A175,A166,SURREALR:66,SURREALR:67;
then Sum (Sum(yY,z|Z1,yz,rY,s|Z1,S,T), Nyz)+
Sum(Sum(yY,zZ/^Z1,yz,rY,sZ/^Z1,S,T), Nyz)
== (Sum(s|Z1,Nz|Z1) + uReal.(s.Z1) * No_omega^ (z..Z1)) * Sum(rY,Ny|Y)
== Sum(r|Y,Ny|Y) * Sum(sZ, Nz|Z)
by SURREALO:4,SURREALR:54,A169,A166,A165,Th64;
then
A180: Sum (Sum(yY,zZ|Z1,yz,rY,sZ|Z1,S,T), Nyz)+
Sum(Sum(yY,zZ/^Z1,yz,rY,sZ/^Z1,S,T), Nyz)
== Sum(r|Y,Ny|Y) * Sum(sZ, Nz|Z) by A168,SURREALO:4;
Sum (Sum(yY,zZ,yz,rY,s|Z,S,T), Nyz) ==
Sum(Sum(yY,zZ|Z1,yz,rY ,sZ|Z1,S,T), Nyz) +
Sum(Sum(yY,zZ /^ Z1,yz,rY,sZ/^Z1,S,T), Nyz)
by A165,ORDINAL3:1,A170,A171,A6,Th100;
hence thesis by A180,SURREALO:4;
end;
end;
A181:dom Ny = dom y & dom Nz=dom z by SURREALC:def 22;
for A being Ordinal holds P[A] from ORDINAL1:sch 2(A3);
then P[dom y (+)(dom z)];
then Sum(r|dom y,Ny|dom y) * Sum(s|dom z,Nz|dom z)==
Sum (Sum(y|dom y,z|dom z,yz,r|dom y,s|dom z,S,T), Nyz);
hence thesis by A181,A2;
end;